csit/suites/netconf/scale/getmulti.robot

   1 *** Settings ***
   2 Documentation     netconf-connector scaling test suite (multi-threaded GET requests).
   3 ...
   4 ...               Copyright (c) 2015 Cisco Systems, Inc. and others. All rights reserved.
   5 ...
   6 ...               This program and the accompanying materials are made available under the
   7 ...               terms of the Eclipse Public License v1.0 which accompanies this distribution,
   8 ...               and is available at http://www.eclipse.org/legal/epl-v10.html
   9 ...
  10 ...
  11 ...               Performs scaling tests:
  12 ...               - Send configurations of the devices one by one (via restconf).
  13 ...               - Wait for the devices to become connected.
  14 ...               - Send requests for configuration data using ${WORKER_COUNT} worker threads
  15 ...               (using external Python tool).
  16 ...               - Deconfigure the devices one by one.
  17 Suite Setup       Setup_Everything
  18 Suite Teardown    Teardown_Everything
  19 Test Setup        SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
  20 Library           Collections
  21 Library           String
  22 Library           SSHLibrary    timeout=10s
  23 Resource          ${CURDIR}/../../../libraries/KarafKeywords.robot
  24 Resource          ${CURDIR}/../../../libraries/NetconfKeywords.robot
  25 Resource          ${CURDIR}/../../../libraries/SetupUtils.robot
  26 Resource          ${CURDIR}/../../../libraries/SSHKeywords.robot
  27 Variables         ${CURDIR}/../../../variables/Variables.py
  28
  29 *** Variables ***
  30 ${DEVICE_COUNT}    500
  31 ${WORKER_COUNT}    10
  32 ${TIMEOUT_FACTOR}    10
  33 ${device_name_base}    netconf-scaling-device
  34 ${device_type}    full-uri-device
  35 ${base_port}      17830
  36
  37 *** Test Cases ***
  38 Start_Test_Tool
  39     [Documentation]    Deploy and start test tool, then wait for all its devices to become online.
  40     NetconfKeywords.Install_And_Start_Testtool    device-count=${DEVICE_COUNT}
  41
  42 Configure_Devices_On_Netconf
  43     [Documentation]    Make requests to configure the testtool devices.
  44     ${timeout}=    BuiltIn.Evaluate    ${DEVICE_COUNT}*${TIMEOUT_FACTOR}
  45     NetconfKeywords.Perform_Operation_On_Each_Device    NetconfKeywords.Configure_Device    timeout=${timeout}
  46
  47 Wait_For_Devices_To_Connect
  48     [Documentation]    Wait for the devices to become connected.
  49     ${timeout}=    BuiltIn.Evaluate    ${DEVICE_COUNT}*${TIMEOUT_FACTOR}
  50     NetconfKeywords.Perform_Operation_On_Each_Device    NetconfKeywords.Wait_Connected    timeout=${timeout}
  51
  52 Issue_Requests_On_Devices
  53     # FIXME: this test case is a keyword and nearly duplicated in the max_devices.robot suite. need to move it to a common lib
  54     [Documentation]    Spawn the specified count of worker threads to issue a GET request to each of the devices.
  55     ${current_ssh_connection}=    SSHLibrary.Get Connection
  56     SSHLibrary.Open_Connection    ${TOOLS_SYSTEM_IP}
  57     SSHKeywords.Flexible_Mininet_Login
  58     SSHLibrary.Write    python getter.py --odladdress=${ODL_SYSTEM_IP} --count=${DEVICE_COUNT} --name=${device_name_base} --workers=${WORKER_COUNT}
  59     FOR    ${number}    IN RANGE    1    ${DEVICE_COUNT}+1
  60         Read_Python_Tool_Operation_Result    ${number}
  61     END
  62     SSHLibrary.Read_Until_Prompt
  63     SSHLibrary.Close_Connection
  64     SSHKeywords.Restore Current SSH Connection From Index    ${current_ssh_connection.index}
  65
  66 Deconfigure_Devices
  67     [Documentation]    Make requests to deconfigure the testtool devices.
  68     ${timeout}=    BuiltIn.Evaluate    ${DEVICE_COUNT}*${TIMEOUT_FACTOR}
  69     NetconfKeywords.Perform_Operation_On_Each_Device    NetconfKeywords.Deconfigure_Device    timeout=${timeout}
  70     [Teardown]    Report_Failure_Due_To_Bug    4547
  71
  72 Check_Devices_Are_Deconfigured
  73     [Documentation]    Check there are no netconf connectors or other stuff related to the testtool devices.
  74     ${timeout}=    BuiltIn.Evaluate    ${DEVICE_COUNT}*${TIMEOUT_FACTOR}
  75     NetconfKeywords.Perform_Operation_On_Each_Device    NetconfKeywords.Check_Device_Deconfigured    timeout=${timeout}
  76
  77 *** Keywords ***
  78 Setup_Everything
  79     [Documentation]    Setup everything needed for the test cases.
  80     # Setup resources used by the suite.
  81     RequestsLibrary.Create_Session    operational    http://${ODL_SYSTEM_IP}:${RESTCONFPORT}${OPERATIONAL_API}    auth=${AUTH}
  82     SSHLibrary.Set_Default_Configuration    prompt=${TOOLS_SYSTEM_PROMPT}
  83     SetupUtils.Setup_Utils_For_Setup_And_Teardown
  84     NetconfKeywords.Setup_Netconf_Keywords
  85     # Deploy testing tools.
  86     SSHLibrary.Put_File    ${CURDIR}/../../../../tools/netconf_tools/getter.py
  87     SSHLibrary.Put_File    ${CURDIR}/../../../libraries/AuthStandalone.py
  88     ${device_type}=    BuiltIn.Set_Variable_If    ${USE_NETCONF_CONNECTOR}==${True}    default    ${device_type}
  89     BuiltIn.Set_Suite_Variable    ${device_type}
  90
  91 Teardown_Everything
  92     [Documentation]    Teardown the test infrastructure, perform cleanup and release all resources.
  93     RequestsLibrary.Delete_All_Sessions
  94     NetconfKeywords.Stop_Testtool
  95
  96 Read_Python_Tool_Operation_Result
  97     [Arguments]    ${number}
  98     [Documentation]    Read and process a report line emitted from the Python tool that corresponds to the device with the given number.
  99     ${test}=    SSHLibrary.Read_Until_Regexp    \\n
 100     ${test}=    String.Split_String    ${test}    |
 101     ${response}=    Collections.Get_From_List    ${test}    0
 102     ${message}=    Collections.Get_From_List    ${test}    1
 103     BuiltIn.Run_Keyword_If    '${response}' == 'ERROR'    Fail    Error getting data: ${message}
 104     ${start}=    Collections.Get_From_List    ${test}    1
 105     ${stop}=    Collections.Get_From_List    ${test}    2
 106     ${ellapsed}=    Collections.Get_From_List    ${test}    3
 107     BuiltIn.Log    DATA REQUEST RESULT: Device=${number} StartTime=${start} StopTime=${stop} EllapsedTime=${ellapsed}
 108     ${data}=    Collections.Get_From_List    ${test}    4
 109     ${expected}=    BuiltIn.Set_Variable    '<data xmlns="${ODL_NETCONF_NAMESPACE}"></data>'
 110     BuiltIn.Should_Be_Equal_As_Strings    ${data}    ${expected}