csit/libraries/NetconfKeywords.robot

   1 *** Settings ***
   2 Documentation     Perform complex operations on netconf.
   3 ...
   4 ...               Copyright (c) 2015 Cisco Systems, Inc. and others. All rights reserved.
   5 ...
   6 ...               This program and the accompanying materials are made available under the
   7 ...               terms of the Eclipse Public License v1.0 which accompanies this distribution,
   8 ...               and is available at http://www.eclipse.org/legal/epl-v10.html
   9 ...
  10 ...
  11 ...               This library encapsulates a bunch of somewhat complex and commonly used
  12 ...               netconf operations into reusable keywords to make writing netconf
  13 ...               test suites easier.
  14 Library           Collections
  15 Library           DateTime
  16 Library           RequestsLibrary
  17 Library           SSHLibrary
  18 Resource          NetconfViaRestconf.robot
  19 Resource          NexusKeywords.robot
  20 Resource          SSHKeywords.robot
  21 Resource          Utils.robot
  22
  23 *** Variables ***
  24 ${TESTTOOL_DEFAULT_JAVA_OPTIONS}    -Xmx1G -XX:MaxPermSize=256M -Dorg.apache.sshd.registerBouncyCastle=false
  25 ${DIRECTORY_WITH_DEVICE_TEMPLATES}    ${CURDIR}/../variables/netconf/device
  26 ${FIRST_TESTTOOL_PORT}    17830
  27 ${BASE_NETCONF_DEVICE_PORT}    17830
  28 ${DEVICE_NAME_BASE}    netconf-scaling-device
  29 ${TESTTOOL_DEVICE_TIMEOUT}    60s
  30 ${ENABLE_NETCONF_TEST_TIMEOUT}    ${ENABLE_GLOBAL_TEST_DEADLINES}
  31
  32 *** Keywords ***
  33 Setup_NetconfKeywords
  34     [Documentation]    Setup the environment for the other keywords of this Resource to work properly.
  35     ${tmp}=    BuiltIn.Create_Dictionary
  36     BuiltIn.Set_Suite_Variable    ${NetconfKeywords__mounted_device_types}    ${tmp}
  37     NetconfViaRestconf.Setup_Netconf_Via_Restconf
  38     NexusKeywords.Initialize_Artifact_Deployment_And_Usage
  39
  40 Configure_Device_In_Netconf
  41     [Arguments]    ${device_name}    ${device_type}=default    ${device_port}=${FIRST_TESTTOOL_PORT}    ${device_address}=${TOOLS_SYSTEM_IP}    ${device_user}=admin    ${device_password}=topsecret
  42     [Documentation]    Tell Netconf about the specified device so it can add it into its configuration.
  43     ${template_as_string}=    BuiltIn.Set_Variable    {'DEVICE_IP': '${device_address}', 'DEVICE_NAME': '${device_name}', 'DEVICE_PORT': '${device_port}', 'DEVICE_USER': '${device_user}', 'DEVICE_PASSWORD': '${device_password}'}
  44     NetconfViaRestconf.Put_Xml_Template_Folder_Via_Restconf    ${DIRECTORY_WITH_DEVICE_TEMPLATES}${/}${device_type}    ${template_as_string}
  45     Collections.Set_To_Dictionary    ${NetconfKeywords__mounted_device_types}    ${device_name}    ${device_type}
  46
  47 Count_Netconf_Connectors_For_Device
  48     [Arguments]    ${device_name}
  49     [Documentation]    Count all instances of the specified device in the Netconf topology (usually 0 or 1).
  50     # FIXME: This no longer counts netconf connectors, it counts "device instances in Netconf topology".
  51     # This keyword should be renamed but without an automatic keyword naming standards checker this is
  52     # potentially destabilizing change so right now it is as FIXME. Proposed new name:
  53     # Count_Device_Instances_In_Netconf_Topology
  54     ${mounts}=    NetconfViaRestconf.Get_Operational_Data_From_URI    network-topology:network-topology/topology/topology-netconf
  55     Builtin.Log    ${mounts}
  56     ${actual_count}=    Builtin.Evaluate    len('''${mounts}'''.split('"node-id":"${device_name}"'))-1
  57     Builtin.Return_From_Keyword    ${actual_count}
  58
  59 Check_Device_Has_No_Netconf_Connector
  60     [Arguments]    ${device_name}
  61     [Documentation]    Check that there are no instances of the specified device in the Netconf topology.
  62     # FIXME: Similarlt to "Count_Netconf_Connectors_For_Device", this does not check whether the device has
  63     # no netconf connector but whether the device is present in the netconf topology or not. Rename, proposed
  64     # new name: Check_Device_Not_Present_In_Netconf_Topology
  65     ${count}    Count_Netconf_Connectors_For_Device    ${device_name}
  66     Builtin.Should_Be_Equal_As_Strings    ${count}    0
  67
  68 Check_Device_Completely_Gone
  69     [Arguments]    ${device_name}
  70     [Documentation]    Check that the specified device has no Netconf connectors nor associated data.
  71     Check_Device_Has_No_Netconf_Connector    ${device_name}
  72     ${uri}=    Builtin.Set_Variable    network-topology:network-topology/topology/topology-netconf/node/${device_name}
  73     ${response}=    RequestsLibrary.Get Request    nvr_session    ${uri}    ${ACCEPT_XML}
  74     BuiltIn.Should_Be_Equal_As_Integers    ${response.status_code}    404
  75
  76 Check_Device_Connected
  77     [Arguments]    ${device_name}
  78     [Documentation]    Check that the specified device is accessible from Netconf.
  79     ${device_status}=    NetconfViaRestconf.Get_Operational_Data_From_URI    network-topology:network-topology/topology/topology-netconf/node/${device_name}
  80     Builtin.Should_Contain    ${device_status}    "netconf-node-topology:connection-status":"connected"
  81
  82 Wait_Device_Connected
  83     [Arguments]    ${device_name}    ${timeout}=10s    ${period}=1s
  84     [Documentation]    Wait for the device to become connected.
  85     ...    It is more readable to use this keyword in a test case than to put the whole WUKS below into it.
  86     BuiltIn.Wait_Until_Keyword_Succeeds    ${timeout}    ${period}    Check_Device_Connected    ${device_name}
  87
  88 Remove_Device_From_Netconf
  89     [Arguments]    ${device_name}
  90     [Documentation]    Tell Netconf to deconfigure the specified device
  91     ${device_type}=    Collections.Pop_From_Dictionary    ${NetconfKeywords__mounted_device_types}    ${device_name}
  92     ${template_as_string}=    BuiltIn.Set_Variable    {'DEVICE_NAME': '${device_name}'}
  93     NetconfViaRestconf.Delete_Xml_Template_Folder_Via_Restconf    ${DIRECTORY_WITH_DEVICE_TEMPLATES}${/}${device_type}    ${template_as_string}
  94
  95 Wait_Device_Fully_Removed
  96     [Arguments]    ${device_name}    ${timeout}=10s    ${period}=1s
  97     [Documentation]    Wait until all netconf connectors for the device with the given name disappear.
  98     ...    Call of Remove_Device_From_Netconf returns before netconf gets
  99     ...    around deleting the device's connector. To ensure the device is
 100     ...    really gone from netconf, use this keyword to make sure all
 101     ...    connectors disappear. If a call to Remove_Device_From_Netconf
 102     ...    is not made before using this keyword, the wait will fail.
 103     ...    Using this keyword is more readable than putting the WUKS below
 104     ...    into a test case.
 105     BuiltIn.Wait_Until_Keyword_Succeeds    ${timeout}    ${period}    Check_Device_Completely_Gone    ${device_name}
 106
 107 NetconfKeywords__Deploy_Additional_Schemas
 108     [Arguments]    ${schemas}
 109     [Documentation]    Internal keyword for Install_And_Start_TestTool
 110     ...    This deploys the additional schemas if any and returns a
 111     ...    command line argument to be added to the testtool commandline
 112     ...    to tell it to load them. While this code could be integrated
 113     ...    into its only user, I considered the resulting code to be too
 114     ...    unreadable as the actions are quite different in the two
 115     ...    possibilities (additional schemas present versus no additional
 116     ...    schemas present), therefore a separate keyword is used.
 117     # Make sure there is no schemas directory on the remote machine. A
 118     # previous test suite might have left some debris there and that might
 119     # lead to spurious failures, so it is better to make sure we start with a
 120     # clean slate. Additionally when the caller did not specify any
 121     # additional schemas for testtool, we want to make extra sure none are
 122     # used.
 123     ${response}=    SSHLibrary.Execute_Command    rm -rf schemas 2>&1
 124     BuiltIn.Log    ${response}
 125     # Drop out of the keyword, returning no command line argument when there
 126     # are no additional schemas to deploy.
 127     BuiltIn.Return_From_Keyword_If    '${schemas}' == 'none'    ${EMPTY}
 128     # Deploy the additional schemas into a standard directory on the remote
 129     # machine and construct a command line argument pointing to that
 130     # directory from the point of view of the process running on that
 131     # machine.
 132     SSHLibrary.Put_Directory    ${schemas}    destination=./schemas
 133     [Return]    --schemas-dir ./schemas
 134
 135 NetconfKeywords__Check_Device_Is_Up
 136     [Arguments]    ${last-port}
 137     ${count}=    SSHKeywords.Count_Port_Occurences    ${last-port}    LISTEN    java
 138     BuiltIn.Should_Be_Equal_As_Integers    ${count}    1
 139
 140 NetconfKeywords__Wait_Device_Is_Up_And_Running
 141     [Arguments]    ${device_name}
 142     ${number}=    BuiltIn.Evaluate    '${device_name}'.split('-').pop()
 143     BuiltIn.Wait_Until_Keyword_Succeeds    ${TESTTOOL_DEVICE_TIMEOUT}    1s    Check_Device_Up_And_Running    ${number}
 144
 145 Install_And_Start_Testtool
 146     [Arguments]    ${device-count}=10    ${debug}=true    ${schemas}=none    ${tool_options}=${EMPTY}    ${java_options}=${TESTTOOL_DEFAULT_JAVA_OPTIONS}    ${mdsal}=true
 147     [Documentation]    Install and run testtool. Also arrange to collect its output into a log file.
 148     ...    When the ${schemas} argument is set to 'none', it signifies that
 149     ...    there are no additional schemas to be deployed, so the directory
 150     ...    for the additional schemas is deleted on the remote machine and
 151     ...    the additional schemas argument is left out.
 152     # Install test tool on the machine.
 153     ${filename}=    NexusKeywords.Deploy_Test_Tool    netconf    netconf-testtool
 154     ${schemas_option}=    NetconfKeywords__Deploy_Additional_Schemas    ${schemas}
 155     # Start the testtool
 156     ${command}=    NexusKeywords.Compose_Full_Java_Command    ${java_options} -jar ${filename} ${tool_options} --device-count ${device-count} --debug ${debug} ${schemas_option} --md-sal ${mdsal}
 157     BuiltIn.Log    Running testtool: ${command}
 158     ${logfile}=    Utils.Get_Log_File_Name    testtool
 159     BuiltIn.Set_Suite_Variable    ${testtool_log}    ${logfile}
 160     SSHLibrary.Write    ${command} >${logfile} 2>&1
 161     # Store information needed by other keywords.
 162     BuiltIn.Set_Suite_Variable    ${NetconfKeywords__testtool_device_count}    ${device-count}
 163     # Wait for the testtool to boot up.
 164     Perform_Operation_On_Each_Device    NetconfKeywords__Wait_Device_Is_Up_And_Running
 165
 166 Check_Device_Up_And_Running
 167     [Arguments]    ${device-number}
 168     [Documentation]    Query netstat on remote machine whether testtool device with the specified number has its port open and fail if not.
 169     ${device-port}=    BuiltIn.Evaluate    ${FIRST_TESTTOOL_PORT}+${device-number}-1
 170     NetconfKeywords__Check_Device_Is_Up    ${device-port}
 171
 172 Stop_Testtool
 173     [Documentation]    Stop testtool and download its log.
 174     Utils.Write_Bare_Ctrl_C
 175     SSHLibrary.Read_Until_Prompt
 176     # TODO: Unify with play.py and pcc-mock handling.
 177     # TODO: Maybe this keyword's content shall be moved into SSHUtils and named somewhat like
 178     # "Interrupt_Program_And_Download_Its_Log" which will get an argument stating the name of
 179     # the log file to get.
 180     SSHLibrary.Get_File    ${testtool_log}
 181
 182 NetconfKeywords__Check_Netconf_Test_Timeout_Not_Expired
 183     [Arguments]    ${deadline_Date}
 184     BuiltIn.Return_From_Keyword_If    not ${ENABLE_NETCONF_TEST_TIMEOUT}
 185     ${current_Date}=    DateTime.Get_Current_Date
 186     ${ellapsed_seconds}=    DateTime.Subtract_Date_From_Date    ${deadline_Date}    ${current_Date}
 187     BuiltIn.Run_Keyword_If    ${ellapsed_seconds}<0    Fail    The global time out period expired
 188
 189 NetconfKeywords__Perform_Operation_With_Checking_On_Next_Device
 190     [Arguments]    ${operation}    ${deadline_Date}
 191     NetconfKeywords__Check_Netconf_Test_Timeout_Not_Expired    ${deadline_Date}
 192     ${number}=    BuiltIn.Evaluate    ${current_port}-${BASE_NETCONF_DEVICE_PORT}+1
 193     BuiltIn.Run_Keyword    ${operation}    ${DEVICE_NAME_BASE}-${number}
 194     ${next}=    BuiltIn.Evaluate    ${current_port}+1
 195     BuiltIn.Set_Suite_Variable    ${current_port}    ${next}
 196
 197 Perform_Operation_On_Each_Device
 198     [Arguments]    ${operation}    ${count}=${NetconfKeywords__testtool_device_count}    ${timeout}=30m
 199     ${current_Date}=    DateTime.Get_Current_Date
 200     ${deadline_Date}=    DateTime.Add_Time_To_Date    ${current_Date}    ${timeout}
 201     BuiltIn.Set_Suite_Variable    ${current_port}    ${BASE_NETCONF_DEVICE_PORT}
 202     BuiltIn.Repeat_Keyword    ${count} times    NetconfKeywords__Perform_Operation_With_Checking_On_Next_Device    ${operation}    ${deadline_Date}