csit/suites/netconf/CRUD/CRUD.robot

   1 *** Settings ***
   2 Documentation     netconf-connector CRUD test suite.
   3 ...
   4 ...               Copyright (c) 2015 Cisco Systems, Inc. and others. All rights reserved.
   5 ...
   6 ...               This program and the accompanying materials are made available under the
   7 ...               terms of the Eclipse Public License v1.0 which accompanies this distribution,
   8 ...               and is available at http://www.eclipse.org/legal/epl-v10.html
   9 ...
  10 ...
  11 ...               Perform basic operations (Create, Read, Update and Delete or CRUD) on device
  12 ...               data mounted onto a netconf connector and see if they work.
  13 ...
  14 ...               FIXME: Replace the BuiltIn.Should_[Not_]Contain instances in the test cases
  15 ...               that check the car list related data with calls to keywords of a Resource
  16 ...               aimed at getting interesting pieces of data from the XML files and checking
  17 ...               them against expected data sets. See MDSAL/northbound.robot suite for
  18 ...               additional information.
  19 Suite Setup       Setup_Everything
  20 Suite Teardown    Teardown_Everything
  21 Test Setup        SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
  22 Library           Collections
  23 Library           RequestsLibrary
  24 Library           OperatingSystem
  25 Library           String
  26 Library           SSHLibrary    timeout=10s
  27 Resource          ${CURDIR}/../../../libraries/FailFast.robot
  28 Resource          ${CURDIR}/../../../libraries/NetconfKeywords.robot
  29 Resource          ${CURDIR}/../../../libraries/SetupUtils.robot
  30 Resource          ${CURDIR}/../../../libraries/TemplatedRequests.robot
  31 Resource          ${CURDIR}/../../../libraries/Utils.robot
  32 Variables         ${CURDIR}/../../../variables/Variables.py
  33
  34 *** Variables ***
  35 ${directory_with_template_folders}    ${CURDIR}/../../../variables/netconf/CRUD
  36 ${device_name}    netconf-test-device
  37 ${device_type}    full-uri-device
  38 ${USE_NETCONF_CONNECTOR}    ${False}
  39
  40 *** Test Cases ***
  41 Start_Testtool
  42     [Documentation]    Deploy and start test tool, then wait for all its devices to become online.
  43     NetconfKeywords.Install_And_Start_Testtool    device-count=1    schemas=${CURDIR}/../../../variables/netconf/CRUD/schemas
  44
  45 Check_Device_Is_Not_Configured_At_Beginning
  46     [Documentation]    Sanity check making sure our device is not there. Fail if found.
  47     [Tags]    critical
  48     NetconfKeywords.Check_Device_Has_No_Netconf_Connector    ${device_name}
  49
  50 Configure_Device_On_Netconf
  51     [Documentation]    Make request to configure a testtool device on Netconf connector.
  52     [Tags]    critical
  53     NetconfKeywords.Configure_Device_In_Netconf    ${device_name}    device_type=${device_type}
  54
  55 Check_ODL_Has_Netconf_Connector_For_Device
  56     [Documentation]    Get the list of configured devices and search for our device there. Fail if not found.
  57     [Tags]    critical
  58     ${count}    NetconfKeywords.Count_Netconf_Connectors_For_Device    ${device_name}
  59     Builtin.Should_Be_Equal_As_Strings    ${count}    1
  60
  61 Wait_For_Device_To_Become_Connected
  62     [Documentation]    Wait until the device becomes available through Netconf.
  63     NetconfKeywords.Wait_Device_Connected    ${device_name}
  64
  65 Check_Device_Data_Is_Empty
  66     [Documentation]    Get the device data and make sure it is empty.
  67     Check_Config_Data    <data xmlns="${ODL_NETCONF_NAMESPACE}"></data>
  68
  69 Create_Device_Data_Label_Via_Xml
  70     [Documentation]    Send a sample test data label into the device and check that the request went OK.
  71     ${template_as_string}=    BuiltIn.Set_Variable    {'DEVICE_NAME': '${device_name}'}
  72     TemplatedRequests.Post_As_Xml_Templated    ${directory_with_template_folders}${/}dataorig    ${template_as_string}
  73
  74 Check_Device_Data_Label_Is_Created
  75     [Documentation]    Get the device data label and make sure it contains the created content.
  76     Check_Config_Data    <data xmlns="${ODL_NETCONF_NAMESPACE}"><cont xmlns="urn:opendaylight:test:netconf:crud"><l>Content</l></cont></data>
  77
  78 Modify_Device_Data_Label_Via_Xml
  79     [Documentation]    Send a request to change the sample test data label and check that the request went OK.
  80     ${template_as_string}=    BuiltIn.Set_Variable    {'DEVICE_NAME': '${device_name}'}
  81     TemplatedRequests.Put_As_Xml_Templated    ${directory_with_template_folders}${/}datamod1    ${template_as_string}
  82
  83 Check_Device_Data_Label_Is_Modified
  84     [Documentation]    Get the device data label and make sure it contains the modified content.
  85     Check_Config_Data    <data xmlns="${ODL_NETCONF_NAMESPACE}"><cont xmlns="urn:opendaylight:test:netconf:crud"><l>Modified Content</l></cont></data>
  86
  87 Deconfigure_Device_From_Netconf_Temporarily
  88     [Documentation]    Make request to deconfigure the testtool device on Netconf connector.
  89     ...    This is the first part of the "configure/deconfigure" cycle of the device
  90     ...    The purpose of cycling the device like this is to see that the configuration
  91     ...    data was really stored in the device.
  92     [Tags]    critical
  93     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
  94     NetconfKeywords.Remove_Device_From_Netconf    ${device_name}
  95
  96 Wait_For_Device_To_Be_Gone
  97     [Documentation]    Wait for the device to completely disappear.
  98     NetconfKeywords.Wait_Device_Fully_Removed    ${device_name}
  99
 100 Configure_The_Device_Back
 101     [Documentation]    Configure the device again.
 102     ...    This is the second step of the device configuration.
 103     [Tags]    critical
 104     NetconfKeywords.Configure_Device_In_Netconf    ${device_name}    device_type=${device_type}
 105
 106 Wait_For_Device_To_Reconnect
 107     [Documentation]    Wait until the device becomes available through Netconf.
 108     NetconfKeywords.Wait_Device_Connected    ${device_name}
 109
 110 Check_Modified_Device_Data_Is_Still_There
 111     [Documentation]    Get the device data and make sure it contains the created content.
 112     BuiltIn.Wait_Until_Keyword_Succeeds    60s    1s    Check_Config_Data    <data xmlns="${ODL_NETCONF_NAMESPACE}"><cont xmlns="urn:opendaylight:test:netconf:crud"><l>Modified Content</l></cont></data>
 113
 114 Modify_Device_Data_Again
 115     [Documentation]    Send a request to change the sample test data and check that the request went OK.
 116     ${template_as_string}=    BuiltIn.Set_Variable    {'DEVICE_NAME': '${device_name}'}
 117     TemplatedRequests.Put_As_Xml_Templated    ${DIRECTORY_WITH_TEMPLATE_FOLDERS}${/}datamod2    ${template_as_string}
 118
 119 Check_Device_Data_Is_Modified_Again
 120     [Documentation]    Get the device data and make sure it contains the created content.
 121     Check_Config_Data    <data xmlns="${ODL_NETCONF_NAMESPACE}"><cont xmlns="urn:opendaylight:test:netconf:crud"><l>Another Modified Content</l></cont></data>
 122
 123 Modify_Device_Data_Label_Via_Json
 124     [Documentation]    Send a JSON request to change the sample test data label and check that the request went OK.
 125     ${template_as_string}=    BuiltIn.Set_Variable    {'DEVICE_NAME': '${device_name}'}
 126     TemplatedRequests.Put_As_Json_Templated    ${directory_with_template_folders}${/}datamodjson    ${template_as_string}
 127
 128 Check_Device_Data_Label_Is_Modified_Via_Json
 129     [Documentation]    Get the device data label as XML and make sure it matches the content posted as JSON in the previous case.
 130     Check_Config_Data    <data xmlns="${ODL_NETCONF_NAMESPACE}"><cont xmlns="urn:opendaylight:test:netconf:crud"><l>Content Modified via JSON</l></cont></data>
 131
 132 Create_Car_List
 133     [Documentation]    Send a request to create a list of cars in the sample test data label and check that the request went OK.
 134     ${template_as_string}=    BuiltIn.Set_Variable    {'DEVICE_NAME': '${device_name}'}
 135     TemplatedRequests.Post_As_Xml_Templated    ${directory_with_template_folders}${/}cars    ${template_as_string}
 136
 137 Check_Car_List_Created
 138     [Documentation]    Get the device data label as XML and make sure it matches the content posted as JSON in the previous case.
 139     ${data}=    Get_Config_Data
 140     BuiltIn.Should_Contain    ${data}    <id>KEEP</id>
 141     BuiltIn.Should_Not_Contain    ${data}    <id>SMALL</id>
 142     BuiltIn.Should_Not_Contain    ${data}    <model>Isetta</model>
 143     BuiltIn.Should_Not_Contain    ${data}    <manufacturer>BMW</manufacturer>
 144     BuiltIn.Should_Not_Contain    ${data}    <year>1953</year>
 145     BuiltIn.Should_Not_Contain    ${data}    <category>microcar</category>
 146     BuiltIn.Should_Not_Contain    ${data}    <id>TOYOTA</id>
 147     BuiltIn.Should_Not_Contain    ${data}    <model>Camry</model>
 148     BuiltIn.Should_Not_Contain    ${data}    <manufacturer>Toyota</manufacturer>
 149     BuiltIn.Should_Not_Contain    ${data}    <year>1982</year>
 150     BuiltIn.Should_Not_Contain    ${data}    <category>sedan</category>
 151
 152 Add_Device_Data_Item_1_Via_XML_Post
 153     [Documentation]    Send a request to create a data item in the test list and check that the request went OK.
 154     ${template_as_string}=    BuiltIn.Set_Variable    {'DEVICE_NAME': '${device_name}'}
 155     TemplatedRequests.Post_As_Xml_Templated    ${directory_with_template_folders}${/}item1    ${template_as_string}
 156
 157 Check_Item1_Is_Created
 158     [Documentation]    Get the device data as XML and make sure it matches the content posted as JSON in the previous case.
 159     ${data}=    Get_Config_Data
 160     BuiltIn.Should_Contain    ${data}    <id>SMALL</id>
 161     BuiltIn.Should_Contain    ${data}    <model>Isetta</model>
 162     BuiltIn.Should_Contain    ${data}    <manufacturer>BMW</manufacturer>
 163     BuiltIn.Should_Contain    ${data}    <year>1953</year>
 164     BuiltIn.Should_Contain    ${data}    <category>microcar</category>
 165     BuiltIn.Should_Not_Contain    ${data}    <id>TOYOTA</id>
 166     BuiltIn.Should_Not_Contain    ${data}    <model>Camry</model>
 167     BuiltIn.Should_Not_Contain    ${data}    <manufacturer>Toyota</manufacturer>
 168     BuiltIn.Should_Not_Contain    ${data}    <year>1982</year>
 169     BuiltIn.Should_Not_Contain    ${data}    <category>sedan</category>
 170
 171 Add_Device_Data_Item_2_Via_JSON_Post
 172     [Documentation]    Send a JSON request to change the sample test data and check that the request went OK.
 173     ${template_as_string}=    BuiltIn.Set_Variable    {'DEVICE_NAME': '${device_name}'}
 174     TemplatedRequests.Post_As_Json_Templated    ${directory_with_template_folders}${/}item2    ${template_as_string}
 175
 176 Check_Item2_Is_Created
 177     [Documentation]    Get the device data as XML and make sure it matches the content posted as JSON in the previous case.
 178     ${data}=    Get_Config_Data
 179     BuiltIn.Should_Contain    ${data}    <id>SMALL</id>
 180     BuiltIn.Should_Contain    ${data}    <model>Isetta</model>
 181     BuiltIn.Should_Contain    ${data}    <manufacturer>BMW</manufacturer>
 182     BuiltIn.Should_Contain    ${data}    <year>1953</year>
 183     BuiltIn.Should_Contain    ${data}    <category>microcar</category>
 184     BuiltIn.Should_Contain    ${data}    <id>TOYOTA</id>
 185     BuiltIn.Should_Contain    ${data}    <model>Camry</model>
 186     BuiltIn.Should_Contain    ${data}    <manufacturer>Toyota</manufacturer>
 187     BuiltIn.Should_Contain    ${data}    <year>1982</year>
 188     BuiltIn.Should_Contain    ${data}    <category>sedan</category>
 189
 190 Delete_Device_Data
 191     [Documentation]    Send a request to delete the sample test data on the device and check that the request went OK.
 192     ${template_as_string}=    BuiltIn.Set_Variable    {'DEVICE_NAME': '${device_name}'}
 193     TemplatedRequests.Delete_Templated    ${directory_with_template_folders}${/}datamod1    ${template_as_string}
 194     TemplatedRequests.Delete_Templated    ${directory_with_template_folders}${/}item1    ${template_as_string}
 195
 196 Check_Device_Data_Is_Deleted
 197     [Documentation]    Get the device data and make sure it is empty again.
 198     Check_Config_Data    <data xmlns="${ODL_NETCONF_NAMESPACE}"></data>
 199
 200 Deconfigure_Device_From_Netconf
 201     [Documentation]    Make request to deconfigure the testtool device on Netconf connector.
 202     [Tags]    critical
 203     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 204     NetconfKeywords.Remove_Device_From_Netconf    ${device_name}
 205
 206 Check_Device_Going_To_Be_Gone_After_Deconfiguring
 207     [Documentation]    Check that the device is really going to be gone. Fail
 208     ...    if found after one minute. This is an expected behavior as the
 209     ...    delete request is sent to the config subsystem which then triggers
 210     ...    asynchronous destruction of the netconf connector referring to the
 211     ...    device and the device's data. This test makes sure this
 212     ...    asynchronous operation does not take unreasonable amount of time
 213     ...    by making sure that both the netconf connector and the device's
 214     ...    data is gone before reporting success.
 215     [Tags]    critical
 216     NetconfKeywords.Wait_Device_Fully_Removed    ${device_name}
 217
 218 *** Keywords ***
 219 Setup_Everything
 220     [Documentation]    Initialize SetupUtils. Setup everything needed for the test cases.
 221     # Setup resources used by the suite.
 222     SetupUtils.Setup_Utils_For_Setup_And_Teardown
 223     RequestsLibrary.Create_Session    operational    http://${ODL_SYSTEM_IP}:${RESTCONFPORT}${OPERATIONAL_API}    auth=${AUTH}
 224     NetconfKeywords.Setup_Netconf_Keywords
 225     ${device_type}=    BuiltIn.Set_Variable_If    """${USE_NETCONF_CONNECTOR}""" == """True"""    default    ${device_type}
 226     BuiltIn.Set_Suite_Variable    ${device_type}
 227
 228 Teardown_Everything
 229     [Documentation]    Teardown the test infrastructure, perform cleanup and release all resources.
 230     RequestsLibrary.Delete_All_Sessions
 231     BuiltIn.Run_Keyword_And_Ignore_Error    NetconfKeywords.Stop_Testtool
 232
 233 Get_Config_Data
 234     [Documentation]    Get and return the config data from the device.
 235     ${url}=    Builtin.Set_Variable    ${CONFIG_API}/network-topology:network-topology/topology/topology-netconf/node/${device_name}/yang-ext:mount
 236     ${data}=    TemplatedRequests.Get_As_Xml_From_Uri    ${url}
 237     [Return]    ${data}
 238
 239 Check_Config_Data
 240     [Arguments]    ${expected}    ${contains}=False
 241     ${data}=    Get_Config_Data
 242     BuiltIn.Run_Keyword_Unless    ${contains}    BuiltIn.Should_Be_Equal_As_Strings    ${data}    ${expected}
 243     BuiltIn.Run_Keyword_If    ${contains}    BuiltIn.Should_Contain    ${data}    ${expected}