csit/libraries/Utils.robot

   1 *** Settings ***
   2 Documentation     General Utils library. This library has broad scope, it can be used by any robot system tests.
   3 Library           SSHLibrary
   4 Library           HttpLibrary.HTTP
   5 Library           String
   6 Library           DateTime
   7 Library           Process
   8 Library           Collections
   9 Library           RequestsLibrary
  10 Library           OperatingSystem
  11 Library           ${CURDIR}/UtilLibrary.py
  12 Resource          ${CURDIR}/SSHKeywords.robot
  13 Resource          ${CURDIR}/TemplatedRequests.robot
  14 Variables         ${CURDIR}/../variables/Variables.py
  15
  16 *** Variables ***
  17 # TODO: Introduce ${tree_size} and use instead of 1 in the next line.
  18 ${start}          sudo mn --controller=remote,ip=${ODL_SYSTEM_IP} --topo tree,1 --switch ovsk,protocols=OpenFlow13
  19
  20 *** Keywords ***
  21 Start Mininet
  22     [Arguments]    ${system}=${TOOLS_SYSTEM_IP}    ${user}=${TOOLS_SYSTEM_USER}    ${password}=${TOOLS_SYSTEM_PASSWORD}    ${prompt}=${DEFAULT_LINUX_PROMPT}    ${timeout}=30s
  23     [Documentation]    Basic setup/cleanup work that can be done safely before any system
  24     ...    is run.
  25     Log    Start the test on the base edition
  26     Clean Mininet System
  27     ${mininet_conn_id}=    Open Connection    ${system}    prompt=${prompt}    timeout=${timeout}
  28     Set Suite Variable    ${mininet_conn_id}
  29     SSHKeywords.Flexible Mininet Login    user=${user}    password=${password}
  30     Execute Command    sudo ovs-vsctl set-manager ptcp:6644
  31     Write    ${start}
  32     Read Until    mininet>
  33
  34 Stop Mininet
  35     [Arguments]    ${prompt}=${DEFAULT_LINUX_PROMPT}
  36     [Documentation]    Cleanup/Shutdown work that should be done at the completion of all
  37     ...    tests
  38     Log    Stop the test on the base edition
  39     Switch Connection    ${mininet_conn_id}
  40     Read
  41     Write    exit
  42     Read Until    ${prompt}
  43     Close Connection
  44
  45 Report_Failure_Due_To_Bug
  46     [Arguments]    ${number}    ${include_bug_in_tags}=True
  47     [Documentation]    Report that a test failed due to a known Bugzilla bug whose
  48     ...    number is provided as an argument.
  49     ...    Not FAILED (incl. SKIPPED) test are not reported.
  50     ...    This keyword must be used in the [Teardown] setting of the affected test
  51     ...    or as the first line of the test if FastFail module is not being
  52     ...    used. It reports the URL of the bug on console and also puts it
  53     ...    into the Robot log file.
  54     ${test_skipped}=    BuiltIn.Evaluate    len(re.findall('SKIPPED', """${TEST_MESSAGE}""")) > 0    modules=re
  55     BuiltIn.Return From Keyword If    ('${TEST_STATUS}' != 'FAIL') or ${test_skipped}
  56     ${bug_url}=    BuiltIn.Set_Variable    https://bugs.opendaylight.org/show_bug.cgi?id=${number}
  57     ${msg}=    BuiltIn.Set_Variable    This test fails due to ${bug_url}
  58     ${newline}=    BuiltIn.Evaluate    chr(10)
  59     BuiltIn.Set Test Message    ${msg}${newline}${newline}${TEST_MESSAGE}
  60     BuiltIn.Log    ${msg}
  61     BuiltIn.Run_Keyword_If    "${include_bug_in_tags}"=="True"    Set Tags    ${bug_url}
  62
  63 Report_Failure_And_Point_To_Linked_Bugs
  64     [Documentation]    Report that a test failed and point to linked Bugzilla bug(s).
  65     ...    Linked bugs must contain the ${reference} inside comments (workaround
  66     ...    becasue of currently missing suitable field for external references and
  67     ...    not correctly working the CONTENT MATCHES filter).
  68     ...    Not FAILED (incl. SKIPPED) test are not reported.
  69     ...    This keyword must be used in the [Teardown] setting of the affected test
  70     ...    or as the first line of the test if FastFail module is not being
  71     ...    used. It reports the URL of the bug on console and also puts it
  72     ...    into the Robot log file.
  73     ${test_skipped}=    BuiltIn.Evaluate    len(re.findall('SKIPPED', """${TEST_MESSAGE}""")) > 0    modules=re
  74     BuiltIn.Return From Keyword If    ('${TEST_STATUS}' != 'FAIL') or ${test_skipped}
  75     ${newline}=    BuiltIn.Evaluate    chr(10)
  76     ${reference}=    String.Replace_String_Using_Regexp    ${SUITE_NAME}_${TEST_NAME}    [ /\.-]    _
  77     ${reference}=    String.Convert_To_Lowercase    ${reference}
  78     ${msg}=    BuiltIn.Set_Variable    ... click for list of related bugs or create a new one if needed (with the${newline}"${reference}"${newline}reference somewhere inside)
  79     ${bugs}=    BuiltIn.Set_Variable    "https://bugs.opendaylight.org/buglist.cgi?f1=cf_external_ref&o1=substring&v1=${reference}&order=bug_status"
  80     BuiltIn.Set Test Message    ${msg}${newline}${bugs}${newline}${newline}${TEST_MESSAGE}
  81     BuiltIn.Log    ${msg}${newline}${bugs}
  82
  83 Check Nodes Stats
  84     [Arguments]    ${node}    ${session}=session
  85     [Documentation]    A GET on the /node/${node} API is made and specific flow stat
  86     ...    strings are checked for existence.
  87     ${resp}    RequestsLibrary.Get Request    ${session}    ${OPERATIONAL_NODES_API}/node/${node}
  88     Should Be Equal As Strings    ${resp.status_code}    200
  89     Should Contain    ${resp.content}    flow-capable-node-connector-statistics
  90     Should Contain    ${resp.content}    flow-table-statistics
  91
  92 Check For Specific Number Of Elements At URI
  93     [Arguments]    ${uri}    ${element}    ${expected_count}    ${session}=session
  94     [Documentation]    A GET is made to the specified ${URI} and the specific count of a
  95     ...    given element is done (as supplied by ${element} and ${expected_count})
  96     ${resp}    RequestsLibrary.Get Request    ${session}    ${uri}
  97     Log    ${resp.content}
  98     Should Be Equal As Strings    ${resp.status_code}    200
  99     Should Contain X Times    ${resp.content}    ${element}    ${expected_count}
 100
 101 Check For Elements At URI
 102     [Arguments]    ${uri}    ${elements}    ${session}=session
 103     [Documentation]    A GET is made at the supplied ${URI} and every item in the list of
 104     ...    ${elements} is verified to exist in the response
 105     ${resp}    RequestsLibrary.Get Request    ${session}    ${uri}
 106     Log    ${resp.content}
 107     Should Be Equal As Strings    ${resp.status_code}    200
 108     : FOR    ${i}    IN    @{elements}
 109     \    Should Contain    ${resp.content}    ${i}
 110
 111 Check For Elements Not At URI
 112     [Arguments]    ${uri}    ${elements}    ${session}=session
 113     [Documentation]    A GET is made at the supplied ${URI} and every item in the list of
 114     ...    ${elements} is verified to NOT exist in the response
 115     ${resp}    RequestsLibrary.Get Request    ${session}    ${uri}
 116     Log    ${resp.content}
 117     Should Be Equal As Strings    ${resp.status_code}    200
 118     : FOR    ${i}    IN    @{elements}
 119     \    Should Not Contain    ${resp.content}    ${i}
 120
 121 Clean Mininet System
 122     [Arguments]    ${system}=${TOOLS_SYSTEM_IP}
 123     Run Command On Mininet    ${system}    sudo mn -c
 124     Run Command On Mininet    ${system}    sudo ps -elf | egrep 'usr/local/bin/mn' | egrep python | awk '{print "sudo kill -9",$4}' | sh
 125
 126 Clean Up Ovs
 127     [Arguments]    ${system}=${TOOLS_SYSTEM_IP}
 128     [Documentation]    Cleans up the OVS instance and remove any existing common known bridges.
 129     ${output}=    Run Command On Mininet    ${system}    sudo ovs-vsctl list-br
 130     Log    ${output}
 131     : FOR    ${i}    IN    ${output}
 132     \    Run Command On Mininet    ${system}    sudo ovs-vsctl --if-exists del-br ${i}
 133     Run Command On Mininet    ${system}    sudo ovs-vsctl del-manager
 134
 135 Extract Value From Content
 136     [Arguments]    ${content}    ${index}    ${strip}=nostrip
 137     [Documentation]    Will take the given response content and return the value at the given index as a string
 138     ${value}=    Get Json Value    ${content}    ${index}
 139     ${value}=    Convert To String    ${value}
 140     ${value}=    Run Keyword If    '${strip}' == 'strip'    Strip Quotes    ${value}
 141     [Return]    ${value}
 142
 143 Get Process ID Based On Regex On Remote System
 144     [Arguments]    ${system}    ${regex_string_to_match_on}    ${user}=${TOOLS_SYSTEM_USER}    ${password}=${EMPTY}    ${prompt}=${DEFAULT_LINUX_PROMPT}    ${prompt_timeout}=30s
 145     [Documentation]    Uses ps to find a process that matches the supplied regex. Returns the PID of that process
 146     ...    The ${regex_string_to_match_on} should produce a unique process otherwise the PID returned may not be
 147     ...    the expected PID
 148     # doing the extra -v grep in this command to exclude the grep process itself from the output
 149     ${cmd}=    Set Variable    ps -elf | grep -v grep | grep ${regex_string_to_match_on} | awk '{print $4}'
 150     ${output}=    Run Command On Remote System    ${system}    ${cmd}    user=${user}    password=${password}    prompt=${prompt}
 151     ...    prompt_timeout=${prompt_timeout}
 152     # ${output} contains the system prompt and all we want is the value of the number
 153     ${pid}=    Fetch From Left    ${output}    \r
 154     # TODO: Get Process * keywords have perhaps non-standard default credentials.
 155     # ...    Should there be * On Mininet and * On Controller specializations?
 156     [Return]    ${pid}
 157
 158 Get Process Thread Count On Remote System
 159     [Arguments]    ${system}    ${pid}    ${user}=${TOOLS_SYSTEM_USER}    ${password}=${EMPTY}    ${prompt}=${DEFAULT_LINUX_PROMPT}    ${prompt_timeout}=30s
 160     [Documentation]    Executes the ps command to retrieve the lightweight process (aka thread) count.
 161     ${cmd}=    Set Variable    ps --no-headers -o nlwp ${pid}
 162     ${output}=    Run Command On Remote System    ${system}    ${cmd}    user=${user}    password=${password}    prompt=${prompt}
 163     ...    prompt_timeout=${prompt_timeout}
 164     # ${output} contains the system prompt and all we want is the value of the number
 165     ${thread_count}=    Fetch From Left    ${output}    \r
 166     [Return]    ${thread_count}
 167
 168 Strip Quotes
 169     [Arguments]    ${string_to_strip}
 170     [Documentation]    Will strip ALL quotes from given string and return the new string
 171     ${string_to_return}=    Replace String    ${string_to_strip}    "    \    count=-1
 172     [Return]    ${string_to_return}
 173
 174 Run Command On Remote System
 175     [Arguments]    ${system}    ${cmd}    ${user}=${DEFAULT_USER}    ${password}=${EMPTY}    ${prompt}=${DEFAULT_LINUX_PROMPT}    ${prompt_timeout}=${DEFAULT_TIMEOUT}
 176     ...    ${return_stdout}=True    ${return_stderr}=False
 177     [Documentation]    Reduces the common work of running a command on a remote system to a single higher level
 178     ...    robot keyword, taking care to log in with a public key and. The command given is written and the return value
 179     ...    depends on the passed argument values of return_stdout (default: True) and return_stderr (default: False).
 180     ...    At least one should be True, or the keyword will exit and FAIL. If both are True, the resulting return value
 181     ...    will be a two element list containing both. Otherwise the resulting return value is a string.
 182     ...    No test conditions are checked.
 183     Run Keyword If    "${return_stdout}"!="True" and "${return_stderr}"!="True"    Fail    At least one of {return_stdout} or {return_stderr} args should be set to True
 184     ${current_ssh_connection}=    SSHLibrary.Get Connection
 185     BuiltIn.Log    Attempting to execute command "${cmd}" on remote system "${system}" by user "${user}" with keyfile pass "${keyfile_pass}" and prompt "${prompt}"
 186     BuiltIn.Log    ${password}
 187     ${conn_id}=    SSHLibrary.Open Connection    ${system}    prompt=${prompt}    timeout=${prompt_timeout}
 188     SSHKeywords.Flexible SSH Login    ${user}    ${password}
 189     ${stdout}    ${stderr}    SSHLibrary.Execute Command    ${cmd}    return_stderr=True
 190     SSHLibrary.Close Connection
 191     Log    ${stderr}
 192     Run Keyword If    "${return_stdout}"!="True"    Return From Keyword    ${stderr}
 193     Run Keyword If    "${return_stderr}"!="True"    Return From Keyword    ${stdout}
 194     [Teardown]    SSHKeywords.Restore_Current_SSH_Connection_From_Index    ${current_ssh_connection.index}
 195     [Return]    ${stdout}    ${stderr}
 196
 197 Run Command On Remote System And Log
 198     [Arguments]    ${system}    ${cmd}    ${user}=${DEFAULT_USER}    ${password}=${EMPTY}    ${prompt}=${DEFAULT_LINUX_PROMPT}    ${prompt_timeout}=${DEFAULT_TIMEOUT}
 199     [Documentation]    Reduces the common work of running a command on a remote system to a single higher level
 200     ...    robot keyword, taking care to log in with a public key and. The command given is written
 201     ...    and the output returned. No test conditions are checked.
 202     ${output} =    Run Command On Remote System    ${system}    ${cmd}    ${user}    ${password}    ${prompt}
 203     ...    ${prompt_timeout}
 204     Log    ${output}
 205     [Return]    ${output}
 206
 207 Run Command On Mininet
 208     [Arguments]    ${system}=${TOOLS_SYSTEM_IP}    ${cmd}=echo    ${user}=${TOOLS_SYSTEM_USER}    ${password}=${TOOLS_SYSTEM_PASSWORD}    ${prompt}=${TOOLS_SYSTEM_PROMPT}
 209     [Documentation]    Call Run Comand On Remote System, but with default values suitable for Mininet machine.
 210     BuiltIn.Run Keyword And Return    Run Command On Remote System    ${system}    ${cmd}    ${user}    ${password}    prompt=${prompt}
 211
 212 Run Command On Controller
 213     [Arguments]    ${system}=${ODL_SYSTEM_IP}    ${cmd}=echo    ${user}=${ODL_SYSTEM_USER}    ${password}=${ODL_SYSTEM_PASSWORD}    ${prompt}=${ODL_SYSTEM_PROMPT}
 214     [Documentation]    Call Run Comand On Remote System, but with default values suitable for Controller machine.
 215     BuiltIn.Log    ${password}
 216     BuiltIn.Run Keyword And Return    Run Command On Remote System    ${system}    ${cmd}    ${user}    ${password}    prompt=${prompt}
 217
 218 Verify File Exists On Remote System
 219     [Arguments]    ${system}    ${file}    ${user}=${TOOLS_SYSTEM_USER}    ${password}=${TOOLS_SYSTEM_PASSWORD}    ${prompt}=${DEFAULT_LINUX_PROMPT}    ${prompt_timeout}=5s
 220     [Documentation]    Will create connection with public key and will PASS if the given ${file} exists,
 221     ...    otherwise will FAIL
 222     ${conn_id}=    Open Connection    ${system}    prompt=${prompt}    timeout=${prompt_timeout}
 223     SSHKeywords.Flexible SSH Login    ${user}    ${password}
 224     SSHLibrary.File Should Exist    ${file}
 225     Close Connection
 226
 227 Check Karaf Log File Does Not Have Messages
 228     [Arguments]    ${ip}    ${message}    ${user}=${ODL_SYSTEM_USER}    ${password}=${ODL_SYSTEM_PASSWORD}    ${prompt}=${ODL_SYSTEM_PROMPT}    ${log_file}=${WORKSPACE}/${BUNDLEFOLDER}/data/log/karaf.log
 229     [Documentation]    Fails if the provided ${message} is found in the karaf.log file. Uses grep to search. The
 230     ...    karaf.log file can be overridden with ${log_file} to be any file on the given system @ ${ip}
 231     ${output}=    Run Command On Controller    ${ip}    grep -c '${message}' ${log_file}    user=${user}    password=${password}    prompt=${prompt}
 232     Should Be Equal As Strings    ${output}    0
 233
 234 Verify Controller Is Not Dead
 235     [Arguments]    ${controller_ip}=${ODL_SYSTEM_IP}
 236     [Documentation]    Will execute any tests to verify the controller is not dead. Some checks are
 237     ...    Out Of Memory Execptions.
 238     Check Karaf Log File Does Not Have Messages    ${controller_ip}    java.lang.OutOfMemoryError
 239     # TODO: Should Verify Controller * keywords also accept user, password, prompt and karaf_log arguments?
 240
 241 Verify Controller Has No Null Pointer Exceptions
 242     [Arguments]    ${controller_ip}=${ODL_SYSTEM_IP}
 243     [Documentation]    Will execute any tests to verify the controller is not having any null pointer eceptions.
 244     Check Karaf Log File Does Not Have Messages    ${controller_ip}    java.lang.NullPointerException
 245
 246 Get Epoch Time
 247     [Arguments]    ${time}
 248     [Documentation]    Get the Epoc time from MM/DD/YYYY HH:MM:SS
 249     ${epoch_time}=    Convert Date    ${time}    epoch    exclude_milles=True    date_format=%m/%d/%Y %H:%M:%S
 250     ${epoch_time}=    Convert To Integer    ${epoch_time}
 251     [Return]    ${epoch_time}
 252
 253 Remove Space on String
 254     [Arguments]    ${str}    ${count}=-1
 255     [Documentation]    Remove the empty space from given string.count is optional,if its given
 256     ...    that many occurence of space will be removed from left
 257     ${x}=    Convert To String    ${str}
 258     ${x}=    Replace String    ${str}    ${SPACE}    ${EMPTY}    count=${count}
 259     [Return]    ${x}
 260
 261 Split Value from String
 262     [Arguments]    ${str}    ${splitter}
 263     [Documentation]    Split the String based on given splitter and return as list
 264     @{x}=    Split String    ${str}    ${splitter}
 265     [Return]    @{x}
 266
 267 Concatenate the String
 268     [Arguments]    ${str1}    ${str2}
 269     [Documentation]    Catenate the two non-string objects and return as String
 270     ${str1}=    Convert to String    ${str1}
 271     ${str2}=    Convert to String    ${str2}
 272     ${output}=    Catenate    ${str1}    ${str2}
 273     [Return]    ${output}
 274
 275 Post Elements To URI
 276     [Arguments]    ${rest_uri}    ${data}    ${headers}=${headers}    ${session}=session
 277     [Documentation]    Perform a POST rest operation, using the URL and data provided
 278     ${resp} =    RequestsLibrary.Post Request    ${session}    ${rest_uri}    data=${data}    headers=${headers}
 279     Log    ${resp.content}
 280     Should Contain    ${ALLOWED_STATUS_CODES}    ${resp.status_code}
 281
 282 Remove All Elements At URI
 283     [Arguments]    ${uri}    ${session}=session
 284     ${resp}    RequestsLibrary.Delete Request    ${session}    ${uri}
 285     Should Contain    ${ALLOWED_STATUS_CODES}    ${resp.status_code}
 286
 287 Remove All Elements At URI And Verify
 288     [Arguments]    ${uri}    ${session}=session
 289     ${resp}    RequestsLibrary.Delete Request    ${session}    ${uri}
 290     Should Contain    ${ALLOWED_STATUS_CODES}    ${resp.status_code}
 291     ${resp}    RequestsLibrary.Get Request    ${session}    ${uri}
 292     Should Be Equal As Strings    ${resp.status_code}    404
 293
 294 Remove All Elements If Exist
 295     [Arguments]    ${uri}    ${session}=session
 296     [Documentation]    Delete all elements from an URI if the configuration was not empty
 297     ${resp}    RequestsLibrary.Get Request    ${session}    ${uri}
 298     Run Keyword If    '${resp.status_code}'!='404'    Remove All Elements At URI    ${uri}    ${session}
 299
 300 Add Elements To URI From File
 301     [Arguments]    ${dest_uri}    ${data_file}    ${headers}=${headers}    ${session}=session
 302     ${body}    OperatingSystem.Get File    ${data_file}
 303     ${resp}    RequestsLibrary.Put Request    ${session}    ${dest_uri}    data=${body}    headers=${headers}
 304     Should Contain    ${ALLOWED_STATUS_CODES}    ${resp.status_code}
 305
 306 Add Elements To URI From File And Verify
 307     [Arguments]    ${dest_uri}    ${data_file}    ${headers}=${headers}    ${session}=session
 308     ${body}    OperatingSystem.Get File    ${data_file}
 309     ${resp}    RequestsLibrary.Put Request    ${session}    ${dest_uri}    data=${body}    headers=${headers}
 310     Should Contain    ${ALLOWED_STATUS_CODES}    ${resp.status_code}
 311     ${resp}    RequestsLibrary.Get Request    ${session}    ${dest_uri}
 312     Should Not Be Equal    ${resp.status_code}    404
 313
 314 Add Elements To URI And Verify
 315     [Arguments]    ${dest_uri}    ${data_file}    ${headers}=${headers}    ${session}=session
 316     ${resp}    RequestsLibrary.Put Request    ${session}    ${dest_uri}    ${data_file}    headers=${headers}
 317     Should Contain    ${ALLOWED_STATUS_CODES}    ${resp.status_code}
 318     ${resp}    RequestsLibrary.Get Request    ${session}    ${dest_uri}
 319     Should Not Be Equal    ${resp.status_code}    404
 320
 321 Add Elements To URI From File And Check Validation Error
 322     [Arguments]    ${dest_uri}    ${data_file}    ${headers}=${headers}    ${session}=session
 323     [Documentation]    Shorthand for PUTting data from file and expecting status code 400.
 324     BuiltIn.Comment    TODO: Does this have any benefits, considering TemplatedRequests can also do this in one line?
 325     ${body}    OperatingSystem.Get File    ${data_file}
 326     ${resp}    RequestsLibrary.Put Request    ${session}    ${dest_uri}    data=${body}    headers=${headers}
 327     Should Contain    ${DATA_VALIDATION_ERROR}    ${resp.status_code}
 328
 329 Add Elements To URI From File And Check Server Error
 330     [Arguments]    ${dest_uri}    ${data_file}    ${headers}=${headers}    ${session}=session
 331     [Documentation]    Shorthand for PUTting data from file and expecting status code 500.
 332     ...    Consider opening a Bug against ODL, as in most test cases, 400 is the http code to expect.
 333     BuiltIn.Comment    TODO: Does this have any benefits, considering TemplatedRequests can also do this in one line?
 334     ${body}    OperatingSystem.Get File    ${data_file}
 335     ${resp}    RequestsLibrary.Put Request    ${session}    ${dest_uri}    data=${body}    headers=${headers}
 336     Should Contain    ${INTERNAL_SERVER_ERROR}    ${resp.status_code}
 337
 338 Post Elements To URI From File
 339     [Arguments]    ${dest_uri}    ${data_file}    ${headers}=${headers}    ${session}=session
 340     ${body}    OperatingSystem.Get File    ${data_file}
 341     ${resp}    RequestsLibrary.Post Request    ${session}    ${dest_uri}    data=${body}    headers=${headers}
 342     Should Contain    ${ALLOWED_STATUS_CODES}    ${resp.status_code}
 343
 344 Run Process With Logging And Status Check
 345     [Arguments]    @{proc_args}
 346     [Documentation]    Execute an OS command, log STDOUT and STDERR output and check exit code to be 0
 347     ${result}=    Run Process    @{proc_args}
 348     Log    ${result.stdout}
 349     Log    ${result.stderr}
 350     Should Be Equal As Integers    ${result.rc}    0
 351     [Return]    ${result}
 352
 353 Get Data From URI
 354     [Arguments]    ${session}    ${uri}    ${headers}=${NONE}
 355     [Documentation]    Issue a GET request and return the data obtained or on error log the error and fail.
 356     ...    Issues a GET request for ${uri} in ${session} using headers from
 357     ...    ${headers}. If the request returns a HTTP error, fails. Otherwise
 358     ...    returns the data obtained by the request.
 359     ${response}=    RequestsLibrary.Get Request    ${session}    ${uri}    ${headers}
 360     Builtin.Return_From_Keyword_If    ${response.status_code} == 200    ${response.text}
 361     Builtin.Log    ${response.text}
 362     Builtin.Fail    The request failed with code ${response.status_code}
 363
 364 No Content From URI
 365     [Arguments]    ${session}    ${uri}    ${headers}=${NONE}
 366     [Documentation]    Issue a GET request and return on error 404 (No content) or will fail and log the content.
 367     ...    Issues a GET request for ${uri} in ${session} using headers from
 368     ...    ${headers}. If the request returns a HTTP error, fails. Otherwise
 369     ...    returns the data obtained by the request.
 370     ${response}=    RequestsLibrary.Get Request    ${session}    ${uri}    ${headers}
 371     Builtin.Return_From_Keyword_If    ${response.status_code} == 404
 372     Builtin.Log    ${response.text}
 373     Builtin.Fail    The request failed with code ${response.status_code}
 374
 375 Get Index From List Of Dictionaries
 376     [Arguments]    ${dictionary_list}    ${key}    ${value}
 377     [Documentation]    Extract index for the dictionary in a list that contains a key-value pair. Returns -1 if key-value is not found.
 378     ${length}=    Get Length    ${dictionary_list}
 379     ${index}=    Set Variable    -1
 380     : FOR    ${i}    IN RANGE    ${length}
 381     \    ${dictionary}=    Get From List    ${dictionary_list}    ${i}
 382     \    Run Keyword If    """&{dictionary}[${key}]""" == """${value}"""    Set Test Variable    ${index}    ${i}
 383     [Return]    ${index}
 384
 385 Check Item Occurrence
 386     [Arguments]    ${string}    ${dictionary_item_occurrence}
 387     [Documentation]    Check string for occurrences of items expressed in a list of dictionaries {item=occurrences}. 0 occurences means item is not present.
 388     : FOR    ${item}    IN    @{dictionary_item_occurrence}
 389     \    Should Contain X Times    ${string}    ${item}    &{dictionary_item_occurrence}[${item}]
 390
 391 Post Log Check
 392     [Arguments]    ${uri}    ${body}    ${status_code}=200    ${session}=session
 393     [Documentation]    Post body to ${uri}, log response content, and check status
 394     ${resp}=    RequestsLibrary.Post Request    ${session}    ${uri}    ${body}
 395     Log    ${resp.content}
 396     Should Be Equal As Strings    ${resp.status_code}    ${status_code}
 397     [Return]    ${resp}
 398
 399 Get Log File Name
 400     [Arguments]    ${testtool}    ${testcase}=${EMPTY}
 401     [Documentation]    Get the name of the suite sanitized to be usable as a part of filename.
 402     ...    These names are used to constructs names of the log files produced
 403     ...    by the testing tools so two suites using a tool wont overwrite the
 404     ...    log files if they happen to run in one job.
 405     ${name}=    BuiltIn.Evaluate    """${SUITE_NAME}""".replace(" ","-").replace("/","-").replace(".","-")
 406     ${suffix}=    BuiltIn.Set_Variable_If    '${testcase}' != ''    --${testcase}    ${EMPTY}
 407     [Return]    ${testtool}--${name}${suffix}.log
 408
 409 Set_User_Configurable_Variable_Default
 410     [Arguments]    ${name}    ${value}
 411     [Documentation]    Set a default value for an user configurable variable.
 412     ...    This keyword is needed if your default value is calculated using
 413     ...    a complex expression which needs BuiltIn.Evaluate or even more
 414     ...    complex keywords. It sets the variable ${name} (the name of the
 415     ...    variable MUST be specified WITHOUT the ${} syntactic sugar due
 416     ...    to limitations of Robot Framework) to ${value} but only if the
 417     ...    variable ${name} was not set previously. This keyword is intended
 418     ...    for user configurable variables which are supposed to be set only
 419     ...    with pybot -v; calling this keyword on a variable that was already
 420     ...    set by another keyword will silently turn the call into a NOP and
 421     ...    thus is a bug in the suite or resource trying to call this
 422     ...    keyword.
 423     # TODO: Figure out how to make the ${value} evaluation "lazy" (meaning
 424     #    evaluating it only when the user did not set anything and thus the
 425     #    default is needed). This might be needed to avoid potentially costly
 426     #    keyword invocations when they are not needed. Currently no need for
 427     #    this was identified, thus leaving it here as a TODO. Based on
 428     #    comments the best approach would be to create another keyword that
 429     #    expects a ScalarClosure in the place of ${value} and calls the
 430     #    closure to get the value but only if the value is needed).
 431     #    The best idea how to implement this "laziness" would be to have the
 432     #    used to define another keyword that will be responsible for getting
 433     #    the default value and then passing the name of this getter keyword
 434     #    to this keyword. Then this keyword would call the getter (to obtain
 435     #    the expensive default value) only if it discovers that this value
 436     #    is really needed (because the variable is not set yet).
 437     # TODO: Is the above TODO really necessary? Right now we don't have any
 438     #    examples of "expensive default values" where to obtain the default
 439     #    value is so expensive on resources (e.g. need to SSH somewhere to
 440     #    check something) that we would want to skip the calculation if the
 441     #    variable for which it is needed has a value already provided by the
 442     #    user using "pybot -v" or something. One example would be
 443     #    JAVA_HOME if it would be designed as user-configurable variable
 444     #    (currently it is not; users can specify "use jdk7" or "use jdk8"
 445     #    but not "use the jdk over there"; and there actually is no JAVA_HOME
 446     #    present in the resource, rather the Java invocation command uses the
 447     #    Java invocation with a full path). The default value of JAVA_HOME
 448     #    has to be obtained by issuing commands on the SSH connection where
 449     #    the resulting Java invocation command will be used (to check
 450     #    multiple candidate paths until one that fits is found) and we could
 451     #    skip all this checking if a JAVA_HOME was supplied by the user using
 452     #    "pybot -v".
 453     ${value}=    BuiltIn.Get_Variable_Value    \${${name}}    ${value}
 454     BuiltIn.Set_Suite_Variable    \${${name}}    ${value}
 455
 456 Convert_To_Minutes
 457     [Arguments]    ${time}
 458     [Documentation]    Convert a Robot time string to an integer expressing the time in minutes, rounded up
 459     ...    This is a wrapper around DateTime.Convert_Time which does not
 460     ...    provide this functionality directly nor is even able to produce
 461     ...    an integer directly. It is needed for RestPerfClient which
 462     ...    cannot accept floats for its --timeout parameter and interprets
 463     ...    the value supplied in this parameter in minutes.
 464     ${seconds}=    DateTime.Convert_Time    ${time}    result_format=number
 465     ${minutes}=    BuiltIn.Evaluate    int(math.ceil(${seconds}/60.0))    modules=math
 466     [Return]    ${minutes}
 467
 468 Write Commands Until Expected Prompt
 469     [Arguments]    ${cmd}    ${prompt}    ${timeout}=30s
 470     [Documentation]    quick wrapper for Write and Read Until Prompt Keywords to make test cases more readable
 471     SSHLibrary.Set Client Configuration    timeout=${timeout}
 472     SSHLibrary.Read
 473     SSHLibrary.Write    ${cmd}
 474     ${output}=    SSHLibrary.Read Until    ${prompt}
 475     [Return]    ${output}
 476
 477 Install Package On Ubuntu System
 478     [Arguments]    ${package_name}    ${system}=${TOOLS_SYSTEM_IP}    ${user}=${TOOLS_SYSTEM_USER}    ${password}=${TOOLS_SYSTEM_PASSWORD}    ${prompt}=${DEFAULT_LINUX_PROMPT}    ${prompt_timeout}=30s
 479     [Documentation]    Keyword to install packages for testing to Ubuntu Mininet VM
 480     Log    Keyword to install package to Mininet Ubuntu VM
 481     Open Connection    ${system}    prompt=${prompt}    timeout=${prompt_timeout}
 482     SSHKeywords.Flexible Mininet Login    user=${user}    password=${password}
 483     Write    sudo apt-get install -y ${package_name}
 484     Read Until    ${prompt}
 485
 486 Json Parse From String
 487     [Arguments]    ${plain_string_with_json}
 488     [Documentation]    Parse given plain string into json (dictionary)
 489     ${json_data}    Evaluate    json.loads('''${plain_string_with_json}''')    json
 490     [Return]    ${json_data}
 491
 492 Json Parse From File
 493     [Arguments]    ${json_file}
 494     [Documentation]    Parse given file content into json (dictionary)
 495     ${json_plain_string}    OperatingSystem.Get file    ${json_file}
 496     ${json_data}    Json Parse From String    ${json_plain_string}
 497     [Return]    ${json_data}
 498
 499 Modify Iptables On Remote System
 500     [Arguments]    ${remote_system_ip}    ${iptables_rule}    ${user}=${ODL_SYSTEM_USER}    ${password}=${ODL_SYSTEM_PASSWORD}    ${prompt}=${ODL_SYSTEM_PROMPT}
 501     [Documentation]    Wrapper keyword to run iptables with any given ${iptables_rule} string on the remote system given
 502     ...    by ${remote_system_ip}. The iptables listing will be output before and after the command is run
 503     ${list_iptables_command} =    BuiltIn.Set Variable    sudo /sbin/iptables -L -n
 504     ${output} =    Utils.Run Command On Remote System    ${remote_system_ip}    ${list_iptables_command}    ${user}    ${password}    prompt=${prompt}
 505     BuiltIn.Log    ${output}
 506     Utils.Run Command On Remote System    ${remote_system_ip}    sudo /sbin/iptables ${iptables_rule}    ${user}    ${password}    prompt=${prompt}
 507     ${output} =    Utils.Run Command On Remote System    ${remote_system_ip}    ${list_iptables_command}    ${user}    ${password}    prompt=${prompt}
 508     BuiltIn.Log    ${output}