csit/libraries/NetconfKeywords.robot

   1 *** Settings ***
   2 Documentation     Perform complex operations on netconf.
   3 ...
   4 ...               Copyright (c) 2015 Cisco Systems, Inc. and others. All rights reserved.
   5 ...
   6 ...               This program and the accompanying materials are made available under the
   7 ...               terms of the Eclipse Public License v1.0 which accompanies this distribution,
   8 ...               and is available at http://www.eclipse.org/legal/epl-v10.html
   9 ...
  10 ...
  11 ...               This library encapsulates a bunch of somewhat complex and commonly used
  12 ...               netconf operations into reusable keywords to make writing netconf
  13 ...               test suites easier.
  14 Library           Collections
  15 Library           DateTime
  16 Library           RequestsLibrary
  17 Resource          NetconfViaRestconf.robot
  18 Resource          NexusKeywords.robot
  19 Resource          SSHKeywords.robot
  20
  21 *** Variables ***
  22 ${TESTTOOL_DEFAULT_JAVA_OPTIONS}    -Xmx1G -XX:MaxPermSize=256M -Dorg.apache.sshd.registerBouncyCastle=false
  23 ${DIRECTORY_WITH_DEVICE_TEMPLATES}    ${CURDIR}/../variables/netconf/device
  24 ${FIRST_TESTTOOL_PORT}    17830
  25 ${BASE_NETCONF_DEVICE_PORT}    17830
  26 ${DEVICE_NAME_BASE}    netconf-scaling-device
  27 ${TESTTOOL_DEVICE_TIMEOUT}    60s
  28 ${ENABLE_NETCONF_TEST_TIMEOUT}    ${ENABLE_GLOBAL_TEST_DEADLINES}
  29
  30 *** Keywords ***
  31 Setup_NetconfKeywords
  32     [Documentation]    Setup the environment for the other keywords of this Resource to work properly.
  33     ${tmp}=    BuiltIn.Create_Dictionary
  34     BuiltIn.Set_Suite_Variable    ${NetconfKeywords__mounted_device_types}    ${tmp}
  35     NetconfViaRestconf.Setup_Netconf_Via_Restconf
  36     NexusKeywords.Initialize_Artifact_Deployment_And_Usage
  37
  38 Configure_Device_In_Netconf
  39     [Arguments]    ${device_name}    ${device_type}=default    ${device_port}=${FIRST_TESTTOOL_PORT}
  40     [Documentation]    Tell Netconf about the specified device so it can add it into its configuration.
  41     ${template_as_string}=    BuiltIn.Set_Variable    {'DEVICE_IP': '${TOOLS_SYSTEM_IP}', 'DEVICE_NAME': '${device_name}', 'DEVICE_PORT': '${device_port}'}
  42     NetconfViaRestconf.Put_Xml_Template_Folder_Via_Restconf    ${DIRECTORY_WITH_DEVICE_TEMPLATES}${/}${device_type}    ${template_as_string}
  43     Collections.Set_To_Dictionary    ${NetconfKeywords__mounted_device_types}    ${device_name}    ${device_type}
  44
  45 Count_Netconf_Connectors_For_Device
  46     [Arguments]    ${device_name}
  47     [Documentation]    Count all instances of the specified device in the Netconf topology (usually 0 or 1).
  48     # FIXME: This no longer counts netconf connectors, it counts "device instances in Netconf topology".
  49     # This keyword should be renamed but without an automatic keyword naming standards checker this is
  50     # potentially destabilizing change so right now it is as FIXME. Proposed new name:
  51     # Count_Device_Instances_In_Netconf_Topology
  52     ${mounts}=    NetconfViaRestconf.Get_Operational_Data_From_URI    network-topology:network-topology/topology/topology-netconf
  53     Builtin.Log    ${mounts}
  54     ${actual_count}=    Builtin.Evaluate    len('''${mounts}'''.split('"node-id":"${device_name}"'))-1
  55     Builtin.Return_From_Keyword    ${actual_count}
  56
  57 Check_Device_Has_No_Netconf_Connector
  58     [Arguments]    ${device_name}
  59     [Documentation]    Check that there are no instances of the specified device in the Netconf topology.
  60     # FIXME: Similarlt to "Count_Netconf_Connectors_For_Device", this does not check whether the device has
  61     # no netconf connector but whether the device is present in the netconf topology or not. Rename, proposed
  62     # new name: Check_Device_Not_Present_In_Netconf_Topology
  63     ${count}    Count_Netconf_Connectors_For_Device    ${device_name}
  64     Builtin.Should_Be_Equal_As_Strings    ${count}    0
  65
  66 Check_Device_Completely_Gone
  67     [Arguments]    ${device_name}
  68     [Documentation]    Check that the specified device has no Netconf connectors nor associated data.
  69     Check_Device_Has_No_Netconf_Connector    ${device_name}
  70     ${uri}=    Builtin.Set_Variable    network-topology:network-topology/topology/topology-netconf/node/${device_name}
  71     ${response}=    RequestsLibrary.Get Request    nvr_session    ${uri}    ${ACCEPT_XML}
  72     BuiltIn.Should_Be_Equal_As_Integers    ${response.status_code}    404
  73
  74 Check_Device_Connected
  75     [Arguments]    ${device_name}
  76     [Documentation]    Check that the specified device is accessible from Netconf.
  77     ${device_status}=    NetconfViaRestconf.Get_Operational_Data_From_URI    network-topology:network-topology/topology/topology-netconf/node/${device_name}
  78     Builtin.Should_Contain    ${device_status}    "netconf-node-topology:connection-status":"connected"
  79
  80 Wait_Device_Connected
  81     [Arguments]    ${device_name}    ${timeout}=10s    ${period}=1s
  82     [Documentation]    Wait for the device to become connected.
  83     ...    It is more readable to use this keyword in a test case than to put the whole WUKS below into it.
  84     BuiltIn.Wait_Until_Keyword_Succeeds    ${timeout}    ${period}    Check_Device_Connected    ${device_name}
  85
  86 Remove_Device_From_Netconf
  87     [Arguments]    ${device_name}
  88     [Documentation]    Tell Netconf to deconfigure the specified device
  89     ${device_type}=    Collections.Pop_From_Dictionary    ${NetconfKeywords__mounted_device_types}    ${device_name}
  90     ${template_as_string}=    BuiltIn.Set_Variable    {'DEVICE_NAME': '${device_name}'}
  91     NetconfViaRestconf.Delete_Xml_Template_Folder_Via_Restconf    ${DIRECTORY_WITH_DEVICE_TEMPLATES}${/}${device_type}    ${template_as_string}
  92
  93 Wait_Device_Fully_Removed
  94     [Arguments]    ${device_name}    ${timeout}=10s    ${period}=1s
  95     [Documentation]    Wait until all netconf connectors for the device with the given name disappear.
  96     ...    Call of Remove_Device_From_Netconf returns before netconf gets
  97     ...    around deleting the device's connector. To ensure the device is
  98     ...    really gone from netconf, use this keyword to make sure all
  99     ...    connectors disappear. If a call to Remove_Device_From_Netconf
 100     ...    is not made before using this keyword, the wait will fail.
 101     ...    Using this keyword is more readable than putting the WUKS below
 102     ...    into a test case.
 103     BuiltIn.Wait_Until_Keyword_Succeeds    ${timeout}    ${period}    Check_Device_Completely_Gone    ${device_name}
 104
 105 NetconfKeywords__Deploy_Additional_Schemas
 106     [Arguments]    ${schemas}
 107     [Documentation]    Internal keyword for Install_And_Start_TestTool
 108     ...    This deploys the additional schemas if any and returns a
 109     ...    command line argument to be added to the testtool commandline
 110     ...    to tell it to load them. While this code could be integrated
 111     ...    into its only user, I considered the resulting code to be too
 112     ...    unreadable as the actions are quite different in the two
 113     ...    possibilities (additional schemas present versus no additional
 114     ...    schemas present), therefore a separate keyword is used.
 115     # Make sure there is no schemas directory on the remote machine. A
 116     # previous test suite might have left some debris there and that might
 117     # lead to spurious failures, so it is better to make sure we start with a
 118     # clean slate. Additionally when the caller did not specify any
 119     # additional schemas for testtool, we want to make extra sure none are
 120     # used.
 121     ${response}=    SSHLibrary.Execute_Command    rm -rf schemas 2>&1
 122     BuiltIn.Log    ${response}
 123     # Drop out of the keyword, returning no command line argument when there
 124     # are no additional schemas to deploy.
 125     BuiltIn.Return_From_Keyword_If    '${schemas}' == 'none'    ${EMPTY}
 126     # Deploy the additional schemas into a standard directory on the remote
 127     # machine and construct a command line argument pointing to that
 128     # directory from the point of view of the process running on that
 129     # machine.
 130     SSHLibrary.Put_Directory    ${schemas}    destination=./schemas
 131     [Return]    --schemas-dir ./schemas
 132
 133 NetconfKeywords__Check_Device_Is_Up
 134     [Arguments]    ${last-port}
 135     ${count}=    SSHKeywords.Count_Port_Occurences    ${last-port}    LISTEN    java
 136     BuiltIn.Should_Be_Equal_As_Integers    ${count}    1
 137
 138 NetconfKeywords__Wait_Device_Is_Up_And_Running
 139     [Arguments]    ${device_name}
 140     ${number}=    BuiltIn.Evaluate    '${device_name}'.split('-').pop()
 141     BuiltIn.Wait_Until_Keyword_Succeeds    ${TESTTOOL_DEVICE_TIMEOUT}    1s    Check_Device_Up_And_Running    ${number}
 142
 143 Install_And_Start_Testtool
 144     [Arguments]    ${device-count}=10    ${debug}=true    ${schemas}=none    ${tool_options}=${EMPTY}    ${java_options}=${TESTTOOL_DEFAULT_JAVA_OPTIONS}    ${mdsal}=true
 145     [Documentation]    Install and run testtool. Also arrange to collect its output into a log file.
 146     ...    When the ${schemas} argument is set to 'none', it signifies that
 147     ...    there are no additional schemas to be deployed, so the directory
 148     ...    for the additional schemas is deleted on the remote machine and
 149     ...    the additional schemas argument is left out.
 150     # Install test tool on the machine.
 151     ${filename}=    NexusKeywords.Deploy_Test_Tool    netconf    netconf-testtool
 152     ${schemas_option}=    NetconfKeywords__Deploy_Additional_Schemas    ${schemas}
 153     # Start the testtool
 154     ${command}    BuiltIn.Set_Variable    java ${java_options} -jar ${filename} ${tool_options} --device-count ${device-count} --debug ${debug} ${schemas_option} --md-sal ${mdsal}
 155     BuiltIn.Log    Running testtool: ${command}
 156     SSHLibrary.Write    ${command} >testtool.log 2>&1
 157     # Store information needed by other keywords.
 158     BuiltIn.Set_Suite_Variable    ${NetconfKeywords__testtool_device_count}    ${device-count}
 159     # Wait for the testtool to boot up.
 160     Perform_Operation_On_Each_Device    NetconfKeywords__Wait_Device_Is_Up_And_Running
 161
 162 Check_Device_Up_And_Running
 163     [Arguments]    ${device-number}
 164     [Documentation]    Query netstat on remote machine whether testtool device with the specified number has its port open and fail if not.
 165     ${device-port}=    BuiltIn.Evaluate    ${FIRST_TESTTOOL_PORT}+${device-number}-1
 166     NetconfKeywords__Check_Device_Is_Up    ${device-port}
 167
 168 Stop_Testtool
 169     [Documentation]    Stop testtool and download its log.
 170     Utils.Write_Bare_Ctrl_C
 171     SSHLibrary.Read_Until_Prompt
 172     # TODO: Unify with play.py and pcc-mock handling.
 173     # TODO: Maybe this keyword's content shall be moved into SSHUtils and named somewhat like
 174     # "Interrupt_Program_And_Download_Its_Log" which will get an argument stating the name of
 175     # the log file to get.
 176     SSHLibrary.Get_File    testtool.log
 177
 178 NetconfKeywords__Check_Netconf_Test_Timeout_Not_Expired
 179     [Arguments]    ${deadline_Date}
 180     BuiltIn.Return_From_Keyword_If    not ${ENABLE_NETCONF_TEST_TIMEOUT}
 181     ${current_Date}=    DateTime.Get_Current_Date
 182     ${ellapsed_seconds}=    DateTime.Subtract_Date_From_Date    ${deadline_Date}    ${current_Date}
 183     BuiltIn.Run_Keyword_If    ${ellapsed_seconds}<0    Fail    The global time out period expired
 184
 185 NetconfKeywords__Perform_Operation_With_Checking_On_Next_Device
 186     [Arguments]    ${operation}    ${deadline_Date}
 187     NetconfKeywords__Check_Netconf_Test_Timeout_Not_Expired    ${deadline_Date}
 188     ${number}=    BuiltIn.Evaluate    ${current_port}-${BASE_NETCONF_DEVICE_PORT}+1
 189     BuiltIn.Run_Keyword    ${operation}    ${DEVICE_NAME_BASE}-${number}
 190     ${next}=    BuiltIn.Evaluate    ${current_port}+1
 191     BuiltIn.Set_Suite_Variable    ${current_port}    ${next}
 192
 193 Perform_Operation_On_Each_Device
 194     [Arguments]    ${operation}    ${count}=${NetconfKeywords__testtool_device_count}    ${timeout}=30m
 195     ${current_Date}=    DateTime.Get_Current_Date
 196     ${deadline_Date}=    DateTime.Add_Time_To_Date    ${current_Date}    ${timeout}
 197     BuiltIn.Set_Suite_Variable    ${current_port}    ${BASE_NETCONF_DEVICE_PORT}
 198     BuiltIn.Repeat_Keyword    ${count} times    NetconfKeywords__Perform_Operation_With_Checking_On_Next_Device    ${operation}    ${deadline_Date}