csit/suites/controller/singleton_service/global_rpc_freeze.robot

   1 *** Settings ***
   2 Documentation     Controller functional HA testing of global singleton rpcs if jvm frozen.
   3 ...
   4 ...               Copyright (c) 2017 Cisco Systems, Inc. and others. All rights reserved.
   5 ...
   6 ...               This program and the accompanying materials are made available under the
   7 ...               terms of the Eclipse Public License v1.0 which accompanies this distribution,
   8 ...               and is available at http://www.eclipse.org/legal/epl-v10.html
   9 Suite Setup       Setup_Suite
  10 Suite Teardown    SSHLibrary.Close_All_Connections
  11 Test Setup        SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing    member_index_list=${active_nodes}
  12 Test Teardown     SetupUtils.Teardown_Test_Show_Bugs_If_Test_Failed
  13 Default Tags      critical
  14 Resource          ${CURDIR}/../../../libraries/ClusterManagement.robot
  15 Resource          ${CURDIR}/../../../libraries/KarafKeywords.robot
  16 Resource          ${CURDIR}/../../../libraries/SetupUtils.robot
  17 Resource          ${CURDIR}/../../../libraries/TemplatedRequests.robot
  18 Resource          ${CURDIR}/../../../libraries/WaitForFailure.robot
  19 Resource          ${CURDIR}/../../../variables/Variables.robot
  20
  21 *** Variables ***
  22 ${RPC_URL}        /restconf/operations/basic-rpc-test:basic-global
  23 &{EMPTY_DICT}
  24 ${SERVICE}        Basic-rpc-test']
  25 ${TEST_LOG_LEVEL}    info
  26 @{TEST_LOG_COMPONENTS}    org.opendaylight.controller.remote.rpc
  27 ${EOS_URL}        /restconf/operational/entity-owners:entity-owners
  28 ${active_nodes}    ${EMPTY}
  29
  30 *** Test Cases ***
  31 Get_Basic_Rpc_Test_Owner
  32     [Documentation]    Find a service owner and successors.
  33     Get_Present_Brt_Owner_And_Successors    1    store=${True}
  34
  35 Rpc_Before_Freezing_On_Owner
  36     [Documentation]    Run rpc on the service owner.
  37     Run_Rpc    ${brt_owner}
  38
  39 Rpc_Before_Freeze_On_Successors
  40     [Documentation]    Run rpc on non owher cluster nodes.
  41     : FOR    ${idx}    IN    @{brt_successors}
  42     \    Run_Rpc    ${idx}
  43
  44 Freeze_Current_Owner_Member
  45     [Documentation]    Stop cluster node which is the owner.
  46     ClusterManagement.Freeze_Single_Member    ${brt_owner}
  47     BuiltIn.Set_Suite_Variable    ${old_brt_owner}    ${brt_owner}
  48     BuiltIn.Set_Suite_Variable    ${old_brt_successors}    ${brt_successors}
  49     BuiltIn.Set_Suite_Variable    ${active_nodes}    ${old_brt_successors}
  50
  51 Verify_New_Basic_Rpc_Test_Owner_Elected
  52     [Documentation]    Verify new owner of the service is elected.
  53     ${idx}=    Collections.Get_From_List    ${old_brt_successors}    0
  54     BuiltIn.Wait_Until_Keyword_Succeeds    60s    5s    Verify_Owner_Elected    ${True}    ${old_brt_owner}    ${idx}
  55     Get_Present_Brt_Owner_And_Successors    ${idx}    store=${True}
  56
  57 Rpc_On_Remained_Cluster_Nodes
  58     [Documentation]    Run rpc on remained cluster nodes.
  59     : FOR    ${idx}    IN    @{old_brt_successors}
  60     \    BuiltIn.Wait_Until_Keyword_Succeeds    60s    5s    Run_Rpc    ${idx}
  61
  62 Unfreeze_Frozen_Member
  63     [Documentation]    Restart frozen node
  64     ClusterManagement.Unfreeze_Single_Member    ${old_brt_owner}
  65     BuiltIn.Set_Suite_Variable    ${active_nodes}    ${EMPTY}
  66
  67 Verify_New_Owner_Remained_After_Rejoin
  68     [Documentation]    Verify no owner change happened after rejoin.
  69     WaitForFailure.Verify_Keyword_Does_Not_Fail_Within_Timeout    15s    2s    Verify_Owner_Elected    ${False}    ${brt_owner}    ${brt_owner}
  70
  71 Rpc_After_Rejoin_On_New_Owner
  72     [Documentation]    Run rpc on the new service owner node.
  73     Run_Rpc    ${brt_owner}
  74
  75 Rpc_After_Rejoin_On_Old_Owner
  76     [Documentation]    Run rpc on rejoined cluster node.
  77     Run_Rpc    ${old_brt_owner}
  78
  79 Rpc_After_Rejoin_On_All
  80     [Documentation]    Run rpc again on all nodes.
  81     Run_Rpc    ${brt_owner}
  82     : FOR    ${idx}    IN    @{brt_successors}
  83     \    Run_Rpc    ${idx}
  84
  85 *** Keywords ***
  86 Setup_Suite
  87     [Documentation]    FIXME: Add a documentation.
  88     SetupUtils.Setup_Utils_For_Setup_And_Teardown    http_timeout=30
  89     SetupUtils.Setup_Logging_For_Debug_Purposes_On_List_Or_All    ${TEST_LOG_LEVEL}    ${TEST_LOG_COMPONENTS}
  90
  91 Run_Rpc
  92     [Arguments]    ${node_idx}
  93     [Documentation]    Run rpc and log the entity ownership service details to karaf log.
  94     ...    Logging the details was a developer's request during the implementation to improve debugging.
  95     ${session} =    Resolve_Http_Session_For_Member    member_index=${node_idx}
  96     ${out} =    TemplatedRequests.Get_From_Uri    ${EOS_URL}    session=${session}
  97     KarafKeywords.Log_Message_To_Controller_Karaf    EOS rest resp: ${out}    member_index_list=${active_nodes}
  98     TemplatedRequests.Post_To_Uri    ${RPC_URL}    ${EMPTY}    ${EMPTY_DICT}    ${EMPTY_DICT}    session=${session}
  99
 100 Verify_Owner_Elected
 101     [Arguments]    ${new_elected}    ${old_owner}    ${node_to_ask}
 102     [Documentation]    Verify new owner was elected or remained the same.
 103     ${owner}    ${successors}=    Get_Present_Brt_Owner_And_Successors    ${node_to_ask}
 104     BuiltIn.Run_Keyword_If    ${new_elected}    BuiltIn.Should_Not_Be_Equal_As_Numbers    ${old_owner}    ${owner}
 105     BuiltIn.Run_Keyword_Unless    ${new_elected}    BuiltIn.Should_Be_Equal_As_numbers    ${old_owner}    ${owner}
 106
 107 Get_Present_Brt_Owner_And_Successors
 108     [Arguments]    ${node_to_ask}    ${store}=${False}
 109     [Documentation]    Find a basic rpc test service owner and successors and store them if indicated.
 110     ${brt_owner}    ${brt_successors}=    ClusterManagement.Get_Owner_And_Successors_For_Device    ${SERVICE}    org.opendaylight.mdsal.ServiceEntityType    ${node_to_ask}
 111     BuiltIn.Run_Keyword_If    ${store}    BuiltIn.Set_Suite_Variable    ${brt_owner}    ${brt_owner}
 112     BuiltIn.Run_Keyword_If    ${store}    BuiltIn.Set_Suite_Variable    ${brt_successors}    ${brt_successors}
 113     BuiltIn.Return_From_Keyword    ${brt_owner}    ${brt_successors}