csit/suites/sfc/SFC_Basic/140__sfc_service_function_classifier.robot

   1 *** Settings ***
   2 Documentation     Test suite for SFC Service Function Classifiers, Operates functions from Restconf APIs.
   3 Suite Setup       Create Session    session    http://${ODL_SYSTEM_IP}:${RESTCONFPORT}    auth=${AUTH}    headers=${HEADERS}
   4 Suite Teardown    Delete All Sessions
   5 Test Setup        Remove All Elements If Exist    ${SERVICE_CLASSIFIERS_URI}
   6 Test Teardown     Remove All Elements At URI    ${SERVICE_CLASSIFIERS_URI}
   7 Library           SSHLibrary
   8 Library           Collections
   9 Library           OperatingSystem
  10 Library           RequestsLibrary
  11 Resource          ../../../variables/sfc/Variables.robot
  12 Resource          ../../../libraries/Utils.robot
  13
  14 *** Variables ***
  15 ${SERVICE_CLASSIFIER_FILE}    ${CURDIR}/../../../variables/sfc/master/service-function-classifiers.json
  16
  17 *** Test Cases ***
  18 Add Service Function Classifier
  19     [Documentation]    Add Service Function Classifiers from JSON file
  20     Add Elements To URI From File    ${SERVICE_CLASSIFIERS_URI}    ${SERVICE_CLASSIFIER_FILE}
  21     ${body}    OperatingSystem.Get File    ${SERVICE_CLASSIFIER_FILE}
  22     ${jsonbody}    To Json    ${body}
  23     ${functions}    Get From Dictionary    ${jsonbody}    service-function-classifiers
  24     ${resp}    RequestsLibrary.Get Request    session    ${SERVICE_CLASSIFIERS_URI}
  25     ${result}    To JSON    ${resp.content}
  26     Should Be Equal As Strings    ${resp.status_code}    200
  27     ${function}    Get From Dictionary    ${result}    service-function-classifiers
  28     Lists Should be Equal    ${function}    ${functions}
  29
  30 Delete All Classifiers
  31     [Documentation]    Delete all Classifiers
  32     ${body}    OperatingSystem.Get File    ${SERVICE_CLASSIFIER_FILE}
  33     Add Elements To URI From File    ${SERVICE_CLASSIFIERS_URI}    ${SERVICE_CLASSIFIER_FILE}
  34     ${resp}    RequestsLibrary.Get Request    session    ${SERVICE_CLASSIFIERS_URI}
  35     Should Contain    ${ALLOWED_STATUS_CODES}    ${resp.status_code}
  36     Remove All Elements At URI    ${SERVICE_CLASSIFIERS_URI}
  37     ${resp}    RequestsLibrary.Get Request    session    ${SERVICE_CLASSIFIERS_URI}
  38     Should Be Equal As Strings    ${resp.status_code}    404
  39     [Teardown]    NONE
  40
  41 Get one Classifier
  42     [Documentation]    Get one Classifier
  43     Add Elements To URI From File    ${SERVICE_CLASSIFIERS_URI}    ${SERVICE_CLASSIFIER_FILE}
  44     ${resp}    RequestsLibrary.Get Request    session    ${SERVICE_CLASSIFIERS_URI}/service-function-classifier/Classifier1
  45     Should Be Equal As Strings    ${resp.status_code}    200
  46
  47 Get A Non-existing Classifier
  48     [Documentation]    Get A Non-existing Classifier
  49     Add Elements To URI From File    ${SERVICE_CLASSIFIERS_URI}    ${SERVICE_CLASSIFIER_FILE}
  50     ${resp}    RequestsLibrary.Get Request    session    ${SERVICE_CLASSIFIERS_URI}/service-function-classifier/nonexistant-classifier
  51     Should Be Equal As Strings    ${resp.status_code}    404
  52
  53 Delete a Classifier
  54     [Documentation]    Delete a classifier
  55     Add Elements To URI From File    ${SERVICE_CLASSIFIERS_URI}    ${SERVICE_CLASSIFIER_FILE}
  56     Remove All Elements At URI    ${SERVICE_CLASSIFIERS_URI}/service-function-classifier/Classifier1
  57     ${resp}    RequestsLibrary.Get Request    session    ${SERVICE_CLASSIFIERS_URI}
  58     Should Contain    ${ALLOWED_STATUS_CODES}    ${resp.status_code}
  59     Should Not Contain    ${resp.content}    Classifier1