csit/suites/genius/BFD_monitoring.robot

   1 *** Settings ***
   2 Documentation     Test Suite for BFD tunnel monitoring
   3 Suite Setup       Genius Suite Setup
   4 Suite Teardown    BFD Suite Stop
   5 Test Teardown     Genius Test Teardown    ${data_models}
   6 Library           OperatingSystem
   7 Library           String
   8 Library           RequestsLibrary
   9 Library           Collections
  10 Library           re
  11 Library           SSHLibrary
  12 Variables         ../../variables/genius/Modules.py
  13 Resource          ../../libraries/DataModels.robot
  14 Resource          ../../libraries/Genius.robot
  15 Resource          ../../libraries/KarafKeywords.robot
  16 Resource          ../../libraries/OVSDB.robot
  17 Resource          ../../libraries/Utils.robot
  18 Resource          ../../libraries/VpnOperations.robot
  19 Resource          ../../variables/Variables.robot
  20
  21 *** Variables ***
  22 @{itm_created}    TZA
  23 ${genius_config_dir}    ${CURDIR}/../../variables/genius
  24 ${Bridge-1}       BR1
  25 ${Bridge-2}       BR2
  26 ${TEP_SHOW}       tep:show
  27 ${TEP_SHOW_STATE}    tep:show-state
  28 ${TUNNEL_MONITOR_ON}    Tunnel Monitoring (for VXLAN tunnels): On
  29 ${DEFAULT_MONITORING_INTERVAL}    Tunnel Monitoring Interval (for VXLAN tunnels): 1000
  30 ${TUNNEL_MONITOR_OFF}    Tunnel Monitoring (for VXLAN tunnels): Off
  31 ${INTERVAL_5000}    {"tunnel-monitor-interval":{"interval":5000}}
  32 ${OK_201}         201
  33 ${ENABLE_MONITORING}    {"tunnel-monitor-params":{"enabled":true,"monitor-protocol":"odl-interface:tunnel-monitoring-type-bfd"}}
  34 ${DISABLE_MONITORING}    {"tunnel-monitor-params":{"enabled":"false","monitor-protocol":"odl-interface:tunnel-monitoring-type-bfd"}}
  35 ${TUNNEL_MONI_PARAMS_TRUE}    true
  36 ${TUNNEL_MONI_PARAMS_FALSE}    false
  37 ${INTERFACE_DS_MONI_FALSE}    "odl-interface:monitor-enabled": false
  38 ${INTERFACE_DS_MONI_TRUE}    "odl-interface:monitor-enabled": true
  39 ${INTERFACE_DS_MONI_INT_1000}    "odl-interface:monitor-interval": 1000
  40 ${INTERFACE_DS_MONI_INT_5000}    "odl-interface:monitor-interval": 5000
  41 ${TUNNEL_MONI_PROTO}    tunnel-monitoring-type-bfd
  42
  43 *** Test Cases ***
  44 BFD_TC00 Create ITM between DPNs Verify_BFD_Enablement
  45     [Documentation]    Create ITM between DPNs Verify_BFD_Enablement
  46     ${Dpn_id_1}    Genius.Get Dpn Ids    ${conn_id_1}
  47     ${Dpn_id_2}    Genius.Get Dpn Ids    ${conn_id_2}
  48     ${vlan}=    Set Variable    0
  49     ${gateway-ip}=    Set Variable    0.0.0.0
  50     Genius.Create Vteps    ${Dpn_id_1}    ${Dpn_id_2}    ${TOOLS_SYSTEM_IP}    ${TOOLS_SYSTEM_2_IP}    ${vlan}    ${gateway-ip}
  51     Wait Until Keyword Succeeds    30s    5s    Genius.Verify Tunnel Status as UP
  52
  53 BFD_TC01 Verify by default BFD monitoring is enabled on Controller
  54     [Documentation]    Verify by default BFD monitoring is enabled on Controller
  55     Wait Until Keyword Succeeds    10s    2s    Verify Tunnel Monitoring Is On
  56     Wait Until Keyword Succeeds    10s    2s    Verify Config Ietf Interface Output    ${INTERFACE_DS_MONI_TRUE}    ${INTERFACE_DS_MONI_INT_1000}    ${TUNNEL_MONI_PROTO}
  57
  58 BFD_TC02 Verify that BFD tunnel monitoring interval is set with appropriate default value i.e.,1000
  59     [Documentation]    This will verify BFD tunnel monitoring default interval
  60     ${output}=    Issue Command On Karaf Console    ${TEP_SHOW}
  61     Should Contain    ${output}    ${DEFAULT_MONITORING_INTERVAL}
  62     Wait Until Keyword Succeeds    10s    2s    Verify Config Ietf Interface Output    ${INTERFACE_DS_MONI_TRUE}    ${INTERFACE_DS_MONI_INT_1000}    ${TUNNEL_MONI_PROTO}
  63
  64 BFD_TC04 Verify that in controller tunnel status is up when ITM tunnel interface is brought up.
  65     [Documentation]    Verify that in controller tunnel status is up when ITM tunnel interface is brought up.
  66     Wait Until Keyword Succeeds    10s    2s    Verify Tunnel Monitoring Is On
  67     Wait Until Keyword Succeeds    10s    1s    Genius.Verify Tunnel Status as UP
  68     Wait Until Keyword Succeeds    10s    2s    Verify Config Ietf Interface Output    ${INTERFACE_DS_MONI_TRUE}    ${INTERFACE_DS_MONI_INT_1000}    ${TUNNEL_MONI_PROTO}
  69
  70 BFD_TC05 Verify BFD tunnel monitoring interval can be changed.
  71     [Documentation]    Verify BFD tunnel monitoring interval can be changed.
  72     ${oper_int}    RequestsLibrary.Get Request    session    ${OPERATIONAL_API}/itm-config:tunnel-monitor-interval/
  73     ${respjson}    RequestsLibrary.To Json    ${oper_int.content}    pretty_print=True
  74     Log    ${respjson}
  75     ${oper_int}    RequestsLibrary.Put Request    session    ${CONFIG_API}/itm-config:tunnel-monitor-interval/    data=${INTERVAL_5000}
  76     ${Bfd_updated_value}=    Create List    5000
  77     Wait Until Keyword Succeeds    30s    10s    Check For Elements At Uri    ${OPERATIONAL_API}/itm-config:tunnel-monitor-interval/    ${Bfd_updated_value}
  78     Wait Until Keyword Succeeds    30s    10s    Check For Elements At Uri    ${CONFIG_API}/itm-config:tunnel-monitor-interval/    ${Bfd_updated_value}
  79     Wait Until Keyword Succeeds    10s    2s    Verify Config Ietf Interface Output    ${INTERFACE_DS_MONI_TRUE}    ${INTERFACE_DS_MONI_INT_5000}    ${TUNNEL_MONI_PROTO}
  80     SSHLibrary.Switch Connection    ${conn_id_1}
  81     Execute Command    sudo ovs-vsctl del-port ${Bridge-1} tap8ed70586-6c
  82     ${ovs_1}    Execute Command    sudo ovs-vsctl show
  83     log    ${ovs_1}
  84     ${tun_name}    Wait Until Keyword Succeeds    20    5    Ovs Tunnel Get    ${Bridge-1}
  85     Wait Until Keyword Succeeds    20s    5    OVSDB.Verify Ovs-vsctl Output    list interface ${tun_name}    5000    ovs_system=${TOOLS_SYSTEM_IP}
  86     SSHLibrary.Switch Connection    ${conn_id_2}
  87     ${ovs_2}    Execute Command    sudo ovs-vsctl show
  88     ${tun_name}    Wait Until Keyword Succeeds    20    5    Ovs Tunnel Get    ${Bridge-2}
  89     Wait Until Keyword Succeeds    20s    5    OVSDB.Verify Ovs-vsctl Output    list interface ${tun_name}    5000    ovs_system=${TOOLS_SYSTEM_2_IP}
  90
  91 BFD_TC06 Verify that the tunnel state goes to UNKNOWN when DPN is disconnected
  92     [Documentation]    Verify that the tunnel state goes to UNKNOWN when DPN is disconnected
  93     Issue Command On Karaf Console    ${TEP_SHOW}
  94     Issue Command On Karaf Console    ${TEP_SHOW_STATE}
  95     SSHLibrary.Switch Connection    ${conn_id_1}
  96     Execute Command    sudo ovs-vsctl del-controller BR1
  97     SSHLibrary.Switch Connection    ${conn_id_2}
  98     Execute Command    sudo ovs-vsctl del-controller BR2
  99     Issue Command On Karaf Console    ${TEP_SHOW}
 100     Issue Command On Karaf Console    ${TEP_SHOW_STATE}
 101     Wait Until Keyword Succeeds    10s    1s    Verify Tunnel Status as UNKNOWN
 102     Wait Until Keyword Succeeds    10s    2s    Verify Config Ietf Interface Output    ${INTERFACE_DS_MONI_TRUE}    ${INTERFACE_DS_MONI_INT_5000}    ${TUNNEL_MONI_PROTO}
 103     SSHLibrary.Switch Connection    ${conn_id_1}
 104     Execute Command    sudo ovs-vsctl set-controller BR1 tcp:${ODL_SYSTEM_IP}:${ODL_OF_PORT}
 105     SSHLibrary.Switch Connection    ${conn_id_2}
 106     Execute Command    sudo ovs-vsctl set-controller BR2 tcp:${ODL_SYSTEM_IP}:${ODL_OF_PORT}
 107     Log    "After connecting CSS with controller"
 108     Issue Command On Karaf Console    ${TEP_SHOW}
 109     Issue Command On Karaf Console    ${TEP_SHOW_STATE}
 110     Wait Until Keyword Succeeds    10s    1s    Genius.Verify Tunnel Status as UP
 111     Wait Until Keyword Succeeds    10s    2s    Verify Config Ietf Interface Output    ${INTERFACE_DS_MONI_TRUE}    ${INTERFACE_DS_MONI_INT_5000}    ${TUNNEL_MONI_PROTO}
 112
 113 BFD_TC07 Verify that BFD monitoring is disabled on Controller
 114     [Documentation]    Verify that BFD monitoring is disabled on Controller
 115     ${resp}    RequestsLibrary.Put Request    session    ${CONFIG_API}/itm-config:tunnel-monitor-params/    data=${DISABLE_MONITORING}
 116     Should Be Equal As Strings    ${resp.status_code}    201
 117     Wait Until Keyword Succeeds    10s    2s    Verify Tunnel Monitoring Params    ${TUNNEL_MONI_PARAMS_FALSE}
 118     ${output}=    Issue Command On Karaf Console    ${TEP_SHOW}
 119     Should Contain    ${output}    ${TUNNEL_MONITOR_OFF}
 120     Wait Until Keyword Succeeds    10s    2s    Verify Config Ietf Interface Output    ${INTERFACE_DS_MONI_FALSE}    ${INTERFACE_DS_MONI_INT_5000}    ${TUNNEL_MONI_PROTO}
 121     Wait Until Keyword Succeeds    10s    1s    Genius.Verify Tunnel Status as UP
 122     ${resp}    RequestsLibrary.Put Request    session    ${CONFIG_API}/itm-config:tunnel-monitor-params/    data=${ENABLE_MONITORING}
 123     Should Be Equal As Strings    ${resp.status_code}    200
 124     Wait Until Keyword Succeeds    10s    2s    Verify Tunnel Monitoring Params    ${TUNNEL_MONI_PARAMS_TRUE}
 125     Wait Until Keyword Succeeds    10s    2s    Verify Tunnel Monitoring Is On
 126     Wait Until Keyword Succeeds    10s    2s    Verify Config Ietf Interface Output    ${INTERFACE_DS_MONI_TRUE}    ${INTERFACE_DS_MONI_INT_5000}    ${TUNNEL_MONI_PROTO}
 127
 128 *** Keywords ***
 129 Verify Config Ietf Interface Output
 130     [Arguments]    ${state}    ${interval}    ${proto}
 131     ${int_resp}    RequestsLibrary.Get Request    session    ${CONFIG_API}/ietf-interfaces:interfaces/
 132     ${respjson}    RequestsLibrary.To Json    ${int_resp.content}    pretty_print=True
 133     Log    ${respjson}
 134     Should Contain    ${respjson}    ${state}
 135     Should Contain    ${respjson}    ${interval}
 136     Should Contain    ${respjson}    ${proto}
 137
 138 Ovs Tunnel Get
 139     [Arguments]    ${bridge}
 140     log    sudo ovs-vsctl list-ports ${bridge}
 141     ${tun_name}    Execute Command    sudo ovs-vsctl list-ports ${bridge}
 142     log    ${tun_name}
 143     Should Not Be Empty    ${tun_name}
 144     [Return]    ${tun_name}
 145
 146 Verify Tunnel Monitoring Params
 147     [Arguments]    ${flag}
 148     @{checklist}    create list    ${flag}
 149     Check For Elements At URI    ${OPERATIONAL_API}/itm-config:tunnel-monitor-params/    ${checklist}