csit/libraries/ClusterManagement.robot

   1 *** Settings ***
   2 Documentation     Resource housing Keywords common to several suites for cluster functional testing.
   3 ...
   4 ...               Copyright (c) 2016 Cisco Systems, Inc. and others. All rights reserved.
   5 ...               Copyright (c) 2016 Brocade Communications Systems, Inc. and others. All rights reserved.
   6 ...
   7 ...               This program and the accompanying materials are made available under the
   8 ...               terms of the Eclipse Public License v1.0 which accompanies this distribution,
   9 ...               and is available at http://www.eclipse.org/legal/epl-v10.html
  10 ...
  11 ...
  12 ...               This resource holds private state (in suite variables),
  13 ...               which is generated once at Setup with ClusterManagement_Setup KW.
  14 ...               The state includes member indexes, IP addresses and Http (RequestsLibrary) sessions.
  15 ...               Cluster Keywords normally use member index, member list or nothing (all members) as argument.
  16 ...
  17 ...               All index lists returned should be sorted numerically, fix if not.
  18 ...
  19 ...               Requirements:
  20 ...               odl-jolokia is assumed to be installed.
  21 ...
  22 ...               Keywords are ordered as follows:
  23 ...               - Cluster Setup
  24 ...               - Shard state, leader and followers
  25 ...               - Entity Owner, candidates and successors
  26 ...               - Kill, Stop and Start Member
  27 ...               - Isolate and Rejoin Member
  28 ...               - Run Commands On Member
  29 ...               - REST requests and checks on Members
  30 ...
  31 ...               TODO: Unify capitalization of Leaders and Followers.
  32 Library           RequestsLibrary    # for Create_Session and To_Json
  33 Library           Collections
  34 Library           String
  35 Library           ClusterEntities.py
  36 Resource          ${CURDIR}/CompareStream.robot
  37 Resource          ${CURDIR}/KarafKeywords.robot
  38 Resource          ${CURDIR}/SSHKeywords.robot
  39 Resource          ${CURDIR}/TemplatedRequests.robot    # for Get_As_Json_From_Uri
  40 Resource          ${CURDIR}/Utils.robot    # for Run_Command_On_Controller
  41 Resource          ../variables/Variables.robot
  42
  43 *** Variables ***
  44 ${ENTITY_OWNER_URI}    restconf/operational/entity-owners:entity-owners
  45 ${RESTCONF_URI}    rests
  46 ${GC_LOG_PATH}    ${KARAF_HOME}/data/log
  47 ${JAVA_HOME}      ${EMPTY}    # releng/builder scripts should provide correct value
  48 ${JOLOKIA_CONF_SHARD_MANAGER_URI}    jolokia/read/org.opendaylight.controller:Category=ShardManager,name=shard-manager-config,type=DistributedConfigDatastore
  49 ${JOLOKIA_OPER_SHARD_MANAGER_URI}    jolokia/read/org.opendaylight.controller:Category=ShardManager,name=shard-manager-operational,type=DistributedOperationalDatastore
  50 ${JOLOKIA_CONFIG_LOCAL_SHARDS_URI}    jolokia/read/org.opendaylight.controller:type=DistributedConfigDatastore,Category=ShardManager,name=shard-manager-config/LocalShards
  51 ${JOLOKIA_OPER_LOCAL_SHARDS_URI}    jolokia/read/org.opendaylight.controller:type=DistributedOperationalDatastore,Category=ShardManager,name=shard-manager-operational/LocalShards
  52 ${JOLOKIA_READ_URI}    jolokia/read/org.opendaylight.controller
  53 # Bug 9044 workaround: delete etc/host.key before restart.
  54 @{ODL_DEFAULT_DATA_PATHS}    tmp/    data/    cache/    snapshots/    journal/    segmented-journal/    etc/opendaylight/current/    etc/host.key
  55 ${RESTCONF_MODULES_DIR}    ${CURDIR}/../variables/restconf/modules
  56 ${SINGLETON_NETCONF_DEVICE_ID_PREFIX}    KeyedInstanceIdentifier{targetType=interface org.opendaylight.yang.gen.v1.urn.tbd.params.xml.ns.yang.network.topology.rev131021.network.topology.topology.Node, path=[org.opendaylight.yang.gen.v1.urn.tbd.params.xml.ns.yang.network.topology.rev131021.NetworkTopology, org.opendaylight.yang.gen.v1.urn.tbd.params.xml.ns.yang.network.topology.rev131021.network.topology.Topology[key=TopologyKey{_topologyId=Uri{_value=topology-netconf}}], org.opendaylight.yang.gen.v1.urn.tbd.params.xml.ns.yang.network.topology.rev131021.network.topology.topology.Node[key=NodeKey{_nodeId=Uri{_value=
  57 ${SINGLETON_NETCONF_DEVICE_ID_SUFFIX}    }}]]}
  58 ${SINGLETON_BGPCEP_DEVICE_ID_SUFFIX}    -service-group
  59 &{SINGLETON_DEVICE_ID_PREFIX}    bgpcep=${EMPTY}    netconf=${SINGLETON_NETCONF_DEVICE_ID_PREFIX}    openflow=${EMPTY}    sxp=${EMPTY}
  60 &{SINGLETON_DEVICE_ID_SUFFIX}    bgpcep=${SINGLETON_BGPCEP_DEVICE_ID_SUFFIX}    netconf=${SINGLETON_NETCONF_DEVICE_ID_SUFFIX}    openflow=${EMPTY}    sxp=${EMPTY}
  61 ${SINGLETON_ELECTION_ENTITY_TYPE}    org.opendaylight.mdsal.ServiceEntityType
  62 ${SINGLETON_CHANGE_OWNERSHIP_ENTITY_TYPE}    org.opendaylight.mdsal.AsyncServiceCloseEntityType
  63 ${NODE_ROLE_INDEX_START}    1
  64 ${NODE_START_COMMAND}    ${KARAF_HOME}/bin/start
  65 ${NODE_STOP_COMMAND}    ${KARAF_HOME}/bin/stop
  66 ${NODE_KARAF_COUNT_COMMAND}    ps axf | grep org.apache.karaf | grep -v grep | wc -l
  67 ${NODE_KILL_COMMAND}    ps axf | grep org.apache.karaf | grep -v grep | awk '{print \"kill -9 \" $1}' | sh
  68 ${NODE_FREEZE_COMMAND}    ps axf | grep org.apache.karaf | grep -v grep | awk '{print \"kill -STOP \" $1}' | sh
  69 ${NODE_UNFREEZE_COMMAND}    ps axf | grep org.apache.karaf | grep -v grep | awk '{print \"kill -CONT \" $1}' | sh
  70
  71 *** Keywords ***
  72 ClusterManagement_Setup
  73     [Arguments]    ${http_timeout}=${DEFAULT_TIMEOUT_HTTP}    ${http_retries}=0
  74     [Documentation]    Detect repeated call, or detect number of members and initialize derived suite variables.
  75     ...    Http sessions are created with parameters to not waste time when ODL is no accepting connections properly.
  76     # Avoid multiple initialization by several downstream libraries.
  77     ${already_done} =    BuiltIn.Get_Variable_Value    \${ClusterManagement__has_setup_run}    False
  78     BuiltIn.Return_From_Keyword_If    ${already_done}
  79     BuiltIn.Set_Suite_Variable    \${ClusterManagement__has_setup_run}    True
  80     ${cluster_size} =    BuiltIn.Get_Variable_Value    \${NUM_ODL_SYSTEM}    1
  81     ${status}    ${possibly_int_of_members} =    BuiltIn.Run_Keyword_And_Ignore_Error    BuiltIn.Convert_To_Integer    ${cluster_size}
  82     ${int_of_members} =    BuiltIn.Set_Variable_If    '${status}' != 'PASS'    ${1}    ${possibly_int_of_members}
  83     ClusterManagement__Compute_Derived_Variables    int_of_members=${int_of_members}    http_timeout=${http_timeout}    http_retries=${http_retries}
  84
  85 Check_Cluster_Is_In_Sync
  86     [Arguments]    ${member_index_list}=${EMPTY}
  87     [Documentation]    Fail if no-sync is detected on a member from list (or any).
  88     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
  89     FOR    ${index}    IN    @{index_list}    # usually: 1, 2, 3.
  90         ${status} =    Get_Sync_Status_Of_Member    member_index=${index}
  91         BuiltIn.Continue_For_Loop_If    'True' == '${status}'
  92         BuiltIn.Fail    Index ${index} has incorrect status: ${status}
  93     END
  94
  95 Get_Sync_Status_Of_Member
  96     [Arguments]    ${member_index}
  97     [Documentation]    Obtain IP, two GETs from jolokia URIs, return combined sync status as string.
  98     ${session} =    Resolve_Http_Session_For_Member    member_index=${member_index}
  99     ${conf_text} =    TemplatedRequests.Get_As_Json_From_Uri    uri=${JOLOKIA_CONF_SHARD_MANAGER_URI}    session=${session}
 100     ${conf_status} =    ClusterManagement__Parse_Sync_Status    shard_manager_text=${conf_text}
 101     BuiltIn.Return_From_Keyword_If    'False' == ${conf_status}    False
 102     ${oper_text} =    TemplatedRequests.Get_As_Json_From_Uri    uri=${JOLOKIA_OPER_SHARD_MANAGER_URI}    session=${session}
 103     ${oper_status} =    ClusterManagement__Parse_Sync_Status    shard_manager_text=${oper_text}
 104     [Return]    ${oper_status}
 105
 106 Verify_Leader_Exists_For_Each_Shard
 107     [Arguments]    ${shard_name_list}    ${shard_type}=operational    ${member_index_list}=${EMPTY}    ${verify_restconf}=True
 108     [Documentation]    For each shard name, call Get_Leader_And_Followers_For_Shard.
 109     ...    Not much logic there, but single Keyword is useful when using BuiltIn.Wait_Until_Keyword_Succeeds.
 110     FOR    ${shard_name}    IN    @{shard_name_list}
 111         Get_Leader_And_Followers_For_Shard    shard_name=${shard_name}    shard_type=${shard_type}    validate=True    member_index_list=${member_index_list}    verify_restconf=${verify_restconf}
 112     END
 113
 114 Get_Leader_And_Followers_For_Shard
 115     [Arguments]    ${shard_name}=default    ${shard_type}=operational    ${validate}=True    ${member_index_list}=${EMPTY}    ${verify_restconf}=True    ${http_timeout}=${EMPTY}
 116     [Documentation]    Get role lists, validate there is one leader, return the leader and list of followers.
 117     ...    Optionally, issue GET to a simple restconf URL to make sure subsequent operations will not encounter 503.
 118     ${leader_list}    ${follower_list} =    Get_State_Info_For_Shard    shard_name=${shard_name}    shard_type=${shard_type}    validate=True    member_index_list=${member_index_list}
 119     ...    verify_restconf=${verify_restconf}    http_timeout=${http_timeout}
 120     ${leader_count} =    BuiltIn.Get_Length    ${leader_list}
 121     BuiltIn.Run_Keyword_If    ${leader_count} < 1    BuiltIn.Fail    No leader found.
 122     BuiltIn.Length_Should_Be    ${leader_list}    ${1}    Too many Leaders.
 123     ${leader} =    Collections.Get_From_List    ${leader_list}    0
 124     [Return]    ${leader}    ${follower_list}
 125
 126 Get_State_Info_For_Shard
 127     [Arguments]    ${shard_name}=default    ${shard_type}=operational    ${validate}=False    ${member_index_list}=${EMPTY}    ${verify_restconf}=False    ${http_timeout}=${EMPTY}
 128     [Documentation]    Return lists of Leader and Follower member indices from a given member index list
 129     ...    (or from the full list if empty). If \${shard_type} is not 'config', 'operational' is assumed.
 130     ...    If \${validate}, Fail if raft state is not Leader or Follower (for example on Candidate).
 131     ...    The biggest difference from Get_Leader_And_Followers_For_Shard
 132     ...    is that no check on number of Leaders is performed.
 133     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 134     Collections.Sort_List    ${index_list}    # to guarantee return values are also sorted lists
 135     # TODO: Support alternative capitalization of 'config'?
 136     ${ds_type} =    BuiltIn.Set_Variable_If    '${shard_type}' != 'config'    operational    config
 137     ${leader_list} =    BuiltIn.Create_List
 138     ${follower_list} =    BuiltIn.Create_List
 139     FOR    ${index}    IN    @{index_list}    # usually: 1, 2, 3.
 140         ${raft_state} =    Get_Raft_State_Of_Shard_At_Member    shard_name=${shard_name}    shard_type=${ds_type}    member_index=${index}    verify_restconf=${verify_restconf}
 141         ...    http_timeout=${http_timeout}
 142         BuiltIn.Run_Keyword_If    'Follower' == '${raft_state}'    Collections.Append_To_List    ${follower_list}    ${index}
 143         ...    ELSE IF    'Leader' == '${raft_state}'    Collections.Append_To_List    ${leader_list}    ${index}
 144         ...    ELSE IF    ${validate}    BuiltIn.Fail    Unrecognized Raft state: ${raft_state}
 145     END
 146     [Return]    ${leader_list}    ${follower_list}
 147
 148 Get_Raft_State_Of_Shard_At_Member
 149     [Arguments]    ${shard_name}    ${shard_type}    ${member_index}    ${verify_restconf}=False    ${http_timeout}=${EMPTY}
 150     [Documentation]    Send request to Jolokia on indexed member, return extracted Raft status.
 151     ...    Optionally, check restconf works.
 152     ${raft_state} =    Get_Raft_Property_From_Shard_Member    RaftState    ${shard_name}    ${shard_type}    ${member_index}    verify_restconf=${verify_restconf}
 153     ...    http_timeout=${http_timeout}
 154     [Return]    ${raft_state}
 155
 156 Get_Raft_State_Of_Shard_Of_All_Member_Nodes
 157     [Arguments]    ${shard_name}=default    ${shard_type}=config    ${member_index_list}=${EMPTY}
 158     [Documentation]    Get raft state of shard of all member nodes
 159     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 160     Collections.Sort_List    ${index_list}
 161     FOR    ${index}    IN    @{index_list}
 162         ClusterManagement.Get Raft State Of Shard At Member    shard_name=${shard_name}    shard_type=${shard_type}    member_index=${index}
 163     END
 164
 165 Get_Raft_Property_From_Shard_Member
 166     [Arguments]    ${property}    ${shard_name}    ${shard_type}    ${member_index}    ${verify_restconf}=False    ${http_timeout}=${EMPTY}
 167     [Documentation]    Send request to Jolokia on indexed member, return extracted Raft property.
 168     ...    Optionally, check restconf works.
 169     ${session} =    Resolve_Http_Session_For_Member    member_index=${member_index}
 170     # TODO: Does the used URI tend to generate large data which floods log.html?
 171     BuiltIn.Run_Keyword_If    ${verify_restconf}    TemplatedRequests.Get_As_Json_Templated    session=${session}    folder=${RESTCONF_MODULES_DIR}    verify=False    http_timeout=${http_timeout}
 172     ${type_class} =    Resolve_Shard_Type_Class    shard_type=${shard_type}
 173     ${cluster_index} =    Evaluate    ${member_index}+${NODE_ROLE_INDEX_START}-1
 174     ${uri} =    BuiltIn.Set_Variable    ${JOLOKIA_READ_URI}:Category=Shards,name=member-${cluster_index}-shard-${shard_name}-${shard_type},type=${type_class}
 175     ${data_text} =    TemplatedRequests.Get_As_Json_From_Uri    uri=${uri}    session=${session}    http_timeout=${http_timeout}
 176     ${data_object} =    RequestsLibrary.To_Json    ${data_text}
 177     ${value} =    Collections.Get_From_Dictionary    ${data_object}    value
 178     ${raft_property} =    Collections.Get_From_Dictionary    ${value}    ${property}
 179     [Return]    ${raft_property}
 180
 181 Verify_Shard_Leader_Elected
 182     [Arguments]    ${shard_name}    ${shard_type}    ${new_elected}    ${old_leader}    ${member_index_list}=${EMPTY}    ${verify_restconf}=True
 183     [Documentation]    Verify new leader was elected or remained the same. Bool paramter ${new_elected} indicates if
 184     ...    new leader is elected or should remained the same as ${old_leader}
 185     ${leader}    ${followers}=    Get_Leader_And_Followers_For_Shard    shard_name=${shard_name}    shard_type=${shard_type}    member_index_list=${member_index_list}    verify_restconf=${verify_restconf}
 186     BuiltIn.Run_Keyword_If    ${new_elected}    BuiltIn.Should_Not_Be_Equal_As_Numbers    ${old_leader}    ${leader}
 187     BuiltIn.Run_Keyword_Unless    ${new_elected}    BuiltIn.Should_Be_Equal_As_numbers    ${old_leader}    ${leader}
 188     BuiltIn.Return_From_Keyword    ${leader}    ${followers}
 189
 190 Verify_Owner_And_Successors_For_Device
 191     [Arguments]    ${device_name}    ${device_type}    ${member_index}    ${candidate_list}=${EMPTY}    ${after_stop}=False
 192     [Documentation]    Returns the owner and successors for the SB device ${device_name} of type ${device_type}. Request is sent to member ${member_index}.
 193     ...    For Boron and beyond, candidates are not removed on node down or isolation,
 194     ...    so this keyword expects candidates to be all members from Boron on.
 195     ...    Extra check is done to verify owner and successors are within the ${candidate_list}. This KW is useful when combined with WUKS.
 196     ...    ${candidate_list} minus owner is returned as ${successor list}.
 197     ...    Users can still use Get_Owner_And_Successors_For_Device if they are interested in downed candidates,
 198     ...    or for testing heterogeneous clusters.
 199     ${index_list} =    List_Indices_Or_All    given_list=${candidate_list}
 200     ${owner}    ${successor_list} =    Get_Owner_And_Successors_For_Device    device_name=${device_name}    device_type=${device_type}    member_index=${member_index}
 201     Collections.List_Should_Contain_Value    ${index_list}    ${owner}    Owner ${owner} is not in candidate list ${index_list}
 202     # In Beryllium or after stopping an instance, the removed instance does not show in the candidate list.
 203     ${expected_candidate_list_origin} =    BuiltIn.Set_Variable_If    ${after_stop}    ${index_list}    ${ClusterManagement__member_index_list}
 204     # We do not want to manipulate either origin list.
 205     ${expected_successor_list} =    BuiltIn.Create_List    @{expected_candidate_list_origin}
 206     Collections.Remove_Values_From_List    ${expected_successor_list}    ${owner}
 207     Collections.Lists_Should_Be_Equal    ${expected_successor_list}    ${successor_list}    Successor list ${successor_list} is not the came as expected ${expected_successor_list}
 208     # User expects the returned successor list to be the provided candidate list minus the owner.
 209     Collections.Remove_Values_From_List    ${index_list}    ${owner}
 210     [Return]    ${owner}    ${index_list}
 211
 212 Get_Owner_And_Successors_For_Device
 213     [Arguments]    ${device_name}    ${device_type}    ${member_index}    ${http_timeout}=${EMPTY}
 214     [Documentation]    Returns the owner and a list of successors for the SB device ${device_name} of type ${device_type}. Request is sent to member ${member_index}.
 215     ...    Successors are those device candidates not elected as owner. The list of successors = (list of candidates) - (owner).
 216     ...    The returned successor list is sorted numerically.
 217     ...    Note that "candidate list" definition currently differs between Beryllium and Boron.
 218     ...    Use Verify_Owner_And_Successors_For_Device if you want the older semantics (inaccessible nodes not present in the list).
 219     # TODO: somewhere to introduce ${DEFAULT_RESTCONF_DATASTORE_TIMEOUT}. Value may depend on protocol (ask vs tell) and perhaps stream.
 220     ${owner}    ${candidate_list} =    Get_Owner_And_Candidates_For_Device    device_name=${device_name}    device_type=${device_type}    member_index=${member_index}    http_timeout=${http_timeout}
 221     ${successor_list} =    BuiltIn.Create_List    @{candidate_list}    # Copy operation is not required, but new variable name requires a line anyway.
 222     Collections.Remove_Values_From_List    ${successor_list}    ${owner}
 223     [Return]    ${owner}    ${successor_list}
 224
 225 Get_Owner_And_Candidates_For_Device_Rpc
 226     [Arguments]    ${device_name}    ${device_type}    ${member_index}    ${http_timeout}=${EMPTY}
 227     [Documentation]    Returns the owner and a list of candidates for the SB device ${device_name} of type ${device_type}. Request is sent to member ${member_index}.
 228     ...    Candidates are all members that register to own a device, so the list of candiates includes the owner.
 229     ...    The returned candidate list is sorted numerically.
 230     ...    Note that "candidate list" definition currently differs between Beryllium and Boron.
 231     ...    It is recommended to use Get_Owner_And_Successors_For_Device instead of this keyword, see documentation there.
 232     BuiltIn.Comment    TODO: Can this implementation be changed to call Get_Owner_And_Candidates_For_Type_And_Id?
 233     ${index} =    BuiltIn.Convert_To_Integer    ${member_index}
 234     ${ip} =    Resolve_IP_Address_For_Member    member_index=${index}
 235     ${entity_type} =    BuiltIn.Set_Variable_If    '${device_type}' == 'netconf'    netconf-node/${device_name}    ${device_type}
 236     ${url} =    BuiltIn.Catenate    SEPARATOR=    http://    ${ip}    :8181/    ${RESTCONF_URI}
 237     ${entity_result} =    ClusterEntities.get entity    ${url}    ${entity_type}    ${device_name}
 238     ${entity_candidates} =    Collections.Get_From_Dictionary    ${entity_result}    candidates
 239     ${entity_owner} =    Collections.Get_From_Dictionary    ${entity_result}    owner
 240     BuiltIn.Should_Not_Be_Empty    ${entity_owner}    No owner found for ${device_name}
 241     ${owner} =    String.Replace_String    ${entity_owner}    member-    ${EMPTY}
 242     ${owner} =    BuiltIn.Convert_To_Integer    ${owner}
 243     ${candidate_list} =    BuiltIn.Create_List
 244     FOR    ${entity_candidate}    IN    @{entity_candidates}
 245         ${candidate} =    String.Replace_String    ${entity_candidate}    member-    ${EMPTY}
 246         ${candidate} =    BuiltIn.Convert_To_Integer    ${candidate}
 247         Collections.Append_To_List    ${candidate_list}    ${candidate}
 248     END
 249     Collections.Sort_List    ${candidate_list}
 250     [Return]    ${owner}    ${candidate_list}
 251
 252 Get_Owner_And_Candidates_For_Device_Singleton
 253     [Arguments]    ${device_name}    ${device_type}    ${member_index}    ${http_timeout}=${EMPTY}
 254     [Documentation]    Returns the owner and a list of candidates for the SB device ${device_name} of type ${device_type}. Request is sent to member ${member_index}.
 255     # Normalize device type to the lowercase as in ${SINGLETON_DEVICE_ID_PREFIX} & ${SINGLETON_DEVICE_ID_SUFFIX}
 256     ${device_type} =    String.Convert To Lower Case    ${device_type}
 257     # Set device ID prefix
 258     Collections.Dictionary Should Contain Key    ${SINGLETON_DEVICE_ID_PREFIX}    ${device_type}
 259     ${device_id_prefix} =    Collections.Get From Dictionary    ${SINGLETON_DEVICE_ID_PREFIX}    ${device_type}
 260     Log    ${device_id_prefix}
 261     # Set device ID suffix
 262     Collections.Dictionary Should Contain Key    ${SINGLETON_DEVICE_ID_SUFFIX}    ${device_type}
 263     ${device_id_suffix} =    Collections.Get From Dictionary    ${SINGLETON_DEVICE_ID_SUFFIX}    ${device_type}
 264     Log    ${device_id_suffix}
 265     # Set device ID
 266     ${id} =    BuiltIn.Set_Variable    ${device_id_prefix}${device_name}${device_id_suffix}
 267     Log    ${id}
 268     # Get election entity type results
 269     ${type} =    BuiltIn.Set_Variable    ${SINGLETON_ELECTION_ENTITY_TYPE}
 270     ${owner_1}    ${candidate_list_1} =    Get_Owner_And_Candidates_For_Type_And_Id    ${type}    ${id}    ${member_index}    http_timeout=${http_timeout}
 271     # Get change ownership entity type results
 272     ${type} =    BuiltIn.Set_Variable    ${SINGLETON_CHANGE_OWNERSHIP_ENTITY_TYPE}
 273     ${owner_2}    ${candidate_list_2} =    Get_Owner_And_Candidates_For_Type_And_Id    ${type}    ${id}    ${member_index}    http_timeout=${http_timeout}
 274     # Owners must be same, if not, there is still some election or change ownership in progress
 275     BuiltIn.Should_Be_Equal_As_Integers    ${owner_1}    ${owner_2}    Owners for device ${device_name} are not same
 276     [Return]    ${owner_1}    ${candidate_list_1}
 277
 278 Get_Owner_And_Candidates_For_Device
 279     [Arguments]    ${device_name}    ${device_type}    ${member_index}    ${http_timeout}=${EMPTY}
 280     [Documentation]    Returns the owner and a list of candidates for the SB device ${device_name} of type ${device_type}. Request is sent to member ${member_index}.
 281     ...    If parsing as singleton failed, kw try to parse data in old way (without singleton).
 282     ...    Candidates are all members that register to own a device, so the list of candiates includes the owner.
 283     ...    The returned candidate list is sorted numerically.
 284     ...    Note that "candidate list" definition currently differs between Beryllium and Boron.
 285     ...    It is recommended to use Get_Owner_And_Successors_For_Device instead of this keyword, see documentation there.
 286     # Try singleton
 287     ${status}    ${results} =    BuiltIn.Run_Keyword_And_Ignore_Error    Get_Owner_And_Candidates_For_Device_Singleton    device_name=${device_name}    device_type=${device_type}    member_index=${member_index}
 288     ...    http_timeout=${http_timeout}
 289     BuiltIn.Return_From_Keyword_If    "${status}"=="PASS"    ${results}
 290     # If singleton failed, try parsing in old way
 291     ${status}    ${results} =    BuiltIn.Run_Keyword_And_Ignore_Error    Get_Owner_And_Candidates_For_Device_Rpc    device_name=${device_name}    device_type=${device_type}    member_index=${member_index}
 292     ...    http_timeout=${http_timeout}
 293     # previous 3 lines (BuilIn.Return.., # If singleton..., ${status}....) could be deleted when old way will not be supported anymore
 294     BuiltIn.Run_Keyword_If    '${status}'=='FAIL'    BuiltIn.Fail    Could not parse owner and candidates for device ${device_name}
 295     [Return]    @{results}
 296
 297 Check_Old_Owner_Stays_Elected_For_Device
 298     [Arguments]    ${device_name}    ${device_type}    ${old_owner}    ${node_to_ask}    ${http_timeout}=${EMPTY}
 299     [Documentation]    Verify the owner remain the same as ${old_owner}
 300     ${owner}    ${candidates} =    Get_Owner_And_Candidates_For_Device    ${device_name}    ${device_type}    ${node_to_ask}    http_timeout=${http_timeout}
 301     BuiltIn.Should_Be_Equal_As_numbers    ${old_owner}    ${owner}
 302     BuiltIn.Return_From_Keyword    ${owner}    ${candidates}
 303
 304 Check_New_Owner_Got_Elected_For_Device
 305     [Arguments]    ${device_name}    ${device_type}    ${old_owner}    ${node_to_ask}    ${http_timeout}=${EMPTY}
 306     [Documentation]    Verify new owner was elected comparing to ${old_owner}
 307     ${owner}    ${candidates} =    Get_Owner_And_Candidates_For_Device    ${device_name}    ${device_type}    ${node_to_ask}    http_timeout=${http_timeout}
 308     BuiltIn.Should_Not_Be_Equal_As_Numbers    ${old_owner}    ${owner}
 309     BuiltIn.Return_From_Keyword    ${owner}    ${candidates}
 310
 311 Get_Owner_And_Candidates_For_Type_And_Id
 312     [Arguments]    ${type}    ${id}    ${member_index}    ${require_candidate_list}=${EMPTY}    ${http_timeout}=${EMPTY}
 313     [Documentation]    Returns the owner and a list of candidates for entity specified by ${type} and ${id}
 314     ...    Request is sent to member ${member_index}.
 315     ...    Candidates are all members that register to own a device, so the list of candiates includes the owner.
 316     ...    Bear in mind that for Boron and beyond, candidates are not removed on node down or isolation.
 317     ...    If ${require_candidate_list} is not \${EMPTY}, check whether the actual list of candidates matches.
 318     ...    Note that differs from "given list" semantics used in other keywords,
 319     ...    namely you cannot use \${EMPTY} to stand for "full list" in this keyword.
 320     BuiltIn.Comment    TODO: Find a way to unify and deduplicate code blocks in Get_Owner_And_Candidates_* keywords.
 321     ${owner}    ${candidates} =    Get_Owner_And_Candidates_For_Device_Rpc    ${id}    ${type}    ${member_index}    http_timeout=${http_timeout}
 322     [Return]    ${owner}    ${candidates}
 323
 324 Extract_Service_Entity_Type
 325     [Arguments]    ${data}
 326     [Documentation]    Remove superfluous device data from Entity Owner printout.
 327     ${clear_data} =    String.Replace_String    ${data}    /odl-general-entity:entity[odl-general-entity:name='    ${EMPTY}
 328     ${clear_data} =    String.Replace_String    ${clear_data}    -service-group']    ${EMPTY}
 329     Log    ${clear_data}
 330     [Return]    ${clear_data}
 331
 332 Extract_OpenFlow_Device_Data
 333     [Arguments]    ${data}
 334     [Documentation]    Remove superfluous OpenFlow device data from Entity Owner printout.
 335     ${clear_data} =    String.Replace_String    ${data}    org.opendaylight.mdsal.ServiceEntityType    openflow
 336     ${clear_data} =    String.Replace_String    ${clear_data}    /odl-general-entity:entity[odl-general-entity:name='    ${EMPTY}
 337     ${clear_data} =    String.Replace_String    ${clear_data}    /general-entity:entity[general-entity:name='    ${EMPTY}
 338     ${clear_data} =    String.Replace_String    ${clear_data}    ']    ${EMPTY}
 339     Log    ${clear_data}
 340     [Return]    ${clear_data}
 341
 342 Extract_Ovsdb_Device_Data
 343     [Arguments]    ${data}
 344     [Documentation]    Remove superfluous OVSDB device data from Entity Owner printout.
 345     ${clear_data} =    String.Replace_String    ${data}    /network-topology:network-topology/network-topology:topology[network-topology:topology-id='ovsdb:1']/network-topology:node[network-topology:node-id='    ${EMPTY}
 346     ${clear_data} =    String.Replace_String    ${clear_data}    ']    ${EMPTY}
 347     Log    ${clear_data}
 348     [Return]    ${clear_data}
 349
 350 Kill_Single_Member
 351     [Arguments]    ${member}    ${original_index_list}=${EMPTY}    ${confirm}=True
 352     [Documentation]    Convenience keyword that kills the specified member of the cluster.
 353     ...    The KW will return a list of available members: \${updated index_list}=\${original_index_list}-\${member}
 354     ${index_list} =    ClusterManagement__Build_List    ${member}
 355     ${member_ip} =    Return_Member_IP    ${member}
 356     KarafKeywords.Log_Message_To_Controller_Karaf    Killing ODL${member} ${member_ip}
 357     ${updated_index_list} =    Kill_Members_From_List_Or_All    ${index_list}    ${original_index_list}    ${confirm}
 358     [Return]    ${updated_index_list}
 359
 360 Kill_Members_From_List_Or_All
 361     [Arguments]    ${member_index_list}=${EMPTY}    ${original_index_list}=${EMPTY}    ${confirm}=True
 362     [Documentation]    If the list is empty, kill all ODL instances. Otherwise, kill members based on \${kill_index_list}
 363     ...    If \${confirm} is True, sleep 1 second and verify killed instances are not there anymore.
 364     ...    The KW will return a list of available members: \${updated index_list}=\${original_index_list}-\${member_index_list}
 365     ${kill_index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 366     ${index_list} =    List_Indices_Or_All    given_list=${original_index_list}
 367     Run_Bash_Command_On_List_Or_All    command=${NODE_KILL_COMMAND}    member_index_list=${member_index_list}
 368     ${updated_index_list} =    BuiltIn.Create_List    @{index_list}
 369     Collections.Remove_Values_From_List    ${updated_index_list}    @{kill_index_list}
 370     BuiltIn.Return_From_Keyword_If    not ${confirm}    ${updated_index_list}
 371     # TODO: Convert to WUKS with configurable timeout if it turns out 1 second is not enough.
 372     BuiltIn.Sleep    1s    Kill -9 closes open files, which may take longer than ssh overhead, but not long enough to warrant WUKS.
 373     FOR    ${index}    IN    @{kill_index_list}
 374         Verify_Karaf_Is_Not_Running_On_Member    member_index=${index}
 375     END
 376     Run_Bash_Command_On_List_Or_All    command=netstat -pnatu | grep 2550
 377     [Return]    ${updated_index_list}
 378
 379 Stop_Single_Member
 380     [Arguments]    ${member}    ${original_index_list}=${EMPTY}    ${confirm}=True    ${msg}=${EMPTY}
 381     [Documentation]    Convenience keyword that stops the specified member of the cluster.
 382     ...    The KW will return a list of available members: \${updated index_list}=\${original_index_list}-\${member}
 383     ${index_list} =    ClusterManagement__Build_List    ${member}
 384     ${member_ip} =    Return_Member_IP    ${member}
 385     ${msg} =    Builtin.Set Variable If    "${msg}" == "${EMPTY}"    Stopping ODL${member} ${member_ip}    Stopping ODL${member} ${member_ip}, ${msg}
 386     KarafKeywords.Log_Message_To_Controller_Karaf    ${msg}
 387     ${updated_index_list} =    Stop_Members_From_List_Or_All    ${index_list}    ${original_index_list}    ${confirm}
 388     [Return]    ${updated_index_list}
 389
 390 Stop_Members_From_List_Or_All
 391     [Arguments]    ${member_index_list}=${EMPTY}    ${original_index_list}=${EMPTY}    ${confirm}=True    ${timeout}=360s
 392     [Documentation]    If the list is empty, stops all ODL instances. Otherwise stop members based on \${stop_index_list}
 393     ...    If \${confirm} is True, verify stopped instances are not there anymore.
 394     ...    The KW will return a list of available members: \${updated index_list}=\${original_index_list}-\${member_index_list}
 395     ${stop_index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 396     ${index_list} =    List_Indices_Or_All    given_list=${original_index_list}
 397     Run_Bash_Command_On_List_Or_All    command=${NODE_STOP_COMMAND}    member_index_list=${member_index_list}
 398     ${updated_index_list} =    BuiltIn.Create_List    @{index_list}
 399     Collections.Remove_Values_From_List    ${updated_index_list}    @{stop_index_list}
 400     BuiltIn.Return_From_Keyword_If    not ${confirm}    ${updated_index_list}
 401     FOR    ${index}    IN    @{stop_index_list}
 402         BuiltIn.Wait Until Keyword Succeeds    ${timeout}    2s    Verify_Karaf_Is_Not_Running_On_Member    member_index=${index}
 403     END
 404     Run_Bash_Command_On_List_Or_All    command=netstat -pnatu | grep 2550
 405     [Return]    ${updated_index_list}
 406
 407 Start_Single_Member
 408     [Arguments]    ${member}    ${wait_for_sync}=True    ${timeout}=300s    ${msg}=${EMPTY}    ${check_system_status}=False    ${verify_restconf}=True
 409     ...    ${service_list}=${EMPTY_LIST}
 410     [Documentation]    Convenience keyword that starts the specified member of the cluster.
 411     ${index_list} =    ClusterManagement__Build_List    ${member}
 412     ${member_ip} =    Return_Member_IP    ${member}
 413     ${msg} =    Builtin.Set Variable If    "${msg}" == "${EMPTY}"    Starting ODL${member} ${member_ip}    Starting ODL${member} ${member_ip}, ${msg}
 414     KarafKeywords.Log_Message_To_Controller_Karaf    ${msg}
 415     Start_Members_From_List_Or_All    ${index_list}    ${wait_for_sync}    ${timeout}    check_system_status=${check_system_status}    verify_restconf=${verify_restconf}    service_list=${service_list}
 416
 417 Start_Members_From_List_Or_All
 418     [Arguments]    ${member_index_list}=${EMPTY}    ${wait_for_sync}=True    ${timeout}=360s    ${karaf_home}=${EMPTY}    ${export_java_home}=${EMPTY}    ${gc_log_dir}=${EMPTY}
 419     ...    ${check_system_status}=False    ${verify_restconf}=True    ${service_list}=${EMPTY_LIST}
 420     [Documentation]    If the list is empty, start all cluster members. Otherwise, start members based on present indices.
 421     ...    If ${wait_for_sync}, wait for cluster sync on listed members.
 422     ...    Optionally karaf_home can be overriden. Optionally specific JAVA_HOME is used for starting.
 423     ...    Garbage collection is unconditionally logged to files. TODO: Make that reasonable conditional?
 424     ${base_command} =    BuiltIn.Set_Variable_If    """${karaf_home}""" != ""    ${karaf_home}/bin/start    ${NODE_START_COMMAND}
 425     ${command} =    BuiltIn.Set_Variable_If    """${export_java_home}""" != ""    export JAVA_HOME="${export_java_home}"; ${base_command}    ${base_command}
 426     ${epoch} =    DateTime.Get_Current_Date    time_zone=UTC    result_format=epoch    exclude_millis=False
 427     ${gc_filepath} =    BuiltIn.Set_Variable_If    """${karaf_home}""" != ""    ${karaf_home}/data/log/gc_${epoch}.log    ${GC_LOG_PATH}/gc_${epoch}.log
 428     ${gc_options} =    BuiltIn.Set_Variable_If    "docker" not in """${node_start_command}"""    -XX:+PrintGCDetails -XX:+PrintGCDateStamps -Xloggc:${gc_filepath}    ${EMPTY}
 429     Run_Bash_Command_On_List_Or_All    command=${command} ${gc_options}    member_index_list=${member_index_list}
 430     BuiltIn.Wait_Until_Keyword_Succeeds    ${timeout}    10s    Verify_Members_Are_Ready    ${member_index_list}    ${wait_for_sync}    ${verify_restconf}
 431     ...    ${check_system_status}    ${service_list}
 432     [Teardown]    Run_Bash_Command_On_List_Or_All    command=netstat -pnatu | grep 2550
 433
 434 Verify_Members_Are_Ready
 435     [Arguments]    ${member_index_list}    ${verify_cluster_sync}    ${verify_restconf}    ${verify_system_status}    ${service_list}
 436     [Documentation]    Verifies the specified readiness conditions for the given listed members after startup.
 437     ...    If ${verify_cluster_sync}, verifies the datastores have synced with the rest of the cluster.
 438     ...    If ${verify_restconf}, verifies RESTCONF is available.
 439     ...    If ${verify_system_status}, verifies the system services are OPERATIONAL.
 440     BuiltIn.Run_Keyword_If    ${verify_cluster_sync}    Check_Cluster_Is_In_Sync    ${member_index_list}
 441     BuiltIn.Run_Keyword_If    ${verify_restconf}    Verify_Restconf_Is_Available    ${member_index_list}
 442     # for backward compatibility, some consumers might not be passing @{service_list}, but since we can't set a list to a default
 443     # value, we need to check here if it's empty in order to skip the check which would throw an error
 444     BuiltIn.Run_Keyword_If    ${verify_system_status} and ("${service_list}" != "[[]]")    ClusterManagement.Check Status Of Services Is OPERATIONAL    @{service_list}
 445
 446 Verify_Restconf_Is_Available
 447     [Arguments]    ${member_index_list}
 448     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 449     FOR    ${index}    IN    @{index_list}
 450         ${session} =    Resolve_Http_Session_For_Member    member_index=${index}
 451         TemplatedRequests.Get_As_Json_Templated    session=${session}    folder=${RESTCONF_MODULES_DIR}    verify=False
 452     END
 453
 454 Freeze_Single_Member
 455     [Arguments]    ${member}
 456     [Documentation]    Convenience keyword that stops the specified member of the cluster by freezing the jvm.
 457     ${index_list} =    ClusterManagement__Build_List    ${member}
 458     Freeze_Or_Unfreeze_Members_From_List_Or_All    ${NODE_FREEZE_COMMAND}    ${index_list}
 459
 460 Unfreeze_Single_Member
 461     [Arguments]    ${member}    ${wait_for_sync}=True    ${timeout}=60s
 462     [Documentation]    Convenience keyword that "continues" the specified member of the cluster by unfreezing the jvm.
 463     ${index_list} =    ClusterManagement__Build_List    ${member}
 464     Freeze_Or_Unfreeze_Members_From_List_Or_All    ${NODE_UNFREEZE_COMMAND}    ${index_list}
 465     BuiltIn.Wait_Until_Keyword_Succeeds    ${timeout}    10s    Check_Cluster_Is_In_Sync
 466
 467 Freeze_Or_Unfreeze_Members_From_List_Or_All
 468     [Arguments]    ${command}    ${member_index_list}=${EMPTY}
 469     [Documentation]    If the list is empty, stops/runs all ODL instances. Otherwise stop/run members based on \${stop_index_list}
 470     ...    For command parameter only ${NODE_FREEZE_COMMAND} and ${NODE_UNFREEZE_COMMAND} should be used
 471     ${freeze_index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 472     Run_Bash_Command_On_List_Or_All    command=${command}    member_index_list=${member_index_list}
 473
 474 Clean_Journals_Data_And_Snapshots_On_List_Or_All
 475     [Arguments]    ${member_index_list}=${EMPTY}    ${karaf_home}=${KARAF_HOME}
 476     [Documentation]    Delete journal and snapshots directories on every node listed (or all).
 477     ...    BEWARE: If only a subset of members is cleaned, this causes RetiredGenerationException in Carbon after the affected node re-start.
 478     ...    See https://bugs.opendaylight.org/show_bug.cgi?id=8138
 479     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 480     ${command} =    Set Variable    rm -rf "${karaf_home}/"*journal "${karaf_home}/snapshots" "${karaf_home}/data"
 481     FOR    ${index}    IN    @{index_list}    # usually: 1, 2, 3.
 482         Run_Bash_Command_On_Member    command=${command}    member_index=${index}
 483     END
 484
 485 Verify_Karaf_Is_Not_Running_On_Member
 486     [Arguments]    ${member_index}
 487     [Documentation]    Fail if non-zero karaf instances are counted on member of given index.
 488     ${count} =    Count_Running_Karafs_On_Member    member_index=${member_index}
 489     BuiltIn.Should_Be_Equal    0    ${count}    Found running Karaf count: ${count}
 490
 491 Verify_Single_Karaf_Is_Running_On_Member
 492     [Arguments]    ${member_index}
 493     [Documentation]    Fail if number of karaf instances on member of given index is not one.
 494     ${count} =    Count_Running_Karafs_On_Member    member_index=${member_index}
 495     BuiltIn.Should_Be_Equal    1    ${count}    Wrong number of Karafs running: ${count}
 496
 497 Count_Running_Karafs_On_Member
 498     [Arguments]    ${member_index}
 499     [Documentation]    Remotely execute grep for karaf process, return count as string.
 500     ${command} =    BuiltIn.Set_Variable    ${NODE_KARAF_COUNT_COMMAND}
 501     ${count} =    Run_Bash_Command_On_Member    command=${command}    member_index=${member_index}
 502     [Return]    ${count}
 503
 504 Isolate_Member_From_List_Or_All
 505     [Arguments]    ${isolate_member_index}    ${member_index_list}=${EMPTY}    ${protocol}=all    ${port}=${EMPTY}
 506     [Documentation]    If the list is empty, isolate member from all ODL instances. Otherwise, isolate member based on present indices.
 507     ...    The KW will return a list of available members: \${updated index_list}=\${member_index_list}-\${isolate_member_index}
 508     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 509     ${source} =    Collections.Get_From_Dictionary    ${ClusterManagement__index_to_ip_mapping}    ${isolate_member_index}
 510     ${dport} =    BuiltIn.Set_Variable_If    '${port}' != '${EMPTY}'    --dport ${port}    ${EMPTY}
 511     FOR    ${index}    IN    @{index_list}
 512         ${destination} =    Collections.Get_From_Dictionary    ${ClusterManagement__index_to_ip_mapping}    ${index}
 513         ${command} =    BuiltIn.Set_Variable    sudo /sbin/iptables -I OUTPUT -p ${protocol} ${dport} --source ${source} --destination ${destination} -j DROP
 514         BuiltIn.Run_Keyword_If    "${index}" != "${isolate_member_index}"    Run_Bash_Command_On_Member    command=${command}    member_index=${isolate_member_index}
 515     END
 516     ${command} =    BuiltIn.Set_Variable    sudo /sbin/iptables -L -n
 517     ${output} =    Run_Bash_Command_On_Member    command=${command}    member_index=${isolate_member_index}
 518     BuiltIn.Log    ${output}
 519     ${updated_index_list} =    BuiltIn.Create_List    @{index_list}
 520     Collections.Remove_Values_From_List    ${updated_index_list}    ${isolate_member_index}
 521     [Return]    ${updated_index_list}
 522
 523 Rejoin_Member_From_List_Or_All
 524     [Arguments]    ${rejoin_member_index}    ${member_index_list}=${EMPTY}    ${protocol}=all    ${port}=${EMPTY}    ${timeout}=60s
 525     [Documentation]    If the list is empty, rejoin member from all ODL instances. Otherwise, rejoin member based on present indices.
 526     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 527     ${source} =    Collections.Get_From_Dictionary    ${ClusterManagement__index_to_ip_mapping}    ${rejoin_member_index}
 528     ${dport} =    BuiltIn.Set_Variable_If    '${port}' != '${EMPTY}'    --dport ${port}    ${EMPTY}
 529     FOR    ${index}    IN    @{index_list}
 530         ${destination} =    Collections.Get_From_Dictionary    ${ClusterManagement__index_to_ip_mapping}    ${index}
 531         ${command} =    BuiltIn.Set_Variable    sudo /sbin/iptables -D OUTPUT -p ${protocol} ${dport} --source ${source} --destination ${destination} -j DROP
 532         BuiltIn.Run_Keyword_If    "${index}" != "${rejoin_member_index}"    Run_Bash_Command_On_Member    command=${command}    member_index=${rejoin_member_index}
 533     END
 534     ${command} =    BuiltIn.Set_Variable    sudo /sbin/iptables -L -n
 535     ${output} =    Run_Bash_Command_On_Member    command=${command}    member_index=${rejoin_member_index}
 536     BuiltIn.Log    ${output}
 537     BuiltIn.Wait_Until_Keyword_Succeeds    ${timeout}    10s    Check_Cluster_Is_In_Sync
 538
 539 Flush_Iptables_From_List_Or_All
 540     [Arguments]    ${member_index_list}=${EMPTY}
 541     [Documentation]    If the list is empty, flush IPTables in all ODL instances. Otherwise, flush member based on present indices.
 542     ${command} =    BuiltIn.Set_Variable    sudo iptables -v -F
 543     ${output} =    Run_Bash_Command_On_List_Or_All    command=${command}    member_index_list=${member_index_list}
 544
 545 Check_Bash_Command_On_List_Or_All
 546     [Arguments]    ${command}    ${member_index_list}=${EMPTY}    ${return_success_only}=False    ${log_on_success}=True    ${log_on_failure}=True    ${stderr_must_be_empty}=True
 547     [Documentation]    Cycle through indices (or all), run bash command on each, using temporary SSH session and restoring the previously active one.
 548     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 549     FOR    ${index}    IN    @{index_list}
 550         Check_Bash_Command_On_Member    command=${command}    member_index=${index}    return_success_only=${return_success_only}    log_on_success=${log_on_success}    log_on_failure=${log_on_failure}
 551         ...    stderr_must_be_empty=${stderr_must_be_empty}
 552     END
 553
 554 Check_Bash_Command_On_Member
 555     [Arguments]    ${command}    ${member_index}    ${return_success_only}=False    ${log_on_success}=True    ${log_on_failure}=True    ${stderr_must_be_empty}=True
 556     [Documentation]    Open SSH session, call SSHKeywords.Execute_Command_Passes, close session, restore previously active session and return output.
 557     BuiltIn.Run_Keyword_And_Return    SSHKeywords.Run_Keyword_Preserve_Connection    Check_Unsafely_Bash_Command_On_Member    ${command}    ${member_index}    return_success_only=${return_success_only}    log_on_success=${log_on_success}
 558     ...    log_on_failure=${log_on_failure}    stderr_must_be_empty=${stderr_must_be_empty}
 559
 560 Check_Unsafely_Bash_Command_On_Member
 561     [Arguments]    ${command}    ${member_index}    ${return_success_only}=False    ${log_on_success}=True    ${log_on_failure}=True    ${stderr_must_be_empty}=True
 562     [Documentation]    Obtain Ip address, open session, call SSHKeywords.Execute_Command_Passes, close session and return output. This affects which SSH session is active.
 563     ${member_ip} =    Resolve_Ip_Address_For_Member    ${member_index}
 564     BuiltIn.Run_Keyword_And_Return    SSHKeywords.Run_Unsafely_Keyword_Over_Temporary_Odl_Session    ${member_ip}    Execute_Command_Passes    ${command}    return_success_only=${return_success_only}    log_on_success=${log_on_success}
 565     ...    log_on_failure=${log_on_failure}    stderr_must_be_empty=${stderr_must_be_empty}
 566
 567 Run_Bash_Command_On_List_Or_All
 568     [Arguments]    ${command}    ${member_index_list}=${EMPTY}
 569     [Documentation]    Cycle through indices (or all), run command on each.
 570     # TODO: Migrate callers to Check_Bash_Command_*
 571     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 572     FOR    ${index}    IN    @{index_list}
 573         Run_Bash_Command_On_Member    command=${command}    member_index=${index}
 574     END
 575
 576 Run_Bash_Command_On_Member
 577     [Arguments]    ${command}    ${member_index}
 578     [Documentation]    Obtain IP, call Utils and return output. This keeps previous ssh session active.
 579     # TODO: Migrate callers to Check_Bash_Command_*
 580     ${member_ip} =    Collections.Get_From_Dictionary    dictionary=${ClusterManagement__index_to_ip_mapping}    key=${member_index}
 581     ${output} =    SSHKeywords.Run_Keyword_Preserve_Connection    Utils.Run_Command_On_Controller    ${member_ip}    ${command}
 582     Log    ${output}
 583     [Return]    ${output}
 584
 585 Run_Karaf_Command_On_List_Or_All
 586     [Arguments]    ${command}    ${member_index_list}=${EMPTY}    ${timeout}=10s
 587     [Documentation]    Cycle through indices (or all), run karaf command on each.
 588     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 589     FOR    ${index}    IN    @{index_list}
 590         ${member_ip} =    Collections.Get_From_Dictionary    dictionary=${ClusterManagement__index_to_ip_mapping}    key=${index}
 591         KarafKeywords.Safe_Issue_Command_On_Karaf_Console    ${command}    ${member_ip}    timeout=${timeout}
 592     END
 593
 594 Run_Karaf_Command_On_Member
 595     [Arguments]    ${command}    ${member_index}    ${timeout}=10s
 596     [Documentation]    Obtain IP address, call KarafKeywords and return output. This does not preserve active ssh session.
 597     ...    This keyword is not used by Run_Karaf_Command_On_List_Or_All, but returned output may be useful.
 598     ${member_ip} =    Collections.Get_From_Dictionary    dictionary=${ClusterManagement__index_to_ip_mapping}    key=${member_index}
 599     ${output} =    KarafKeywords.Safe_Issue_Command_On_Karaf_Console    ${command}    controller=${member_ip}    timeout=${timeout}
 600     [Return]    ${output}
 601
 602 Install_Feature_On_List_Or_All
 603     [Arguments]    ${feature_name}    ${member_index_list}=${EMPTY}    ${timeout}=60s
 604     [Documentation]    Attempt installation on each member from list (or all). Then look for failures.
 605     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 606     ${status_list} =    BuiltIn.Create_List
 607     FOR    ${index}    IN    @{index_list}
 608         ${status}    ${text} =    BuiltIn.Run_Keyword_And_Ignore_Error    Install_Feature_On_Member    feature_name=${feature_name}    member_index=${index}
 609         ...    timeout=${timeout}
 610         BuiltIn.Log    ${text}
 611         Collections.Append_To_List    ${status_list}    ${status}
 612     END
 613     FOR    ${status}    IN    @{status_list}
 614         BuiltIn.Run_Keyword_If    "${status}" != "PASS"    BuiltIn.Fail    ${feature_name} installation failed, see log.
 615     END
 616
 617 Install_Feature_On_Member
 618     [Arguments]    ${feature_name}    ${member_index}    ${timeout}=60s
 619     [Documentation]    Run feature:install karaf command, fail if installation was not successful. Return output.
 620     ${status}    ${output} =    BuiltIn.Run_Keyword_And_Ignore_Error    Run_Karaf_Command_On_Member    command=feature:install ${feature_name}    member_index=${member_index}    timeout=${timeout}
 621     BuiltIn.Run_Keyword_If    "${status}" != "PASS"    BuiltIn.Fail    Failed to install ${feature_name}: ${output}
 622     BuiltIn.Should_Not_Contain    ${output}    Can't install    Failed to install ${feature_name}: ${output}
 623     [Return]    ${output}
 624
 625 With_Ssh_To_List_Or_All_Run_Keyword
 626     [Arguments]    ${member_index_list}    ${keyword_name}    @{args}    &{kwargs}
 627     [Documentation]    For each index in given list (or all): activate SSH connection, run given Keyword, close active connection. Return None.
 628     ...    Beware that in order to avoid "got positional argument after named arguments", first two arguments in the call should not be named.
 629     BuiltIn.Comment    This keyword is experimental and there is high risk of being replaced by another approach.
 630     # TODO: For_Index_From_List_Or_All_Run_Keyword applied to With_Ssh_To_Member_Run_Keyword?
 631     # TODO: Imagine another keyword, using ScalarClosures and adding member index as first argument for each call. Worth it?
 632     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 633     FOR    ${member_index}    IN    @{index_list}
 634         ${member_ip} =    Resolve_IP_Address_For_Member    ${member_index}
 635         SSHKeywords.Run_Unsafely_Keyword_Over_Temporary_Odl_Session    ${member_ip}    ${keyword_name}    @{args}    &{kwargs}
 636     END
 637
 638 Safe_With_Ssh_To_List_Or_All_Run_Keyword
 639     [Arguments]    ${member_index_list}    ${keyword_name}    @{args}    &{kwargs}
 640     [Documentation]    Remember active ssh connection index, call With_Ssh_To_List_Or_All_Run_Keyword, return None. Restore the conection index on teardown.
 641     SSHKeywords.Run_Keyword_Preserve_Connection    With_Ssh_To_List_Or_All_Run_Keyword    ${member_index_list}    ${keyword_name}    @{args}    &{kwargs}
 642
 643 Clean_Directories_On_List_Or_All
 644     [Arguments]    ${member_index_list}=${EMPTY}    ${directory_list}=${EMPTY}    ${karaf_home}=${KARAF_HOME}    ${tmp_dir}=${EMPTY}
 645     [Documentation]    Clear @{directory_list} or @{ODL_DEFAULT_DATA_PATHS} for members in given list or all. Return None.
 646     ...    If \${tmp_dir} is nonempty, use that location to preserve data/log/.
 647     ...    This is intended to return Karaf (offline) to the state it was upon the first boot.
 648     ${path_list} =    Builtin.Set Variable If    "${directory_list}" == "${EMPTY}"    ${ODL_DEFAULT_DATA_PATHS}    ${directory_list}
 649     BuiltIn.Run_Keyword_If    """${tmp_dir}""" != ""    Check_Bash_Command_On_List_Or_All    mkdir -p '${tmp_dir}' && rm -vrf '${tmp_dir}/log' && mv -vf '${karaf_home}/data/log' '${tmp_dir}/'    ${member_index_list}
 650     Safe_With_Ssh_To_List_Or_All_Run_Keyword    ${member_index_list}    ClusterManagement__Clean_Directories    ${path_list}    ${karaf_home}
 651     BuiltIn.Run_Keyword_If    """${tmp_dir}""" != ""    Check_Bash_Command_On_List_Or_All    mkdir -p '${karaf_home}/data' && rm -vrf '${karaf_home}/log' && mv -vf '${tmp_dir}/log' '${karaf_home}/data/'    ${member_index_list}
 652
 653 Store_Karaf_Log_On_List_Or_All
 654     [Arguments]    ${member_index_list}=${EMPTY}    ${dst_dir}=/tmp    ${karaf_home}=${KARAF_HOME}
 655     [Documentation]    Saves karaf.log to the ${dst_dir} for members in given list or all. Return None.
 656     Safe_With_Ssh_To_List_Or_All_Run_Keyword    ${member_index_list}    SSHKeywords.Execute_Command_Should_Pass    cp ${karaf_home}/data/log/karaf.log ${dst_dir}
 657
 658 Restore_Karaf_Log_On_List_Or_All
 659     [Arguments]    ${member_index_list}=${EMPTY}    ${src_dir}=/tmp    ${karaf_home}=${KARAF_HOME}
 660     [Documentation]    Places stored karaf.log to the ${karaf_home}/data/log for members in given list or all. Return None.
 661     Safe_With_Ssh_To_List_Or_All_Run_Keyword    ${member_index_list}    SSHKeywords.Execute_Command_Should_Pass    cp ${src_dir}/karaf.log ${karaf_home}/data/log/
 662
 663 ClusterManagement__Clean_Directories
 664     [Arguments]    ${relative_path_list}    ${karaf_home}
 665     [Documentation]    For each relative path, remove files with respect to ${karaf_home}. Return None.
 666     FOR    ${relative_path}    IN    @{relative_path_list}
 667         SSHLibrary.Execute_Command    rm -rf ${karaf_home}${/}${relative_path}
 668     END
 669
 670 Put_As_Json_And_Check_Member_List_Or_All
 671     [Arguments]    ${uri}    ${data}    ${member_index}    ${member_index_list}=${EMPTY}
 672     [Documentation]    Send a PUT with the supplied uri ${uri} and body ${data} to member ${member_index}.
 673     ...    Then check data is replicated in all or some members defined in ${member_index_list}.
 674     ${response_text} =    Put_As_Json_To_Member    uri=${uri}    data=${data}    member_index=${member_index}
 675     Wait Until Keyword Succeeds    5s    1s    Check_Json_Member_List_Or_All    uri=${uri}    expected_data=${data}    member_index_list=${member_index_list}
 676     [Return]    ${response_text}
 677
 678 Put_As_Json_To_Member
 679     [Arguments]    ${uri}    ${data}    ${member_index}
 680     [Documentation]    Send a PUT with the supplied uri and data to member ${member_index}.
 681     ${session} =    Resolve_Http_Session_For_Member    member_index=${member_index}
 682     ${response_text} =    TemplatedRequests.Put_As_Json_To_Uri    uri=${uri}    data=${data}    session=${session}
 683     [Return]    ${response_text}
 684
 685 Post_As_Json_To_Member
 686     [Arguments]    ${uri}    ${data}    ${member_index}
 687     [Documentation]    Send a POST with the supplied uri and data to member ${member_index}.
 688     ${session} =    Resolve_Http_Session_For_Member    member_index=${member_index}
 689     ${response_text} =    TemplatedRequests.Post_As_Json_To_Uri    uri=${uri}    data=${data}    session=${session}
 690     [Return]    ${response_text}
 691
 692 Delete_And_Check_Member_List_Or_All
 693     [Arguments]    ${uri}    ${member_index}    ${member_index_list}=${EMPTY}
 694     [Documentation]    Send a DELETE with the supplied uri to the member ${member_index}.
 695     ...    Then check the data is removed from all members in ${member_index_list}.
 696     ${response_text} =    Delete_From_Member    ${uri}    ${member_index}
 697     BuiltIn.Wait_Until_Keyword_Succeeds    5s    1s    Check_No_Content_Member_List_Or_All    uri=${uri}    member_index_list=${member_index_list}
 698     [Return]    ${response_text}
 699
 700 Delete_From_Member
 701     [Arguments]    ${uri}    ${member_index}
 702     [Documentation]    Send a DELETE with the supplied uri to member ${member_index}.
 703     ${session} =    Resolve_Http_Session_For_Member    member_index=${member_index}
 704     ${response_text} =    TemplatedRequests.Delete_From_Uri    uri=${uri}    session=${session}
 705     [Return]    ${response_text}
 706
 707 Check_Json_Member_List_Or_All
 708     [Arguments]    ${uri}    ${expected_data}    ${member_index_list}=${EMPTY}
 709     [Documentation]    Send a GET with the supplied uri to all or some members defined in ${member_index_list}.
 710     ...    Then check received data is = ${expected data}.
 711     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 712     FOR    ${index}    IN    @{index_list}
 713         ${data} =    Get_From_Member    uri=${uri}    member_index=${index}
 714         TemplatedRequests.Normalize_Jsons_And_Compare    ${expected_data}    ${data}
 715     END
 716
 717 Check_Item_Occurrence_Member_List_Or_All
 718     [Arguments]    ${uri}    ${dictionary}    ${member_index_list}=${EMPTY}
 719     [Documentation]    Send a GET with the supplied uri to all or some members defined in ${member_index_list}.
 720     ...    Then check received for occurrences of items expressed in a dictionary ${dictionary}.
 721     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 722     FOR    ${index}    IN    @{index_list}
 723         ${data} =    Get_From_Member    uri=${uri}    member_index=${index}
 724         Utils.Check Item Occurrence    ${data}    ${dictionary}
 725     END
 726
 727 Check_No_Content_Member_List_Or_All
 728     [Arguments]    ${uri}    ${member_index_list}=${EMPTY}
 729     [Documentation]    Send a GET with the supplied uri to all or some members defined in ${member_index_list}.
 730     ...    Then check there is no content.
 731     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 732     FOR    ${index}    IN    @{index_list}
 733         ${session} =    Resolve_Http_Session_For_Member    member_index=${index}
 734         Utils.No_Content_From_URI    ${session}    ${uri}
 735     END
 736
 737 Get_From_Member
 738     [Arguments]    ${uri}    ${member_index}    ${access}=${ACCEPT_EMPTY}
 739     [Documentation]    Send a GET with the supplied uri to member ${member_index}.
 740     ${session} =    Resolve_Http_Session_For_Member    member_index=${member_index}
 741     ${response_text} =    TemplatedRequests.Get_From_Uri    uri=${uri}    accept=${access}    session=${session}
 742     [Return]    ${response_text}
 743
 744 Resolve_IP_Address_For_Member
 745     [Arguments]    ${member_index}
 746     [Documentation]    Return node IP address of given index.
 747     ${ip_address} =    Collections.Get From Dictionary    dictionary=${ClusterManagement__index_to_ip_mapping}    key=${member_index}
 748     [Return]    ${ip_address}
 749
 750 Resolve_IP_Address_For_Members
 751     [Arguments]    ${member_index_list}
 752     [Documentation]    Return a list of IP address of given indexes.
 753     ${member_ip_list} =    BuiltIn.Create_List
 754     FOR    ${index}    IN    @{member_index_list}
 755         ${ip_address} =    Collections.Get From Dictionary    dictionary=${ClusterManagement__index_to_ip_mapping}    key=${index}
 756         Collections.Append_To_List    ${member_ip_list}    ${ip_address}
 757     END
 758     [Return]    ${member_ip_list}
 759
 760 Resolve_Http_Session_For_Member
 761     [Arguments]    ${member_index}
 762     [Documentation]    Return RequestsLibrary session alias pointing to node of given index.
 763     ${session} =    BuiltIn.Set_Variable    ClusterManagement__session_${member_index}
 764     [Return]    ${session}
 765
 766 Resolve_Shard_Type_Class
 767     [Arguments]    ${shard_type}
 768     [Documentation]    Simple lookup for class name corresponding to desired type.
 769     BuiltIn.Run_Keyword_If    '${shard_type}' == 'config'    BuiltIn.Return_From_Keyword    DistributedConfigDatastore
 770     ...    ELSE IF    '${shard_type}' == 'operational'    BuiltIn.Return_From_Keyword    DistributedOperationalDatastore
 771     BuiltIn.Fail    Unrecognized shard type: ${shard_type}
 772
 773 ClusterManagement__Build_List
 774     [Arguments]    ${member}
 775     ${member_int} =    BuiltIn.Convert_To_Integer    ${member}
 776     ${index_list} =    BuiltIn.Create_List    ${member_int}
 777     [Return]    ${index_list}
 778
 779 ClusterManagement__Parse_Sync_Status
 780     [Arguments]    ${shard_manager_text}
 781     [Documentation]    Return sync status parsed out of given text. Called twice by Get_Sync_Status_Of_Member.
 782     BuiltIn.Log    ${shard_manager_text}
 783     ${manager_object} =    RequestsLibrary.To_Json    ${shard_manager_text}
 784     ${value_object} =    Collections.Get_From_Dictionary    dictionary=${manager_object}    key=value
 785     ${sync_status} =    Collections.Get_From_Dictionary    dictionary=${value_object}    key=SyncStatus
 786     [Return]    ${sync_status}
 787
 788 List_All_Indices
 789     [Documentation]    Create a new list of all indices.
 790     BuiltIn.Run_Keyword_And_Return    List_Indices_Or_All
 791
 792 List_Indices_Or_All
 793     [Arguments]    ${given_list}=${EMPTY}
 794     [Documentation]    Utility to allow \${EMPTY} as default argument value, as the internal list is computed at runtime.
 795     ...    This keyword always returns a (shallow) copy of given or default list,
 796     ...    so operations with the returned list should not affect other lists.
 797     ...    Also note that this keyword does not consider empty list to be \${EMPTY}.
 798     ${return_list_reference} =    BuiltIn.Set_Variable_If    """${given_list}""" != ""    ${given_list}    ${ClusterManagement__member_index_list}
 799     ${return_list_copy} =    BuiltIn.Create_List    @{return_list_reference}
 800     [Return]    ${return_list_copy}
 801
 802 List_Indices_Minus_Member
 803     [Arguments]    ${member_index}    ${member_index_list}=${EMPTY}
 804     [Documentation]    Create a new list which contains indices from ${member_index_list} (or all) without ${member_index}.
 805     ${index_list} =    List_Indices_Or_All    ${member_index_list}
 806     Collections.Remove Values From List    ${index_list}    ${member_index}
 807     [Return]    ${index_list}
 808
 809 ClusterManagement__Compute_Derived_Variables
 810     [Arguments]    ${int_of_members}    ${http_timeout}=${DEFAULT_TIMEOUT_HTTP}    ${http_retries}=0
 811     [Documentation]    Construct index list, session list and IP mapping, publish them as suite variables.
 812     @{member_index_list} =    BuiltIn.Create_List
 813     @{session_list} =    BuiltIn.Create_List
 814     &{index_to_ip_mapping} =    BuiltIn.Create_Dictionary
 815     FOR    ${index}    IN RANGE    1    ${int_of_members+1}
 816         ClusterManagement__Include_Member_Index    ${index}    ${member_index_list}    ${session_list}    ${index_to_ip_mapping}    http_timeout=${http_timeout}
 817         ...    http_retries=${http_retries}
 818     END
 819     BuiltIn.Set_Suite_Variable    \${ClusterManagement__member_index_list}    ${member_index_list}
 820     BuiltIn.Set_Suite_Variable    \${ClusterManagement__index_to_ip_mapping}    ${index_to_ip_mapping}
 821     BuiltIn.Set_Suite_Variable    \${ClusterManagement__session_list}    ${session_list}
 822
 823 ClusterManagement__Include_Member_Index
 824     [Arguments]    ${index}    ${member_index_list}    ${session_list}    ${index_to_ip_mapping}    ${http_timeout}=${DEFAULT_TIMEOUT_HTTP}    ${http_retries}=0
 825     [Documentation]    Add a corresponding item based on index into the last three arguments.
 826     ...    Create the Http session whose alias is added to list.
 827     Collections.Append_To_List    ${member_index_list}    ${index}
 828     ${member_ip} =    BuiltIn.Set_Variable    ${ODL_SYSTEM_${index}_IP}
 829     # ${index} is int (not string) so "key=value" syntax does not work in the following line.
 830     Collections.Set_To_Dictionary    ${index_to_ip_mapping}    ${index}    ${member_ip}
 831     # Http session, with ${AUTH}, without headers.
 832     ${session_alias} =    Resolve_Http_Session_For_Member    member_index=${index}
 833     RequestsLibrary.Create_Session    ${session_alias}    http://${member_ip}:${RESTCONFPORT}    auth=${AUTH}    timeout=${http_timeout}    max_retries=${http_retries}
 834     Collections.Append_To_List    ${session_list}    ${session_alias}
 835
 836 Sync_Status_Should_Be_False
 837     [Arguments]    ${controller_index}
 838     [Documentation]    Verify that cluster node is not in sync with others
 839     ${status}    Get_Sync_Status_Of_Member    ${controller_index}
 840     BuiltIn.Should_Not_Be_True    ${status}
 841
 842 Sync_Status_Should_Be_True
 843     [Arguments]    ${controller_index}
 844     [Documentation]    Verify that cluster node is in sync with others
 845     ${status}    Get_Sync_Status_Of_Member    ${controller_index}
 846     BuiltIn.Should_Be_True    ${status}
 847
 848 Return_Member_IP
 849     [Arguments]    ${member_index}
 850     [Documentation]    Return the IP address of the member given the member_index.
 851     ${member_int} =    BuiltIn.Convert_To_Integer    ${member_index}
 852     ${member_ip} =    Collections.Get_From_Dictionary    dictionary=${ClusterManagement__index_to_ip_mapping}    key=${member_int}
 853     [Return]    ${member_ip}
 854
 855 Check Service Status
 856     [Arguments]    ${odl_ip}    ${system_ready_state}    ${service_state}    @{service_list}
 857     [Documentation]    Issues the karaf shell command showSvcStatus to verify the ready and service states are the same as the arguments passed
 858     ${service_status_output} =    BuiltIn.Run Keyword If    ${NUM_ODL_SYSTEM} > 1    KarafKeywords.Issue_Command_On_Karaf_Console    showSvcStatus -n ${odl_ip}    ${odl_ip}    ${KARAF_SHELL_PORT}
 859     ...    ELSE    KarafKeywords.Issue_Command_On_Karaf_Console    showSvcStatus    ${odl_ip}    ${KARAF_SHELL_PORT}
 860     BuiltIn.Should Contain    ${service_status_output}    ${system_ready_state}
 861     FOR    ${service}    IN    @{service_list}
 862         BuiltIn.Should Match Regexp    ${service_status_output}    ${service} +: ${service_state}
 863     END
 864
 865 Check Status Of Services Is OPERATIONAL
 866     [Arguments]    @{service_list}
 867     [Documentation]    This keyword will verify whether all the services are operational in all the ODL nodes
 868     FOR    ${i}    IN RANGE    ${NUM_ODL_SYSTEM}
 869         ClusterManagement.Check Service Status    ${ODL_SYSTEM_${i+1}_IP}    ACTIVE    OPERATIONAL    @{service_list}
 870     END