csit/suites/netconf/CRUD/CRUD.robot

   1 *** Settings ***
   2 Documentation       netconf-connector CRUD test suite.
   3 ...
   4 ...                 Copyright (c) 2015 Cisco Systems, Inc. and others. All rights reserved.
   5 ...
   6 ...                 This program and the accompanying materials are made available under the
   7 ...                 terms of the Eclipse Public License v1.0 which accompanies this distribution,
   8 ...                 and is available at http://www.eclipse.org/legal/epl-v10.html
   9 ...
  10 ...
  11 ...                 Perform basic operations (Create, Read, Update and Delete or CRUD) on device
  12 ...                 data mounted onto a netconf connector and see if they work.
  13 ...
  14 ...                 FIXME: Replace the BuiltIn.Should_[Not_]Contain instances in the test cases
  15 ...                 that check the car list related data with calls to keywords of a Resource
  16 ...                 aimed at getting interesting pieces of data from the XML files and checking
  17 ...                 them against expected data sets. See MDSAL/northbound.robot suite for
  18 ...                 additional information.
  19
  20 Library             Collections
  21 Library             RequestsLibrary
  22 Library             OperatingSystem
  23 Library             String
  24 Library             SSHLibrary    timeout=10s
  25 Resource            ${CURDIR}/../../../libraries/CompareStream.robot
  26 Resource            ${CURDIR}/../../../libraries/FailFast.robot
  27 Resource            ${CURDIR}/../../../libraries/NetconfKeywords.robot
  28 Resource            ${CURDIR}/../../../libraries/SetupUtils.robot
  29 Resource            ${CURDIR}/../../../libraries/TemplatedRequests.robot
  30 Variables           ${CURDIR}/../../../variables/Variables.py
  31
  32 Suite Setup         Setup_Everything
  33 Suite Teardown      Teardown_Everything
  34 Test Setup          SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
  35
  36
  37 *** Variables ***
  38 ${directory_with_template_folders}      ${CURDIR}/../../../variables/netconf/CRUD
  39 ${device_name}                          netconf-test-device
  40 ${device_type}                          full-uri-device
  41 ${USE_NETCONF_CONNECTOR}                ${False}
  42
  43
  44 *** Test Cases ***
  45 Start_Testtool
  46     [Documentation]    Deploy and start test tool, then wait for all its devices to become online.
  47     [Tags]    odlmicro_ign
  48     NetconfKeywords.Install_And_Start_Testtool
  49     ...    device-count=1
  50     ...    schemas=${CURDIR}/../../../variables/netconf/CRUD/schemas
  51     ...    mdsal=true
  52
  53 Check_Device_Is_Not_Configured_At_Beginning
  54     [Documentation]    Sanity check making sure our device is not there. Fail if found.
  55     [Tags]    critical
  56     NetconfKeywords.Check_Device_Has_No_Netconf_Connector    ${device_name}
  57
  58 Configure_Device_On_Netconf
  59     [Documentation]    Make request to configure a testtool device on Netconf connector.
  60     [Tags]    critical
  61     NetconfKeywords.Configure_Device_In_Netconf    ${device_name}    device_type=${device_type}    http_timeout=2
  62
  63 Check_ODL_Has_Netconf_Connector_For_Device
  64     [Documentation]    Get the list of configured devices and search for our device there. Fail if not found.
  65     [Tags]    critical
  66     BuiltIn.Wait_Until_Keyword_Succeeds    5 sec    1 sec    Count_Netconf_Connectors
  67
  68 Wait_For_Device_To_Become_Connected
  69     [Documentation]    Wait until the device becomes available through Netconf.
  70     NetconfKeywords.Wait_Device_Connected    ${device_name}
  71
  72 Check_Device_Data_Is_Empty
  73     [Documentation]    Get the device data and make sure it is empty.
  74     Run_Keyword_If_Less_Than_Neon    Check_Config_Data    <data xmlns\="${ODL_NETCONF_NAMESPACE}"></data>
  75     Run_Keyword_If_At_Least_Neon    Check_Config_Data    <data xmlns\="${ODL_NETCONF_NAMESPACE}"/>
  76
  77 Create_Device_Data_Label_Via_Xml
  78     [Documentation]    Send a sample test data label into the device and check that the request went OK.
  79     ${template_as_string}=    BuiltIn.Create_Dictionary    DEVICE_NAME=${device_name}
  80     TemplatedRequests.Post_As_Xml_Templated    ${directory_with_template_folders}${/}dataorig    ${template_as_string}
  81
  82 Check_Device_Data_Label_Is_Created
  83     [Documentation]    Get the device data label and make sure it contains the created content.
  84     Check_Config_Data
  85     ...    <data xmlns="${ODL_NETCONF_NAMESPACE}"><cont xmlns="urn:opendaylight:test:netconf:crud"><l>Content</l></cont></data>
  86
  87 Modify_Device_Data_Label_Via_Xml
  88     [Documentation]    Send a request to change the sample test data label and check that the request went OK.
  89     ${template_as_string}=    BuiltIn.Create_Dictionary    DEVICE_NAME=${device_name}
  90     TemplatedRequests.Put_As_Xml_Templated    ${directory_with_template_folders}${/}datamod1    ${template_as_string}
  91
  92 Check_Device_Data_Label_Is_Modified
  93     [Documentation]    Get the device data label and make sure it contains the modified content.
  94     Check_Config_Data
  95     ...    <data xmlns="${ODL_NETCONF_NAMESPACE}"><cont xmlns="urn:opendaylight:test:netconf:crud"><l>Modified Content</l></cont></data>
  96
  97 Deconfigure_Device_From_Netconf_Temporarily
  98     [Documentation]    Make request to deconfigure the testtool device on Netconf connector.
  99     ...    This is the first part of the "configure/deconfigure" cycle of the device
 100     ...    The purpose of cycling the device like this is to see that the configuration
 101     ...    data was really stored in the device.
 102     [Tags]    critical
 103     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 104     NetconfKeywords.Remove_Device_From_Netconf    ${device_name}
 105
 106 Wait_For_Device_To_Be_Gone
 107     [Documentation]    Wait for the device to completely disappear.
 108     NetconfKeywords.Wait_Device_Fully_Removed    ${device_name}
 109
 110 Configure_The_Device_Back
 111     [Documentation]    Configure the device again.
 112     ...    This is the second step of the device configuration.
 113     [Tags]    critical
 114     NetconfKeywords.Configure_Device_In_Netconf    ${device_name}    device_type=${device_type}
 115
 116 Wait_For_Device_To_Reconnect
 117     [Documentation]    Wait until the device becomes available through Netconf.
 118     NetconfKeywords.Wait_Device_Connected    ${device_name}
 119
 120 Check_Modified_Device_Data_Is_Still_There
 121     [Documentation]    Get the device data and make sure it contains the created content.
 122     BuiltIn.Wait_Until_Keyword_Succeeds
 123     ...    60s
 124     ...    1s
 125     ...    Check_Config_Data
 126     ...    <data xmlns="${ODL_NETCONF_NAMESPACE}"><cont xmlns="urn:opendaylight:test:netconf:crud"><l>Modified Content</l></cont></data>
 127
 128 Modify_Device_Data_Again
 129     [Documentation]    Send a request to change the sample test data and check that the request went OK.
 130     ${template_as_string}=    BuiltIn.Create_Dictionary    DEVICE_NAME=${device_name}
 131     TemplatedRequests.Put_As_Xml_Templated    ${DIRECTORY_WITH_TEMPLATE_FOLDERS}${/}datamod2    ${template_as_string}
 132
 133 Check_Device_Data_Is_Modified_Again
 134     [Documentation]    Get the device data and make sure it contains the created content.
 135     Check_Config_Data
 136     ...    <data xmlns="${ODL_NETCONF_NAMESPACE}"><cont xmlns="urn:opendaylight:test:netconf:crud"><l>Another Modified Content</l></cont></data>
 137
 138 Modify_Device_Data_Label_Via_Json
 139     [Documentation]    Send a JSON request to change the sample test data label and check that the request went OK.
 140     ${template_as_string}=    BuiltIn.Create_Dictionary    DEVICE_NAME=${device_name}
 141     TemplatedRequests.Put_As_Json_Templated
 142     ...    ${directory_with_template_folders}${/}datamodjson
 143     ...    ${template_as_string}
 144
 145 Check_Device_Data_Label_Is_Modified_Via_Json
 146     [Documentation]    Get the device data label as XML and make sure it matches the content posted as JSON in the previous case.
 147     Check_Config_Data
 148     ...    <data xmlns="${ODL_NETCONF_NAMESPACE}"><cont xmlns="urn:opendaylight:test:netconf:crud"><l>Content Modified via JSON</l></cont></data>
 149
 150 Create_Car_List
 151     [Documentation]    Send a request to create a list of cars in the sample test data label and check that the request went OK.
 152     ${template_as_string}=    BuiltIn.Create_Dictionary    DEVICE_NAME=${device_name}
 153     TemplatedRequests.Post_As_Xml_Templated    ${directory_with_template_folders}${/}cars    ${template_as_string}
 154
 155 Check_Car_List_Created
 156     [Documentation]    Get the device data label as XML and make sure it matches the content posted as JSON in the previous case.
 157     ${data}=    Get_Config_Data
 158     BuiltIn.Should_Contain    ${data}    <id>KEEP</id>
 159     BuiltIn.Should_Not_Contain    ${data}    <id>SMALL</id>
 160     BuiltIn.Should_Not_Contain    ${data}    <model>Isetta</model>
 161     BuiltIn.Should_Not_Contain    ${data}    <manufacturer>BMW</manufacturer>
 162     BuiltIn.Should_Not_Contain    ${data}    <year>1953</year>
 163     BuiltIn.Should_Not_Contain    ${data}    <category>microcar</category>
 164     BuiltIn.Should_Not_Contain    ${data}    <id>TOYOTA</id>
 165     BuiltIn.Should_Not_Contain    ${data}    <model>Camry</model>
 166     BuiltIn.Should_Not_Contain    ${data}    <manufacturer>Toyota</manufacturer>
 167     BuiltIn.Should_Not_Contain    ${data}    <year>1982</year>
 168     BuiltIn.Should_Not_Contain    ${data}    <category>sedan</category>
 169
 170 Add_Device_Data_Item_1_Via_XML_Post
 171     [Documentation]    Send a request to create a data item in the test list and check that the request went OK.
 172     ${template_as_string}=    BuiltIn.Create_Dictionary    DEVICE_NAME=${device_name}
 173     TemplatedRequests.Post_As_Xml_Templated    ${directory_with_template_folders}${/}item1    ${template_as_string}
 174
 175 Check_Item1_Is_Created
 176     [Documentation]    Get the device data as XML and make sure it matches the content posted as JSON in the previous case.
 177     ${data}=    Get_Config_Data
 178     BuiltIn.Should_Contain    ${data}    <id>SMALL</id>
 179     BuiltIn.Should_Contain    ${data}    <model>Isetta</model>
 180     BuiltIn.Should_Contain    ${data}    <manufacturer>BMW</manufacturer>
 181     BuiltIn.Should_Contain    ${data}    <year>1953</year>
 182     BuiltIn.Should_Contain    ${data}    <category>microcar</category>
 183     BuiltIn.Should_Not_Contain    ${data}    <id>TOYOTA</id>
 184     BuiltIn.Should_Not_Contain    ${data}    <model>Camry</model>
 185     BuiltIn.Should_Not_Contain    ${data}    <manufacturer>Toyota</manufacturer>
 186     BuiltIn.Should_Not_Contain    ${data}    <year>1982</year>
 187     BuiltIn.Should_Not_Contain    ${data}    <category>sedan</category>
 188
 189 Add_Device_Data_Item_2_Via_JSON_Post
 190     [Documentation]    Send a JSON request to change the sample test data and check that the request went OK.
 191     ${template_as_string}=    BuiltIn.Create_Dictionary    DEVICE_NAME=${device_name}
 192     TemplatedRequests.Post_As_Json_Templated    ${directory_with_template_folders}${/}item2    ${template_as_string}
 193
 194 Check_Item2_Is_Created
 195     [Documentation]    Get the device data as XML and make sure it matches the content posted as JSON in the previous case.
 196     ${data}=    Get_Config_Data
 197     BuiltIn.Should_Contain    ${data}    <id>SMALL</id>
 198     BuiltIn.Should_Contain    ${data}    <model>Isetta</model>
 199     BuiltIn.Should_Contain    ${data}    <manufacturer>BMW</manufacturer>
 200     BuiltIn.Should_Contain    ${data}    <year>1953</year>
 201     BuiltIn.Should_Contain    ${data}    <category>microcar</category>
 202     BuiltIn.Should_Contain    ${data}    <id>TOYOTA</id>
 203     BuiltIn.Should_Contain    ${data}    <model>Camry</model>
 204     BuiltIn.Should_Contain    ${data}    <manufacturer>Toyota</manufacturer>
 205     BuiltIn.Should_Contain    ${data}    <year>1982</year>
 206     BuiltIn.Should_Contain    ${data}    <category>sedan</category>
 207
 208 Delete_Device_Data
 209     [Documentation]    Send a request to delete the sample test data on the device and check that the request went OK.
 210     ${template_as_string}=    BuiltIn.Create_Dictionary    DEVICE_NAME=${device_name}
 211     TemplatedRequests.Delete_Templated    ${directory_with_template_folders}${/}datamod1    ${template_as_string}
 212     TemplatedRequests.Delete_Templated    ${directory_with_template_folders}${/}item1    ${template_as_string}
 213
 214 Check_Device_Data_Is_Deleted
 215     [Documentation]    Get the device data and make sure it is empty again.
 216     Run_Keyword_If_Less_Than_Neon    Check_Config_Data    <data xmlns\="${ODL_NETCONF_NAMESPACE}"></data>
 217     Run_Keyword_If_At_Least_Neon    Check_Config_Data    <data xmlns\="${ODL_NETCONF_NAMESPACE}"/>
 218
 219 Deconfigure_Device_From_Netconf
 220     [Documentation]    Make request to deconfigure the testtool device on Netconf connector.
 221     [Tags]    critical
 222     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 223     NetconfKeywords.Remove_Device_From_Netconf    ${device_name}
 224
 225 Check_Device_Going_To_Be_Gone_After_Deconfiguring
 226     [Documentation]    Check that the device is really going to be gone. Fail
 227     ...    if found after one minute. This is an expected behavior as the
 228     ...    delete request is sent to the config subsystem which then triggers
 229     ...    asynchronous destruction of the netconf connector referring to the
 230     ...    device and the device's data. This test makes sure this
 231     ...    asynchronous operation does not take unreasonable amount of time
 232     ...    by making sure that both the netconf connector and the device's
 233     ...    data is gone before reporting success.
 234     [Tags]    critical
 235     NetconfKeywords.Wait_Device_Fully_Removed    ${device_name}
 236
 237
 238 *** Keywords ***
 239 Setup_Everything
 240     [Documentation]    Initialize SetupUtils. Setup everything needed for the test cases.
 241     # Setup resources used by the suite.
 242     SetupUtils.Setup_Utils_For_Setup_And_Teardown
 243     RequestsLibrary.Create_Session    operational    http://${ODL_SYSTEM_IP}:${RESTCONFPORT}${REST_API}    auth=${AUTH}
 244     NetconfKeywords.Setup_Netconf_Keywords
 245     ${device_type}=    BuiltIn.Set_Variable_If
 246     ...    """${USE_NETCONF_CONNECTOR}""" == """True"""
 247     ...    default
 248     ...    ${device_type}
 249     BuiltIn.Set_Suite_Variable    ${device_type}
 250
 251 Teardown_Everything
 252     [Documentation]    Teardown the test infrastructure, perform cleanup and release all resources.
 253     RequestsLibrary.Delete_All_Sessions
 254     BuiltIn.Run_Keyword_And_Ignore_Error    NetconfKeywords.Stop_Testtool
 255
 256 Get_Config_Data
 257     [Documentation]    Get and return the config data from the device.
 258     ${url}=    Builtin.Set_Variable
 259     ...    ${REST_API}/network-topology:network-topology/topology=topology-netconf/node=${device_name}/yang-ext:mount?content=config
 260     ${data}=    TemplatedRequests.Get_As_Xml_From_Uri    ${url}
 261     RETURN    ${data}
 262
 263 Check_Config_Data
 264     [Arguments]    ${expected}    ${contains}=False
 265     ${data}=    Get_Config_Data
 266     IF    not ${contains}
 267         BuiltIn.Should_Be_Equal_As_Strings    ${data}    ${expected}
 268     END
 269     IF    ${contains}    BuiltIn.Should_Contain    ${data}    ${expected}
 270
 271 Count_Netconf_Connectors
 272     ${count}=    NetconfKeywords.Count_Netconf_Connectors_For_Device    ${device_name}
 273     Builtin.Should_Be_Equal_As_Strings    ${count}    1