csit/suites/bgpcep/bgpingest/manypeers_prefixcount.robot

   1 *** Settings ***
   2 Documentation     BGP performance of ingesting from many iBGP peers, data change counter NOT used.
   3 ...
   4 ...               Copyright (c) 2015 Cisco Systems, Inc. and others. All rights reserved.
   5 ...
   6 ...               This program and the accompanying materials are made available under the
   7 ...               terms of the Eclipse Public License v1.0 which accompanies this distribution,
   8 ...               and is available at http://www.eclipse.org/legal/epl-v10.html
   9 ...
  10 ...
  11 ...               This suite uses play.py processes as iBGP peers.
  12 ...               This is analogue of single peer performance suite, which uses many peers.
  13 ...               Each peer is of ibgp type, and they contribute to the same example-bgp-rib,
  14 ...               and thus to the same single example-ipv4-topology.
  15 ...               The suite only looks at example-ipv4-topology, so RIB is not examined.
  16 ...
  17 ...               The suite consists of two halves, differing on which side initiates BGP connection.
  18 ...               State of "work is being done" is detected by increasing value of prefixes in topology.
  19 ...               The time for Wait_For_Stable_* cases to finish is the main performance metric.
  20 ...               After waiting for stability is done, full check on number of prefixes present is performed.
  21 ...
  22 ...               TODO: Currently, if a bug causes prefix count to remain at zero,
  23 ...               affected test cases will wait for max time. Reconsider.
  24 ...               If zero is allowed as stable, higher period or repetitions would be required.
  25 ...
  26 ...               The prefix counting is quite heavyweight and may induce large variation in time.
  27 ...               Try the other version of the suite (manypeers_changecount.robot) to get better precision.
  28 ...
  29 ...               ODL distinguishes peers by their IP addresses.
  30 ...               Currently, this suite requires python utils to be started on ODL System,
  31 ...               to guarantee IP address block is available for them to bind to.
  32 ...               TODO: Figure out how to use Docker and docker IP pool available in RelEng.
  33 ...
  34 ...               Currently, 127.0.0.1 is hardcoded as the first peer address to use.
  35 ...               TODO: Figure out how to make it configurable.
  36 ...               As peer IP adresses are set incrementally, we need ipaddr to be used in Robot somehow.
  37 ...
  38 ...               TODO: Is there a need for version of this suite where ODL connects to pers?
  39 ...               Note that configuring ODL is slow, which may affect measured performance singificantly.
  40 ...               Advanced TODO: Give manager ability to start pushing on trigger long after connections are established.
  41 Suite Setup       Setup_Everything
  42 Suite Teardown    Teardown_Everything
  43 Test Setup        SetupUtils.Setup_Test_With_Logging_And_Fast_Failing
  44 Test Teardown     FailFast.Start_Failing_Fast_If_This_Failed
  45 Library           DateTime
  46 Library           RequestsLibrary
  47 Library           SSHLibrary    timeout=10s
  48 Variables         ${CURDIR}/../../../variables/Variables.py
  49 Resource          ${CURDIR}/../../../libraries/BGPSpeaker.robot
  50 Resource          ${CURDIR}/../../../libraries/ConfigViaRestconf.robot
  51 Resource          ${CURDIR}/../../../libraries/FailFast.robot
  52 Resource          ${CURDIR}/../../../libraries/KillPythonTool.robot
  53 Resource          ${CURDIR}/../../../libraries/PrefixCounting.robot
  54 Resource          ${CURDIR}/../../../libraries/SetupUtils.robot
  55 Resource          ${CURDIR}/../../../libraries/SSHKeywords.robot
  56
  57 *** Variables ***
  58 ${BGP_TOOL_LOG_LEVEL}    info
  59 ${BGP_VARIABLES_FOLDER}    ${CURDIR}/../../../variables/bgpuser/
  60 ${CHECK_PERIOD}    1    # ${MULTIPLICITY*2} recommended for this suite, but keeping the common default.
  61 ${CHECK_PERIOD_PREFIX_COUNT}    ${CHECK_PERIOD}
  62 ${CHECK_PERIOD_PREFIX_COUNT_MANY}    ${CHECK_PERIOD_PREFIX_COUNT}
  63 ${COUNT}          1000000
  64 ${COUNT_PREFIX_COUNT}    ${COUNT}
  65 ${COUNT_PREFIX_COUNT_MANY}    ${COUNT_PREFIX_COUNT}
  66 ${FIRST_PEER_IP}    127.0.0.1
  67 ${HOLDTIME}       180
  68 ${HOLDTIME_PREFIX_COUNT}    ${HOLDTIME}
  69 ${HOLDTIME_PREFIX_COUNT_MANY}    ${HOLDTIME_PREFIX_COUNT}
  70 ${KARAF_LOG_LEVEL}    INFO
  71 ${KARAF_BGPCEP_LOG_LEVEL}    ${KARAF_LOG_LEVEL}
  72 ${KARAF_PROTOCOL_LOG_LEVEL}    ${KARAF_BGPCEP_LOG_LEVEL}
  73 ${MULTIPLICITY}    2    # May be increased after Bug 4488 is fixed.
  74 ${MULTIPLICITY_PREFIX_COUNT}    ${MULTIPLICITY}
  75 ${MULTIPLICITY_PREFIX_COUNT_MANY}    ${MULTIPLICITY_PREFIX_COUNT}
  76 ${REPETITIONS}    1
  77 ${REPETITIONS_PREFIX_COUNT}    ${REPETITIONS}
  78 ${REPETITIONS_PREFIX_COUNT_MANY}    ${REPETITIONS_PREFIX_COUNT}
  79 ${TEST_DURATION_MULTIPLIER}    1
  80 ${TEST_DURATION_MULTIPLIER_PREFIX_COUNT}    ${TEST_DURATION_MULTIPLIER}
  81 ${TEST_DURATION_MULTIPLIER_PREFIX_COUNT_MANY}    ${TEST_DURATION_MULTIPLIER_PREFIX_COUNT}
  82 # TODO: Option names can be better.
  83
  84 *** Test Cases ***
  85 Check_For_Empty_Ipv4_Topology_Before_Talking
  86     [Documentation]    Wait for example-ipv4-topology to come up and empty. Give large timeout for case when BGP boots slower than restconf.
  87     [Tags]    critical
  88     # TODO: Choose which tags to assign and make sure they are assigned correctly.
  89     BuiltIn.Wait_Until_Keyword_Succeeds    120s    1s    PrefixCounting.Check_Ipv4_Topology_Is_Empty
  90
  91 Reconfigure_ODL_To_Accept_Connections
  92     [Documentation]    Configure BGP peer modules with initiate-connection set to false.
  93     : FOR    ${index}    IN RANGE    1    ${MULTIPLICITY_PREFIX_COUNT_MANY}+1
  94     \    ${peer_name} =    BuiltIn.Set_Variable    example-bgp-peer-${index}
  95     \    ${peer_ip} =    BuiltIn.Evaluate    str(ipaddr.IPAddress('${FIRST_PEER_IP}') + ${index} - 1)    modules=ipaddr
  96     \    ${template_as_string} =    BuiltIn.Set_Variable    {'NAME': '${peer_name}', 'IP': '${peer_ip}', 'PEER_PORT': '${BGP_TOOL_PORT}', 'HOLDTIME': '${HOLDTIME_PREFIX_COUNT_MANY}', 'INITIATE': 'false'}
  97     \    ConfigViaRestconf.Put_Xml_Template_Folder_Config_Via_Restconf    ${BGP_VARIABLES_FOLDER}${/}bgp_peer    ${template_as_string}
  98     # FIXME: Add testcase to change bgpcep and protocol log levels, when a Keyword that does it without messing with current connection is ready.
  99
 100 Change_Karaf_Logging_Levels
 101     [Documentation]    We may want to set more verbose logging here after configuration is done.
 102     KarafKeywords.Set_Bgpcep_Log_Levels    bgpcep_level=${KARAF_BGPCEP_LOG_LEVEL}    protocol_level=${KARAF_PROTOCOL_LOG_LEVEL}
 103
 104 Start_Talking_BGP_Manager
 105     [Documentation]    Start Python manager to connect speakers to ODL.
 106     # Myport value is needed for checking whether connection at precise port was established.
 107     BGPSpeaker.Start_BGP_Manager    --amount=${COUNT_PREFIX_COUNT_MANY} --multiplicity=${MULTIPLICITY_PREFIX_COUNT_MANY} --myip=${FIRST_PEER_IP} --myport=${BGP_TOOL_PORT} --peerip=${ODL_SYSTEM_IP} --peerport=${ODL_BGP_PORT}
 108
 109 Wait_For_Stable_Talking_Ipv4_Topology
 110     [Documentation]    Wait until example-ipv4-topology becomes stable. This is done by checking stability of prefix count.
 111     PrefixCounting.Wait_For_Ipv4_Topology_Prefixes_To_Become_Stable    timeout=${bgp_filling_timeout}    period=${CHECK_PERIOD_PREFIX_COUNT_MANY}    repetitions=${REPETITIONS_PREFIX_COUNT_MANY}    excluded_count=0
 112
 113 Check_Talking_Ipv4_Topology_Count
 114     [Documentation]    Count the routes in example-ipv4-topology and fail if the count is not correct.
 115     [Tags]    critical
 116     PrefixCounting.Check_Ipv4_Topology_Count    ${COUNT_PREFIX_COUNT_MANY}
 117
 118 Kill_Talking_BGP_Speakers
 119     [Documentation]    Abort the Python speakers. Also, attempt to stop failing fast.
 120     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 121     BGPSpeaker.Kill_BGP_Speaker
 122     FailFast.Do_Not_Fail_Fast_From_Now_On
 123     # NOTE: It is still possible to remain failing fast, if both previous and this test have failed.
 124     [Teardown]    FailFast.Do_Not_Start_Failing_If_This_Failed
 125
 126 Wait_For_Stable_Ipv4_Topology_After_Talking
 127     [Documentation]    Wait until example-ipv4-topology becomes stable again.
 128     [Tags]    critical
 129     # TODO: Is is possible to have failed at Check_Talking_Ipv4_Topology_Count and still have initial period of constant count?
 130     # FIXME: If yes, do count here to get the initial value and use it (if nonzero).
 131     # TODO: If yes, decide whether access to the FailFast state should have keyword or just variable name.
 132     PrefixCounting.Wait_For_Ipv4_Topology_Prefixes_To_Become_Stable    timeout=${bgp_filling_timeout}    period=${CHECK_PERIOD_PREFIX_COUNT_MANY}    repetitions=${REPETITIONS_PREFIX_COUNT_MANY}    excluded_count=${COUNT_PREFIX_COUNT_MANY}
 133
 134 Check_For_Empty_Ipv4_Topology_After_Talking
 135     [Documentation]    Example-ipv4-topology should be empty now.
 136     [Tags]    critical
 137     PrefixCounting.Check_Ipv4_Topology_Is_Empty
 138
 139 Restore_Karaf_Logging_Levels
 140     [Documentation]    Set logging on bgpcep and protocol to the global value.
 141     KarafKeywords.Set_Bgpcep_Log_Levels    bgpcep_level=${KARAF_LOG_LEVEL}    protocol_level=${KARAF_LOG_LEVEL}
 142
 143 Delete_Bgp_Peer_Configuration
 144     [Documentation]    Revert the BGP configuration to the original state: without any configured peers.
 145     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 146     # TODO: Is it useful to extract peer naming logic to separate Keyword?
 147     : FOR    ${index}    IN RANGE    1    ${MULTIPLICITY_PREFIX_COUNT_MANY}+1
 148     \    ${template_as_string}=    BuiltIn.Set_Variable    {'NAME': 'example-bgp-peer-${index}'}
 149     \    ConfigViaRestconf.Delete_Xml_Template_Folder_Config_Via_Restconf    ${BGP_VARIABLESFOLDER}${/}bgp_peer    ${template_as_string}
 150
 151 *** Keywords ***
 152 Setup_Everything
 153     [Documentation]    Setup imported resources, SSH-login to ODL system,
 154     ...    create HTTP session, put Python tool to ODL system.
 155     SetupUtils.Setup_Utils_For_Setup_And_Teardown
 156     ConfigViaRestconf.Setup_Config_Via_Restconf
 157     PrefixCounting.PC_Setup
 158     SSHLibrary.Set_Default_Configuration    prompt=${ODL_SYSTEM_PROMPT}
 159     SSHLibrary.Open_Connection    ${ODL_SYSTEM_IP}
 160     Utils.Flexible_Controller_Login
 161     RequestsLibrary.Create_Session    operational    http://${ODL_SYSTEM_IP}:${RESTCONFPORT}${OPERATIONAL_API}    auth=${AUTH}
 162     # TODO: Do not include slash in ${OPERATIONAL_TOPO_API}, having it typed here is more readable.
 163     # TODO: Alternatively, create variable in Variables which starts with http.
 164     # Both TODOs would probably need to update every suite relying on current Variables.
 165     SSHKeywords.Require_Python
 166     SSHKeywords.Assure_Library_Ipaddr    target_dir=.
 167     SSHLibrary.Put_File    ${CURDIR}/../../../../tools/fastbgp/play.py
 168     # Calculate the timeout value based on how many routes are going to be pushed.
 169     ${period} =    DateTime.Convert_Time    ${CHECK_PERIOD_PREFIX_COUNT_MANY}    result_format=number
 170     ${timeout} =    BuiltIn.Evaluate    ${TEST_DURATION_MULTIPLIER_PREFIX_COUNT_MANY} * (${COUNT_PREFIX_COUNT_MANY} * 3.0 / 10000 + ${period} * (${REPETITIONS_PREFIX_COUNT_MANY} + 1))
 171     Builtin.Set_Suite_Variable    ${bgp_filling_timeout}    ${timeout}
 172     ${timeout} =    BuiltIn.Evaluate    ${TEST_DURATION_MULTIPLIER_PREFIX_COUNT_MANY} * (${COUNT_PREFIX_COUNT_MANY} * 2.0 / 10000 + ${period} * (${REPETITIONS_PREFIX_COUNT_MANY} + 1))
 173     Builtin.Set_Suite_Variable    ${bgp_emptying_timeout}    ${timeout}
 174     KarafKeywords.Execute_Controller_Karaf_Command_On_Background    log:set ${KARAF_LOG_LEVEL}
 175
 176 Teardown_Everything
 177     [Documentation]    Make sure Python tool was killed and tear down imported Resources.
 178     # Environment issue may have dropped the SSH connection, but we do not want Teardown to fail.
 179     BuiltIn.Run_Keyword_And_Ignore_Error    KillPythonTool.Search_And_Kill_Remote_Python    'play\.py'
 180     ConfigViaRestconf.Teardown_Config_Via_Restconf
 181     RequestsLibrary.Delete_All_Sessions
 182     SSHLibrary.Close_All_Connections