csit/libraries/ClusterKeywords.robot

   1 *** Settings ***
   2 Library           RequestsLibrary
   3 Library           Collections
   4 Library           UtilLibrary.py
   5 Library           ClusterStateLibrary.py
   6 Library           ./HsfJson/hsf_json.py
   7 Resource          Utils.robot
   8
   9 *** Variables ***
  10 ${jolokia_conf}    /jolokia/read/org.opendaylight.controller:Category=ShardManager,name=shard-manager-config,type=DistributedConfigDatastore
  11 ${jolokia_oper}    /jolokia/read/org.opendaylight.controller:Category=ShardManager,name=shard-manager-operational,type=DistributedOperationalDatastore
  12 ${jolokia_read}    /jolokia/read/org.opendaylight.controller
  13
  14 *** Keywords ***
  15 Create Controller Index List
  16     [Documentation]    Reads number of controllers and returns a list with all controllers indexes.
  17     ${controller_index_list}    Create List
  18     ${NUM_ODL_SYSTEM}=    Convert to Integer    ${NUM_ODL_SYSTEM}
  19     : FOR    ${i}    IN RANGE    ${NUM_ODL_SYSTEM}
  20     \    Append To List    ${controller_index_list}    ${i+1}
  21     [Return]    ${controller_index_list}
  22
  23 Create Controller Sessions
  24     [Documentation]    Creates REST session to all controller instances.
  25     ${NUM_ODL_SYSTEM}=    Convert to Integer    ${NUM_ODL_SYSTEM}
  26     : FOR    ${i}    IN RANGE    ${NUM_ODL_SYSTEM}
  27     \    Log    Create Session ${ODL_SYSTEM_${i+1}_IP}
  28     \    Create Session    controller${i+1}    http://${ODL_SYSTEM_${i+1}_IP}:${RESTCONFPORT}    auth=${AUTH}
  29
  30 Get Cluster Shard Status
  31     [Arguments]    ${controller_index_list}    ${shard_type}    ${shard}
  32     [Documentation]    Checks ${shard} status and returns Leader index and a list of Followers from a ${controller_index_list}.
  33     ...    ${shard_type} is either config or operational.
  34     ${lenght}=    Get Length    ${controller_index_list}
  35     Run Keyword If    '${shard_type}' == 'config'    Set Test Variable    ${type}    DistributedConfigDatastore
  36     Run Keyword If    '${shard_type}' == 'operational'    Set Test Variable    ${type}    DistributedOperationalDatastore
  37     Should Not Be Empty    ${type}    Wrong type, valid values are config and operational.
  38     ${leader}=    Set Variable    0
  39     ${follower_list}=    Create List
  40     : FOR    ${i}    IN    @{controller_index_list}
  41     \    ${data}=    Get Data From URI    controller${i}    ${jolokia_read}:Category=Shards,name=member-${i}-shard-${shard}-${shard_type},type=${type}
  42     \    Log    ${data}
  43     \    ${json}=    To Json    ${data}
  44     \    ${status}=    Get From Dictionary    &{json}[value]    RaftState
  45     \    Log    Controller ${ODL_SYSTEM_${i}_IP} is ${status} for shard ${shard}
  46     \    Run Keyword If    '${status}' == 'Leader'    Set Test Variable    ${leader}    ${i}
  47     \    Run Keyword If    '${status}' == 'Follower'    Append To List    ${follower_list}    ${i}
  48     Should Not Be Equal    ${leader}    0    No Leader elected in shard ${shard_type} ${shard}
  49     Length Should Be    ${follower_list}    ${lenght-1}    Not enough or too many Followers in shard ${shard_type} ${shard}
  50     [Return]    ${leader}    ${follower_list}
  51
  52 Get Cluster Entity Owner Status
  53     [Arguments]    ${controller_index_list}    ${device_type}    ${device}
  54     [Documentation]    Checks Entity Owner status for a ${device} and returns owner index and list of candidates from a ${controller_index_list}.
  55     ...    ${device_type} is openflow, ovsdb, etc...
  56     ${length}=    Get Length    ${controller_index_list}
  57     ${candidates_list}=    Create List
  58     ${data}=    Get Data From URI    controller@{controller_index_list}[0]    /restconf/operational/entity-owners:entity-owners
  59     Log    ${data}
  60     ${data}=    Replace String    ${data}    /general-entity:entity[general-entity:name='    ${EMPTY}
  61     ${clear_data}=    Replace String    ${data}    ']    ${EMPTY}
  62     Log    ${clear_data}
  63     ${json}=    To Json    ${clear_data}
  64     ${entity_type_list}=    Get From Dictionary    &{json}[entity-owners]    entity-type
  65     ${entity_type_index}=    Get Index From List Of Dictionaries    ${entity_type_list}    type    ${device_type}
  66     Should Not Be Equal    ${entity_type_index}    -1    No Entity Owner found for ${device_type}
  67     ${entity_list}=    Get From Dictionary    @{entity_type_list}[${entity_type_index}]    entity
  68     ${entity_index}=    Get Index From List Of Dictionaries    ${entity_list}    id    ${device}
  69     Should Not Be Equal    ${entity_index}    -1    Device ${device} not found in Entity Owner ${device_type}
  70     ${entity_owner}=    Get From Dictionary    @{entity_list}[${entity_index}]    owner
  71     Should Not Be Empty    ${entity_owner}    No owner found for ${device}
  72     ${owner}=    Replace String    ${entity_owner}    member-    ${EMPTY}
  73     ${owner}=    Convert To Integer    ${owner}
  74     List Should Contain Value    ${controller_index_list}    ${owner}    Owner ${owner} not exisiting in ${controller_index_list}
  75     ${entity_candidates_list}=    Get From Dictionary    @{entity_list}[${entity_index}]    candidate
  76     ${list_length}=    Get Length    ${entity_candidates_list}
  77     : FOR    ${entity_candidate}    IN    @{entity_candidates_list}
  78     \    ${candidate}=    Replace String    &{entity_candidate}[name]    member-    ${EMPTY}
  79     \    ${candidate}=    Convert To Integer    ${candidate}
  80     \    List Should Contain Value    ${controller_index_list}    ${candidate}    Candidate ${candidate} not exisiting in ${controller_index_list}
  81     \    Run Keyword If    '${candidate}' != '${owner}'    Append To List    ${candidates_list}    ${candidate}
  82     [Return]    ${owner}    ${candidates_list}
  83
  84 Check Item Occurrence At URI In Cluster
  85     [Arguments]    ${controller_index_list}    ${dictionary_item_occurrence}    ${uri}    ${headers}=${HEADERS}
  86     [Documentation]    Send a GET with the supplied ${uri} to all cluster instances in ${controller_index_list}
  87     ...    and check for occurrences of items expressed in a dictionary ${dictionary_item_occurrence}.
  88     : FOR    ${i}    IN    @{controller_index_list}
  89     \    ${data}    Get Data From URI    controller${i}    ${uri}    ${headers}
  90     \    Log    ${data}
  91     \    Check Item Occurrence    ${data}    ${dictionary_item_occurrence}
  92
  93 Put And Check At URI In Cluster
  94     [Arguments]    ${controller_index_list}    ${controller_index}    ${uri}    ${body}    ${headers}=${HEADERS}
  95     [Documentation]    Send a PUT with the supplied ${uri} and ${body} to a ${controller_index}
  96     ...    and check the data is replicated in all instances in ${controller_index_list}.
  97     ${expected_body}=    Hsf Json    ${body}
  98     ${resp}    RequestsLibrary.Put Request    controller${controller_index}    ${uri}    ${body}    ${headers}
  99     Should Be Equal As Strings    ${resp.status_code}    200
 100     : FOR    ${i}    IN    @{controller_index_list}
 101     \    ${data}    Wait Until Keyword Succeeds    5s    1s    Get Data From URI    controller${i}
 102     \    ...    ${uri}    ${headers}
 103     \    Log    ${data}
 104     \    ${received_body}    Hsf Json    ${data}
 105     \    Should Be Equal    ${expected_body}    ${received_body}
 106
 107 Delete And Check At URI In Cluster
 108     [Arguments]    ${controller_index_list}    ${controller_index}    ${uri}    ${headers}=${HEADERS}
 109     [Documentation]    Send a DELETE with the supplied ${uri} to a ${controller_index}
 110     ...    and check the data is removed from all instances in ${controller_index_list}.
 111     ${resp}    RequestsLibrary.Delete Request    controller${controller_index}    ${uri}    ${headers}
 112     Should Be Equal As Strings    ${resp.status_code}    200
 113     : FOR    ${i}    IN    @{controller_index_list}
 114     \    Wait Until Keyword Succeeds    5s    1s    No Content From URI    controller${i}    ${uri}
 115     \    ...    ${headers}
 116
 117 Kill Multiple Controllers
 118     [Arguments]    @{controller_index_list}
 119     [Documentation]    Give this keyword a scalar or list of controllers to be stopped.
 120     : FOR    ${i}    IN    @{controller_index_list}
 121     \    ${output}=    Run Command On Controller    ${ODL_SYSTEM_${i}_IP}    ps axf | grep karaf | grep -v grep | awk '{print \"kill -9 \" $1}' | sh
 122     \    Controller Down Check    ${ODL_SYSTEM_${i}_IP}
 123
 124 Start Multiple Controllers
 125     [Arguments]    ${timeout}    @{controller_index_list}
 126     [Documentation]    Give this keyword a scalar or list of controllers to be started.
 127     : FOR    ${i}    IN    @{controller_index_list}
 128     \    ${output}=    Run Command On Controller    ${ODL_SYSTEM_${i}_IP}    ${WORKSPACE}/${BUNDLEFOLDER}/bin/start
 129     \    Wait For Controller Sync    ${timeout}    ${ODL_SYSTEM_${i}_IP}
 130
 131 Get Controller List
 132     [Arguments]    ${exclude_controller}=${EMPTY}
 133     [Documentation]    Creates a list of all controllers minus any excluded controller.
 134     Log    ${exclude_controller}
 135     @{searchlist}    Create List    ${CONTROLLER}    ${CONTROLLER1}    ${CONTROLLER2}
 136     Remove Values From List    ${searchlist}    ${exclude_controller}
 137     Log    ${searchlist}
 138     [Return]    ${searchlist}
 139
 140 Get Leader And Verify
 141     [Arguments]    ${shard_name}    ${old_leader}=${EMPTY}
 142     [Documentation]    Returns the IP addr or hostname of the leader of the specified shard.
 143     ...    Controllers are specifed in the pybot command line.
 144     ${searchlist}    Get Controller List    ${old_leader}
 145     ${leader}    GetLeader    ${shard_name}    ${3}    ${3}    ${1}    ${RESTCONFPORT}
 146     ...    @{searchlist}
 147     Should Not Be Equal As Strings    ${leader}    None
 148     Run Keyword If    '${old_leader}'!='${EMPTY}'    Should Not Be Equal    ${old_leader}    ${leader}
 149     [Return]    ${leader}
 150
 151 Expect No Leader
 152     [Arguments]    ${shard_name}
 153     [Documentation]    No leader is elected in the car shard
 154     ${leader}    GetLeader    ${shard_name}    ${3}    ${1}    ${1}    ${RESTCONFPORT}
 155     ...    ${CURRENT_CAR_LEADER}
 156     Should Be Equal As Strings    ${leader}    None
 157
 158 Get All Followers
 159     [Arguments]    ${shard_name}    ${exclude_controller}=${EMPTY}
 160     [Documentation]    Returns the IP addresses or hostnames of all followers of the specified shard.
 161     ${searchlist}    Get Controller List    ${exclude_controller}
 162     ${followers}    GetFollowers    ${shard_name}    ${3}    ${3}    ${1}    ${RESTCONFPORT}
 163     ...    @{searchlist}
 164     Log    ${followers}
 165     Should Not Be Empty    ${followers}
 166     [Return]    ${followers}
 167
 168 Stop One Or More Controllers
 169     [Arguments]    @{controllers}
 170     [Documentation]    Give this keyword a scalar or list of controllers to be stopped.
 171     ${cmd} =    Set Variable    ${KARAF_HOME}/bin/stop
 172     : FOR    ${ip}    IN    @{controllers}
 173     \    Run Command On Remote System    ${ip}    ${cmd}
 174
 175 Kill One Or More Controllers
 176     [Arguments]    @{controllers}
 177     [Documentation]    Give this keyword a scalar or list of controllers to be stopped.
 178     ${cmd} =    Set Variable    ps axf | grep karaf | grep -v grep | awk '{print \"kill -9 \" $1}' | sh
 179     log    ${cmd}
 180     : FOR    ${ip}    IN    @{controllers}
 181     \    Run Command On Remote System    ${ip}    ${cmd}
 182
 183 Wait For Cluster Down
 184     [Arguments]    ${timeout}    @{controllers}
 185     [Documentation]    Waits for one or more clustered controllers to be down.
 186     : FOR    ${ip}    IN    @{controllers}
 187     \    ${status}=    Run Keyword And Return Status    Wait For Controller Down    ${timeout}    ${ip}
 188     \    Exit For Loop If    '${status}' == 'FAIL'
 189
 190 Wait For Controller Down
 191     [Arguments]    ${timeout}    ${ip}
 192     [Documentation]    Waits for one controllers to be down.
 193     Wait Until Keyword Succeeds    ${timeout}    2s    Controller Down Check    ${ip}
 194
 195 Controller Down Check
 196     [Arguments]    ${ip}
 197     [Documentation]    Checks to see if a controller is down by verifying that the karaf process isn't present.
 198     ${cmd} =    Set Variable    ps axf | grep karaf | grep -v grep | wc -l
 199     ${response}    Run Command On COntroller    ${ip}    ${cmd}
 200     Log    Number of controller instances running: ${response}
 201     Should Start With    ${response}    0    Controller process found or there may be extra instances of karaf running on the host machine.
 202
 203 Start One Or More Controllers
 204     [Arguments]    @{controllers}
 205     [Documentation]    Give this keyword a scalar or list of controllers to be started.
 206     ${cmd} =    Set Variable    ${KARAF_HOME}/bin/start
 207     : FOR    ${ip}    IN    @{controllers}
 208     \    Run Command On Remote System    ${ip}    ${cmd}
 209
 210 Wait For Cluster Sync
 211     [Arguments]    ${timeout}    @{controllers}
 212     [Documentation]    Waits for one or more clustered controllers to report Sync Status as true.
 213     : FOR    ${ip}    IN    @{controllers}
 214     \    ${status}=    Run Keyword And Return Status    Wait For Controller Sync    ${timeout}    ${ip}
 215     \    Exit For Loop If    '${status}' == 'FAIL'
 216
 217 Wait For Controller Sync
 218     [Arguments]    ${timeout}    ${ip}
 219     [Documentation]    Waits for one controllers to report Sync Status as true.
 220     Wait Until Keyword Succeeds    ${timeout}    2s    Controller Sync Status Should Be True    ${ip}
 221
 222 Controller Sync Status Should Be True
 223     [Arguments]    ${ip}
 224     [Documentation]    Checks if Sync Status is true.
 225     ${SyncStatus}=    Get Controller Sync Status    ${ip}
 226     Should Be Equal    ${SyncStatus}    ${TRUE}
 227
 228 Controller Sync Status Should Be False
 229     [Arguments]    ${ip}
 230     [Documentation]    Checks if Sync Status is false.
 231     ${SyncStatus}=    Get Controller Sync Status    ${ip}
 232     Should Be Equal    ${SyncStatus}    ${FALSE}
 233
 234 Get Controller Sync Status
 235     [Arguments]    ${controller_ip}
 236     [Documentation]    Return Sync Status.
 237     Create_Session    session    http://${controller_ip}:${RESTCONFPORT}    headers=${HEADERS}    auth=${AUTH}
 238     ${data}=    Get Data From URI    session    ${jolokia_conf}
 239     Log    ${data}
 240     ${json}=    To Json    ${data}
 241     ${value}=    Get From Dictionary    ${json}    value
 242     ${ConfSyncStatus}=    Get From Dictionary    ${value}    SyncStatus
 243     Log    Configuration Sync Status: ${ConfSyncStatus}
 244     ${data}=    Get Data From URI    session    ${jolokia_oper}
 245     Log    ${data}
 246     ${json}=    To Json    ${data}
 247     ${value}=    Get From Dictionary    ${json}    value
 248     ${OperSyncStatus}=    Get From Dictionary    ${value}    SyncStatus
 249     Log    Operational Sync Status: ${OperSyncStatus}
 250     Run Keyword If    ${OperSyncStatus} and ${ConfSyncStatus}    Set Test Variable    ${SyncStatus}    ${TRUE}
 251     ...    ELSE    Set Test Variable    ${SyncStatus}    ${FALSE}
 252     [Return]    ${SyncStatus}
 253
 254 Clean One Or More Journals
 255     [Arguments]    @{controllers}
 256     [Documentation]    Give this keyword a scalar or list of controllers on which to clean journals.
 257     ${del_cmd} =    Set Variable    rm -rf ${KARAF_HOME}/journal
 258     : FOR    ${ip}    IN    @{controllers}
 259     \    Run Command On Remote System    ${ip}    ${del_cmd}
 260
 261 Clean One Or More Snapshots
 262     [Arguments]    @{controllers}
 263     [Documentation]    Give this keyword a scalar or list of controllers on which to clean snapshots.
 264     ${del_cmd} =    Set Variable    rm -rf ${KARAF_HOME}/snapshots
 265     : FOR    ${ip}    IN    @{controllers}
 266     \    Run Command On Remote System    ${ip}    ${del_cmd}
 267
 268 Show Cluster Configuation Files
 269     [Arguments]    @{controllers}
 270     [Documentation]    Prints out the cluster configuration files for one or more controllers.
 271     Log    controllers: @{controllers}
 272     ${cmd} =    Set Variable    cat ${KARAF_HOME}/configuration/initial/akka.conf
 273     : FOR    ${ip}    IN    @{controllers}
 274     \    Run Command On Remote System    ${ip}    ${cmd}
 275     ${cmd} =    Set Variable    cat ${KARAF_HOME}/configuration/initial/modules.conf
 276     : FOR    ${ip}    IN    @{controllers}
 277     \    Run Command On Remote System    ${ip}    ${cmd}
 278     ${cmd} =    Set Variable    cat ${KARAF_HOME}/configuration/initial/module-shards.conf
 279     : FOR    ${ip}    IN    @{controllers}
 280     \    Run Command On Remote System    ${ip}    ${cmd}
 281     ${cmd} =    Set Variable    cat ${KARAF_HOME}/configuration/initial/jolokia.xml
 282     : FOR    ${ip}    IN    @{controllers}
 283     \    Run Command On Remote System    ${ip}    ${cmd}
 284     ${cmd} =    Set Variable    cat ${KARAF_HOME}/etc/initial/org.apache.karaf.management.cfg
 285     : FOR    ${ip}    IN    @{controllers}
 286     \    Run Command On Remote System    ${ip}    ${cmd}
 287     ${cmd} =    Set Variable    cat ${KARAF_HOME}/etc/org.apache.karaf.features.cfg
 288     : FOR    ${ip}    IN    @{controllers}
 289     \    Run Command On Remote System    ${ip}    ${cmd}
 290
 291 Isolate a Controller From Cluster
 292     [Arguments]    ${isolated controller}    @{controllers}
 293     [Documentation]    Use IPTables to isolate one controller from the cluster.
 294     ...    On the isolated controller it blocks IP traffic to and from each of the other controllers.
 295     : FOR    ${controller}    IN    @{controllers}
 296     \    ${other controller}=    Evaluate    "${isolated controller}" != "${controller}"
 297     \    Run Keyword If    ${other controller}    Isolate One Controller From Another    ${isolated controller}    ${controller}
 298
 299 Rejoin a Controller To Cluster
 300     [Arguments]    ${isolated controller}    @{controllers}
 301     [Documentation]    Use IPTables to rejoin one controller to the cluster.
 302     ...    On the isolated controller it unblocks IP traffic to and from each of the other controllers.
 303     : FOR    ${controller}    IN    @{controllers}
 304     \    ${other controller}=    Evaluate    "${isolated controller}" != "${controller}"
 305     \    Run Keyword If    ${other controller}    Rejoin One Controller To Another    ${isolated controller}    ${controller}
 306
 307 Isolate One Controller From Another
 308     [Arguments]    ${isolated controller}    ${controller}
 309     [Documentation]    Inserts an IPTable rule to disconnect one controller from another controller in the cluster.
 310     Modify IPTables    ${isolated controller}    ${controller}    -I
 311
 312 Rejoin One Controller To Another
 313     [Arguments]    ${isolated controller}    ${controller}
 314     [Documentation]    Deletes an IPTable rule, allowing one controller to reconnect to another controller in the cluster.
 315     Modify IPTables    ${isolated controller}    ${controller}    -D
 316
 317 Modify IPTables
 318     [Arguments]    ${isolated controller}    ${controller}    ${rule type}
 319     [Documentation]    Adds a rule, usually inserting or deleting an entry between two controllers.
 320     ${base string}    Set Variable    sudo iptables ${rule type} OUTPUT -p all --source
 321     ${cmd string}    Catenate    ${base string}    ${isolated controller} --destination ${controller} -j DROP
 322     Run Command On Remote System    ${isolated controller}    ${cmd string}
 323     ${cmd string}    Catenate    ${base string}    ${controller} --destination ${isolated controller} -j DROP
 324     Run Command On Remote System    ${isolated controller}    ${cmd string}
 325     ${cmd string}    Set Variable    sudo iptables -L -n
 326     ${return string}=    Run Command On Remote System    ${isolated controller}    ${cmd string}
 327     #If inserting rules:
 328     Run Keyword If    "${rule type}" == '-I'    Should Match Regexp    ${return string}    [\s\S]*DROP *all *-- *${isolated controller} *${controller}[\s\S]*
 329     Run Keyword If    "${rule type}" == '-I'    Should Match Regexp    ${return string}    [\s\S]*DROP *all *-- *${controller} *${isolated controller}[\s\S]*
 330     #If deleting rules:
 331     Run Keyword If    "${rule type}" == '-D'    Should Match Regexp    ${return string}    (?![\s\S]*DROP *all *-- *${isolated controller} *${controller}[\s\S]*)
 332     Run Keyword If    "${rule type}" == '-D'    Should Match Regexp    ${return string}    (?![\s\S]*DROP *all *-- *${controller} *${isolated controller}[\s\S]*)
 333
 334 Rejoin All Isolated Controllers
 335     [Arguments]    @{controllers}
 336     [Documentation]    Wipe all IPTables rules from all controllers, thus rejoining all controllers.
 337     : FOR    ${isolated controller}    IN    @{controllers}
 338     \    Flush IPTables    ${isolated controller}
 339
 340 Flush IPTables
 341     [Arguments]    ${isolated controller}
 342     [Documentation]    This keyword is generally not called from a test case but supports a complete wipe of all rules on
 343     ...    all contollers.
 344     ${cmd string}    Set Variable    sudo iptables -v -F
 345     ${return string}=    Run Command On Remote System    ${isolated controller}    ${cmd string}
 346     Log    return: ${return string}
 347     Should Contain    ${return string}    Flushing chain `INPUT'
 348     Should Contain    ${return string}    Flushing chain `FORWARD'
 349     Should Contain    ${return string}    Flushing chain `OUTPUT'