csit/suites/tsdr/HSQLDB/040_QueueMetrics.robot

   1 *** Settings ***
   2 Documentation       Test suite for HSQLDB DataStore Queue Metrics Verification
   3
   4 Library             SSHLibrary
   5 Library             Collections
   6 Library             String
   7 Library             ../../../libraries/Common.py
   8 Resource            ../../../libraries/CompareStream.robot
   9 Resource            ../../../libraries/KarafKeywords.robot
  10 Resource            ../../../libraries/TsdrUtils.robot
  11 Variables           ../../../variables/Variables.py
  12
  13 Suite Setup         Run Keywords    Start Tsdr Suite    Configuration of Queue on Switch
  14 Suite Teardown      Stop Tsdr Suite
  15
  16
  17 *** Variables ***
  18 @{QUEUE_METRICS}    TransmittedPackets    TransmittedBytes    TransmissionErrors
  19
  20
  21 *** Test Cases ***
  22 Init Variables
  23     [Documentation]    Initialize ODL version specific variables
  24     Init Variables Master
  25
  26 Verify the QueueStats attributes exist thru Karaf console
  27     [Documentation]    Verify the QueueMetrics attributes exist on Karaf Console
  28     Wait Until Keyword Succeeds    60s    1s    Verify the Metric is Collected?    ${TSDR_QUEUE_STATS}    Transmitted
  29     ${output}=    Issue Command On Karaf Console
  30     ...    ${TSDR_QUEUE_STATS}
  31     ...    ${ODL_SYSTEM_IP}
  32     ...    ${KARAF_SHELL_PORT}
  33     ...    30
  34     FOR    ${list}    IN    @{QUEUE_METRICS}
  35         Should Contain    ${output}    ${list}
  36     END
  37
  38
  39 *** Keywords ***
  40 Configuration of Queue on Switch
  41     [Documentation]    Queue configuration on openvswitch
  42     Configure the Queue on Switch    s2-eth2
  43
  44 Init Variables Master
  45     [Documentation]    Sets variables specific to latest(master) version
  46     Set Suite Variable    ${TSDR_QUEUE_STATS}    tsdr:list QUEUESTATS