csit/suites/bgpcep/bgpingest/singlepeer_changecount.robot

   1 *** Settings ***
   2 Documentation     BGP performance of ingesting from 1 iBGP peer, data change counter is used.
   3 ...
   4 ...               Copyright (c) 2015 Cisco Systems, Inc. and others. All rights reserved.
   5 ...
   6 ...               This program and the accompanying materials are made available under the
   7 ...               terms of the Eclipse Public License v1.0 which accompanies this distribution,
   8 ...               and is available at http://www.eclipse.org/legal/epl-v10.html
   9 ...
  10 ...
  11 ...               This suite uses play.py as single iBGP peer.
  12 ...               The suite only looks at example-ipv4-topology, so RIB is not examined.
  13 ...
  14 ...               This suite requires odl-bgpcep-data-change-counter to be installed so
  15 ...               make sure it is added to "install-features" of any jobs that are going
  16 ...               to invoke it.
  17 ...
  18 ...               The suite consists of two halves, differing on which side initiates BGP connection.
  19 ...               Data change counter is a lightweight way to detect "work is being done".
  20 ...               WaitUtils provide a nice Keyword to wait for stability, but it needs
  21 ...               initial value, that is why Store_Change_Count appears just before work-inducing action.
  22 ...               The time for Wait_For_Stable_* cases to finish is the main performance metric.
  23 ...               After waiting for stability is done, full check on number of prefixes present is performed.
  24 ...
  25 ...               TODO: Currently, if a bug causes zero increase of data changes,
  26 ...               affected test cases will wait for max time. Reconsider.
  27 ...               If zero increase is allowed as stable, higher number of repetitions should be required.
  28 ...
  29 ...               Additionally this test suite is not compatible with Helium and Hydrogen
  30 ...               releases as they don't include data change counter feature.
  31 ...               Use the other version of the suite (singlepeer_prefixcount.robot) to test them.
  32 Suite Setup       Setup_Everything
  33 Suite Teardown    Teardown_Everything
  34 Test Setup        SetupUtils.Setup_Test_With_Logging_And_Fast_Failing
  35 Test Teardown     FailFast.Start_Failing_Fast_If_This_Failed
  36 Library           SSHLibrary    timeout=10s
  37 Library           RequestsLibrary
  38 Variables         ${CURDIR}/../../../variables/Variables.py
  39 Resource          ${CURDIR}/../../../libraries/BGPSpeaker.robot
  40 Resource          ${CURDIR}/../../../libraries/ChangeCounter.robot
  41 Resource          ${CURDIR}/../../../libraries/ConfigViaRestconf.robot
  42 Resource          ${CURDIR}/../../../libraries/FailFast.robot
  43 Resource          ${CURDIR}/../../../libraries/KillPythonTool.robot
  44 Resource          ${CURDIR}/../../../libraries/PrefixCounting.robot
  45 Resource          ${CURDIR}/../../../libraries/SetupUtils.robot
  46
  47 *** Variables ***
  48 ${BGP_TOOL_LOG_LEVEL}    info
  49 ${BGP_VARIABLES_FOLDER}    ${CURDIR}/../../../variables/bgpuser/
  50 ${CHECK_PERIOD}    1
  51 ${CHECK_PERIOD_CHANGE_COUNT}    ${CHECK_PERIOD}
  52 ${CHECK_PERIOD_CHANGE_COUNT_SINGLE}    ${CHECK_PERIOD_CHANGE_COUNT}
  53 ${COUNT}          1000000
  54 ${COUNT_CHANGE_COUNT}    ${COUNT}
  55 ${COUNT_CHANGE_COUNT_SINGLE}    ${COUNT_CHANGE_COUNT}
  56 ${HOLDTIME}       180
  57 ${HOLDTIME_CHANGE_COUNT}    ${HOLDTIME}
  58 ${HOLDTIME_CHANGE_COUNT_SINGLE}    ${HOLDTIME_CHANGE_COUNT}
  59 ${INSERT}         1
  60 ${KARAF_LOG_LEVEL}    INFO
  61 ${KARAF_BGPCEP_LOG_LEVEL}    ${KARAF_LOG_LEVEL}
  62 ${KARAF_PROTOCOL_LOG_LEVEL}    ${KARAF_BGPCEP_LOG_LEVEL}
  63 ${PREFILL}        0
  64 ${REPETITIONS}    1
  65 ${REPETITIONS_CHANGE_COUNT}    ${REPETITIONS}
  66 ${REPETITIONS_CHANGE_COUNT_SINGLE}    ${REPETITIONS_CHANGE_COUNT}
  67 ${RESULTS_FILE_NAME}    bgp.csv
  68 ${TEST_DURATION_MULTIPLIER}    1
  69 ${TEST_DURATION_MULTIPLIER_CHANGE_COUNT}    ${TEST_DURATION_MULTIPLIER}
  70 ${TEST_DURATION_MULTIPLIER_CHANGE_COUNT_SINGLE}    ${TEST_DURATION_MULTIPLIER_CHANGE_COUNT}
  71 ${UPDATE}         single
  72 ${WITHDRAW}       0
  73 # TODO: Option names can be better.
  74 ${last_change_count_single}    -1
  75
  76 *** Test Cases ***
  77 Check_For_Empty_Ipv4_Topology_Before_Talking
  78     [Documentation]    Wait for example-ipv4-topology to come up and empty. Give large timeout for case when BGP boots slower than restconf.
  79     [Tags]    critical
  80     # TODO: Choose which tags to assign and make sure they are assigned correctly.
  81     BuiltIn.Wait_Until_Keyword_Succeeds    120s    1s    PrefixCounting.Check_Ipv4_Topology_Is_Empty
  82
  83 Reconfigure_ODL_To_Accept_Connection
  84     [Documentation]    Configure BGP peer module with initiate-connection set to false.
  85     ${template_as_string} =    BuiltIn.Set_Variable    {'NAME': 'example-bgp-peer', 'IP': '${TOOLS_SYSTEM_IP}', 'HOLDTIME': '${HOLDTIME_CHANGE_COUNT_SINGLE}', 'PEER_PORT': '${BGP_TOOL_PORT}', 'INITIATE': 'false'}
  86     ConfigViaRestconf.Put_Xml_Template_Folder_Config_Via_Restconf    ${BGP_VARIABLES_FOLDER}${/}bgp_peer    ${template_as_string}
  87
  88 Wait_For_Data_Change_Counter_Ready
  89     [Documentation]    Data change counter might have been slower to start than ipv4 topology, wait for it.
  90     BuiltIn.Wait_Until_Keyword_Succeeds    60s    1s    ChangeCounter.Get_Change_Count
  91
  92 Reconfigure_Data_Change_Counter
  93     [Documentation]    Configure data change counter to count transactions in example-ipv4-topology instead of example-linkstate-topology.
  94     ChangeCounter.Reconfigure_Topology_Name    example-ipv4-topology
  95
  96 Change_Karaf_Logging_Levels
  97     [Documentation]    We may want to set more verbose logging here after configuration is done.
  98     KarafKeywords.Set_Bgpcep_Log_Levels    bgpcep_level=${KARAF_BGPCEP_LOG_LEVEL}    protocol_level=${KARAF_PROTOCOL_LOG_LEVEL}
  99
 100 Start_Talking_BGP_Speaker
 101     [Documentation]    Start Python speaker to connect to ODL.
 102     Store_Change_Count
 103     # Myport value is needed for checking whether connection at precise port was established.
 104     BGPSpeaker.Start_BGP_Speaker    --amount ${COUNT_CHANGE_COUNT_SINGLE} --myip=${TOOLS_SYSTEM_IP} --myport=${BGP_TOOL_PORT} --peerip=${ODL_SYSTEM_IP} --peerport=${ODL_BGP_PORT} --insert=${INSERT} --withdraw=${WITHDRAW} --prefill ${PREFILL} --update ${UPDATE} --${BGP_TOOL_LOG_LEVEL} --results ${RESULTS_FILE_NAME}
 105
 106 Wait_For_Stable_Talking_Ipv4_Topology
 107     [Documentation]    Wait until example-ipv4-topology becomes stable. This is done by checking the change counter.
 108     ChangeCounter.Wait_For_Change_Count_To_Become_Stable    timeout=${bgp_filling_timeout}    period=${CHECK_PERIOD_CHANGE_COUNT_SINGLE}    repetitions=${REPETITIONS_CHANGE_COUNT_SINGLE}    count_to_overcome=${last_change_count_single}
 109
 110 Check_Talking_Ipv4_Topology_Count
 111     [Documentation]    Count the routes in example-ipv4-topology and fail if the count is not correct.
 112     [Tags]    critical
 113     PrefixCounting.Check_Ipv4_Topology_Count    ${COUNT_CHANGE_COUNT_SINGLE}
 114
 115 Kill_Talking_BGP_Speaker
 116     [Documentation]    Abort the Python speaker. Also, attempt to stop failing fast.
 117     [Tags]    critical
 118     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 119     Store_Change_Count
 120     BGPSpeaker.Kill_BGP_Speaker
 121     FailFast.Do_Not_Fail_Fast_From_Now_On
 122     # NOTE: It is still possible to remain failing fast, if both previous and this test have failed.
 123     [Teardown]    FailFast.Do_Not_Start_Failing_If_This_Failed
 124
 125 Store_Results_For_Talking_BGP_Speaker
 126     [Documentation]    Store results for plotting
 127     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 128     Store_File_To_Workspace    totals-${RESULTS_FILE_NAME}    totals-${RESULTS_FILE_NAME}
 129     Store_File_To_Workspace    performance-${RESULTS_FILE_NAME}    performance-${RESULTS_FILE_NAME}
 130     Store_File_To_Workspace    totals-${RESULTS_FILE_NAME}    changecount-talking-totals-${RESULTS_FILE_NAME}
 131     Store_File_To_Workspace    performance-${RESULTS_FILE_NAME}    changecount-talking-performance-${RESULTS_FILE_NAME}
 132
 133 Wait_For_Stable_Ipv4_Topology_After_Talking
 134     [Documentation]    Wait until example-ipv4-topology becomes stable again.
 135     [Tags]    critical
 136     ChangeCounter.Wait_For_Change_Count_To_Become_Stable    timeout=${bgp_emptying_timeout}    period=${CHECK_PERIOD_CHANGE_COUNT_SINGLE}    repetitions=${REPETITIONS_CHANGE_COUNT_SINGLE}    count_to_overcome=${last_change_count_single}
 137
 138 Check_For_Empty_Ipv4_Topology_After_Talking
 139     [Documentation]    Example-ipv4-topology should be empty now.
 140     [Tags]    critical
 141     PrefixCounting.Check_Ipv4_Topology_Is_Empty
 142
 143 Start_Listening_BGP_Speaker
 144     [Documentation]    Start Python speaker in listening mode.
 145     BGPSpeaker.Start_BGP_Speaker    --amount ${COUNT_CHANGE_COUNT_SINGLE} --listen --myip=${TOOLS_SYSTEM_IP} --myport=${BGP_TOOL_PORT} --peerip=${ODL_SYSTEM_IP} --insert=${INSERT} --withdraw=${WITHDRAW} --prefill ${PREFILL} --update ${UPDATE} --${BGP_TOOL_LOG_LEVEL} --results ${RESULTS_FILE_NAME}
 146
 147 Reconfigure_ODL_To_Initiate_Connection
 148     [Documentation]    Replace BGP peer config module, now with initiate-connection set to true.
 149     Store_Change_Count
 150     ${template_as_string} =    BuiltIn.Set_Variable    {'NAME': 'example-bgp-peer', 'IP': '${TOOLS_SYSTEM_IP}', 'HOLDTIME': '${HOLDTIME_CHANGE_COUNT_SINGLE}', 'PEER_PORT': '${BGP_TOOL_PORT}', 'INITIATE': 'true'}
 151     ConfigViaRestconf.Put_Xml_Template_Folder_Config_Via_Restconf    ${BGP_VARIABLES_FOLDER}${/}bgp_peer    ${template_as_string}
 152
 153 Wait_For_Stable_Listening_Ipv4_Topology
 154     [Documentation]    Wait until example-ipv4-topology becomes stable.
 155     ChangeCounter.Wait_For_Change_Count_To_Become_Stable    timeout=${bgp_filling_timeout}    period=${CHECK_PERIOD_CHANGE_COUNT_SINGLE}    repetitions=${REPETITIONS_CHANGE_COUNT_SINGLE}    count_to_overcome=${last_change_count_single}
 156
 157 Check_Listening_Ipv4_Topology_Count
 158     [Documentation]    Count the routes in example-ipv4-topology and fail if the count is not correct.
 159     [Tags]    critical
 160     PrefixCounting.Check_Ipv4_Topology_Count    ${COUNT_CHANGE_COUNT_SINGLE}
 161
 162 Kill_Listening_BGP_Speaker
 163     [Documentation]    Abort the Python speaker. Also, attempt to stop failing fast.
 164     [Tags]    critical
 165     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 166     Store_Change_Count
 167     BGPSpeaker.Kill_BGP_Speaker
 168     FailFast.Do_Not_Fail_Fast_From_Now_On
 169     # NOTE: It is still possible to remain failing fast, if both previous and this test have failed.
 170     [Teardown]    FailFast.Do_Not_Start_Failing_If_This_Failed
 171
 172 Store_Results_For_Listening_BGP_Speaker
 173     [Documentation]    Store results for plotting
 174     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 175     Store_File_To_Workspace    totals-${RESULTS_FILE_NAME}    totals-${RESULTS_FILE_NAME}
 176     Store_File_To_Workspace    performance-${RESULTS_FILE_NAME}    performance-${RESULTS_FILE_NAME}
 177     Store_File_To_Workspace    totals-${RESULTS_FILE_NAME}    changecount-listening-totals-${RESULTS_FILE_NAME}
 178     Store_File_To_Workspace    performance-${RESULTS_FILE_NAME}    changecount-listening-performance-${RESULTS_FILE_NAME}
 179
 180 Wait_For_Stable_Ipv4_Topology_After_Listening
 181     [Documentation]    Wait until example-ipv4-topology becomes stable again.
 182     [Tags]    critical
 183     ChangeCounter.Wait_For_Change_Count_To_Become_Stable    timeout=${bgp_emptying_timeout}    period=${CHECK_PERIOD_CHANGE_COUNT_SINGLE}    repetitions=${REPETITIONS_CHANGE_COUNT_SINGLE}    count_to_overcome=${last_change_count_single}
 184
 185 Check_For_Empty_Ipv4_Topology_After_Listening
 186     [Documentation]    Example-ipv4-topology should be empty now.
 187     [Tags]    critical
 188     PrefixCounting.Check_Ipv4_Topology_Is_Empty
 189
 190 Restore_Karaf_Logging_Levels
 191     [Documentation]    Set logging on bgpcep and protocol to the global value.
 192     KarafKeywords.Set_Bgpcep_Log_Levels    bgpcep_level=${KARAF_LOG_LEVEL}    protocol_level=${KARAF_LOG_LEVEL}
 193
 194 Restore_Data_Change_Counter_Configuration
 195     [Documentation]    Configure data change counter back to count transactions affecting example-linkstate-topology.
 196     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 197     ChangeCounter.Reconfigure_Topology_Name    example-linkstate-topology
 198
 199 Delete_Bgp_Peer_Configuration
 200     [Documentation]    Revert the BGP configuration to the original state: without any configured peers.
 201     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 202     ${template_as_string} =    BuiltIn.Set_Variable    {'NAME': 'example-bgp-peer'}
 203     ConfigViaRestconf.Delete_Xml_Template_Folder_Config_Via_Restconf    ${BGP_VARIABLES_FOLDER}${/}bgp_peer    ${template_as_string}
 204
 205 *** Keywords ***
 206 Setup_Everything
 207     [Documentation]    Setup imported resources, SSH-login to tools system,
 208     ...    create HTTP session, put Python tool to tools system.
 209     SetupUtils.Setup_Utils_For_Setup_And_Teardown
 210     ConfigViaRestconf.Setup_Config_Via_Restconf
 211     ChangeCounter.CC_Setup
 212     PrefixCounting.PC_Setup
 213     SSHLibrary.Set_Default_Configuration    prompt=${TOOLS_SYSTEM_PROMPT}
 214     SSHLibrary.Open_Connection    ${TOOLS_SYSTEM_IP}
 215     Utils.Flexible_Mininet_Login
 216     RequestsLibrary.Create_Session    operational    http://${ODL_SYSTEM_IP}:${RESTCONFPORT}${OPERATIONAL_API}    auth=${AUTH}
 217     # TODO: Do not include slash in ${OPERATIONAL_TOPO_API}, having it typed here is more readable.
 218     # TODO: Alternatively, create variable in Variables which starts with http.
 219     # Both TODOs would probably need to update every suite relying on current Variables.
 220     SSHLibrary.Put_File    ${CURDIR}/../../../../tools/fastbgp/play.py
 221     # Calculate the timeout value based on how many routes are going to be pushed
 222     # TODO: Unify formulas with other suites in this directory.
 223     ${timeout} =    BuiltIn.Evaluate    ${TEST_DURATION_MULTIPLIER_CHANGE_COUNT_SINGLE} * (${COUNT_CHANGE_COUNT_SINGLE} * 3.0 / 10000 + 20)
 224     Builtin.Set_Suite_Variable    ${bgp_filling_timeout}    ${timeout}
 225     Builtin.Set_Suite_Variable    ${bgp_emptying_timeout}    ${bgp_filling_timeout*3.0/4}
 226     KarafKeywords.Execute_Controller_Karaf_Command_On_Background    log:set ${KARAF_LOG_LEVEL}
 227
 228 Teardown_Everything
 229     [Documentation]    Make sure Python tool was killed and tear down imported Resources.
 230     # Environment issue may have dropped the SSH connection, but we do not want Teardown to fail.
 231     BuiltIn.Run_Keyword_And_Ignore_Error    KillPythonTool.Search_And_Kill_Remote_Python    'play\.py'
 232     ConfigViaRestconf.Teardown_Config_Via_Restconf
 233     RequestsLibrary.Delete_All_Sessions
 234     SSHLibrary.Close_All_Connections
 235
 236 Store_Change_Count
 237     [Documentation]    Get the count of changes from BGP change counter. Ignore error or store the value.
 238     ${status}    ${count} =    BuiltIn.Run_Keyword_And_Ignore_Error    ChangeCounter.Get_Change_Count
 239     BuiltIn.Run_Keyword_If    '${status}' == 'PASS'    BuiltIn.Set_Suite_Variable    ${last_change_count_single}    ${count}
 240
 241 Store_File_To_Workspace
 242     [Arguments]    ${src_file_name}    ${dst_file_name}
 243     [Documentation]    Store the provided file from the SSH client to workspace.
 244     ${files}=    SSHLibrary.List Files In Directory    .
 245     ${output_log}=    SSHLibrary.Execute_Command    cat ${src_file_name}
 246     BuiltIn.Log    ${output_log}
 247     Create File    ${dst_file_name}    ${output_log}