csit/suites/netconf/scale/getmulti.robot

   1 *** Settings ***
   2 Documentation     netconf-connector scaling test suite (multi-threaded GET requests).
   3 ...
   4 ...               Copyright (c) 2015 Cisco Systems, Inc. and others. All rights reserved.
   5 ...
   6 ...               This program and the accompanying materials are made available under the
   7 ...               terms of the Eclipse Public License v1.0 which accompanies this distribution,
   8 ...               and is available at http://www.eclipse.org/legal/epl-v10.html
   9 ...
  10 ...
  11 ...               Performs scaling tests:
  12 ...               - Send configurations of the devices one by one (via restconf).
  13 ...               - Wait for the devices to become connected.
  14 ...               - Send requests for configuration data using ${WORKER_COUNT} worker threads
  15 ...               (using external Python tool).
  16 ...               - Deconfigure the devices one by one.
  17 Suite Setup       Setup_Everything
  18 Suite Teardown    Teardown_Everything
  19 Test Setup        SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
  20 Library           Collections
  21 Library           String
  22 Library           SSHLibrary    timeout=10s
  23 Resource          ${CURDIR}/../../../libraries/KarafKeywords.robot
  24 Resource          ${CURDIR}/../../../libraries/NetconfKeywords.robot
  25 Resource          ${CURDIR}/../../../libraries/SetupUtils.robot
  26 Resource          ${CURDIR}/../../../libraries/SSHKeywords.robot
  27 Resource          ${CURDIR}/../../../libraries/Utils.robot
  28 Variables         ${CURDIR}/../../../variables/Variables.py
  29
  30 *** Variables ***
  31 ${DEVICE_COUNT}    500
  32 ${WORKER_COUNT}    10
  33 ${device_name_base}    netconf-scaling-device
  34 ${base_port}      17830
  35
  36 *** Test Cases ***
  37 Start_Test_Tool
  38     [Documentation]    Deploy and start test tool, then wait for all its devices to become online.
  39     NetconfKeywords.Install_And_Start_Testtool    device-count=${DEVICE_COUNT}    mdsal=false
  40
  41 Configure_Devices_On_Netconf
  42     [Documentation]    Make requests to configure the testtool devices.
  43     ${timeout}=    BuiltIn.Evaluate    ${DEVICE_COUNT}*10
  44     NetconfKeywords.Perform_Operation_On_Each_Device    Configure_Device    timeout=${timeout}
  45
  46 Wait_For_Devices_To_Connect
  47     [Documentation]    Wait for the devices to become connected.
  48     ${timeout}=    BuiltIn.Evaluate    ${DEVICE_COUNT}*10
  49     NetconfKeywords.Perform_Operation_On_Each_Device    Wait_Connected    timeout=${timeout}
  50
  51 Issue_Requests_On_Devices
  52     [Documentation]    Spawn the specified count of worker threads to issue a GET request to each of the devices.
  53     ${current_ssh_connection}=    SSHLibrary.Get Connection
  54     SSHLibrary.Open_Connection    ${TOOLS_SYSTEM_IP}
  55     Utils.Flexible_Mininet_Login
  56     SSHLibrary.Write    python getter.py --odladdress=${ODL_SYSTEM_IP} --count=${DEVICE_COUNT} --name=${device_name_base} --workers=${WORKER_COUNT}
  57     : FOR    ${number}    IN RANGE    1    ${DEVICE_COUNT}+1
  58     \    Read_Python_Tool_Operation_Result    ${number}
  59     SSHLibrary.Read_Until_Prompt
  60     SSHLibrary.Close_Connection
  61     SSHKeywords.Restore Current SSH Connection From Index    ${current_ssh_connection.index}
  62
  63 Deconfigure_Devices
  64     [Documentation]    Make requests to deconfigure the testtool devices.
  65     ${timeout}=    BuiltIn.Evaluate    ${DEVICE_COUNT}*10
  66     NetconfKeywords.Perform_Operation_On_Each_Device    Deconfigure_Device    timeout=${timeout}
  67     [Teardown]    Report_Failure_Due_To_Bug    4547
  68
  69 Check_Devices_Are_Deconfigured
  70     [Documentation]    Check there are no netconf connectors or other stuff related to the testtool devices.
  71     ${timeout}=    BuiltIn.Evaluate    ${DEVICE_COUNT}*10
  72     NetconfKeywords.Perform_Operation_On_Each_Device    Check_Device_Deconfigured    timeout=${timeout}
  73
  74 *** Keywords ***
  75 Setup_Everything
  76     [Documentation]    Setup everything needed for the test cases.
  77     # Setup resources used by the suite.
  78     RequestsLibrary.Create_Session    operational    http://${ODL_SYSTEM_IP}:${RESTCONFPORT}${OPERATIONAL_API}    auth=${AUTH}
  79     SSHLibrary.Set_Default_Configuration    prompt=${TOOLS_SYSTEM_PROMPT}
  80     SetupUtils.Setup_Utils_For_Setup_And_Teardown
  81     NetconfKeywords.Setup_Netconf_Keywords
  82     # Deploy testing tools.
  83     SSHLibrary.Put_File    ${CURDIR}/../../../../tools/netconf_tools/getter.py
  84     SSHLibrary.Put_File    ${CURDIR}/../../../libraries/AuthStandalone.py
  85
  86 Teardown_Everything
  87     [Documentation]    Teardown the test infrastructure, perform cleanup and release all resources.
  88     RequestsLibrary.Delete_All_Sessions
  89     NetconfKeywords.Stop_Testtool
  90
  91 Configure_Device
  92     [Arguments]    ${current_name}
  93     [Documentation]    Operation for configuring the device.
  94     KarafKeywords.Log_Message_To_Controller_Karaf    Configuring device ${current_name} to Netconf
  95     NetconfKeywords.Configure_Device_In_Netconf    ${current_name}    device_port=${current_port}
  96     KarafKeywords.Log_Message_To_Controller_Karaf    Device ${current_name} configured
  97
  98 Wait_Connected
  99     [Arguments]    ${current_name}
 100     [Documentation]    Operation for waiting until the device is connected.
 101     KarafKeywords.Log_Message_To_Controller_Karaf    Waiting for device ${current_name} to connect
 102     NetconfKeywords.Wait_Device_Connected    ${current_name}    period=0.5s    timeout=120s
 103     KarafKeywords.Log_Message_To_Controller_Karaf    Device ${current_name} connected
 104
 105 Read_Python_Tool_Operation_Result
 106     [Arguments]    ${number}
 107     [Documentation]    Read and process a report line emitted from the Python tool that corresponds to the device with the given number.
 108     ${test}=    SSHLibrary.Read_Until_Regexp    \\n
 109     ${test}=    String.Split_String    ${test}    |
 110     ${response}=    Collections.Get_From_List    ${test}    0
 111     ${message}=    Collections.Get_From_List    ${test}    1
 112     BuiltIn.Run_Keyword_If    '${response}' == 'ERROR'    Fail    Error getting data: ${message}
 113     ${start}=    Collections.Get_From_List    ${test}    1
 114     ${stop}=    Collections.Get_From_List    ${test}    2
 115     ${ellapsed}=    Collections.Get_From_List    ${test}    3
 116     BuiltIn.Log    DATA REQUEST RESULT: Device=${number} StartTime=${start} StopTime=${stop} EllapsedTime=${ellapsed}
 117     ${data}=    Collections.Get_From_List    ${test}    4
 118     ${expected}=    BuiltIn.Set_Variable    '<data xmlns="${ODL_NETCONF_NAMESPACE}"></data>'
 119     BuiltIn.Should_Be_Equal_As_Strings    ${data}    ${expected}
 120
 121 Deconfigure_Device
 122     [Arguments]    ${current_name}
 123     [Documentation]    Operation for deconfiguring the device.
 124     KarafKeywords.Log_Message_To_Controller_Karaf    Deconfiguring device ${current_name}
 125     NetconfKeywords.Remove_Device_From_Netconf    ${current_name}
 126     KarafKeywords.Log_Message_To_Controller_Karaf    Device ${current_name} deconfigured
 127
 128 Check_Device_Deconfigured
 129     [Arguments]    ${current_name}
 130     [Documentation]    Operation for making sure the device is really deconfigured.
 131     KarafKeywords.Log_Message_To_Controller_Karaf    Waiting for device ${current_name} to disappear
 132     NetconfKeywords.Wait_Device_Fully_Removed    ${current_name}    period=0.5s    timeout=120s
 133     KarafKeywords.Log_Message_To_Controller_Karaf    Device ${current_name} removed