binding/mdsal-binding-java-api-generator/src/main/java/org/opendaylight/mdsal/binding/java/api/generator/BuilderTemplate.xtend

   1 /*
   2  * Copyright (c) 2014 Cisco Systems, Inc. and others.  All rights reserved.
   3  *
   4  * This program and the accompanying materials are made available under the
   5  * terms of the Eclipse Public License v1.0 which accompanies this distribution,
   6  * and is available at http://www.eclipse.org/legal/epl-v10.html
   7  */
   8 package org.opendaylight.mdsal.binding.java.api.generator
   9
  10 import static extension org.apache.commons.text.StringEscapeUtils.escapeJava
  11 import static org.opendaylight.mdsal.binding.spec.naming.BindingMapping.AUGMENTABLE_AUGMENTATION_NAME
  12 import static org.opendaylight.mdsal.binding.spec.naming.BindingMapping.AUGMENTATION_FIELD
  13
  14 import com.google.common.collect.ImmutableList
  15 import java.util.ArrayList
  16 import java.util.Collection
  17 import java.util.HashMap
  18 import java.util.HashSet
  19 import java.util.List
  20 import java.util.Map
  21 import java.util.Set
  22 import org.opendaylight.mdsal.binding.model.api.AnnotationType
  23 import org.opendaylight.mdsal.binding.model.api.GeneratedProperty
  24 import org.opendaylight.mdsal.binding.model.api.GeneratedTransferObject
  25 import org.opendaylight.mdsal.binding.model.api.GeneratedType
  26 import org.opendaylight.mdsal.binding.model.api.JavaTypeName
  27 import org.opendaylight.mdsal.binding.model.api.ParameterizedType
  28 import org.opendaylight.mdsal.binding.model.api.Type
  29 import org.opendaylight.mdsal.binding.model.util.TypeConstants
  30 import org.opendaylight.mdsal.binding.model.util.Types
  31 import org.opendaylight.mdsal.binding.spec.naming.BindingMapping
  32 import org.opendaylight.yangtools.concepts.Builder
  33 import org.opendaylight.yangtools.yang.binding.AugmentationHolder
  34 import org.opendaylight.yangtools.yang.binding.DataObject
  35
  36 /**
  37  * Template for generating JAVA builder classes.
  38  */
  39 class BuilderTemplate extends AbstractBuilderTemplate {
  40     /**
  41      * Constant used as suffix for builder name.
  42      */
  43     public static val BUILDER = "Builder";
  44
  45     static val AUGMENTATION_FIELD_UPPER = AUGMENTATION_FIELD.toFirstUpper
  46
  47     /**
  48      * Constructs new instance of this class.
  49      * @throws IllegalArgumentException if <code>genType</code> equals <code>null</code>
  50      */
  51     new(GeneratedType genType, GeneratedType targetType, Set<GeneratedProperty> properties, Type augmentType,
  52             Type keyType) {
  53         super(genType, targetType, properties, augmentType, keyType)
  54     }
  55
  56     override isLocalInnerClass(JavaTypeName name) {
  57         // Builders do not have inner types
  58         return false;
  59     }
  60
  61     /**
  62      * Template method which generates JAVA class body for builder class and for IMPL class.
  63      *
  64      * @return string with JAVA source code
  65      */
  66     override body() '''
  67         «wrapToDocumentation(formatDataForJavaDoc(targetType))»
  68         «targetType.annotations.generateDeprecatedAnnotation»
  69         public class «type.name» implements «Builder.importedName»<«targetType.importedName»> {
  70
  71             «generateFields(false)»
  72
  73             «constantsDeclarations()»
  74
  75             «IF augmentType !== null»
  76                 «generateAugmentField()»
  77             «ENDIF»
  78
  79             «generateConstructorsFromIfcs()»
  80
  81             public «generateCopyConstructor(targetType, type.enclosedTypes.get(0))»
  82
  83             «generateMethodFieldsFrom()»
  84
  85             «generateGetters(false)»
  86             «IF augmentType !== null»
  87
  88                 «generateAugmentation()»
  89             «ENDIF»
  90
  91             «generateSetters»
  92
  93             @«OVERRIDE.importedName»
  94             public «targetType.name» build() {
  95                 return new «type.enclosedTypes.get(0).importedName»(this);
  96             }
  97
  98             «new BuilderImplTemplate(this, type.enclosedTypes.get(0)).body»
  99         }
 100     '''
 101
 102     override generateDeprecatedAnnotation(AnnotationType ann) {
 103         val forRemoval = ann.getParameter("forRemoval")
 104         if (forRemoval !== null) {
 105             return "@" + DEPRECATED.importedName + "(forRemoval = " + forRemoval.value + ")"
 106         }
 107         return "@" + SUPPRESS_WARNINGS.importedName + "(\"deprecation\")"
 108     }
 109
 110     /**
 111      * Generate default constructor and constructor for every implemented interface from uses statements.
 112      */
 113     def private generateConstructorsFromIfcs() '''
 114         public «type.name»() {
 115         }
 116         «IF (!(targetType instanceof GeneratedTransferObject))»
 117             «FOR impl : targetType.implements»
 118                 «generateConstructorFromIfc(impl)»
 119             «ENDFOR»
 120         «ENDIF»
 121     '''
 122
 123     /**
 124      * Generate constructor with argument of given type.
 125      */
 126     def private Object generateConstructorFromIfc(Type impl) '''
 127         «IF (impl instanceof GeneratedType)»
 128             «IF impl.hasNonDefaultMethods»
 129                 public «type.name»(«impl.fullyQualifiedName» arg) {
 130                     «printConstructorPropertySetter(impl)»
 131                 }
 132             «ENDIF»
 133             «FOR implTypeImplement : impl.implements»
 134                 «generateConstructorFromIfc(implTypeImplement)»
 135             «ENDFOR»
 136         «ENDIF»
 137     '''
 138
 139     def private Object printConstructorPropertySetter(Type implementedIfc) '''
 140         «IF (implementedIfc instanceof GeneratedType && !(implementedIfc instanceof GeneratedTransferObject))»
 141             «val ifc = implementedIfc as GeneratedType»
 142             «FOR getter : ifc.nonDefaultMethods»
 143                 «IF BindingMapping.isGetterMethodName(getter.name)»
 144                     this._«getter.propertyNameFromGetter» = arg.«getter.name»();
 145                 «ENDIF»
 146             «ENDFOR»
 147             «FOR impl : ifc.implements»
 148                 «printConstructorPropertySetter(impl)»
 149             «ENDFOR»
 150         «ENDIF»
 151     '''
 152
 153     /**
 154      * Generate 'fieldsFrom' method to set builder properties based on type of given argument.
 155      */
 156     def private generateMethodFieldsFrom() '''
 157         «IF (!(targetType instanceof GeneratedTransferObject))»
 158             «IF targetType.hasImplementsFromUses»
 159                 «val List<Type> done = targetType.getBaseIfcs»
 160                 «generateMethodFieldsFromComment(targetType)»
 161                 public void fieldsFrom(«DataObject.importedName» arg) {
 162                     boolean isValidArg = false;
 163                     «FOR impl : targetType.getAllIfcs»
 164                         «generateIfCheck(impl, done)»
 165                     «ENDFOR»
 166                     «CODEHELPERS.importedName».validValue(isValidArg, arg, "«targetType.getAllIfcs.toListOfNames»");
 167                 }
 168             «ENDIF»
 169         «ENDIF»
 170     '''
 171
 172     def private generateMethodFieldsFromComment(GeneratedType type) '''
 173         /**
 174          * Set fields from given grouping argument. Valid argument is instance of one of following types:
 175          * <ul>
 176          «FOR impl : type.getAllIfcs»
 177          * <li>«impl.fullyQualifiedName»</li>
 178          «ENDFOR»
 179          * </ul>
 180          *
 181          * @param arg grouping object
 182          * @throws IllegalArgumentException if given argument is none of valid types
 183         */
 184     '''
 185
 186     /**
 187      * Method is used to find out if given type implements any interface from uses.
 188      */
 189     def boolean hasImplementsFromUses(GeneratedType type) {
 190         var i = 0
 191         for (impl : type.getAllIfcs) {
 192             if (impl instanceof GeneratedType && (impl as GeneratedType).hasNonDefaultMethods) {
 193                 i = i + 1
 194             }
 195         }
 196         return i > 0
 197     }
 198
 199     def private generateIfCheck(Type impl, List<Type> done) '''
 200         «IF (impl instanceof GeneratedType && (impl as GeneratedType).hasNonDefaultMethods)»
 201             «val implType = impl as GeneratedType»
 202             if (arg instanceof «implType.fullyQualifiedName») {
 203                 «printPropertySetter(implType)»
 204                 isValidArg = true;
 205             }
 206         «ENDIF»
 207     '''
 208
 209     def private printPropertySetter(Type implementedIfc) '''
 210         «IF (implementedIfc instanceof GeneratedType && !(implementedIfc instanceof GeneratedTransferObject))»
 211         «val ifc = implementedIfc as GeneratedType»
 212         «FOR getter : ifc.nonDefaultMethods»
 213             «IF BindingMapping.isGetterMethodName(getter.name)»
 214                 this._«getter.propertyNameFromGetter» = ((«implementedIfc.fullyQualifiedName»)arg).«getter.name»();
 215             «ENDIF»
 216         «ENDFOR»
 217         «ENDIF»
 218     '''
 219
 220     private def List<Type> getBaseIfcs(GeneratedType type) {
 221         val List<Type> baseIfcs = new ArrayList();
 222         for (ifc : type.implements) {
 223             if (ifc instanceof GeneratedType && (ifc as GeneratedType).hasNonDefaultMethods) {
 224                 baseIfcs.add(ifc)
 225             }
 226         }
 227         return baseIfcs
 228     }
 229
 230     private def Set<Type> getAllIfcs(Type type) {
 231         val Set<Type> baseIfcs = new HashSet()
 232         if (type instanceof GeneratedType && !(type instanceof GeneratedTransferObject)) {
 233             val ifc = type as GeneratedType
 234             for (impl : ifc.implements) {
 235                 if (impl instanceof GeneratedType && (impl as GeneratedType).hasNonDefaultMethods) {
 236                     baseIfcs.add(impl)
 237                 }
 238                 baseIfcs.addAll(impl.getAllIfcs)
 239             }
 240         }
 241         return baseIfcs
 242     }
 243
 244     private def List<String> toListOfNames(Collection<Type> types) {
 245         val List<String> names = new ArrayList
 246         for (type : types) {
 247             names.add(type.fullyQualifiedName)
 248         }
 249         return names
 250     }
 251
 252     def private constantsDeclarations() '''
 253         «FOR c : type.getConstantDefinitions»
 254             «IF c.getName.startsWith(TypeConstants.PATTERN_CONSTANT_NAME)»
 255                 «val cValue = c.value as Map<String, String>»
 256                 «val String fieldSuffix = c.getName.substring(TypeConstants.PATTERN_CONSTANT_NAME.length)»
 257                 «val jurPatternRef = JUR_PATTERN.importedName»
 258                 «IF cValue.size == 1»
 259                    «val firstEntry = cValue.entrySet.iterator.next»
 260                    private static final «jurPatternRef» «Constants.MEMBER_PATTERN_LIST»«fieldSuffix» = «jurPatternRef».compile("«firstEntry.key.escapeJava»");
 261                    private static final String «Constants.MEMBER_REGEX_LIST»«fieldSuffix» = "«firstEntry.value.escapeJava»";
 262                 «ELSE»
 263                    private static final «jurPatternRef»[] «Constants.MEMBER_PATTERN_LIST»«fieldSuffix» = «CODEHELPERS.importedName».compilePatterns(«ImmutableList.importedName».of(
 264                    «FOR v : cValue.keySet SEPARATOR ", "»"«v.escapeJava»"«ENDFOR»));
 265                    private static final String[] «Constants.MEMBER_REGEX_LIST»«fieldSuffix» = { «
 266                    FOR v : cValue.values SEPARATOR ", "»"«v.escapeJava»"«ENDFOR» };
 267                 «ENDIF»
 268             «ELSE»
 269                 «emitConstant(c)»
 270             «ENDIF»
 271         «ENDFOR»
 272     '''
 273
 274     def private generateSetter(GeneratedProperty field) {
 275         val returnType = field.returnType
 276         if (returnType instanceof ParameterizedType) {
 277             if (Types.isListType(returnType)) {
 278                 return generateListSetter(field, returnType.actualTypeArguments.get(0))
 279             }
 280         }
 281         return generateSimpleSetter(field, returnType)
 282     }
 283
 284     def private generateListSetter(GeneratedProperty field, Type actualType) '''
 285         «val restrictions = restrictionsForSetter(actualType)»
 286         «IF restrictions !== null»
 287             «generateCheckers(field, restrictions, actualType)»
 288         «ENDIF»
 289         public «type.getName» set«field.getName.toFirstUpper»(final «field.returnType.importedName» values) {
 290         «IF restrictions !== null»
 291             if (values != null) {
 292                for («actualType.getFullyQualifiedName» value : values) {
 293                    «checkArgument(field, restrictions, actualType, "value")»
 294                }
 295             }
 296         «ENDIF»
 297             this.«field.fieldName» = values;
 298             return this;
 299         }
 300
 301     '''
 302
 303     def private generateSimpleSetter(GeneratedProperty field, Type actualType) '''
 304         «val restrictions = restrictionsForSetter(actualType)»
 305         «IF restrictions !== null»
 306
 307             «generateCheckers(field, restrictions, actualType)»
 308         «ENDIF»
 309
 310         «val setterName = "set" + field.getName.toFirstUpper»
 311         public «type.getName» «setterName»(final «field.returnType.importedName» value) {
 312             «IF restrictions !== null»
 313                 if (value != null) {
 314                     «checkArgument(field, restrictions, actualType, "value")»
 315                 }
 316             «ENDIF»
 317             this.«field.fieldName» = value;
 318             return this;
 319         }
 320         «val uintType = UINT_TYPES.get(field.returnType)»
 321         «IF uintType !== null»
 322
 323             /**
 324              * Utility migration setter.
 325              *
 326              * @param value field value in legacy type
 327              * @return this builder
 328              * @deprecated Use {#link «setterName»(«field.returnType.importedJavadocName»)} instead.
 329              */
 330             @Deprecated(forRemoval = true)
 331             public «type.getName» «setterName»(final «uintType.importedName» value) {
 332                 return «setterName»(«CODEHELPERS.importedName».compatUint(value));
 333             }
 334         «ENDIF»
 335     '''
 336
 337     /**
 338      * Template method which generates setter methods
 339      *
 340      * @return string with the setter methods
 341      */
 342     def private generateSetters() '''
 343         «IF keyType !== null»
 344             public «type.getName» withKey(final «keyType.importedName» key) {
 345                 this.key = key;
 346                 return this;
 347             }
 348         «ENDIF»
 349         «FOR property : properties»
 350             «generateSetter(property)»
 351         «ENDFOR»
 352
 353         «IF augmentType !== null»
 354             «val augmentTypeRef = augmentType.importedName»
 355             «val jlClassRef = CLASS.importedName»
 356             public «type.name» add«AUGMENTATION_FIELD_UPPER»(«jlClassRef»<? extends «augmentTypeRef»> augmentationType, «augmentTypeRef» augmentationValue) {
 357                 if (augmentationValue == null) {
 358                     return remove«AUGMENTATION_FIELD_UPPER»(augmentationType);
 359                 }
 360
 361                 if (!(this.«AUGMENTATION_FIELD» instanceof «HashMap.importedName»)) {
 362                     this.«AUGMENTATION_FIELD» = new «HashMap.importedName»<>();
 363                 }
 364
 365                 this.«AUGMENTATION_FIELD».put(augmentationType, augmentationValue);
 366                 return this;
 367             }
 368
 369             public «type.name» remove«AUGMENTATION_FIELD_UPPER»(«jlClassRef»<? extends «augmentTypeRef»> augmentationType) {
 370                 if (this.«AUGMENTATION_FIELD» instanceof «HashMap.importedName») {
 371                     this.«AUGMENTATION_FIELD».remove(augmentationType);
 372                 }
 373                 return this;
 374             }
 375         «ENDIF»
 376     '''
 377
 378     private def createDescription(GeneratedType targetType) {
 379         val target = type.importedName
 380         return '''
 381         Class that builds {@link «target»} instances. Overall design of the class is that of a
 382         <a href="https://en.wikipedia.org/wiki/Fluent_interface">fluent interface</a>, where method chaining is used.
 383
 384         <p>
 385         In general, this class is supposed to be used like this template:
 386         <pre>
 387           <code>
 388             «target» createTarget(int fooXyzzy, int barBaz) {
 389                 return new «target»Builder()
 390                     .setFoo(new FooBuilder().setXyzzy(fooXyzzy).build())
 391                     .setBar(new BarBuilder().setBaz(barBaz).build())
 392                     .build();
 393             }
 394           </code>
 395         </pre>
 396
 397         <p>
 398         This pattern is supported by the immutable nature of «target», as instances can be freely passed around without
 399         worrying about synchronization issues.
 400
 401         <p>
 402         As a side note: method chaining results in:
 403         <ul>
 404           <li>very efficient Java bytecode, as the method invocation result, in this case the Builder reference, is
 405               on the stack, so further method invocations just need to fill method arguments for the next method
 406               invocation, which is terminated by {@link #build()}, which is then returned from the method</li>
 407           <li>better understanding by humans, as the scope of mutable state (the builder) is kept to a minimum and is
 408               very localized</li>
 409           <li>better optimization oportunities, as the object scope is minimized in terms of invocation (rather than
 410               method) stack, making <a href="https://en.wikipedia.org/wiki/Escape_analysis">escape analysis</a> a lot
 411               easier. Given enough compiler (JIT/AOT) prowess, the cost of th builder object can be completely
 412               eliminated</li>
 413         </ul>
 414
 415         @see «target»
 416         @see «Builder.importedName»
 417     '''
 418     }
 419
 420     override protected String formatDataForJavaDoc(GeneratedType type) {
 421         val typeDescription = createDescription(type)
 422
 423         return '''
 424             «IF !typeDescription.nullOrEmpty»
 425             «typeDescription»
 426             «ENDIF»
 427         '''.toString
 428     }
 429
 430     private def generateAugmentation() '''
 431         @«SUPPRESS_WARNINGS.importedName»({ "unchecked", "checkstyle:methodTypeParameterName"})
 432         public <E$$ extends «augmentType.importedName»> E$$ «AUGMENTABLE_AUGMENTATION_NAME»(«CLASS.importedName»<E$$> augmentationType) {
 433             return (E$$) «AUGMENTATION_FIELD».get(«CODEHELPERS.importedName».nonNullValue(augmentationType, "augmentationType"));
 434         }
 435     '''
 436
 437     override protected generateCopyKeys(List<GeneratedProperty> keyProps) '''
 438         this.key = base.«BindingMapping.IDENTIFIABLE_KEY_NAME»();
 439         «FOR field : keyProps»
 440             this.«field.fieldName» = base.«field.getterMethodName»();
 441         «ENDFOR»
 442     '''
 443
 444     override protected generateCopyAugmentation(Type implType) {
 445         val augmentationHolderRef = AugmentationHolder.importedName
 446         val typeRef = targetType.importedName
 447         val hashMapRef = HashMap.importedName
 448         val augmentTypeRef = augmentType.importedName
 449         return '''
 450             if (base instanceof «augmentationHolderRef») {
 451                 @SuppressWarnings("unchecked")
 452                 «JU_MAP.importedName»<«CLASS.importedName»<? extends «augmentTypeRef»>, «augmentTypeRef»> aug =((«augmentationHolderRef»<«typeRef»>) base).augmentations();
 453                 if (!aug.isEmpty()) {
 454                     this.«AUGMENTATION_FIELD» = new «hashMapRef»<>(aug);
 455                 }
 456             }
 457         '''
 458     }
 459
 460     private static def hasNonDefaultMethods(GeneratedType type) {
 461         !type.methodDefinitions.isEmpty && type.methodDefinitions.exists([def | !def.isDefault])
 462     }
 463
 464     private static def nonDefaultMethods(GeneratedType type) {
 465         type.methodDefinitions.filter([def | !def.isDefault])
 466     }
 467 }