csit/libraries/ClusterAdmin.robot

   1 *** Settings ***
   2 Documentation       Keywords wrapping controller's cluster-admin yang model rpcs.
   3 ...
   4 ...                 Copyright (c) 2017 Cisco Systems, Inc. and others. All rights reserved.
   5 ...
   6 ...                 This program and the accompanying materials are made available under the
   7 ...                 terms of the Eclipse Public License v1.0 which accompanies this distribution,
   8 ...                 and is available at http://www.eclipse.org/legal/epl-v10.html
   9
  10 Library             XML
  11 Resource            ${CURDIR}/ClusterManagement.robot
  12 Resource            ${CURDIR}/TemplatedRequests.robot
  13
  14
  15 *** Variables ***
  16 ${CLUSTERADMIN_RPC_DIR}                 ${CURDIR}/../variables/mdsal/clusteradmin
  17 ${ADD_PREFIX_SHARD_REPLICA_DIR}         ${CLUSTERADMIN_RPC_DIR}/add_prefix_shard_replica
  18 ${ADD_SHARD_REPLICA_DIR}                ${CLUSTERADMIN_RPC_DIR}/add_shard_replica
  19 ${MAKE_LEADER_LOCAL_DIR}                ${CLUSTERADMIN_RPC_DIR}/make_leader_local
  20 ${REMOVE_PREFIX_SHARD_REPLICA_DIR}      ${CLUSTERADMIN_RPC_DIR}/remove_prefix_shard_replica
  21 ${REMOVE_SHARD_REPLICA_DIR}             ${CLUSTERADMIN_RPC_DIR}/remove_shard_replica
  22 ${GET_SHARD_ROLE_DIR}                   ${CLUSTERADMIN_RPC_DIR}/get_shard_role
  23 ${GET_PREFIX_SHARD_ROLE_DIR}            ${CLUSTERADMIN_RPC_DIR}/get_prefix_shard_role
  24
  25
  26 *** Keywords ***
  27 Make_Leader_Local
  28     [Documentation]    Makes the node to be a shard leader by invoking make-leader-local rpc.
  29     [Arguments]    ${member_index}    ${shard_name}    ${shard_type}
  30     ${session} =    ClusterManagement.Resolve_Http_Session_For_Member    member_index=${member_index}
  31     &{mapping} =    BuiltIn.Create_Dictionary    SHARD_NAME=${shard_name}    SHARD_TYPE=${shard_type}
  32     ${text} =    TemplatedRequests.Post_As_Xml_Templated
  33     ...    ${MAKE_LEADER_LOCAL_DIR}
  34     ...    mapping=${mapping}
  35     ...    session=${session}
  36
  37 Add_Prefix_Shard_Replica
  38     [Documentation]    Add prefix shard replica to given member by invoking add-prefix-shard-replica rpc.
  39     [Arguments]    ${member_index}    ${shard_prefix}    ${ds_type}
  40     ${session} =    ClusterManagement.Resolve_Http_Session_For_Member    member_index=${member_index}
  41     &{mapping} =    BuiltIn.Create_Dictionary    SHARD_PREFIX=${shard_prefix}    DATA_STORE_TYPE=${ds_type}
  42     ${text} =    TemplatedRequests.Post_As_Xml_Templated
  43     ...    ${ADD_PREFIX_SHARD_REPLICA_DIR}
  44     ...    mapping=${mapping}
  45     ...    session=${session}
  46
  47 Remove_Prefix_Shard_Replica
  48     [Documentation]    Remove prefix shard replica from the given member by invoking remove-prefix-shard-replica rpc.
  49     [Arguments]    ${member_index}    ${shard_prefix}    ${member_name}    ${ds_type}
  50     ${session} =    ClusterManagement.Resolve_Http_Session_For_Member    member_index=${member_index}
  51     &{mapping} =    BuiltIn.Create_Dictionary
  52     ...    SHARD_PREFIX=${shard_prefix}
  53     ...    MEMBER_NAME=${member_name}
  54     ...    DATA_STORE_TYPE=${ds_type}
  55     ${text} =    TemplatedRequests.Post_As_Xml_Templated
  56     ...    ${REMOVE_PREFIX_SHARD_REPLICA_DIR}
  57     ...    mapping=${mapping}
  58     ...    session=${session}
  59
  60 Add_Shard_Replica
  61     [Documentation]    Add shard replica to given member by invoking add-shard-replica rpc.
  62     [Arguments]    ${member_index}    ${shard_name}    ${ds_type}
  63     ${session} =    ClusterManagement.Resolve_Http_Session_For_Member    member_index=${member_index}
  64     &{mapping} =    BuiltIn.Create_Dictionary    SHARD_NAME=${shard_name}    DATA_STORE_TYPE=${ds_type}
  65     ${text} =    TemplatedRequests.Post_As_Xml_Templated
  66     ...    ${ADD_SHARD_REPLICA_DIR}
  67     ...    mapping=${mapping}
  68     ...    session=${session}
  69
  70 Remove_Shard_Replica
  71     [Documentation]    Remove shard replica from the given member by invoking remove-shard-replica rpc.
  72     [Arguments]    ${member_index}    ${shard_name}    ${member_name}    ${ds_type}
  73     ${session} =    ClusterManagement.Resolve_Http_Session_For_Member    member_index=${member_index}
  74     &{mapping} =    BuiltIn.Create_Dictionary
  75     ...    SHARD_NAME=${shard_name}
  76     ...    MEMBER_NAME=${member_name}
  77     ...    DATA_STORE_TYPE=${ds_type}
  78     ${text} =    TemplatedRequests.Post_As_Xml_Templated
  79     ...    ${REMOVE_SHARD_REPLICA_DIR}
  80     ...    mapping=${mapping}
  81     ...    session=${session}
  82
  83 Get_Shard_Role
  84     [Documentation]    Get shard member role.
  85     [Arguments]    ${member_index}    ${shard_name}    ${ds_type}
  86     ${session} =    ClusterManagement.Resolve_Http_Session_For_Member    member_index=${member_index}
  87     &{mapping} =    BuiltIn.Create_Dictionary    SHARD_NAME=${shard_name}    DATA_STORE_TYPE=${ds_type}
  88     ${text} =    TemplatedRequests.Post_As_Xml_Templated
  89     ...    ${GET_SHARD_ROLE_DIR}
  90     ...    mapping=${mapping}
  91     ...    session=${session}
  92     ${xml} =    XML.Parse_Xml    ${text}
  93     ${role} =    XML.Get_Element_Text    ${xml}    xpath=role
  94     RETURN    ${role}
  95
  96 Get_Prefix_Shard_Role
  97     [Documentation]    Get prefix shard member role.
  98     [Arguments]    ${member_index}    ${shard_prefix}    ${ds_type}
  99     ${session} =    ClusterManagement.Resolve_Http_Session_For_Member    member_index=${member_index}
 100     &{mapping} =    BuiltIn.Create_Dictionary    SHARD_PREFIX=${shard_prefix}    DATA_STORE_TYPE=${ds_type}
 101     ${text} =    TemplatedRequests.Post_As_Xml_Templated
 102     ...    ${GET_PREFIX_SHARD_ROLE_DIR}
 103     ...    mapping=${mapping}
 104     ...    session=${session}
 105     ${xml} =    XML.Parse_Xml    ${text}
 106     ${role} =    XML.Get_Element_Text    ${xml}    xpath=role
 107     RETURN    ${role}