csit/suites/sfc/SFC_Basic/140__sfc_service_function_classifier.robot

   1 *** Settings ***
   2 Documentation       Test suite for SFC Service Function Classifiers, Operates functions from Restconf APIs.
   3
   4 Library             SSHLibrary
   5 Library             Collections
   6 Library             OperatingSystem
   7 Library             RequestsLibrary
   8 Resource            ../../../variables/sfc/Variables.robot
   9 Resource            ../../../libraries/Utils.robot
  10
  11 Suite Setup         Create Session    session    http://${ODL_SYSTEM_IP}:${RESTCONFPORT}    auth=${AUTH}    headers=${HEADERS}
  12 Suite Teardown      Delete All Sessions
  13 Test Setup          Remove All Elements If Exist    ${SERVICE_CLASSIFIERS_URI}
  14 Test Teardown       Remove All Elements At URI    ${SERVICE_CLASSIFIERS_URI}
  15
  16
  17 *** Variables ***
  18 ${SERVICE_CLASSIFIER_FILE}      ${CURDIR}/../../../variables/sfc/master/service-function-classifiers.json
  19
  20
  21 *** Test Cases ***
  22 Add Service Function Classifier
  23     [Documentation]    Add Service Function Classifiers from JSON file
  24     Add Elements To URI From File    ${SERVICE_CLASSIFIERS_URI}    ${SERVICE_CLASSIFIER_FILE}
  25     ${body}    OperatingSystem.Get File    ${SERVICE_CLASSIFIER_FILE}
  26     ${jsonbody}    To Json    ${body}
  27     ${functions}    Get From Dictionary    ${jsonbody}    service-function-classifiers
  28     ${resp}    RequestsLibrary.Get Request    session    ${SERVICE_CLASSIFIERS_URI}
  29     ${result}    To JSON    ${resp.content}
  30     Should Be Equal As Strings    ${resp.status_code}    200
  31     ${function}    Get From Dictionary    ${result}    service-function-classifiers
  32     Lists Should be Equal    ${function}    ${functions}
  33
  34 Delete All Classifiers
  35     [Documentation]    Delete all Classifiers
  36     ${body}    OperatingSystem.Get File    ${SERVICE_CLASSIFIER_FILE}
  37     Add Elements To URI From File    ${SERVICE_CLASSIFIERS_URI}    ${SERVICE_CLASSIFIER_FILE}
  38     ${resp}    RequestsLibrary.Get Request    session    ${SERVICE_CLASSIFIERS_URI}
  39     Should Contain    ${ALLOWED_STATUS_CODES}    ${resp.status_code}
  40     Remove All Elements At URI    ${SERVICE_CLASSIFIERS_URI}
  41     ${resp}    RequestsLibrary.Get Request    session    ${SERVICE_CLASSIFIERS_URI}
  42     Should Be Equal As Strings    ${resp.status_code}    404
  43     [Teardown]    NONE
  44
  45 Get one Classifier
  46     [Documentation]    Get one Classifier
  47     Add Elements To URI From File    ${SERVICE_CLASSIFIERS_URI}    ${SERVICE_CLASSIFIER_FILE}
  48     ${resp}    RequestsLibrary.Get Request
  49     ...    session
  50     ...    ${SERVICE_CLASSIFIERS_URI}/service-function-classifier/Classifier1
  51     Should Be Equal As Strings    ${resp.status_code}    200
  52
  53 Get A Non-existing Classifier
  54     [Documentation]    Get A Non-existing Classifier
  55     Add Elements To URI From File    ${SERVICE_CLASSIFIERS_URI}    ${SERVICE_CLASSIFIER_FILE}
  56     ${resp}    RequestsLibrary.Get Request
  57     ...    session
  58     ...    ${SERVICE_CLASSIFIERS_URI}/service-function-classifier/nonexistant-classifier
  59     Should Be Equal As Strings    ${resp.status_code}    404
  60
  61 Delete a Classifier
  62     [Documentation]    Delete a classifier
  63     Add Elements To URI From File    ${SERVICE_CLASSIFIERS_URI}    ${SERVICE_CLASSIFIER_FILE}
  64     Remove All Elements At URI    ${SERVICE_CLASSIFIERS_URI}/service-function-classifier/Classifier1
  65     ${resp}    RequestsLibrary.Get Request    session    ${SERVICE_CLASSIFIERS_URI}
  66     Should Contain    ${ALLOWED_STATUS_CODES}    ${resp.status_code}
  67     Should Not Contain    ${resp.text}    Classifier1