csit/suites/bgpcep/bgpingest/manypeers_changecount.robot

   1 *** Settings ***
   2 Documentation     BGP performance of ingesting from many iBGP peers, data change counter is used.
   3 ...
   4 ...               Copyright (c) 2015 Cisco Systems, Inc. and others. All rights reserved.
   5 ...
   6 ...               This program and the accompanying materials are made available under the
   7 ...               terms of the Eclipse Public License v1.0 which accompanies this distribution,
   8 ...               and is available at http://www.eclipse.org/legal/epl-v10.html
   9 ...
  10 ...
  11 ...               This suite uses play.py processes as iBGP peers.
  12 ...               This is analogue of single peer performance suite, which uses many peers.
  13 ...               Each peer is of ibgp type, and they contribute to the same example-bgp-rib,
  14 ...               and thus to the same single example-ipv4-topology.
  15 ...               The suite only looks at example-ipv4-topology, so RIB is not examined.
  16 ...
  17 ...               This suite requires odl-bgpcep-data-change-counter to be installed so
  18 ...               make sure it is added to "install-features" of any jobs that are going to invoke it.
  19 ...               Use the other version of the suite (manypeers_prefixcount.robot) if the feature does not work.
  20 ...
  21 ...               The suite consists of two halves, differing on which side initiates BGP connection.
  22 ...               Data change counter is a lightweight way to detect "work is being done".
  23 ...               WaitUtils provide a nice Keyword to wait for stability, but it needs
  24 ...               initial value, that is why Store_Change_Count appears just before work-inducing action.
  25 ...               The time for Wait_For_Stable_* cases to finish is the main performance metric.
  26 ...               After waiting for stability is done, full check on number of prefixes present is performed.
  27 ...
  28 ...               TODO: Currently, if a bug causes zero increase of data changes,
  29 ...               affected test cases will wait for max time. Reconsider.
  30 ...               If zero increase is allowed as stable, higher number of repetitions should be required.
  31 ...
  32 ...               ODL distinguishes peers by their IP addresses.
  33 ...               Currently, this suite requires python utils to be started on ODL System,
  34 ...               to guarantee IP address block is available for them to bind to.
  35 ...               TODO: Figure out how to use Docker and docker IP pool available in RelEng.
  36 ...
  37 ...               Currently, 127.0.0.1 is hardcoded as the first peer address to use.
  38 ...               TODO: Figure out how to make it configurable.
  39 ...               As peer IP adresses are set incrementally, we need ipaddr to be used in Robot somehow.
  40 ...
  41 ...               TODO: Is there a need for version of this suite where ODL connects to pers?
  42 ...               Note that configuring ODL is slow, which may affect measured performance singificantly.
  43 ...               Advanced TODO: Give manager ability to start pushing on trigger long after connections are established.
  44 Suite Setup       Setup_Everything
  45 Suite Teardown    Teardown_Everything
  46 Test Setup        SetupUtils.Setup_Test_With_Logging_And_Fast_Failing
  47 Test Teardown     FailFast.Start_Failing_Fast_If_This_Failed
  48 Library           DateTime
  49 Library           RequestsLibrary
  50 Library           SSHLibrary    timeout=10s
  51 Variables         ${CURDIR}/../../../variables/Variables.py
  52 Resource          ${CURDIR}/../../../libraries/BGPSpeaker.robot
  53 Resource          ${CURDIR}/../../../libraries/ChangeCounter.robot
  54 Resource          ${CURDIR}/../../../libraries/ConfigViaRestconf.robot
  55 Resource          ${CURDIR}/../../../libraries/FailFast.robot
  56 Resource          ${CURDIR}/../../../libraries/KillPythonTool.robot
  57 Resource          ${CURDIR}/../../../libraries/PrefixCounting.robot
  58 Resource          ${CURDIR}/../../../libraries/SetupUtils.robot
  59 Resource          ${CURDIR}/../../../libraries/SSHKeywords.robot
  60
  61 *** Variables ***
  62 ${BGP_TOOL_LOG_LEVEL}    info
  63 ${BGP_VARIABLES_FOLDER}    ${CURDIR}/../../../variables/bgpuser/
  64 ${CHECK_PERIOD}    1
  65 ${CHECK_PERIOD_CHANGE_COUNT}    ${CHECK_PERIOD}
  66 ${CHECK_PERIOD_CHANGE_COUNT_MANY}    ${CHECK_PERIOD_CHANGE_COUNT}
  67 ${COUNT}          1000000
  68 ${COUNT_CHANGE_COUNT}    ${COUNT}
  69 ${COUNT_CHANGE_COUNT_MANY}    ${COUNT_CHANGE_COUNT}
  70 ${FIRST_PEER_IP}    127.0.0.1
  71 ${HOLDTIME}       180
  72 ${HOLDTIME_CHANGE_COUNT}    ${HOLDTIME}
  73 ${HOLDTIME_CHANGE_COUNT_MANY}    ${HOLDTIME_CHANGE_COUNT}
  74 ${KARAF_LOG_LEVEL}    INFO
  75 ${KARAF_BGPCEP_LOG_LEVEL}    ${KARAF_LOG_LEVEL}
  76 ${KARAF_PROTOCOL_LOG_LEVEL}    ${KARAF_BGPCEP_LOG_LEVEL}
  77 ${MULTIPLICITY}    2    # May be increased after Bug 4488 is fixed.
  78 ${MULTIPLICITY_CHANGE_COUNT}    ${MULTIPLICITY}
  79 ${MULTIPLICITY_CHANGE_COUNT_MANY}    ${MULTIPLICITY_CHANGE_COUNT}
  80 ${REPETITIONS}    1    # Should be increased depending on multiplicity.
  81 ${REPETITIONS_CHANGE_COUNT}    ${REPETITIONS}
  82 ${REPETITIONS_CHANGE_COUNT_MANY}    ${REPETITIONS_CHANGE_COUNT}
  83 ${TEST_DURATION_MULTIPLIER}    1
  84 ${TEST_DURATION_MULTIPLIER_CHANGE_COUNT}    ${TEST_DURATION_MULTIPLIER}
  85 ${TEST_DURATION_MULTIPLIER_CHANGE_COUNT_MANY}    ${TEST_DURATION_MULTIPLIER_CHANGE_COUNT}
  86 # TODO: Option names can be better.
  87 ${last_change_count_many}    -1
  88
  89 *** Test Cases ***
  90 Check_For_Empty_Ipv4_Topology_Before_Talking
  91     [Documentation]    Wait for example-ipv4-topology to come up and empty. Give large timeout for case when BGP boots slower than restconf.
  92     [Tags]    critical
  93     # TODO: Choose which tags to assign and make sure they are assigned correctly.
  94     BuiltIn.Wait_Until_Keyword_Succeeds    120s    1s    PrefixCounting.Check_Ipv4_Topology_Is_Empty
  95
  96 Reconfigure_ODL_To_Accept_Connections
  97     [Documentation]    Configure BGP peer modules with initiate-connection set to false.
  98     : FOR    ${index}    IN RANGE    1    ${MULTIPLICITY_CHANGE_COUNT_MANY}+1
  99     \    ${peer_name} =    BuiltIn.Set_Variable    example-bgp-peer-${index}
 100     \    ${peer_ip} =    BuiltIn.Evaluate    str(ipaddr.IPAddress('${FIRST_PEER_IP}') + ${index} - 1)    modules=ipaddr
 101     \    ${template_as_string} =    BuiltIn.Set_Variable    {'NAME': '${peer_name}', 'IP': '${peer_ip}', 'PEER_PORT': '${BGP_TOOL_PORT}', 'HOLDTIME': '${HOLDTIME_CHANGE_COUNT_MANY}', 'INITIATE': 'false'}
 102     \    ConfigViaRestconf.Put_Xml_Template_Folder_Config_Via_Restconf    ${BGP_VARIABLES_FOLDER}${/}bgp_peer    ${template_as_string}
 103     # FIXME: Add testcase to change bgpcep and protocol log levels, when a Keyword that does it without messing with current connection is ready.
 104
 105 Wait_For_Data_Change_Counter_Ready
 106     [Documentation]    Data change counter might have been slower to start than ipv4 topology, wait for it.
 107     BuiltIn.Wait_Until_Keyword_Succeeds    60s    1s    ChangeCounter.Get_Change_Count
 108
 109 Reconfigure_Data_Change_Counter
 110     [Documentation]    Configure data change counter to count transactions in example-ipv4-topology instead of example-linkstate-topology.
 111     ChangeCounter.Reconfigure_Topology_Name    example-ipv4-topology
 112
 113 Change_Karaf_Logging_Levels
 114     [Documentation]    We may want to set more verbose logging here after configuration is done.
 115     KarafKeywords.Set_Bgpcep_Log_Levels    bgpcep_level=${KARAF_BGPCEP_LOG_LEVEL}    protocol_level=${KARAF_PROTOCOL_LOG_LEVEL}
 116
 117 Start_Talking_BGP_Manager
 118     [Documentation]    Start Python manager to connect speakers to ODL.
 119     Store_Change_Count
 120     # Myport value is needed for checking whether connection at precise port was established.
 121     BGPSpeaker.Start_BGP_Manager    --amount=${COUNT_CHANGE_COUNT_MANY} --multiplicity=${MULTIPLICITY_CHANGE_COUNT_MANY} --myip=${FIRST_PEER_IP} --myport=${BGP_TOOL_PORT} --peerip=${ODL_SYSTEM_IP} --peerport=${ODL_BGP_PORT}
 122
 123 Wait_For_Stable_Talking_Ipv4_Topology
 124     [Documentation]    Wait until example-ipv4-topology becomes stable. This is done by checking stability of the change counter.
 125     ChangeCounter.Wait_For_Change_Count_To_Become_Stable    timeout=${bgp_filling_timeout}    period=${CHECK_PERIOD_CHANGE_COUNT_MANY}    repetitions=${REPETITIONS_CHANGE_COUNT_MANY}    count_to_overcome=${last_change_count_many}
 126
 127 Check_Talking_Ipv4_Topology_Count
 128     [Documentation]    Count the routes in example-ipv4-topology and fail if the count is not correct.
 129     [Tags]    critical
 130     PrefixCounting.Check_Ipv4_Topology_Count    ${COUNT_CHANGE_COUNT_MANY}
 131
 132 Kill_Talking_BGP_Speakers
 133     [Documentation]    Abort the Python speakers. Also, attempt to stop failing fast.
 134     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 135     Store_Change_Count
 136     BGPSpeaker.Kill_BGP_Speaker
 137     FailFast.Do_Not_Fail_Fast_From_Now_On
 138     # NOTE: It is still possible to remain failing fast, if both previous and this test have failed.
 139     [Teardown]    FailFast.Do_Not_Start_Failing_If_This_Failed
 140
 141 Wait_For_Stable_Ipv4_Topology_After_Talking
 142     [Documentation]    Wait until example-ipv4-topology becomes stable again.
 143     [Tags]    critical
 144     ChangeCounter.Wait_For_Change_Count_To_Become_Stable    timeout=${bgp_filling_timeout}    period=${CHECK_PERIOD_CHANGE_COUNT_MANY}    repetitions=${REPETITIONS_CHANGE_COUNT_MANY}    count_to_overcome=${last_change_count_many}
 145
 146 Check_For_Empty_Ipv4_Topology_After_Talking
 147     [Documentation]    Example-ipv4-topology should be empty now.
 148     [Tags]    critical
 149     PrefixCounting.Check_Ipv4_Topology_Is_Empty
 150
 151 Restore_Karaf_Logging_Levels
 152     [Documentation]    Set logging on bgpcep and protocol to the global value.
 153     KarafKeywords.Set_Bgpcep_Log_Levels    bgpcep_level=${KARAF_LOG_LEVEL}    protocol_level=${KARAF_LOG_LEVEL}
 154
 155 Restore_Data_Change_Counter_Configuration
 156     [Documentation]    Configure data change counter back to count transactions affecting example-linkstate-topology.
 157     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 158     ChangeCounter.Reconfigure_Topology_Name    example-linkstate-topology
 159
 160 Delete_Bgp_Peer_Configuration
 161     [Documentation]    Revert the BGP configuration to the original state: without any configured peers.
 162     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 163     # TODO: Is it useful to extract peer naming logic to separate Keyword?
 164     : FOR    ${index}    IN RANGE    1    ${MULTIPLICITY_CHANGE_COUNT_MANY}+1
 165     \    ${template_as_string}=    BuiltIn.Set_Variable    {'NAME': 'example-bgp-peer-${index}'}
 166     \    ConfigViaRestconf.Delete_Xml_Template_Folder_Config_Via_Restconf    ${BGP_VARIABLESFOLDER}${/}bgp_peer    ${template_as_string}
 167
 168 *** Keywords ***
 169 Setup_Everything
 170     [Documentation]    Setup imported resources, SSH-login to ODL system,
 171     ...    create HTTP session, put Python tool to ODL system.
 172     SetupUtils.Setup_Utils_For_Setup_And_Teardown
 173     ConfigViaRestconf.Setup_Config_Via_Restconf
 174     ChangeCounter.CC_Setup
 175     PrefixCounting.PC_Setup
 176     KarafKeywords.Open Controller Karaf Console On Background
 177     SSHLibrary.Set_Default_Configuration    prompt=${ODL_SYSTEM_PROMPT}
 178     SSHLibrary.Open_Connection    ${ODL_SYSTEM_IP}
 179     Utils.Flexible_Controller_Login
 180     RequestsLibrary.Create_Session    operational    http://${ODL_SYSTEM_IP}:${RESTCONFPORT}${OPERATIONAL_API}    auth=${AUTH}
 181     # TODO: Do not include slash in ${OPERATIONAL_TOPO_API}, having it typed here is more readable.
 182     # TODO: Alternatively, create variable in Variables which starts with http.
 183     # Both TODOs would probably need to update every suite relying on current Variables.
 184     SSHKeywords.Require_Python
 185     SSHLibrary.Put_File    ${CURDIR}/../../../../tools/fastbgp/play.py
 186     SSHKeywords.Assure_Library_Ipaddr    target_dir=.
 187     # Calculate the timeout value based on how many routes are going to be pushed
 188     ${period} =    DateTime.Convert_Time    ${CHECK_PERIOD_CHANGE_COUNT_MANY}    result_format=number
 189     ${timeout} =    BuiltIn.Evaluate    ${TEST_DURATION_MULTIPLIER_CHANGE_COUNT_MANY} * (${COUNT_CHANGE_COUNT_MANY} * 3.0 / 10000 + ${period} * (${REPETITIONS_CHANGE_COUNT_MANY} + 1))
 190     Builtin.Set_Suite_Variable    ${bgp_filling_timeout}    ${timeout}
 191     ${timeout} =    BuiltIn.Evaluate    ${TEST_DURATION_MULTIPLIER_CHANGE_COUNT_MANY} * (${COUNT_CHANGE_COUNT_MANY} * 2.0 / 10000 + ${period} * (${REPETITIONS_CHANGE_COUNT_MANY} + 1))
 192     Builtin.Set_Suite_Variable    ${bgp_emptying_timeout}    ${timeout}
 193     KarafKeywords.Execute_Controller_Karaf_Command_On_Background    log:set ${KARAF_LOG_LEVEL}
 194
 195 Teardown_Everything
 196     [Documentation]    Make sure Python tool was killed and tear down imported Resources.
 197     # Environment issue may have dropped the SSH connection, but we do not want Teardown to fail.
 198     BuiltIn.Run_Keyword_And_Ignore_Error    KillPythonTool.Search_And_Kill_Remote_Python    'play\.py'
 199     ConfigViaRestconf.Teardown_Config_Via_Restconf
 200     RequestsLibrary.Delete_All_Sessions
 201     SSHLibrary.Close_All_Connections
 202
 203 Store_Change_Count
 204     [Documentation]    Get the count of changes from BGP change counter. Ignore error or store the value.
 205     ${status}    ${count} =    BuiltIn.Run_Keyword_And_Ignore_Error    ChangeCounter.Get_Change_Count
 206     BuiltIn.Run_Keyword_If    '${status}' == 'PASS'    BuiltIn.Set_Suite_Variable    ${last_change_count_many}    ${count}