csit/suites/distribution/karaf_sequence_install.robot

   1 *** Settings ***
   2 Documentation     Bug 4462 test suite.
   3 ...
   4 ...               Copyright (c) 2016 Cisco Systems, Inc. and others. All rights reserved.
   5 ...
   6 ...               This program and the accompanying materials are made available under the
   7 ...               terms of the Eclipse Public License v1.0 which accompanies this distribution,
   8 ...               and is available at http://www.eclipse.org/legal/epl-v10.html
   9 ...
  10 ...
  11 ...               Try to detect whether Karaf hangs when trying to install
  12 ...               list of features one by one. Default list is odl-integration-compatible-with-all.
  13 Suite Setup       SetupUtils.Setup_Utils_For_Setup_And_Teardown
  14 Default Tags      critical    distribution    features
  15 Resource          ${CURDIR}/../../libraries/ClusterManagement.robot
  16 Resource          ${CURDIR}/../../libraries/SetupUtils.robot
  17 Resource          ${CURDIR}/../../libraries/SSHKeywords.robot
  18 Resource          ${CURDIR}/../../variables/Variables.robot
  19 Library           XML
  20 Library           SSHLibrary
  21
  22 *** Variables ***
  23 ${FEATURES_LIST_NAME}    odl-integration-compatible-with-all
  24 ${FEATURE_INSTALL_TIMEOUT}    10m
  25
  26 *** Testcases ***
  27 Install_Features_One_By_One
  28     [Documentation]    Try to install current list of features and check whether Karaf hangs on it or not (bug 4462).
  29     SSHKeywords.Open_Connection_To_ODL_System
  30     ${actual_version}=    BuiltIn.Evaluate    '''${BUNDLEFOLDER}'''[len("distribution-karaf-"):]
  31     SSHLibrary.Get_File    ${WORKSPACE}/${BUNDLEFOLDER}/system/org/opendaylight/integration/features-integration-test/${actual_version}/features-integration-test-${actual_version}-features.xml    features.xml
  32     @{features}=    XML.Get_Elements_Texts    features.xml    .feature[@name="${FEATURES_LIST_NAME}"]/feature
  33     Collections.Log_List    ${features}
  34     KarafKeywords.Open_Controller_Karaf_Console_With_Timeout    ${1}    ${FEATURE_INSTALL_TIMEOUT}
  35     : FOR    ${feature}    IN    @{features}
  36     \    KarafKeywords.Log_Message_To_Controller_Karaf    Installing feature: ${feature}
  37     \    KarafKeywords.Install_a_Feature_Using_Active_Connection    ${feature}