csit/suites/bgpcep/bgpclustering/060_pcep_ha_karaf_restart.robot

   1 *** Settings ***
   2 Documentation     PCEP functional HA testing with one pcep peer.
   3 ...
   4 ...               Copyright (c) 2017 AT&T Intellectual Property. All rights reserved.
   5 ...
   6 ...               This program and the accompanying materials are made available under the
   7 ...               terms of the Eclipse Public License v1.0 which accompanies this distbmution,
   8 ...               and is available at http://www.eclipse.org/legal/epl-v10.html
   9 ...
  10 ...               This suite uses PCC mock. It is configured to have 3 peers (all 3 nodes of odl).
  11 ...               PCEP implemented with singleton accepts only one incomming conection. PCC mock
  12 ...               logs will show that one peer will be connected and two will fail.
  13 ...               After killing karaf which owned connection new owner should be elected and
  14 ...               this new owner should accept incomming PCC connection.
  15 ...               TODO: Add similar keywords from all bgpclustering-ha tests into same libraries
  16 Suite Setup       Setup_Everything
  17 Suite Teardown    Teardown_Everything
  18 Test Setup        SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
  19 Test Teardown     SetupUtils.Teardown_Test_Show_Bugs_If_Test_Failed
  20 Library           SSHLibrary    timeout=10s
  21 Library           Collections
  22 Library           OperatingSystem
  23 Resource          ../../../libraries/BGPcliKeywords.robot
  24 Resource          ../../../libraries/ClusterManagement.robot
  25 Resource          ../../../libraries/NexusKeywords.robot
  26 Resource          ../../../libraries/PcepOperations.robot
  27 Resource          ../../../libraries/SetupUtils.robot
  28 Resource          ../../../libraries/TemplatedRequests.robot
  29 Resource          ../../../variables/Variables.robot
  30
  31 *** Variables ***
  32 ${HOLDTIME}       180
  33 ${DIR_WITH_TEMPLATES}    ${CURDIR}/../../../variables/bgpclustering/
  34 ${PCC_LOG_FILE}    pccmock.restart.log
  35 ${CONFIG_SESSION}    session
  36
  37 *** Test Cases ***
  38 Get_Example_Pcep_Owner
  39     [Documentation]    Find an odl node which is able to accept incomming connection.
  40     ${pcep_owner}    ${pcep_candidates}=    Wait_Until_Keyword_Succeeds    5x    2s    ClusterManagement.Get_Owner_And_Successors_For_device    pcep-topology
  41     ...    Bgpcep    1
  42     BuiltIn.Set Suite variable    ${pcep_owner}
  43     BuiltIn.Log    ${pcep_owner}
  44     BuiltIn.Set Suite variable    ${pcep_candidates}
  45     ${session}=    ClusterManagement.Resolve_Http_Session_For_Member    member_index=${pcep_owner}
  46     BuiltIn.Set_Suite_Variable    ${living_session}    ${session}
  47     BuiltIn.Log    ${living_session}
  48     BuiltIn.Set_Suite_Variable    ${living_node}    ${pcep_owner}
  49
  50 Verify_Data_Reported_1
  51     [Documentation]    Verifies if pcep-topology reported expected data
  52     ...    Expects pcep-topology not be empty/filled path-computation.
  53     Pcep_Topology_Postcondition
  54
  55 Kill_Current_Owner_Member
  56     [Documentation]    Killing cluster node which is connected with pcc-mock.
  57     ClusterManagement.Kill_Single_Member    ${pcep_owner}
  58     BuiltIn.Set Suite variable    ${old_pcep_owner}    ${pcep_owner}
  59     BuiltIn.Set Suite variable    ${old_pcep_candidates}    ${pcep_candidates}
  60     ${idx}=    Collections.Get From List    ${old_pcep_candidates}    0
  61     ${session}=    ClusterManagement.Resolve_Http_Session_For_Member    member_index=${idx}
  62     BuiltIn.Set_Suite_Variable    ${living_session}    ${session}
  63     BuiltIn.Set_Suite_Variable    ${living_node}    ${idx}
  64
  65 Verify_New_Pcep_Owner
  66     [Documentation]    Verifies if new owner of pcep-topology is elected.
  67     BuiltIn.Wait_Until_Keyword_Succeeds    10x    5s    Verify_New_Pcep_Owner_Elected    ${old_pcep_owner}    ${living_node}
  68
  69 Verify_Data_Reported_2
  70     [Documentation]    Verifies if pcep-topology reports expected data
  71     ...    Expects pcep-topology not be empty/filled path-computation.
  72     Pcep_Topology_Postcondition
  73
  74 Start_Stopped_Member
  75     [Documentation]    Starting stopped node
  76     ClusterManagement.Start_Single_Member    ${old_pcep_owner}
  77
  78 Verify_New_Candidate
  79     [Documentation]    Verifies started node become candidate for pcep_topology
  80     BuiltIn.Wait_Until_Keyword_Succeeds    10x    5s    Verify_New_Pcep_Candidate_Present    ${old_pcep_owner}    ${living_node}
  81
  82 Verify_Data_Reported_3
  83     [Documentation]    Verifies if pcep-topology reported expected data
  84     ...    Expects pcep-topology not be empty/filled path-computation.
  85     Pcep_Topology_Postcondition
  86
  87 Stop_Pcc_Mock
  88     [Documentation]    Send ctrl+c to pcc-mock to stop it.
  89     BGPcliKeywords.Stop_Console_Tool_And_Wait_Until_Prompt
  90
  91 *** Keywords ***
  92 Setup_Everything
  93     [Documentation]    Initial setup
  94     SetupUtils.Setup_Utils_For_Setup_And_Teardown
  95     ClusterManagement.ClusterManagement_Setup
  96     NexusKeywords.Initialize_Artifact_Deployment_And_Usage
  97     RequestsLibrary.Create_Session    ${CONFIG_SESSION}    http://${ODL_SYSTEM_IP}:${RESTCONFPORT}    auth=${AUTH}
  98     ${name}=    NexusKeywords.Deploy_Test_Tool    bgpcep    pcep-pcc-mock
  99     BuiltIn.Set_Suite_Variable    ${filename}    ${name}
 100     #Setting Pcc Name and its code for mapping for templates
 101     #TODO: Move variable definitions into PcepOperations setup after its update
 102     BuiltIn.Set_Suite_Variable    ${pcc_name}    pcc_${TOOLS_SYSTEM_IP}_tunnel_1
 103     ${code}=    Evaluate    binascii.b2a_base64('${pcc_name}')[:-1]    modules=binascii
 104     BuiltIn.Set_Suite_Variable    ${pcc_name_code}    ${code}
 105     PcepOperations.Pcep_Topology_Precondition    ${CONFIG_SESSION}
 106     Start_Pcc_Mock
 107
 108 Teardown_Everything
 109     [Documentation]    Suite cleanup
 110     BGPcliKeywords.Store_File_To_Workspace    ${PCC_LOG_FILE}    ${PCC_LOG_FILE}
 111     RequestsLibrary.Delete_All_Sessions
 112     SSHLibrary.Close_All_Connections
 113
 114 Start_Pcc_Mock
 115     [Documentation]    Starts pcc mock
 116     ${command}=    BuiltIn.Set_Variable    -jar ${filename} --reconnect 1 --local-address ${TOOLS_SYSTEM_IP} --remote-address ${ODL_SYSTEM_1_IP}:4189,${ODL_SYSTEM_2_IP}:4189,${ODL_SYSTEM_3_IP}:4189 --log-level INFO 2>&1 | tee ${PCC_LOG_FILE}
 117     BGPcliKeywords.Start_Java_Tool_And_Verify_Connection    ${command}    started
 118
 119 Pcep_Topology_Postcondition
 120     [Documentation]    Verifies if the tool reported expected data
 121     &{mapping}    BuiltIn.Create_Dictionary    IP=${TOOLS_SYSTEM_IP}    CODE=${pcc_name_code}    NAME=${pcc_name}    IP_ODL=${ODL_SYSTEM_${pcep_owner}_IP}
 122     BuiltIn.Wait_Until_Keyword_Succeeds    10x    5s    TemplatedRequests.Get_As_Json_Templated    ${DIR_WITH_TEMPLATES}${/}pcep_on_state    ${mapping}    ${living_session}
 123     ...    verify=True
 124
 125 Verify_New_Pcep_Owner_Elected
 126     [Arguments]    ${old_owner}    ${node_to_ask}
 127     [Documentation]    Verifies new owner was elected
 128     ${owner}    ${candidates}=    ClusterManagement.Get_Owner_And_Successors_For_device    pcep-topology    Bgpcep    ${node_to_ask}
 129     BuiltIn.Should_Not_Be_Equal    ${old_owner}    ${owner}
 130     BuiltIn.Set_Suite_Variable    ${pcep_owner}    ${owner}
 131
 132 Verify_New_Pcep_Candidate_Present
 133     [Arguments]    ${candidate}    ${node_to_ask}
 134     [Documentation]    Verifies candidate's presence.
 135     ${owner}    ${candidates}=    ClusterManagement.Get_Owner_And_Successors_For_device    pcep-topology    Bgpcep    ${node_to_ask}
 136     Collections.Append_To_List    ${candidates}    ${owner}
 137     BuiltIn.Should_Contain    ${candidates}    ${candidate}
 138     BuiltIn.Set_Suite_Variable    ${pcep_owner}    ${owner}