csit/libraries/ChangeCounter.robot

   1 *** Settings ***
   2 Documentation     Robot keyword library (Resource) for common handling of data change counter.
   3 ...
   4 ...               Copyright (c) 2015 Cisco Systems, Inc. and others. All rights reserved.
   5 ...
   6 ...               This program and the accompanying materials are made available under the
   7 ...               terms of the Eclipse Public License v1.0 which accompanies this distribution,
   8 ...               and is available at http://www.eclipse.org/legal/epl-v10.html
   9 ...
  10 ...
  11 ...               This resource creates a "default" session using TemplatedRequests.Create_Default_Session
  12 ...               which points to (an analogue of) http://${ODL_SYSTEM_IP}:${RESTCONFPORT}
  13 Library           RequestsLibrary
  14 Resource          ${CURDIR}/CompareStream.robot
  15 Resource          ${CURDIR}/ScalarClosures.robot
  16 Resource          ${CURDIR}/TemplatedRequests.robot
  17 Resource          ${CURDIR}/WaitUtils.robot
  18
  19 *** Variables ***
  20 ${CHANGE_COUNTER_TEMPLATE_FOLDER}    ${CURDIR}/../variables/bgpuser
  21 ${CC_DATA_CHANGE_COUNTER_URL}    /restconf/operational/data-change-counter:data-change-counter
  22
  23 *** Keywords ***
  24 CC_Setup
  25     [Documentation]    Initialize dependency libraries.
  26     TemplatedRequests.Create_Default_Session
  27     WaitUtils.WU_Setup    # includes ScalarClosures.SC_Setup
  28     ${counter} =    ScalarClosures.Closure_From_Keyword_And_Arguments    Get_Change_Count
  29     BuiltIn.Set_Suite_Variable    ${ChangeCounter__getter}    ${counter}
  30
  31 Get_Change_Count
  32     [Arguments]    ${session}=operational
  33     [Documentation]    GET data change request, assert status 200, return the value.
  34     ${response} =    RequestsLibrary.Get_Request    ${session}    ${CC_DATA_CHANGE_COUNTER_URL}
  35     BuiltIn.Should_Be_Equal    ${response.status_code}    ${200}    Got status: ${response.status_code} and message: ${response.text}
  36     # CompareStream.Set_Variable_If_At_Least_Else cannot be used direcly, because ${response.text}["data-change-counter"]["count"] would be
  37     # evaluated before the stream comparison and it causes failures
  38     BuiltIn.Log    ${response.text}
  39     ${count} =    BuiltIn.Evaluate    json.loads('${response.text}')["data-change-counter"]["counter"][0]["count"]    modules=json
  40     [Return]    ${count}
  41
  42 Reconfigure_Topology_Name
  43     [Arguments]    ${topology_name}=example-linkstate-topology
  44     [Documentation]    Configure data change counter to count transactions affecting
  45     ...    ${topology_name} instead of previously configured topology name.
  46     &{mapping}    Create Dictionary    DEVICE_NAME=${DEVICE_NAME}    TOPOLOGY_NAME=${topology_name}
  47     TemplatedRequests.Put_As_Xml_Templated    ${CHANGE_COUNTER_TEMPLATE_FOLDER}${/}change_counter    mapping=${mapping}
  48
  49 Wait_For_Change_Count_To_Become_Stable
  50     [Arguments]    ${timeout}=60s    ${period}=1s    ${repetitions}=4    ${count_to_overcome}=-1
  51     [Documentation]    Each ${period} get count. After ${repetitions} of constant value above ${count_to_overcome} within ${timeout}, Return validator output. Fail early on getter error.
  52     ${validator} =    WaitUtils.Create_Limiting_Stability_Safe_Stateful_Validator_From_Value_To_Overcome    maximum_invalid=${count_to_overcome}
  53     ${result} =    WaitUtils.Wait_For_Getter_Error_Or_Safe_Stateful_Validator_Consecutive_Success    timeout=${timeout}    period=${period}    count=${repetitions}    getter=${ChangeCounter__getter}    safe_validator=${validator}
  54     ...    initial_state=${count_to_overcome}
  55     [Return]    ${result}