csit/suites/openflowplugin/Performance/010_Cbench.robot

   1 *** Settings ***
   2 Documentation     Cbench Latency and Throughput tests can be run from an external
   3 ...               cbench.
   4 ...               If cbench is run with a medium number of switches or higher (e.g. 32+)
   5 ...               the normal openflow operations seem to break.
   6 ...               BUG: https://bugs.opendaylight.org/show_bug.cgi?id=2897
   7 Suite Setup       Cbench Suite Setup
   8 Test Teardown     Log Results As Zero If Cbench Timed Out
   9 Force Tags        cbench
  10 Library           String
  11 Library           Process
  12 Resource          ../../../libraries/Utils.robot
  13 Resource          ../../../libraries/KarafKeywords.robot
  14
  15 *** Variables ***
  16 ${throughput_threshold}    30000
  17 ${latency_threshold}    10000
  18 ${switch_count}    16
  19 ${duration_in_secs}    10
  20 ${loops}          10
  21 ${num_of_unique_macs}    100
  22 ${start_delay}    5000
  23 ${test_delay}     0
  24 ${cbench_system}    ${TOOLS_SYSTEM_IP}
  25 ${cbench_executable}    /usr/local/bin/cbench
  26 ${throughput_results_file}    throughput.csv
  27 ${latency_results_file}    latency.csv
  28
  29 *** Testcases ***
  30 Cbench Latency Test
  31     [Documentation]    cbench executed in default latency mode. Test parameters have defaults, but can be overridden
  32     ...    on the pybot command line
  33     [Tags]    latency
  34     [Timeout]    ${test_timeout}
  35     Log    Cbench tests using ${loops} iterations of ${duration_in_secs} second tests. Switch Count: ${switch_count}. Unique MACS to cycle: ${num_of_unique_macs}
  36     Run Cbench And Log Results    -m ${duration_in_ms} -M ${num_of_unique_macs} -s ${switch_count} -l ${loops} -D ${start_delay}    ${latency_threshold}    ${latency_results_file}
  37     # We have to give some time for the controller to recover. See bug 6176.
  38     Sleep    ${test_delay}
  39
  40 Cbench Throughput Test
  41     [Documentation]    cbench executed in throughput mode (-t). Test parameters have defaults, but can be overridden
  42     ...    on the pybot command line
  43     [Tags]    throughput
  44     [Timeout]    ${test_timeout}
  45     Log    Cbench tests using ${loops} iterations of ${duration_in_secs} second tests. Switch Count: ${switch_count}. Unique MACS to cycle: ${num_of_unique_macs}
  46     Run Cbench And Log Results    -t -m ${duration_in_ms} -M ${num_of_unique_macs} -s ${switch_count} -l ${loops} -D ${start_delay}    ${throughput_threshold}    ${throughput_results_file}
  47     # We have to give some time for the controller to recover. See bug 6176.
  48     Sleep    ${test_delay}
  49
  50 Rerun Latency Test To Check Bug 6176
  51     [Documentation]    cbench executed in latency mode to see if controller is healthy
  52     [Tags]    latency
  53     [Timeout]    ${test_timeout}
  54     Log    Cbench tests using ${loops} iterations of ${duration_in_secs} second tests. Switch Count: ${switch_count}. Unique MACS to cycle: ${num_of_unique_macs}
  55     Run Cbench And Log Results    -m ${duration_in_ms} -M ${num_of_unique_macs} -s ${switch_count} -l ${loops} -D ${start_delay}    ${latency_threshold}    bug.csv
  56     # We have to give some time for the controller to recover. See bug 6176.
  57     Sleep    ${test_delay}
  58
  59 *** Keywords ***
  60 Run Cbench And Log Results
  61     [Arguments]    ${cbench_args}    ${average_threshold}    ${output_filename}=results.csv
  62     ##If the cbench command fails to return, the keyword to run it will time out.    The test tear
  63     ##down can catch this problem and log the results as zero.    However, we need to know which
  64     ##file to log to, so setting it as a suite variable here.
  65     Set Suite Variable    ${output_filename}
  66     ${output}=    Run Keyword If    "${cbench_system}" == "localhost"    Run Process    ${cbench_executable}    -c    ${ODL_SYSTEM_IP}
  67     ...    ${cbench_args}
  68     ...    ELSE    Run Command On Remote System    ${cbench_system}    ${cbench_executable} -c ${ODL_SYSTEM_IP} ${cbench_args}    prompt_timeout=${test_timeout}
  69     Log    ${output}
  70     Should Contain    ${output}    RESULT
  71     ${result_line}=    Get Lines Containing String    ${output}    RESULT
  72     @{results_list}=    Split String    ${result_line}
  73     Log    ${results_list[5]}
  74     Log    ${results_list[7]}
  75     @{result_name_list}=    Split String    ${results_list[5]}    /
  76     @{result_value_list}=    Split String    ${results_list[7]}    /
  77     ${num_stats}=    Get Length    ${result_name_list}
  78     : FOR    ${i}    IN RANGE    0    ${num_stats}
  79     \    Log    ${result_name_list[${i}]} :: ${result_value_list[${i}]}
  80     ${min}=    Set Variable    ${result_value_list[${0}]}
  81     ${max}=    Set Variable    ${result_value_list[${1}]}
  82     ${average}=    Set Variable    ${result_value_list[${2}]}
  83     ${stdev}=    Set Variable    ${result_value_list[${3}]}
  84     ${date}=    Get Time    d,m,s
  85     Log    CBench Result: ${date},${cbench_args},${min},${max},${average},${stdev}
  86     Log Results And Determine Status    ${min}    ${max}    ${average}    ${average_threshold}    ${output_filename}
  87
  88 Cbench Suite Setup
  89     Wait Until Keyword Succeeds    3x    1s    KarafKeywords.Issue Command On Karaf Console    log:set ERROR
  90     Append To File    ${latency_results_file}    LATENCY_MIN,LATENCY_MAX,LATENCY_AVERAGE\n
  91     Append To File    ${throughput_results_file}    THROUGHPUT_MIN,THROUGHPUT_MAX,THROUGHPUT_AVERAGE\n
  92     ${duration_in_ms}    Evaluate    ${duration_in_secs} * 1000
  93     Set Suite Variable    ${duration_in_ms}
  94     ##Setting the test timeout dynamically in case larger values on command line override default
  95     ${test_timeout}    Evaluate    (${loops} * ${duration_in_secs}) * 1.5
  96     Set Suite Variable    ${test_timeout}
  97     Run Keyword If    "${cbench_system}" == "localhost"    File Should Exist    ${cbench_executable}
  98     ...    ELSE    Verify File Exists On Remote System    ${cbench_system}    ${cbench_executable}
  99     Should Be True    ${loops} >= 2    If number of loops is less than 2, cbench will not run
 100     Verify Feature Is Installed    odl-openflowplugin-drop-test
 101     Issue Command On Karaf Console    dropallpacketsrpc on
 102
 103 Log Results And Determine Status
 104     [Arguments]    ${min}    ${max}    ${average}    ${threshold}    ${output_file}
 105     Append To File    ${output_file}    ${min},${max},${average}\n
 106     Should Be True    ${average} > ${threshold}    ${average} flow_mods per/sec did not exceed threshold of ${threshold}
 107
 108 Log Results As Zero If Cbench Timed Out
 109     Run Keyword If Timeout Occurred    Log Results And Determine Status    0    0    0    0    ${output_filename}