csit/suites/netvirt/subnet_routing/subnet_routing_and_multicast.robot

   1 *** Settings ***
   2 Documentation     Test suite to validate subnet routing and multicast functionality in an openstack integrated environment.
   3 ...               The assumption of this suite is that the environment is already configured with the proper
   4 ...               integration bridges and vxlan tunnels.
   5 Suite Setup       Start Suite
   6 Suite Teardown    Stop Suite
   7 Test Setup        SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
   8 Test Teardown     OpenStackOperations.Get Test Teardown Debugs
   9 Resource          ../../../libraries/BgpOperations.robot
  10 Resource          ../../../libraries/KarafKeywords.robot
  11 Resource          ../../../libraries/OpenStackOperations.robot
  12 Resource          ../../../libraries/Utils.robot
  13 Resource          ../../../libraries/SetupUtils.robot
  14 Resource          ../../../variables/Variables.robot
  15 Resource          ../../../variables/netvirt/Variables.robot
  16 Resource          ../../../libraries/VpnOperations.robot
  17
  18 *** Variables ***
  19 ${AS_ID}          100
  20 ${SECURITY_GROUP}    mc_sg
  21 ${NUM_OF_PORTS_PER_NETWORK}    4
  22 ${NUM_OF_INSTANCES}    20
  23 ${VPN_INSTANCE_ID}    4ae8cd92-48ca-49b5-94e1-b2921a261111
  24 ${VPN_NAME}       mc_vpn1
  25 ${LOOPBACK_IP}    5.5.5.2
  26 ${L3VPN_RD}       2200:2
  27 ${DCGW_SYSTEM_IP}    ${TOOLS_SYSTEM_1_IP}
  28 ${RPING_MIP_IP}    sudo arping -I eth0:1 -c 5 -b -s @{EXTRA_NW_SUBNET}[0] @{EXTRA_NW_SUBNET}[0]
  29 ${RPING_MIP_IP1}    sudo arping -I eth0:1 -c 5 -b -s @{EXTRA_NW_SUBNET}[1] @{EXTRA_NW_SUBNET}[1]
  30 ${RPING_MIP_IP2}    sudo arping -I eth0:1 -c 5 -b -s @{EXTRA_NW_SUBNET}[2] @{EXTRA_NW_SUBNET}[2]
  31 @{INTERFACE_STATE}    up    down
  32 @{NETWORKS}       mc_net_1    mc_net_2    mc_net_3
  33 @{NET_1_VMS}      mc_net_1_vm_1    mc_net_1_vm_2    mc_net_1_vm_3    mc_net_1_vm_4
  34 @{NET_2_VMS}      mc_net_2_vm_1    mc_net_2_vm_2    mc_net_2_vm_3    mc_net_2_vm_4
  35 @{NET_3_VMS}      mc_net_3_vm_1    mc_net_3_vm_2    mc_net_3_vm_3    mc_net_3_vm_4
  36 @{NET_1_PORTS}    mc_net_1_port_1    mc_net_1_port_2    mc_net_1_port_3    mc_net_1_port_4
  37 @{NET_2_PORTS}    mc_net_2_port_1    mc_net_2_port_2    mc_net_2_port_3    mc_net_2_port_4
  38 @{NET_3_PORTS}    mc_net_3_port_1    mc_net_3_port_2    mc_net_3_port_3    mc_net_3_port_4
  39 @{SUBNETS}        mc_sub_1    mc_sub_2    mc_sub_3
  40 @{SUBNET_CIDR}    10.1.0.0/24    10.2.0.0/24    10.3.0.0/24
  41 @{EXTRA_NW_SUBNET}    10.1.0.100    10.2.0.100    10.3.0.100
  42 ${MASK}           255.255.255.0
  43
  44 *** Test Cases ***
  45 Verify The Subnet Route When Neutron Port Hosting Subnet Route Is Down/up On Single VSwitch Topology
  46     [Documentation]    Verify the subnet route when enterprise host is down and up.
  47     BuiltIn.Wait Until Keyword Succeeds    30s    5s    Configure_IP_On_Sub_Interface    @{NETWORKS}[0]    @{EXTRA_NW_SUBNET}[0]    @{NET_1_VM_IPS}[0]
  48     ...    ${MASK}    @{INTERFACE_STATE}[1]
  49     ${allowed_ip_list} =    BuiltIn.Create List    @{EXTRA_NW_SUBNET}[0]
  50     BuiltIn.Wait Until Keyword Succeeds    30s    10s    Utils.Check For Elements At URI    ${FIB_ENTRY_URL}    ${allowed_ip_list}
  51     BuiltIn.Wait Until Keyword Succeeds    30s    5s    Configure_IP_On_Sub_Interface    @{NETWORKS}[0]    @{EXTRA_NW_SUBNET}[0]    @{NET_1_VM_IPS}[0]
  52     ...    ${MASK}    @{INTERFACE_STATE}[0]
  53     BuiltIn.Wait Until Keyword Succeeds    30s    5s    Verify_IP_Configured_On_Sub_Interface    @{NETWORKS}[0]    @{EXTRA_NW_SUBNET}[0]    @{NET_1_VM_IPS}[0]
  54     BuiltIn.Wait Until Keyword Succeeds    30s    10s    Utils.Check For Elements At URI    ${FIB_ENTRY_URL}    ${allowed_ip_list}
  55     Verify Ping between Inter Intra And Enterprise host
  56
  57 Verify Enterprise Hosts Reachability After VM Reboot
  58     [Documentation]    Restart the VSwitch1 which is hosting the enterprise host and check the subnet route
  59     OpenStackOperations.Get ControlNode Connection
  60     @{NET_1_VM_IPS}    ${NET1_DHCP_IP} =    OpenStackOperations.Get VM IPs    @{NET_1_VMS}
  61     OpenStackOperations.Reboot Nova VM    @{NET_1_VMS}[0]
  62     @{NET_1_VM_IPS}    ${NET1_DHCP_IP} =    OpenStackOperations.Get VM IPs    @{NET_1_VMS}
  63     BuiltIn.Wait Until Keyword Succeeds    30s    5s    Configure_IP_On_Sub_Interface    @{NETWORKS}[0]    @{EXTRA_NW_SUBNET}[0]    @{NET_1_VM_IPS}[0]
  64     ...    ${MASK}    @{INTERFACE_STATE}[0]
  65     BuiltIn.Wait Until Keyword Succeeds    30s    5s    Verify_IP_Configured_On_Sub_Interface    @{NETWORKS}[0]    @{EXTRA_NW_SUBNET}[0]    @{NET_1_VM_IPS}[0]
  66     Verify Ping between Inter Intra And Enterprise host
  67
  68 Verify The Subnet Route For Multiple Subnets On Multi VSwitch Topology When DC-GW Is Restarted
  69     [Documentation]    Restart dcgw and check enterprise hosts reachability
  70     BgpOperations.Restart BGP Processes On DCGW    ${DCGW_SYSTEM_IP}
  71     Create BGP Config On DCGW
  72     Verify Ping between Inter Intra And Enterprise host
  73
  74 Verify The Subnet Route For Multiple Subnets On Multi VSwitch Topology When Qbgp Is Restarted
  75     [Documentation]    Restart qbgp and check enterprise hosts reachability
  76     BgpOperations.Restart BGP Processes On ODL    ${ODL_SYSTEM_IP}
  77     Verify Ping between Inter Intra And Enterprise host
  78
  79 *** Keywords ***
  80 Start Suite
  81     [Documentation]    Test Suite for Subnet_Routing_and_Multicast_Deployments.
  82     VpnOperations.Basic Suite Setup
  83     BgpOperations.Start Quagga Processes On ODL    ${ODL_SYSTEM_IP}
  84     BgpOperations.Start Quagga Processes On DCGW    ${DCGW_SYSTEM_IP}
  85     Create Setup
  86
  87 Stop Suite
  88     [Documentation]    Test Teardown for Subnet_Routing_and_Multicast_Deployments.
  89     BgpOperations.Delete BGP Configuration On ODL    session
  90     BgpOperations.Delete BGP Config On Quagga    ${DCGW_SYSTEM_IP}    ${AS_ID}
  91     BgpOperations.Stop BGP Processes On Node    ${ODL_SYSTEM_IP}
  92     BgpOperations.Stop BGP Processes On Node    ${DCGW_SYSTEM_IP}
  93     OpenStackOperations.OpenStack Suite Teardown
  94
  95 Create Neutron Networks
  96     [Documentation]    Create required number of networks
  97     : FOR    ${net}    IN    @{NETWORKS}
  98     \    OpenStackOperations.Create Network    ${net}
  99     BuiltIn.Wait Until Keyword Succeeds    3s    1s    Utils.Check For Elements At URI    ${NETWORK_URL}    ${NETWORKS}
 100
 101 Create Neutron Subnets
 102     [Arguments]    ${num_of_network}    ${additional_args}=${EMPTY}    ${verbose}=TRUE
 103     [Documentation]    Create required number of subnets for previously created networks
 104     : FOR    ${index}    IN RANGE    0    ${num_of_network}
 105     \    OpenStackOperations.Create SubNet    @{NETWORKS}[${index}]    @{SUBNETS}[${index}]    @{SUBNET_CIDR}[${index}]
 106     BuiltIn.Wait Until Keyword Succeeds    3s    1s    Utils.Check For Elements At URI    ${SUBNETWORK_URL}    ${SUBNETS}
 107
 108 Create Neutron Ports
 109     [Documentation]    Create required number of ports under previously created subnets
 110     ${allowed_address_pairs_args1} =    BuiltIn.Set Variable    --allowed-address ip-address=@{EXTRA_NW_SUBNET}[0] --allowed-address ip-address=@{EXTRA_NW_SUBNET}[1]
 111     ${allowed_address_pairs_args2} =    BuiltIn.Set Variable    --allowed-address ip-address=@{EXTRA_NW_SUBNET}[1] --allowed-address ip-address=@{EXTRA_NW_SUBNET}[2]
 112     ${allowed_address_pairs_args3} =    BuiltIn.Set Variable    --allowed-address ip-address=@{EXTRA_NW_SUBNET}[2] --allowed-address ip-address=@{EXTRA_NW_SUBNET}[0]
 113     : FOR    ${index}    IN RANGE    0    ${NUM_OF_PORTS_PER_NETWORK}
 114     \    OpenStackOperations.Create Port    @{NETWORKS}[0]    @{NET_1_PORTS}[${index}]    sg=${SECURITY_GROUP}    additional_args=${allowed_address_pairs_args1}
 115     : FOR    ${index}    IN RANGE    0    ${NUM_OF_PORTS_PER_NETWORK}
 116     \    OpenStackOperations.Create Port    @{NETWORKS}[1]    @{NET_2_PORTS}[${index}]    sg=${SECURITY_GROUP}    additional_args=${allowed_address_pairs_args2}
 117     : FOR    ${index}    IN RANGE    0    ${NUM_OF_PORTS_PER_NETWORK}
 118     \    OpenStackOperations.Create Port    @{NETWORKS}[2]    @{NET_3_PORTS}[${index}]    sg=${SECURITY_GROUP}    additional_args=${allowed_address_pairs_args3}
 119
 120 Create Nova VMs
 121     [Documentation]    Create Vm instances on compute nodes
 122     : FOR    ${index}    IN RANGE    0    2
 123     \    OpenStackOperations.Create Vm Instance With Port On Compute Node    @{NET_1_PORTS}[${index}]    @{NET_1_VMS}[${index}]    ${OS_CMP1_HOSTNAME}    sg=${SECURITY_GROUP}
 124     \    OpenStackOperations.Create Vm Instance With Port On Compute Node    @{NET_1_PORTS}[${index+2}]    @{NET_1_VMS}[${index+2}]    ${OS_CMP2_HOSTNAME}    sg=${SECURITY_GROUP}
 125     \    OpenStackOperations.Create Vm Instance With Port On Compute Node    @{NET_2_PORTS}[${index}]    @{NET_2_VMS}[${index}]    ${OS_CMP1_HOSTNAME}    sg=${SECURITY_GROUP}
 126     \    OpenStackOperations.Create Vm Instance With Port On Compute Node    @{NET_2_PORTS}[${index+2}]    @{NET_2_VMS}[${index+2}]    ${OS_CMP2_HOSTNAME}    sg=${SECURITY_GROUP}
 127     \    OpenStackOperations.Create Vm Instance With Port On Compute Node    @{NET_3_PORTS}[${index}]    @{NET_3_VMS}[${index}]    ${OS_CMP1_HOSTNAME}    sg=${SECURITY_GROUP}
 128     \    OpenStackOperations.Create Vm Instance With Port On Compute Node    @{NET_3_PORTS}[${index+2}]    @{NET_3_VMS}[${index+2}]    ${OS_CMP2_HOSTNAME}    sg=${SECURITY_GROUP}
 129     @{NET_1_VM_IPS}    ${NET1_DHCP_IP} =    OpenStackOperations.Get VM IPs    @{NET_1_VMS}
 130     @{NET_2_VM_IPS}    ${NET2_DHCP_IP} =    OpenStackOperations.Get VM IPs    @{NET_2_VMS}
 131     @{NET_3_VM_IPS}    ${NET3_DHCP_IP} =    OpenStackOperations.Get VM IPs    @{NET_3_VMS}
 132     BuiltIn.Set Suite Variable    @{NET_1_VM_IPS}
 133     BuiltIn.Set Suite Variable    @{NET_2_VM_IPS}
 134     BuiltIn.Set Suite Variable    @{NET_3_VM_IPS}
 135     BuiltIn.Should Not Contain    ${NET_1_VM_IPS}    None
 136     BuiltIn.Should Not Contain    ${NET_2_VM_IPS}    None
 137     BuiltIn.Should Not Contain    ${NET_3_VM_IPS}    None
 138     OpenStackOperations.Show Debugs    @{NET_1_VMS}    @{NET_2_VMS}    @{NET_3_VMS}
 139
 140 Create Setup
 141     [Documentation]    Create basic topology
 142     OpenStackOperations.OpenStack Suite Setup
 143     ${id} =    OpenStackOperations.Get Project Id    ${ODL_RESTCONF_USER}
 144     OpenStackOperations.Set Instance Quota For Project    ${NUM_OF_INSTANCES}    ${id}
 145     Create Neutron Networks
 146     Create Neutron Subnets    ${3}
 147     OpenStackOperations.Create And Configure Security Group    ${SECURITY_GROUP}
 148     Create Neutron Ports
 149     Create Nova VMs
 150     Create Sub Interfaces And Verify
 151     Create L3VPN
 152     : FOR    ${network}    IN    @{NETWORKS}
 153     \    ${network_id} =    OpenStackOperations.Get Net Id    ${network}
 154     \    VpnOperations.Associate L3VPN To Network    networkid=${network_id}    vpnid=${VPN_INSTANCE_ID}
 155     Create BGP Config On ODL
 156     Create BGP Config On DCGW
 157     BuiltIn.Wait Until Keyword Succeeds    60s    10s    VpnOperations.Verify Tunnel Status as UP
 158     ${output} =    OpenStackOperations.Execute Command on VM Instance    @{NETWORKS}[0]    @{NET_1_VM_IPS}[0]    ${RPING_MIP_IP}
 159     BuiltIn.Should Contain    ${output}    broadcast    Received 0 reply
 160     ${output} =    OpenStackOperations.Execute Command on VM Instance    @{NETWORKS}[1]    @{NET_2_VM_IPS}[0]    ${RPING_MIP_IP1}
 161     BuiltIn.Should Contain    ${output}    broadcast    Received 0 reply
 162     ${output} =    OpenStackOperations.Execute Command on VM Instance    @{NETWORKS}[2]    @{NET_3_VM_IPS}[0]    ${RPING_MIP_IP2}
 163     BuiltIn.Should Contain    ${output}    broadcast    Received 0 reply
 164
 165 Create Sub Interfaces And Verify
 166     [Documentation]    Create Sub Interface and verify for all VMs
 167     BuiltIn.Wait Until Keyword Succeeds    30s    5s    Configure_IP_On_Sub_Interface    @{NETWORKS}[0]    @{EXTRA_NW_SUBNET}[0]    @{NET_1_VM_IPS}[0]
 168     ...    ${MASK}    @{INTERFACE_STATE}[0]
 169     BuiltIn.Wait Until Keyword Succeeds    30s    5s    Verify_IP_Configured_On_Sub_Interface    @{NETWORKS}[0]    @{EXTRA_NW_SUBNET}[0]    @{NET_1_VM_IPS}[0]
 170     BuiltIn.Wait Until Keyword Succeeds    30s    5s    Configure_IP_On_Sub_Interface    @{NETWORKS}[1]    @{EXTRA_NW_SUBNET}[1]    @{NET_2_VM_IPS}[0]
 171     ...    ${MASK}    @{INTERFACE_STATE}[0]
 172     BuiltIn.Wait Until Keyword Succeeds    30s    5s    Verify_IP_Configured_On_Sub_Interface    @{NETWORKS}[1]    @{EXTRA_NW_SUBNET}[1]    @{NET_2_VM_IPS}[0]
 173     BuiltIn.Wait Until Keyword Succeeds    30s    5s    Configure_IP_On_Sub_Interface    @{NETWORKS}[2]    @{EXTRA_NW_SUBNET}[2]    @{NET_3_VM_IPS}[0]
 174     ...    ${MASK}    @{INTERFACE_STATE}[0]
 175     BuiltIn.Wait Until Keyword Succeeds    30s    5s    Verify_IP_Configured_On_Sub_Interface    @{NETWORKS}[2]    @{EXTRA_NW_SUBNET}[2]    @{NET_3_VM_IPS}[0]
 176
 177 Create L3VPN
 178     [Documentation]    Create L3VPN and verify the same
 179     ${net_id} =    OpenStackOperations.Get Net Id    @{NETWORKS}[0]
 180     ${tenant_id} =    OpenStackOperations.Get Tenant ID From Network    ${net_id}
 181     VpnOperations.VPN Create L3VPN    vpnid=${VPN_INSTANCE_ID}    name=${VPN_NAME}    rd=["${L3VPN_RD}"]    exportrt=["${L3VPN_RD}"]    importrt=["${L3VPN_RD}"]    tenantid=${tenant_id}
 182     VpnOperations.Verify L3VPN On ODL    ${VPN_INSTANCE_ID}
 183
 184 Create BGP Config On ODL
 185     [Documentation]    Configure BGP Config on ODL
 186     KarafKeywords.Issue Command On Karaf Console    ${BGP_CONFIG_SERVER_CMD}
 187     BgpOperations.Create BGP Configuration On ODL    localas=${AS_ID}    routerid=${ODL_SYSTEM_IP}
 188     BgpOperations.AddNeighbor To BGP Configuration On ODL    remoteas=${AS_ID}    neighborAddr=${DCGW_SYSTEM_IP}
 189     ${output} =    BgpOperations.Get BGP Configuration On ODL    session
 190     BuiltIn.Should Contain    ${output}    ${DCGW_SYSTEM_IP}
 191
 192 Create BGP Config On DCGW
 193     [Documentation]    Configure BGP on DCGW
 194     BgpOperations.Configure BGP And Add Neighbor On DCGW    ${DCGW_SYSTEM_IP}    ${AS_ID}    ${DCGW_SYSTEM_IP}    ${ODL_SYSTEM_IP}    ${VPN_NAME}    ${L3VPN_RD}
 195     ...    ${LOOPBACK_IP}
 196     ${output} =    BgpOperations.Execute Show Command On Quagga    ${DCGW_SYSTEM_IP}    ${RUN_CONFIG}
 197     BuiltIn.Should Contain    ${output}    ${ODL_SYSTEM_IP}
 198     ${output} =    BuiltIn.Wait Until Keyword Succeeds    180s    10s    BgpOperations.Verify BGP Neighbor Status On Quagga    ${DCGW_SYSTEM_IP}    ${ODL_SYSTEM_IP}
 199
 200 Configure_IP_On_Sub_Interface
 201     [Arguments]    ${network_name}    ${ip}    ${vm_ip}    ${mask}    ${sub_interface_state}=${EMPTY}    ${interface}=eth0
 202     ...    ${sub_interface_number}=1
 203     [Documentation]    Keyword for configuring specified IP on specified interface and the corresponding specified sub interface
 204     OpenStackOperations.Execute Command on VM Instance    ${network_name}    ${vm_ip}    sudo ifconfig ${interface}:${sub_interface_number} ${ip} netmask ${mask} ${sub_interface_state}
 205
 206 Verify_IP_Configured_On_Sub_Interface
 207     [Arguments]    ${network_name}    ${ip}    ${vm_ip}    ${interface}=eth0    ${sub_interface_number}=1
 208     [Documentation]    Keyword for verifying specified IP on specified interface and the corresponding specified sub interface
 209     ${resp} =    OpenStackOperations.Execute Command on VM Instance    ${network_name}    ${vm_ip}    sudo ifconfig ${interface}:${sub_interface_number}
 210     BuiltIn.Should Contain    ${resp}    ${ip}
 211
 212 Verify Ping between Inter Intra And Enterprise host
 213     [Documentation]    Ping Enterprise Host for Intra, Inter from different and same network
 214     ${dst_ip_list} =    BuiltIn.Create List    @{NET_1_VM_IPS}    @{NET_2_VM_IPS}    @{EXTRA_NW_SUBNET}
 215     OpenStackOperations.Test Operations From Vm Instance    @{NETWORKS}[0]    @{NET_1_VM_IPS}[0]    ${dst_ip_list}
 216     OpenStackOperations.Test Operations From Vm Instance    @{NETWORKS}[1]    @{NET_2_VM_IPS}[0]    ${dst_ip_list}
 217     OpenStackOperations.Test Operations From Vm Instance    @{NETWORKS}[0]    @{NET_1_VM_IPS}[2]    ${dst_ip_list}
 218     OpenStackOperations.Test Operations From Vm Instance    @{NETWORKS}[1]    @{NET_2_VM_IPS}[2]    ${dst_ip_list}