csit/suites/openflowplugin/Bug_Validation/7349.robot

   1 *** Settings ***
   2 Documentation     Test suite for bug 6917 validation.
   3 Suite Setup       Initialization Phase
   4 Suite Teardown    Final Phase
   5 Library           XML
   6 Library           RequestsLibrary
   7 Resource          ../../../libraries/MininetKeywords.robot
   8 Resource          ../../../libraries/FlowLib.robot
   9 Resource          ../../../variables/Variables.robot
  10 Resource          ../../../variables/openflowplugin/Variables.robot
  11
  12 *** Variables ***
  13 ${XmlsDir}        ${CURDIR}/../../../variables/xmls
  14 ${flowfile1}      f162.xml
  15 ${flowfile2}      f164.xml
  16 ${switch_idx}     1
  17 ${switch_name}    s${switch_idx}
  18
  19 *** Test Cases ***
  20 Add Flow And Check It Is In Operational DS
  21     [Documentation]    Add flow match IP and Ethertype IP
  22     FlowLib.Create Flow Variables For Suite From XML File    ${XmlsDir}/${flowfile1}
  23     FlowLib.Add Flow Via Restconf    ${switch_idx}    ${table_id}    ${data}
  24     BuiltIn.Wait Until Keyword Succeeds    10s    1s    FlowLib.Check Datastore Presence    ${flowfile1}    ${True}    ${True}
  25     ...    ${False}    ${True}
  26
  27 Delete and Add Flow Same Match With Different ID
  28     [Documentation]    Delete flow and add flow with same body and different ID. New ID should be shown in operational.
  29     FlowLib.Delete Flow Via Restconf    ${switch_idx}    ${table_id}    ${flow_id}
  30     FlowLib.Create Flow Variables For Suite From XML File    ${XmlsDir}/${flowfile2}
  31     FlowLib.Add Flow Via Restconf    ${switch_idx}    ${table_id}    ${data}
  32     BuiltIn.Wait Until Keyword Succeeds    10s    1s    FlowLib.Check Datastore Presence    ${flowfile2}    ${True}    ${True}
  33     ...    ${False}    ${True}
  34     [Teardown]    Report_Failure_Due_To_Bug    7349
  35
  36 *** Keywords ***
  37 Initialization Phase
  38     [Documentation]    Starts mininet and verify if topology is in operational datastore.
  39     ${mininet_conn_id}=    MininetKeywords.Start Mininet Single Controller
  40     BuiltIn.Set Suite Variable    ${mininet_conn_id}
  41     RequestsLibrary.Create Session    session    http://${ODL_SYSTEM_IP}:${RESTCONFPORT}    auth=${AUTH}    headers=${HEADERS_XML}
  42     BuiltIn.Wait Until Keyword Succeeds    10s    1s    FlowLib.Check Switches In Topology    1
  43
  44 Final Phase
  45     [Documentation]    Stops mininet.
  46     BuiltIn.Run Keyword And Ignore Error    RequestsLibrary.Delete Request    session    ${RFC8040_NODES_API}
  47     MininetKeywords.Stop Mininet And Exit    ${mininet_conn_id}
  48     RequestsLibrary.Delete All Sessions