binding/mdsal-binding-java-api-generator/src/main/java/org/opendaylight/mdsal/binding/java/api/generator/BuilderTemplate.xtend

   1 /*
   2  * Copyright (c) 2014 Cisco Systems, Inc. and others.  All rights reserved.
   3  *
   4  * This program and the accompanying materials are made available under the
   5  * terms of the Eclipse Public License v1.0 which accompanies this distribution,
   6  * and is available at http://www.eclipse.org/legal/epl-v10.html
   7  */
   8 package org.opendaylight.mdsal.binding.java.api.generator
   9
  10 import static extension org.apache.commons.text.StringEscapeUtils.escapeJava
  11 import static org.opendaylight.mdsal.binding.model.ri.BindingTypes.DATA_OBJECT
  12 import static org.opendaylight.mdsal.binding.spec.naming.BindingMapping.AUGMENTABLE_AUGMENTATION_NAME
  13 import static org.opendaylight.mdsal.binding.spec.naming.BindingMapping.AUGMENTATION_FIELD
  14 import static org.opendaylight.mdsal.binding.spec.naming.BindingMapping.BINDING_CONTRACT_IMPLEMENTED_INTERFACE_NAME
  15
  16 import com.google.common.collect.ImmutableList
  17 import com.google.common.collect.ImmutableSet
  18 import com.google.common.collect.Sets
  19 import java.util.ArrayList
  20 import java.util.Collection
  21 import java.util.HashSet
  22 import java.util.List
  23 import java.util.Map
  24 import java.util.Set
  25 import org.opendaylight.mdsal.binding.model.api.AnnotationType
  26 import org.opendaylight.mdsal.binding.model.api.GeneratedProperty
  27 import org.opendaylight.mdsal.binding.model.api.GeneratedTransferObject
  28 import org.opendaylight.mdsal.binding.model.api.GeneratedType
  29 import org.opendaylight.mdsal.binding.model.api.JavaTypeName
  30 import org.opendaylight.mdsal.binding.model.api.MethodSignature;
  31 import org.opendaylight.mdsal.binding.model.api.ParameterizedType
  32 import org.opendaylight.mdsal.binding.model.api.Type
  33 import org.opendaylight.mdsal.binding.model.ri.TypeConstants
  34 import org.opendaylight.mdsal.binding.model.ri.Types
  35 import org.opendaylight.mdsal.binding.spec.naming.BindingMapping
  36
  37 /**
  38  * Template for generating JAVA builder classes.
  39  */
  40 class BuilderTemplate extends AbstractBuilderTemplate {
  41     val BuilderImplTemplate implTemplate
  42
  43     /**
  44      * Constructs new instance of this class.
  45      * @throws IllegalArgumentException if <code>genType</code> equals <code>null</code>
  46      */
  47     new(GeneratedType genType, GeneratedType targetType, Type keyType) {
  48         super(genType, targetType, keyType)
  49         implTemplate = new BuilderImplTemplate(this, type.enclosedTypes.get(0))
  50     }
  51
  52     override isLocalInnerClass(JavaTypeName name) {
  53         // Builders do not have inner types
  54         return false;
  55     }
  56
  57     /**
  58      * Template method which generates JAVA class body for builder class and for IMPL class.
  59      *
  60      * @return string with JAVA source code
  61      */
  62     override body() '''
  63         «wrapToDocumentation(formatDataForJavaDoc(targetType))»
  64         «targetType.annotations.generateDeprecatedAnnotation»
  65         «generatedAnnotation»
  66         public class «type.name» {
  67
  68             «generateFields(false)»
  69
  70             «constantsDeclarations()»
  71
  72             «IF augmentType !== null»
  73                 «val augmentTypeRef = augmentType.importedName»
  74                 «val mapTypeRef = JU_MAP.importedName»
  75                 «mapTypeRef»<«CLASS.importedName»<? extends «augmentTypeRef»>, «augmentTypeRef»> «AUGMENTATION_FIELD» = «mapTypeRef».of();
  76             «ENDIF»
  77
  78             /**
  79              * Construct an empty builder.
  80              */
  81             public «type.name»() {
  82                 // No-op
  83             }
  84
  85             «generateConstructorsFromIfcs()»
  86
  87             «val targetTypeName = targetType.importedName»
  88             /**
  89              * Construct a builder initialized with state from specified {@link «targetTypeName»}.
  90              *
  91              * @param base «targetTypeName» from which the builder should be initialized
  92              */
  93             public «generateCopyConstructor(targetType, type.enclosedTypes.get(0))»
  94
  95             «generateMethodFieldsFrom()»
  96
  97             «generateGetters(false)»
  98             «IF augmentType !== null»
  99
 100                 «generateAugmentation()»
 101             «ENDIF»
 102
 103             «generateSetters»
 104
 105             /**
 106              * A new {@link «targetTypeName»} instance.
 107              *
 108              * @return A new {@link «targetTypeName»} instance.
 109              */
 110             public «targetTypeName» build() {
 111                 return new «type.enclosedTypes.get(0).importedName»(this);
 112             }
 113
 114             «implTemplate.body»
 115         }
 116     '''
 117
 118     override generateDeprecatedAnnotation(AnnotationType ann) {
 119         val forRemoval = ann.getParameter("forRemoval")
 120         if (forRemoval !== null) {
 121             return "@" + DEPRECATED.importedName + "(forRemoval = " + forRemoval.value + ")"
 122         }
 123         return "@" + SUPPRESS_WARNINGS.importedName + "(\"deprecation\")"
 124     }
 125
 126     /**
 127      * Generate default constructor and constructor for every implemented interface from uses statements.
 128      */
 129     def private generateConstructorsFromIfcs() '''
 130         «IF (!(targetType instanceof GeneratedTransferObject))»
 131             «FOR impl : targetType.implements SEPARATOR "\n"»
 132                 «generateConstructorFromIfc(impl)»
 133             «ENDFOR»
 134         «ENDIF»
 135     '''
 136
 137     /**
 138      * Generate constructor with argument of given type.
 139      */
 140     def private Object generateConstructorFromIfc(Type impl) '''
 141         «IF (impl instanceof GeneratedType)»
 142             «IF impl.hasNonDefaultMethods»
 143                 «val typeName = impl.importedName»
 144                 /**
 145                  * Construct a new builder initialized from specified {@link «typeName»}.
 146                  *
 147                  * @param arg «typeName» from which the builder should be initialized
 148                  */
 149                 public «type.name»(«typeName» arg) {
 150                     «printConstructorPropertySetter(impl)»
 151                 }
 152
 153             «ENDIF»
 154             «FOR implTypeImplement : impl.implements»
 155                 «generateConstructorFromIfc(implTypeImplement)»
 156             «ENDFOR»
 157         «ENDIF»
 158     '''
 159
 160     def private Object printConstructorPropertySetter(Type implementedIfc) '''
 161         «IF (implementedIfc instanceof GeneratedType && !(implementedIfc instanceof GeneratedTransferObject))»
 162             «val ifc = implementedIfc as GeneratedType»
 163             «FOR getter : ifc.nonDefaultMethods»
 164                 «IF BindingMapping.isGetterMethodName(getter.name)»
 165                     «val propertyName = getter.propertyNameFromGetter»
 166                     «printPropertySetter(getter, '''arg.«getter.name»()''', propertyName)»;
 167                 «ENDIF»
 168             «ENDFOR»
 169             «FOR impl : ifc.implements»
 170                 «printConstructorPropertySetter(impl, getSpecifiedGetters(ifc))»
 171             «ENDFOR»
 172         «ENDIF»
 173     '''
 174
 175     def private Object printConstructorPropertySetter(Type implementedIfc, Set<MethodSignature> alreadySetProperties) '''
 176         «IF (implementedIfc instanceof GeneratedType && !(implementedIfc instanceof GeneratedTransferObject))»
 177             «val ifc = implementedIfc as GeneratedType»
 178             «FOR getter : ifc.nonDefaultMethods»
 179                 «IF BindingMapping.isGetterMethodName(getter.name) && getterByName(alreadySetProperties, getter.name).isEmpty»
 180                     «val propertyName = getter.propertyNameFromGetter»
 181                     «printPropertySetter(getter, '''arg.«getter.name»()''', propertyName)»;
 182                 «ENDIF»
 183             «ENDFOR»
 184             «FOR descendant : ifc.implements»
 185                 «printConstructorPropertySetter(descendant, Sets.union(alreadySetProperties, getSpecifiedGetters(ifc)))»
 186             «ENDFOR»
 187         «ENDIF»
 188     '''
 189
 190     def static Set<MethodSignature> getSpecifiedGetters(GeneratedType type) {
 191         val ImmutableSet.Builder<MethodSignature> setBuilder = new ImmutableSet.Builder
 192         for (MethodSignature method : type.getMethodDefinitions()) {
 193             if (method.hasOverrideAnnotation) {
 194                 setBuilder.add(method)
 195             }
 196         }
 197         return setBuilder.build()
 198     }
 199
 200     /**
 201      * Generate 'fieldsFrom' method to set builder properties based on type of given argument.
 202      */
 203     def private generateMethodFieldsFrom() '''
 204         «IF (!(targetType instanceof GeneratedTransferObject))»
 205             «IF targetType.hasImplementsFromUses»
 206                 «val List<Type> done = targetType.getBaseIfcs»
 207                 «generateMethodFieldsFromComment(targetType)»
 208                 public void fieldsFrom(«DATA_OBJECT.importedName» arg) {
 209                     boolean isValidArg = false;
 210                     «FOR impl : targetType.getAllIfcs»
 211                         «generateIfCheck(impl, done)»
 212                     «ENDFOR»
 213                     «CODEHELPERS.importedName».validValue(isValidArg, arg, "«targetType.getAllIfcs.toListOfNames»");
 214                 }
 215             «ENDIF»
 216         «ENDIF»
 217     '''
 218
 219     def private generateMethodFieldsFromComment(GeneratedType type) '''
 220         /**
 221          * Set fields from given grouping argument. Valid argument is instance of one of following types:
 222          * <ul>
 223          «FOR impl : type.getAllIfcs»
 224          *   <li>{@link «impl.importedName»}</li>
 225          «ENDFOR»
 226          * </ul>
 227          *
 228          * @param arg grouping object
 229          * @throws IllegalArgumentException if given argument is none of valid types or has property with incompatible value
 230         */
 231     '''
 232
 233     /**
 234      * Method is used to find out if given type implements any interface from uses.
 235      */
 236     def boolean hasImplementsFromUses(GeneratedType type) {
 237         var i = 0
 238         for (impl : type.getAllIfcs) {
 239             if (impl instanceof GeneratedType && (impl as GeneratedType).hasNonDefaultMethods) {
 240                 i = i + 1
 241             }
 242         }
 243         return i > 0
 244     }
 245
 246     def private generateIfCheck(Type impl, List<Type> done) '''
 247         «IF (impl instanceof GeneratedType && (impl as GeneratedType).hasNonDefaultMethods)»
 248             «val implType = impl as GeneratedType»
 249             if (arg instanceof «implType.importedName») {
 250                 «printPropertySetter(implType)»
 251                 isValidArg = true;
 252             }
 253         «ENDIF»
 254     '''
 255
 256     def private printPropertySetter(Type implementedIfc) '''
 257         «IF (implementedIfc instanceof GeneratedType && !(implementedIfc instanceof GeneratedTransferObject))»
 258         «val ifc = implementedIfc as GeneratedType»
 259         «FOR getter : ifc.nonDefaultMethods»
 260             «IF BindingMapping.isGetterMethodName(getter.name) && !hasOverrideAnnotation(getter)»
 261                 «printPropertySetter(getter, '''((«ifc.importedName»)arg).«getter.name»()''', getter.propertyNameFromGetter)»;
 262             «ENDIF»
 263         «ENDFOR»
 264         «ENDIF»
 265     '''
 266
 267     def private printPropertySetter(MethodSignature getter, String retrieveProperty, String propertyName) {
 268         val ownGetter = implTemplate.findGetter(getter.name)
 269         val ownGetterType = ownGetter.returnType
 270         if (Types.strictTypeEquals(getter.returnType, ownGetterType)) {
 271             return "this._" + propertyName + " = " + retrieveProperty
 272         }
 273         if (ownGetterType instanceof ParameterizedType) {
 274             val itemType = ownGetterType.actualTypeArguments.get(0)
 275             if (Types.isListType(ownGetterType)) {
 276                 return printPropertySetter(retrieveProperty, propertyName, "checkListFieldCast", itemType.importedName)
 277             }
 278             if (Types.isSetType(ownGetterType)) {
 279                 return printPropertySetter(retrieveProperty, propertyName, "checkSetFieldCast", itemType.importedName)
 280             }
 281         }
 282         return printPropertySetter(retrieveProperty, propertyName, "checkFieldCast", ownGetterType.importedName)
 283     }
 284
 285     def private printPropertySetter(String retrieveProperty, String propertyName, String checkerName, String className) '''
 286             this._«propertyName» = «CODEHELPERS.importedName».«checkerName»(«className».class, "«propertyName»", «retrieveProperty»)'''
 287
 288     private def List<Type> getBaseIfcs(GeneratedType type) {
 289         val List<Type> baseIfcs = new ArrayList();
 290         for (ifc : type.implements) {
 291             if (ifc instanceof GeneratedType && (ifc as GeneratedType).hasNonDefaultMethods) {
 292                 baseIfcs.add(ifc)
 293             }
 294         }
 295         return baseIfcs
 296     }
 297
 298     private def Set<Type> getAllIfcs(Type type) {
 299         val Set<Type> baseIfcs = new HashSet()
 300         if (type instanceof GeneratedType && !(type instanceof GeneratedTransferObject)) {
 301             val ifc = type as GeneratedType
 302             for (impl : ifc.implements) {
 303                 if (impl instanceof GeneratedType && (impl as GeneratedType).hasNonDefaultMethods) {
 304                     baseIfcs.add(impl)
 305                 }
 306                 baseIfcs.addAll(impl.getAllIfcs)
 307             }
 308         }
 309         return baseIfcs
 310     }
 311
 312     private def List<String> toListOfNames(Collection<Type> types) {
 313         val List<String> names = new ArrayList
 314         for (type : types) {
 315             names.add(type.importedName)
 316         }
 317         return names
 318     }
 319
 320     def private constantsDeclarations() '''
 321         «FOR c : type.getConstantDefinitions»
 322             «IF c.getName.startsWith(TypeConstants.PATTERN_CONSTANT_NAME)»
 323                 «val cValue = c.value as Map<String, String>»
 324                 «val String fieldSuffix = c.getName.substring(TypeConstants.PATTERN_CONSTANT_NAME.length)»
 325                 «val jurPatternRef = JUR_PATTERN.importedName»
 326                 «IF cValue.size == 1»
 327                    «val firstEntry = cValue.entrySet.iterator.next»
 328                    private static final «jurPatternRef» «Constants.MEMBER_PATTERN_LIST»«fieldSuffix» = «jurPatternRef».compile("«firstEntry.key.escapeJava»");
 329                    private static final String «Constants.MEMBER_REGEX_LIST»«fieldSuffix» = "«firstEntry.value.escapeJava»";
 330                 «ELSE»
 331                    private static final «jurPatternRef»[] «Constants.MEMBER_PATTERN_LIST»«fieldSuffix» = «CODEHELPERS.importedName».compilePatterns(«ImmutableList.importedName».of(
 332                    «FOR v : cValue.keySet SEPARATOR ", "»"«v.escapeJava»"«ENDFOR»));
 333                    private static final String[] «Constants.MEMBER_REGEX_LIST»«fieldSuffix» = { «
 334                    FOR v : cValue.values SEPARATOR ", "»"«v.escapeJava»"«ENDFOR» };
 335                 «ENDIF»
 336             «ELSE»
 337                 «emitConstant(c)»
 338             «ENDIF»
 339         «ENDFOR»
 340     '''
 341
 342     def private generateSetter(GeneratedProperty field) {
 343         val returnType = field.returnType
 344         if (returnType instanceof ParameterizedType) {
 345             if (Types.isListType(returnType) || Types.isSetType(returnType)) {
 346                 val arguments = returnType.actualTypeArguments
 347                 if (arguments.isEmpty) {
 348                     return generateListSetter(field, Types.objectType)
 349                 }
 350                 return generateListSetter(field, arguments.get(0))
 351             } else if (Types.isMapType(returnType)) {
 352                 return generateMapSetter(field, returnType.actualTypeArguments.get(1))
 353             }
 354         }
 355         return generateSimpleSetter(field, returnType)
 356     }
 357
 358     def private generateListSetter(GeneratedProperty field, Type actualType) '''
 359         «val restrictions = restrictionsForSetter(actualType)»
 360         «IF restrictions !== null»
 361             «generateCheckers(field, restrictions, actualType)»
 362         «ENDIF»
 363         public «type.getName» set«field.getName.toFirstUpper»(final «field.returnType.importedName» values) {
 364         «IF restrictions !== null»
 365             if (values != null) {
 366                for («actualType.importedName» value : values) {
 367                    «checkArgument(field, restrictions, actualType, "value")»
 368                }
 369             }
 370         «ENDIF»
 371             this.«field.fieldName» = values;
 372             return this;
 373         }
 374
 375     '''
 376
 377     def private generateMapSetter(GeneratedProperty field, Type actualType) '''
 378         «val restrictions = restrictionsForSetter(actualType)»
 379         «IF restrictions !== null»
 380             «generateCheckers(field, restrictions, actualType)»
 381         «ENDIF»
 382         public «type.getName» set«field.name.toFirstUpper»(final «field.returnType.importedName» values) {
 383         «IF restrictions !== null»
 384             if (values != null) {
 385                for («actualType.importedName» value : values.values()) {
 386                    «checkArgument(field, restrictions, actualType, "value")»
 387                }
 388             }
 389         «ENDIF»
 390             this.«field.fieldName» = values;
 391             return this;
 392         }
 393     '''
 394
 395     def private generateSimpleSetter(GeneratedProperty field, Type actualType) '''
 396         «val restrictions = restrictionsForSetter(actualType)»
 397         «IF restrictions !== null»
 398
 399             «generateCheckers(field, restrictions, actualType)»
 400         «ENDIF»
 401
 402         «val setterName = "set" + field.getName.toFirstUpper»
 403         public «type.getName» «setterName»(final «field.returnType.importedName» value) {
 404             «IF restrictions !== null»
 405                 if (value != null) {
 406                     «checkArgument(field, restrictions, actualType, "value")»
 407                 }
 408             «ENDIF»
 409             this.«field.fieldName» = value;
 410             return this;
 411         }
 412     '''
 413
 414     /**
 415      * Template method which generates setter methods
 416      *
 417      * @return string with the setter methods
 418      */
 419     def private generateSetters() '''
 420         «IF keyType !== null»
 421             public «type.getName» withKey(final «keyType.importedName» key) {
 422                 this.key = key;
 423                 return this;
 424             }
 425         «ENDIF»
 426         «FOR property : properties»
 427             «generateSetter(property)»
 428         «ENDFOR»
 429
 430         «IF augmentType !== null»
 431             «val augmentTypeRef = augmentType.importedName»
 432             «val hashMapRef = JU_HASHMAP.importedName»
 433             /**
 434               * Add an augmentation to this builder's product.
 435               *
 436               * @param augmentation augmentation to be added
 437               * @return this builder
 438               * @throws NullPointerException if {@code augmentation} is null
 439               */
 440             public «type.name» addAugmentation(«augmentTypeRef» augmentation) {
 441                 if (!(this.«AUGMENTATION_FIELD» instanceof «hashMapRef»)) {
 442                     this.«AUGMENTATION_FIELD» = new «hashMapRef»<>();
 443                 }
 444
 445                 this.«AUGMENTATION_FIELD».put(augmentation.«BINDING_CONTRACT_IMPLEMENTED_INTERFACE_NAME»(), augmentation);
 446                 return this;
 447             }
 448
 449             /**
 450               * Remove an augmentation from this builder's product. If this builder does not track such an augmentation
 451               * type, this method does nothing.
 452               *
 453               * @param augmentationType augmentation type to be removed
 454               * @return this builder
 455               */
 456             public «type.name» removeAugmentation(«CLASS.importedName»<? extends «augmentTypeRef»> augmentationType) {
 457                 if (this.«AUGMENTATION_FIELD» instanceof «hashMapRef») {
 458                     this.«AUGMENTATION_FIELD».remove(augmentationType);
 459                 }
 460                 return this;
 461             }
 462         «ENDIF»
 463     '''
 464
 465     private def createDescription(GeneratedType targetType) {
 466         val target = targetType.importedName
 467         return '''
 468         Class that builds {@link «target»} instances. Overall design of the class is that of a
 469         <a href="https://en.wikipedia.org/wiki/Fluent_interface">fluent interface</a>, where method chaining is used.
 470
 471         <p>
 472         In general, this class is supposed to be used like this template:
 473         <pre>
 474           <code>
 475             «target» create«target»(int fooXyzzy, int barBaz) {
 476                 return new «target»Builder()
 477                     .setFoo(new FooBuilder().setXyzzy(fooXyzzy).build())
 478                     .setBar(new BarBuilder().setBaz(barBaz).build())
 479                     .build();
 480             }
 481           </code>
 482         </pre>
 483
 484         <p>
 485         This pattern is supported by the immutable nature of «target», as instances can be freely passed around without
 486         worrying about synchronization issues.
 487
 488         <p>
 489         As a side note: method chaining results in:
 490         <ul>
 491           <li>very efficient Java bytecode, as the method invocation result, in this case the Builder reference, is
 492               on the stack, so further method invocations just need to fill method arguments for the next method
 493               invocation, which is terminated by {@link #build()}, which is then returned from the method</li>
 494           <li>better understanding by humans, as the scope of mutable state (the builder) is kept to a minimum and is
 495               very localized</li>
 496           <li>better optimization opportunities, as the object scope is minimized in terms of invocation (rather than
 497               method) stack, making <a href="https://en.wikipedia.org/wiki/Escape_analysis">escape analysis</a> a lot
 498               easier. Given enough compiler (JIT/AOT) prowess, the cost of th builder object can be completely
 499               eliminated</li>
 500         </ul>
 501
 502         @see «target»
 503     '''
 504     }
 505
 506     override protected String formatDataForJavaDoc(GeneratedType type) {
 507         val typeDescription = createDescription(type)
 508
 509         return '''
 510             «IF !typeDescription.nullOrEmpty»
 511             «typeDescription»
 512             «ENDIF»
 513         '''.toString
 514     }
 515
 516     private def generateAugmentation() '''
 517         @«SUPPRESS_WARNINGS.importedName»({ "unchecked", "checkstyle:methodTypeParameterName"})
 518         public <E$$ extends «augmentType.importedName»> E$$ «AUGMENTABLE_AUGMENTATION_NAME»(«CLASS.importedName»<E$$> augmentationType) {
 519             return (E$$) «AUGMENTATION_FIELD».get(«JU_OBJECTS.importedName».requireNonNull(augmentationType));
 520         }
 521     '''
 522
 523     override protected generateCopyKeys(List<GeneratedProperty> keyProps) '''
 524         this.key = base.«BindingMapping.IDENTIFIABLE_KEY_NAME»();
 525         «FOR field : keyProps»
 526             this.«field.fieldName» = base.«field.getterMethodName»();
 527         «ENDFOR»
 528     '''
 529
 530     override protected CharSequence generateCopyNonKeys(Collection<BuilderGeneratedProperty> props) '''
 531         «FOR field : props»
 532             this.«field.fieldName» = base.«field.getterName»();
 533         «ENDFOR»
 534     '''
 535
 536     override protected generateCopyAugmentation(Type implType) {
 537         val hashMapRef = JU_HASHMAP.importedName
 538         val augmentTypeRef = augmentType.importedName
 539         return '''
 540             «JU_MAP.importedName»<«CLASS.importedName»<? extends «augmentTypeRef»>, «augmentTypeRef»> aug = base.augmentations();
 541             if (!aug.isEmpty()) {
 542                 this.«AUGMENTATION_FIELD» = new «hashMapRef»<>(aug);
 543             }
 544         '''
 545     }
 546 }