csit/suites/sxp/filtering/020_Outbound_Filtering.robot

   1 *** Settings ***
   2 Documentation       Test suite to verify Outbound filtering functionality
   3
   4 Library             RequestsLibrary
   5 Library             SSHLibrary
   6 Library             ../../../libraries/Sxp.py
   7 Library             ../../../libraries/Common.py
   8 Resource            ../../../libraries/SxpLib.robot
   9 Resource            ../../../libraries/SXP/FilteringResources.robot
  10
  11 Suite Setup         Setup SXP Environment    5
  12 Suite Teardown      Clean SXP Environment    5
  13 Test Teardown       Clean Nodes
  14
  15
  16 *** Test Cases ***
  17 Access List Filtering
  18     [Documentation]    Test ACL filter behaviour during filter update
  19     [Tags]    sxp    filtering
  20     ${peers}    Add Peers    127.0.0.4    127.0.0.5
  21     Add PeerGroup    GROUP    ${peers}
  22     ${entry1}    Get Filter Entry    10    permit    acl=10.10.10.0,0.0.0.255
  23     ${entry2}    Get Filter Entry    20    deny    acl=10.10.0.0,0.0.255.0
  24     ${entry3}    Get Filter Entry    30    permit    acl=10.0.0.0,0.255.255.0
  25     ${entries}    Combine Strings    ${entry1}    ${entry2}    ${entry3}
  26     Add Filter    GROUP    outbound    ${entries}
  27     Setup Nodes
  28     Wait Until Keyword Succeeds    4    2    Check One Group 4-5
  29     Delete Filter    GROUP    outbound
  30     ${entry1}    Get Filter Entry    10    permit    acl=10.20.0.0,0.0.255.255
  31     ${entry2}    Get Filter Entry    20    permit    acl=10.10.0.0,0.0.255.0
  32     ${entries}    Combine Strings    ${entry1}    ${entry2}
  33     Add Filter    GROUP    outbound    ${entries}
  34     Wait Until Keyword Succeeds    4    2    Check Two Group 4-5
  35
  36 Access List Sgt Filtering
  37     [Documentation]    Test ACL and SGT filter behaviour during filter update
  38     [Tags]    sxp    filtering
  39     ${peers}    Add Peers    127.0.0.2    127.0.0.5
  40     Add PeerGroup    GROUP    ${peers}
  41     ${entry1}    Get Filter Entry    10    deny    acl=10.10.20.0,0.0.0.255
  42     ${entry2}    Get Filter Entry    20    permit    acl=10.10.0.0,0.0.255.0
  43     ${entry3}    Get Filter Entry    30    permit    sgt=30    acl=10.10.10.0,0.0.0.255
  44     ${entries}    Combine Strings    ${entry1}    ${entry2}    ${entry3}
  45     Add Filter    GROUP    outbound    ${entries}
  46     Setup Nodes
  47     Wait Until Keyword Succeeds    4    2    Check One Group 2-5
  48     Delete Filter    GROUP    outbound
  49     ${entries}    Get Filter Entry    10    permit    esgt=20,40    acl=10.10.0.0,0.0.255.255
  50     Add Filter    GROUP    outbound    ${entries}
  51     Wait Until Keyword Succeeds    4    2    Check Two Group 2-5
  52
  53 Prefix List Filtering
  54     [Documentation]    Test Prefix List filter behaviour during filter update
  55     [Tags]    sxp    filtering
  56     ${peers}    Add Peers    127.0.0.4    127.0.0.5
  57     Add PeerGroup    GROUP    ${peers}
  58     ${entry1}    Get Filter Entry    10    permit    pl=10.10.10.0/24
  59     ${entry2}    Get Filter Entry    20    deny    epl=10.10.0.0/16,le,24
  60     ${entry3}    Get Filter Entry    30    permit    epl=10.0.0.0/8,le,24
  61     ${entries}    Combine Strings    ${entry1}    ${entry2}    ${entry3}
  62     Add Filter    GROUP    outbound    ${entries}
  63     Setup Nodes
  64     Wait Until Keyword Succeeds    4    2    Check One Group 4-5
  65     Delete Filter    GROUP    outbound
  66     ${entry1}    Get Filter Entry    10    permit    pl=10.20.0.0/16
  67     ${entry2}    Get Filter Entry    20    permit    epl=10.10.0.0/16,le,24
  68     ${entries}    Combine Strings    ${entry1}    ${entry2}
  69     Add Filter    GROUP    outbound    ${entries}
  70     Wait Until Keyword Succeeds    4    2    Check Two Group 4-5
  71
  72 Prefix List Sgt Filtering
  73     [Documentation]    Test Prefix List and SGT filter behaviour during filter update
  74     [Tags]    sxp    filtering
  75     ${peers}    Add Peers    127.0.0.2    127.0.0.5
  76     Add PeerGroup    GROUP    ${peers}
  77     ${entry1}    Get Filter Entry    10    deny    pl=10.10.20.0/24
  78     ${entry2}    Get Filter Entry    20    permit    epl=10.10.0.0/16,le,24
  79     ${entry3}    Get Filter Entry    30    permit    sgt=30    pl=10.10.10.0/24
  80     ${entries}    Combine Strings    ${entry1}    ${entry2}    ${entry3}
  81     Add Filter    GROUP    outbound    ${entries}
  82     Setup Nodes
  83     Wait Until Keyword Succeeds    4    2    Check One Group 2-5
  84     Delete Filter    GROUP    outbound
  85     ${entries}    Get Filter Entry    10    permit    esgt=20,40    pl=10.10.0.0/16
  86     Add Filter    GROUP    outbound    ${entries}
  87     Wait Until Keyword Succeeds    4    2    Check Two Group 2-5