csit/libraries/ClusterManagement.robot

   1 *** Settings ***
   2 Documentation     Resource housing Keywords common to several suites for cluster functional testing.
   3 ...
   4 ...               Copyright (c) 2016 Cisco Systems, Inc. and others. All rights reserved.
   5 ...               Copyright (c) 2016 Brocade Communications Systems, Inc. and others. All rights reserved.
   6 ...
   7 ...               This program and the accompanying materials are made available under the
   8 ...               terms of the Eclipse Public License v1.0 which accompanies this distribution,
   9 ...               and is available at http://www.eclipse.org/legal/epl-v10.html
  10 ...
  11 ...
  12 ...               This resource holds private state (in suite variables),
  13 ...               which is generated once at Setup with ClusterManagement_Setup KW.
  14 ...               The state includes member indexes, IP addresses and Http (RequestsLibrary) sessions.
  15 ...               Cluster Keywords normally use member index, member list or nothing (all members) as argument.
  16 ...
  17 ...               All index lists returned should be sorted numerically, fix if not.
  18 ...
  19 ...               Requirements:
  20 ...               odl-jolokia is assumed to be installed.
  21 ...
  22 ...               Keywords are ordered as follows:
  23 ...               - Cluster Setup
  24 ...               - Shard state, leader and followers
  25 ...               - Entity Owner, candidates and successors
  26 ...               - Kill, Stop and Start Member
  27 ...               - Isolate and Rejoin Member
  28 ...               - Run Commands On Member
  29 ...               - REST requests and checks on Members
  30 ...
  31 ...               TODO: Unify capitalization of Leaders and Followers.
  32 Library           RequestsLibrary    # for Create_Session and To_Json
  33 Library           Collections
  34 Resource          ${CURDIR}/CompareStream.robot
  35 Resource          ${CURDIR}/KarafKeywords.robot
  36 Resource          ${CURDIR}/SSHKeywords.robot
  37 Resource          ${CURDIR}/TemplatedRequests.robot    # for Get_As_Json_From_Uri
  38 Resource          ${CURDIR}/Utils.robot    # for Run_Command_On_Controller
  39
  40 *** Variables ***
  41 ${ENTITY_OWNER_URI}    restconf/operational/entity-owners:entity-owners
  42 ${GC_LOG_PATH}    ${KARAF_HOME}/data/log
  43 ${JAVA_HOME}      ${EMPTY}    # releng/builder scripts should provide correct value
  44 ${JOLOKIA_CONF_SHARD_MANAGER_URI}    jolokia/read/org.opendaylight.controller:Category=ShardManager,name=shard-manager-config,type=DistributedConfigDatastore
  45 ${JOLOKIA_OPER_SHARD_MANAGER_URI}    jolokia/read/org.opendaylight.controller:Category=ShardManager,name=shard-manager-operational,type=DistributedOperationalDatastore
  46 ${JOLOKIA_READ_URI}    jolokia/read/org.opendaylight.controller
  47 ${KARAF_HOME}     ${WORKSPACE}${/}${BUNDLEFOLDER}    # TODO: Migrate to Variables.robot
  48 # Bug 9044 workaround: delete etc/host.key before restart.
  49 @{ODL_DEFAULT_DATA_PATHS}    tmp/    data/    cache/    snapshots/    journal/    etc/opendaylight/current/    etc/host.key
  50 ${RESTCONF_MODULES_DIR}    ${CURDIR}/../variables/restconf/modules
  51 ${SINGLETON_NETCONF_DEVICE_ID_PREFIX}    /odl-general-entity:entity[odl-general-entity:name='KeyedInstanceIdentifier{targetType=interface org.opendaylight.yang.gen.v1.urn.tbd.params.xml.ns.yang.network.topology.rev131021.network.topology.topology.Node, path=[org.opendaylight.yang.gen.v1.urn.tbd.params.xml.ns.yang.network.topology.rev131021.NetworkTopology, org.opendaylight.yang.gen.v1.urn.tbd.params.xml.ns.yang.network.topology.rev131021.network.topology.Topology[key=TopologyKey [_topologyId=Uri [_value=topology-netconf]]], org.opendaylight.yang.gen.v1.urn.tbd.params.xml.ns.yang.network.topology.rev131021.network.topology.topology.Node[key=NodeKey [_nodeId=Uri [_value=
  52 ${SINGLETON_NETCONF_DEVICE_ID_SUFFIX}    ]]]]}']
  53 ${SINGLETON_ELECTION_ENTITY_TYPE}    org.opendaylight.mdsal.ServiceEntityType
  54 ${SINGLETON_CHANGE_OWNERSHIP_ENTITY_TYPE}    org.opendaylight.mdsal.AsyncServiceCloseEntityType
  55 ${NODE_START_COMMAND}    ${KARAF_HOME}/bin/start
  56 ${NODE_STOP_COMMAND}    ${KARAF_HOME}/bin/stop
  57 ${NODE_KILL_COMMAND}    ps axf | grep org.apache.karaf | grep -v grep | awk '{print \"kill -9 \" $1}' | sh
  58 ${NODE_FREEZE_COMMAND}    ps axf | grep org.apache.karaf | grep -v grep | awk '{print \"kill -STOP \" $1}' | sh
  59 ${NODE_UNFREEZE_COMMAND}    ps axf | grep org.apache.karaf | grep -v grep | awk '{print \"kill -CONT \" $1}' | sh
  60
  61 *** Keywords ***
  62 ClusterManagement_Setup
  63     [Arguments]    ${http_timeout}=1    ${http_retries}=0
  64     [Documentation]    Detect repeated call, or detect number of members and initialize derived suite variables.
  65     ...    Http sessions are created with parameters to not waste time when ODL is no accepting connections properly.
  66     # Avoid multiple initialization by several downstream libraries.
  67     ${already_done} =    BuiltIn.Get_Variable_Value    \${ClusterManagement__has_setup_run}    False
  68     BuiltIn.Return_From_Keyword_If    ${already_done}
  69     BuiltIn.Set_Suite_Variable    \${ClusterManagement__has_setup_run}    True
  70     ${cluster_size} =    BuiltIn.Get_Variable_Value    \${NUM_ODL_SYSTEM}    1
  71     ${status}    ${possibly_int_of_members} =    BuiltIn.Run_Keyword_And_Ignore_Error    BuiltIn.Convert_To_Integer    ${cluster_size}
  72     ${int_of_members} =    BuiltIn.Set_Variable_If    '${status}' != 'PASS'    ${1}    ${possibly_int_of_members}
  73     ClusterManagement__Compute_Derived_Variables    int_of_members=${int_of_members}    http_timeout=${http_timeout}    http_retries=${http_retries}
  74
  75 Check_Cluster_Is_In_Sync
  76     [Arguments]    ${member_index_list}=${EMPTY}
  77     [Documentation]    Fail if no-sync is detected on a member from list (or any).
  78     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
  79     : FOR    ${index}    IN    @{index_list}    # usually: 1, 2, 3.
  80     \    ${status} =    Get_Sync_Status_Of_Member    member_index=${index}
  81     \    BuiltIn.Continue_For_Loop_If    'True' == '${status}'
  82     \    BuiltIn.Fail    Index ${index} has incorrect status: ${status}
  83
  84 Get_Sync_Status_Of_Member
  85     [Arguments]    ${member_index}
  86     [Documentation]    Obtain IP, two GETs from jolokia URIs, return combined sync status as string.
  87     ${session} =    Resolve_Http_Session_For_Member    member_index=${member_index}
  88     ${conf_text} =    TemplatedRequests.Get_As_Json_From_Uri    uri=${JOLOKIA_CONF_SHARD_MANAGER_URI}    session=${session}
  89     ${conf_status} =    ClusterManagement__Parse_Sync_Status    shard_manager_text=${conf_text}
  90     BuiltIn.Return_From_Keyword_If    'False' == ${conf_status}    False
  91     ${oper_text} =    TemplatedRequests.Get_As_Json_From_Uri    uri=${JOLOKIA_OPER_SHARD_MANAGER_URI}    session=${session}
  92     ${oper_status} =    ClusterManagement__Parse_Sync_Status    shard_manager_text=${oper_text}
  93     [Return]    ${oper_status}
  94
  95 Verify_Leader_Exists_For_Each_Shard
  96     [Arguments]    ${shard_name_list}    ${shard_type}=operational    ${member_index_list}=${EMPTY}    ${verify_restconf}=True
  97     [Documentation]    For each shard name, call Get_Leader_And_Followers_For_Shard.
  98     ...    Not much logic there, but single Keyword is useful when using BuiltIn.Wait_Until_Keyword_Succeeds.
  99     : FOR    ${shard_name}    IN    @{shard_name_list}
 100     \    Get_Leader_And_Followers_For_Shard    shard_name=${shard_name}    shard_type=${shard_type}    validate=True    member_index_list=${member_index_list}    verify_restconf=${verify_restconf}
 101
 102 Get_Leader_And_Followers_For_Shard
 103     [Arguments]    ${shard_name}=default    ${shard_type}=operational    ${validate}=True    ${member_index_list}=${EMPTY}    ${verify_restconf}=True    ${http_timeout}=5
 104     [Documentation]    Get role lists, validate there is one leader, return the leader and list of followers.
 105     ...    Optionally, issue GET to a simple restconf URL to make sure subsequent operations will not encounter 503.
 106     ${leader_list}    ${follower_list} =    Get_State_Info_For_Shard    shard_name=${shard_name}    shard_type=${shard_type}    validate=True    member_index_list=${member_index_list}
 107     ...    verify_restconf=${verify_restconf}    http_timeout=${http_timeout}
 108     ${leader_count} =    BuiltIn.Get_Length    ${leader_list}
 109     BuiltIn.Run_Keyword_If    ${leader_count} < 1    BuiltIn.Fail    No leader found.
 110     BuiltIn.Length_Should_Be    ${leader_list}    ${1}    Too many Leaders.
 111     ${leader} =    Collections.Get_From_List    ${leader_list}    0
 112     [Return]    ${leader}    ${follower_list}
 113
 114 Get_State_Info_For_Shard
 115     [Arguments]    ${shard_name}=default    ${shard_type}=operational    ${validate}=False    ${member_index_list}=${EMPTY}    ${verify_restconf}=False    ${http_timeout}=5
 116     [Documentation]    Return lists of Leader and Follower member indices from a given member index list
 117     ...    (or from the full list if empty). If \${shard_type} is not 'config', 'operational' is assumed.
 118     ...    If \${validate}, Fail if raft state is not Leader or Follower (for example on Candidate).
 119     ...    The biggest difference from Get_Leader_And_Followers_For_Shard
 120     ...    is that no check on number of Leaders is performed.
 121     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 122     Collections.Sort_List    ${index_list}    # to guarantee return values are also sorted lists
 123     # TODO: Support alternative capitalization of 'config'?
 124     ${ds_type} =    BuiltIn.Set_Variable_If    '${shard_type}' != 'config'    operational    config
 125     ${leader_list} =    BuiltIn.Create_List
 126     ${follower_list} =    BuiltIn.Create_List
 127     : FOR    ${index}    IN    @{index_list}    # usually: 1, 2, 3.
 128     \    ${raft_state} =    Get_Raft_State_Of_Shard_At_Member    shard_name=${shard_name}    shard_type=${ds_type}    member_index=${index}    verify_restconf=${verify_restconf}
 129     \    ...    http_timeout=${http_timeout}
 130     \    BuiltIn.Run_Keyword_If    'Follower' == '${raft_state}'    Collections.Append_To_List    ${follower_list}    ${index}
 131     \    ...    ELSE IF    'Leader' == '${raft_state}'    Collections.Append_To_List    ${leader_list}    ${index}
 132     \    ...    ELSE IF    ${validate}    BuiltIn.Fail    Unrecognized Raft state: ${raft_state}
 133     [Return]    ${leader_list}    ${follower_list}
 134
 135 Get_Raft_State_Of_Shard_At_Member
 136     [Arguments]    ${shard_name}    ${shard_type}    ${member_index}    ${verify_restconf}=False    ${http_timeout}=5
 137     [Documentation]    Send request to Jolokia on indexed member, return extracted Raft status.
 138     ...    Optionally, check restconf works.
 139     ${raft_state} =    Get_Raft_Property_From_Shard_Member    RaftState    ${shard_name}    ${shard_type}    ${member_index}    verify_restconf=${verify_restconf}
 140     ...    http_timeout=${http_timeout}
 141     [Return]    ${raft_state}
 142
 143 Get_Raft_Property_From_Shard_Member
 144     [Arguments]    ${property}    ${shard_name}    ${shard_type}    ${member_index}    ${verify_restconf}=False    ${http_timeout}=5
 145     [Documentation]    Send request to Jolokia on indexed member, return extracted Raft property.
 146     ...    Optionally, check restconf works.
 147     ${session} =    Resolve_Http_Session_For_Member    member_index=${member_index}
 148     # TODO: Does the used URI tend to generate large data which floods log.html?
 149     BuiltIn.Run_Keyword_If    ${verify_restconf}    TemplatedRequests.Get_As_Json_Templated    session=${session}    folder=${RESTCONF_MODULES_DIR}    verify=False    http_timeout=${http_timeout}
 150     ${type_class} =    Resolve_Shard_Type_Class    shard_type=${shard_type}
 151     ${uri} =    BuiltIn.Set_Variable    ${JOLOKIA_READ_URI}:Category=Shards,name=member-${member_index}-shard-${shard_name}-${shard_type},type=${type_class}
 152     ${data_text} =    TemplatedRequests.Get_As_Json_From_Uri    uri=${uri}    session=${session}    http_timeout=${http_timeout}
 153     ${data_object} =    RequestsLibrary.To_Json    ${data_text}
 154     ${value} =    Collections.Get_From_Dictionary    ${data_object}    value
 155     ${raft_property} =    Collections.Get_From_Dictionary    ${value}    ${property}
 156     [Return]    ${raft_property}
 157
 158 Verify_Shard_Leader_Elected
 159     [Arguments]    ${shard_name}    ${shard_type}    ${new_elected}    ${old_leader}    ${member_index_list}=${EMPTY}    ${verify_restconf}=True
 160     [Documentation]    Verify new leader was elected or remained the same. Bool paramter ${new_elected} indicates if
 161     ...    new leader is elected or should remained the same as ${old_leader}
 162     ${leader}    ${followers}=    Get_Leader_And_Followers_For_Shard    shard_name=${shard_name}    shard_type=${shard_type}    member_index_list=${member_index_list}    verify_restconf=${verify_restconf}
 163     BuiltIn.Run_Keyword_If    ${new_elected}    BuiltIn.Should_Not_Be_Equal_As_Numbers    ${old_leader}    ${leader}
 164     BuiltIn.Run_Keyword_Unless    ${new_elected}    BuiltIn.Should_Be_Equal_As_numbers    ${old_leader}    ${leader}
 165     BuiltIn.Return_From_Keyword    ${leader}    ${followers}
 166
 167 Verify_Owner_And_Successors_For_Device
 168     [Arguments]    ${device_name}    ${device_type}    ${member_index}    ${candidate_list}=${EMPTY}    ${after_stop}=False
 169     [Documentation]    Returns the owner and successors for the SB device ${device_name} of type ${device_type}. Request is sent to member ${member_index}.
 170     ...    For Boron and beyond, candidates are not removed on node down or isolation,
 171     ...    so this keyword expects candidates to be all members from Boron on.
 172     ...    Extra check is done to verify owner and successors are within the ${candidate_list}. This KW is useful when combined with WUKS.
 173     ...    ${candidate_list} minus owner is returned as ${successor list}.
 174     ...    Users can still use Get_Owner_And_Successors_For_Device if they are interested in downed candidates,
 175     ...    or for testing heterogeneous clusters.
 176     ${index_list} =    List_Indices_Or_All    given_list=${candidate_list}
 177     ${owner}    ${successor_list} =    Get_Owner_And_Successors_For_Device    device_name=${device_name}    device_type=${device_type}    member_index=${member_index}
 178     Collections.List_Should_Contain_Value    ${index_list}    ${owner}    Owner ${owner} is not in candidate list ${index_list}
 179     # In Beryllium or after stopping an instance, the removed instance does not show in the candidate list.
 180     ${expected_candidate_list_origin} =    BuiltIn.Set_Variable_If    ${after_stop}    ${index_list}    ${ClusterManagement__member_index_list}
 181     # We do not want to manipulate either origin list.
 182     ${expected_successor_list} =    BuiltIn.Create_List    @{expected_candidate_list_origin}
 183     Collections.Remove_Values_From_List    ${expected_successor_list}    ${owner}
 184     Collections.Lists_Should_Be_Equal    ${expected_successor_list}    ${successor_list}    Successor list ${successor_list} is not the came as expected ${expected_successor_list}
 185     # User expects the returned successor list to be the provided candidate list minus the owner.
 186     Collections.Remove_Values_From_List    ${index_list}    ${owner}
 187     [Return]    ${owner}    ${index_list}
 188
 189 Get_Owner_And_Successors_For_Device
 190     [Arguments]    ${device_name}    ${device_type}    ${member_index}    ${http_timeout}=${EMPTY}
 191     [Documentation]    Returns the owner and a list of successors for the SB device ${device_name} of type ${device_type}. Request is sent to member ${member_index}.
 192     ...    Successors are those device candidates not elected as owner. The list of successors = (list of candidates) - (owner).
 193     ...    The returned successor list is sorted numerically.
 194     ...    Note that "candidate list" definition currently differs between Beryllium and Boron.
 195     ...    Use Verify_Owner_And_Successors_For_Device if you want the older semantics (inaccessible nodes not present in the list).
 196     # TODO: somewhere to introduce ${DEFAULT_RESTCONF_DATASTORE_TIMEOUT}. Value may depend on protocol (ask vs tell) and perhaps stream.
 197     ${owner}    ${candidate_list} =    Get_Owner_And_Candidates_For_Device    device_name=${device_name}    device_type=${device_type}    member_index=${member_index}    http_timeout=${http_timeout}
 198     ${successor_list} =    BuiltIn.Create_List    @{candidate_list}    # Copy operation is not required, but new variable name requires a line anyway.
 199     Collections.Remove_Values_From_List    ${successor_list}    ${owner}
 200     [Return]    ${owner}    ${successor_list}
 201
 202 Get_Owner_And_Candidates_For_Device_Old
 203     [Arguments]    ${device_name}    ${device_type}    ${member_index}    ${http_timeout}=${EMPTY}
 204     [Documentation]    Returns the owner and a list of candidates for the SB device ${device_name} of type ${device_type}. Request is sent to member ${member_index}.
 205     ...    Candidates are all members that register to own a device, so the list of candiates includes the owner.
 206     ...    The returned candidate list is sorted numerically.
 207     ...    Note that "candidate list" definition currently differs between Beryllium and Boron.
 208     ...    It is recommended to use Get_Owner_And_Successors_For_Device instead of this keyword, see documentation there.
 209     BuiltIn.Comment    TODO: Can this implementation be changed to call Get_Owner_And_Candidates_For_Type_And_Id?
 210     ${session} =    Resolve_Http_Session_For_Member    member_index=${member_index}
 211     ${data} =    TemplatedRequests.Get_As_Json_From_Uri    uri=${ENTITY_OWNER_URI}    session=${session}    http_timeout=${http_timeout}
 212     ${candidate_list} =    BuiltIn.Create_List
 213     ${entity_type} =    BuiltIn.Set_Variable_If    '${device_type}' == 'netconf'    netconf-node/${device_name}    ${device_type}
 214     ${clear_data} =    BuiltIn.Run_Keyword_If    '${device_type}' == 'openflow' or '${device_type}' == 'netconf'    Extract_OpenFlow_Device_Data    ${data}
 215     ...    ELSE IF    '${device_type}' == 'ovsdb'    Extract_Ovsdb_Device_Data    ${data}
 216     ...    ELSE IF    '${device_type}' == 'org.opendaylight.mdsal.ServiceEntityType'    Extract_Service_Entity_Type    ${data}
 217     ...    ELSE    Fail    Not recognized device type: ${device_type}
 218     ${json} =    RequestsLibrary.To_Json    ${clear_data}
 219     ${entity_type_list} =    Collections.Get_From_Dictionary    &{json}[entity-owners]    entity-type
 220     ${entity_type_index} =    Utils.Get_Index_From_List_Of_Dictionaries    ${entity_type_list}    type    ${entity_type}
 221     BuiltIn.Should_Not_Be_Equal_As_Integers    ${entity_type_index}    -1    No Entity Owner found for ${device_type}
 222     ${entity_list} =    Collections.Get_From_Dictionary    @{entity_type_list}[${entity_type_index}]    entity
 223     ${entity_index} =    Utils.Get_Index_From_List_Of_Dictionaries    ${entity_list}    id    ${device_name}
 224     BuiltIn.Should_Not_Be_Equal_As_Integers    ${entity_index}    -1    Device ${device_name} not found in Entity Owner ${device_type}
 225     ${entity_owner} =    Collections.Get_From_Dictionary    @{entity_list}[${entity_index}]    owner
 226     BuiltIn.Should_Not_Be_Empty    ${entity_owner}    No owner found for ${device_name}
 227     ${owner} =    String.Replace_String    ${entity_owner}    member-    ${EMPTY}
 228     ${owner} =    BuiltIn.Convert_To_Integer    ${owner}
 229     ${entity_candidates_list} =    Collections.Get_From_Dictionary    @{entity_list}[${entity_index}]    candidate
 230     : FOR    ${entity_candidate}    IN    @{entity_candidates_list}
 231     \    ${candidate} =    String.Replace_String    &{entity_candidate}[name]    member-    ${EMPTY}
 232     \    ${candidate} =    BuiltIn.Convert_To_Integer    ${candidate}
 233     \    Collections.Append_To_List    ${candidate_list}    ${candidate}
 234     Collections.Sort_List    ${candidate_list}
 235     [Return]    ${owner}    ${candidate_list}
 236
 237 Get_Owner_And_Candidates_For_Device_Singleton
 238     [Arguments]    ${device_name}    ${device_type}    ${member_index}    ${http_timeout}=${EMPTY}
 239     [Documentation]    Returns the owner and a list of candidates for the SB device ${device_name} of type ${device_type}. Request is sent to member ${member_index}.
 240     ...    Parsing method is selected by device type
 241     ...    Separate kw for every supported device type must be defined
 242     BuiltIn.Keyword_Should_Exist    Get_Owner_And_Candidates_For_Device_Singleton_${device_type}
 243     BuiltIn.Run_Keyword_And_Return    Get_Owner_And_Candidates_For_Device_Singleton_${device_type}    ${device_name}    ${member_index}    http_timeout=${http_timeout}
 244
 245 Get_Owner_And_Candidates_For_Device_Singleton_Netconf
 246     [Arguments]    ${device_name}    ${member_index}    ${http_timeout}=${EMPTY}
 247     [Documentation]    Returns the owner and a list of candidates for the SB device ${device_name} of type netconf. Request is sent to member ${member_index}.
 248     ...    Parsing method is set as netconf (using netconf device id prefix and suffix)
 249     # Get election entity type results
 250     ${type} =    BuiltIn.Set_Variable    ${SINGLETON_ELECTION_ENTITY_TYPE}
 251     ${id} =    BuiltIn.Set_Variable    ${SINGLETON_NETCONF_DEVICE_ID_PREFIX}${device_name}${SINGLETON_NETCONF_DEVICE_ID_SUFFIX}
 252     ${owner_1}    ${candidate_list_1} =    Get_Owner_And_Candidates_For_Type_And_Id    ${type}    ${id}    ${member_index}    http_timeout=${http_timeout}
 253     # Get change ownership entity type results
 254     ${type} =    BuiltIn.Set_Variable    ${SINGLETON_CHANGE_OWNERSHIP_ENTITY_TYPE}
 255     ${id} =    BuiltIn.Set_Variable    ${SINGLETON_NETCONF_DEVICE_ID_PREFIX}${device_name}${SINGLETON_NETCONF_DEVICE_ID_SUFFIX}
 256     ${owner_2}    ${candidate_list_2} =    Get_Owner_And_Candidates_For_Type_And_Id    ${type}    ${id}    ${member_index}    http_timeout=${http_timeout}
 257     # Owners must be same, if not, there is still some election or change ownership in progress
 258     BuiltIn.Should_Be_Equal_As_Integers    ${owner_1}    ${owner_2}    Owners for device ${device_name} are not same
 259     [Return]    ${owner_1}    ${candidate_list_1}
 260
 261 Get_Owner_And_Candidates_For_Device
 262     [Arguments]    ${device_name}    ${device_type}    ${member_index}    ${http_timeout}=${EMPTY}
 263     [Documentation]    Returns the owner and a list of candidates for the SB device ${device_name} of type ${device_type}. Request is sent to member ${member_index}.
 264     ...    If parsing as singleton failed, kw try to parse data in old way (without singleton).
 265     ...    Candidates are all members that register to own a device, so the list of candiates includes the owner.
 266     ...    The returned candidate list is sorted numerically.
 267     ...    Note that "candidate list" definition currently differs between Beryllium and Boron.
 268     ...    It is recommended to use Get_Owner_And_Successors_For_Device instead of this keyword, see documentation there.
 269     # Try singleton
 270     ${status}    ${results} =    BuiltIn.Run_Keyword_And_Ignore_Error    Get_Owner_And_Candidates_For_Device_Singleton    device_name=${device_name}    device_type=${device_type}    member_index=${member_index}
 271     ...    http_timeout=${http_timeout}
 272     BuiltIn.Return_From_Keyword_If    "${status}"=="PASS"    ${results}
 273     # If singleton failed, try parsing in old way
 274     ${status}    ${results} =    BuiltIn.Run_Keyword_And_Ignore_Error    Get_Owner_And_Candidates_For_Device_Old    device_name=${device_name}    device_type=${device_type}    member_index=${member_index}
 275     ...    http_timeout=${http_timeout}
 276     # previous 3 lines (BuilIn.Return.., # If singleton..., ${status}....) could be deleted when old way will not be supported anymore
 277     BuiltIn.Run_Keyword_If    '${status}'=='FAIL'    BuiltIn.Fail    Could not parse owner and candidates for device ${device_name}
 278     [Return]    @{results}
 279
 280 Check_Old_Owner_Stays_Elected_For_Device
 281     [Arguments]    ${device_name}    ${device_type}    ${old_owner}    ${node_to_ask}    ${http_timeout}=${EMPTY}
 282     [Documentation]    Verify the owner remain the same as ${old_owner}
 283     ${owner}    ${candidates} =    Get_Owner_And_Candidates_For_Device    ${device_name}    ${device_type}    ${node_to_ask}    http_timeout=${http_timeout}
 284     BuiltIn.Should_Be_Equal_As_numbers    ${old_owner}    ${owner}
 285     BuiltIn.Return_From_Keyword    ${owner}    ${candidates}
 286
 287 Check_New_Owner_Got_Elected_For_Device
 288     [Arguments]    ${device_name}    ${device_type}    ${old_owner}    ${node_to_ask}    ${http_timeout}=${EMPTY}
 289     [Documentation]    Verify new owner was elected comparing to ${old_owner}
 290     ${owner}    ${candidates} =    Get_Owner_And_Candidates_For_Device    ${device_name}    ${device_type}    ${node_to_ask}    http_timeout=${http_timeout}
 291     BuiltIn.Should_Not_Be_Equal_As_Numbers    ${old_owner}    ${owner}
 292     BuiltIn.Return_From_Keyword    ${owner}    ${candidates}
 293
 294 Get_Owner_And_Candidates_For_Type_And_Id
 295     [Arguments]    ${type}    ${id}    ${member_index}    ${require_candidate_list}=${EMPTY}    ${http_timeout}=${EMPTY}
 296     [Documentation]    Returns the owner and a list of candidates for entity specified by ${type} and ${id}
 297     ...    Request is sent to member ${member_index}.
 298     ...    Candidates are all members that register to own a device, so the list of candiates includes the owner.
 299     ...    Bear in mind that for Boron and beyond, candidates are not removed on node down or isolation.
 300     ...    If ${require_candidate_list} is not \${EMPTY}, check whether the actual list of candidates matches.
 301     ...    Note that differs from "given list" semantics used in other keywords,
 302     ...    namely you cannot use \${EMPTY} to stand for "full list" in this keyword.
 303     BuiltIn.Comment    TODO: Find a way to unify and deduplicate code blocks in Get_Owner_And_Candidates_* keywords.
 304     ${session} =    Resolve_Http_Session_For_Member    member_index=${member_index}
 305     ${data} =    TemplatedRequests.Get_As_Json_From_Uri    uri=${ENTITY_OWNER_URI}    session=${session}    http_timeout=${http_timeout}
 306     ${candidate_list} =    BuiltIn.Create_List
 307     ${json} =    RequestsLibrary.To_Json    ${data}
 308     ${entity_type_list} =    Collections.Get_From_Dictionary    &{json}[entity-owners]    entity-type
 309     ${entity_type_index} =    Utils.Get_Index_From_List_Of_Dictionaries    ${entity_type_list}    type    ${type}
 310     BuiltIn.Should_Not_Be_Equal_As_Integers    ${entity_type_index}    -1    No Entity Owner found for ${type}
 311     ${entity_list} =    Collections.Get_From_Dictionary    @{entity_type_list}[${entity_type_index}]    entity
 312     ${entity_index} =    Utils.Get_Index_From_List_Of_Dictionaries    ${entity_list}    id    ${id}
 313     BuiltIn.Should Not_Be_Equal_As_Integers    ${entity_index}    -1    Id ${id} not found in Entity Owner ${type}
 314     ${entity_owner} =    Collections.Get_From_Dictionary    @{entity_list}[${entity_index}]    owner
 315     BuiltIn.Should_Not_Be_Empty    ${entity_owner}    No owner found for type=${type} id=${id}
 316     ${owner} =    String.Replace_String    ${entity_owner}    member-    ${EMPTY}
 317     ${owner} =    BuiltIn.Convert_To_Integer    ${owner}
 318     ${entity_candidates_list} =    Collections.Get_From_Dictionary    @{entity_list}[${entity_index}]    candidate
 319     : FOR    ${entity_candidate}    IN    @{entity_candidates_list}
 320     \    ${candidate} =    String.Replace_String    &{entity_candidate}[name]    member-    ${EMPTY}
 321     \    ${candidate} =    BuiltIn.Convert_To_Integer    ${candidate}
 322     \    Collections.Append_To_List    ${candidate_list}    ${candidate}
 323     Collections.Sort_List    ${candidate_list}
 324     BuiltIn.Comment    TODO: Separate check lines into Verify_Owner_And_Candidates_For_Type_And_Id
 325     BuiltIn.Run_Keyword_If    """${require_candidate_list}"""    BuiltIn.Should_Be_Equal    ${require_candidate_list}    ${candidate_list}    Candidate list does not match: ${candidate_list} is not ${require_candidate_list}
 326     [Return]    ${owner}    ${candidate_list}
 327
 328 Extract_Service_Entity_Type
 329     [Arguments]    ${data}
 330     [Documentation]    Remove superfluous device data from Entity Owner printout.
 331     ${clear_data} =    String.Replace_String    ${data}    /odl-general-entity:entity[odl-general-entity:name='    ${EMPTY}
 332     ${clear_data} =    String.Replace_String    ${clear_data}    -service-group']    ${EMPTY}
 333     Log    ${clear_data}
 334     [Return]    ${clear_data}
 335
 336 Extract_OpenFlow_Device_Data
 337     [Arguments]    ${data}
 338     [Documentation]    Remove superfluous OpenFlow device data from Entity Owner printout.
 339     ${clear_data} =    String.Replace_String    ${data}    org.opendaylight.mdsal.ServiceEntityType    openflow
 340     ${clear_data} =    String.Replace_String    ${clear_data}    /odl-general-entity:entity[odl-general-entity:name='    ${EMPTY}
 341     ${clear_data} =    String.Replace_String    ${clear_data}    /general-entity:entity[general-entity:name='    ${EMPTY}
 342     ${clear_data} =    String.Replace_String    ${clear_data}    ']    ${EMPTY}
 343     Log    ${clear_data}
 344     [Return]    ${clear_data}
 345
 346 Extract_Ovsdb_Device_Data
 347     [Arguments]    ${data}
 348     [Documentation]    Remove superfluous OVSDB device data from Entity Owner printout.
 349     ${clear_data} =    String.Replace_String    ${data}    /network-topology:network-topology/network-topology:topology[network-topology:topology-id='ovsdb:1']/network-topology:node[network-topology:node-id='    ${EMPTY}
 350     ${clear_data} =    String.Replace_String    ${clear_data}    ']    ${EMPTY}
 351     Log    ${clear_data}
 352     [Return]    ${clear_data}
 353
 354 Kill_Single_Member
 355     [Arguments]    ${member}    ${original_index_list}=${EMPTY}    ${confirm}=True
 356     [Documentation]    Convenience keyword that kills the specified member of the cluster.
 357     ...    The KW will return a list of available members: \${updated index_list}=\${original_index_list}-\${member}
 358     ${index_list} =    ClusterManagement__Build_List    ${member}
 359     ${member_ip} =    Return_Member_IP    ${member}
 360     KarafKeywords.Log_Message_To_Controller_Karaf    Killing ODL${member} ${member_ip}
 361     ${updated_index_list} =    Kill_Members_From_List_Or_All    ${index_list}    ${original_index_list}    ${confirm}
 362     [Return]    ${updated_index_list}
 363
 364 Kill_Members_From_List_Or_All
 365     [Arguments]    ${member_index_list}=${EMPTY}    ${original_index_list}=${EMPTY}    ${confirm}=True
 366     [Documentation]    If the list is empty, kill all ODL instances. Otherwise, kill members based on \${kill_index_list}
 367     ...    If \${confirm} is True, sleep 1 second and verify killed instances are not there anymore.
 368     ...    The KW will return a list of available members: \${updated index_list}=\${original_index_list}-\${member_index_list}
 369     ${kill_index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 370     ${index_list} =    List_Indices_Or_All    given_list=${original_index_list}
 371     Run_Bash_Command_On_List_Or_All    command=${NODE_KILL_COMMAND}    member_index_list=${member_index_list}
 372     ${updated_index_list} =    BuiltIn.Create_List    @{index_list}
 373     Collections.Remove_Values_From_List    ${updated_index_list}    @{kill_index_list}
 374     BuiltIn.Return_From_Keyword_If    not ${confirm}    ${updated_index_list}
 375     # TODO: Convert to WUKS with configurable timeout if it turns out 1 second is not enough.
 376     BuiltIn.Sleep    1s    Kill -9 closes open files, which may take longer than ssh overhead, but not long enough to warrant WUKS.
 377     : FOR    ${index}    IN    @{kill_index_list}
 378     \    Verify_Karaf_Is_Not_Running_On_Member    member_index=${index}
 379     [Return]    ${updated_index_list}
 380
 381 Stop_Single_Member
 382     [Arguments]    ${member}    ${original_index_list}=${EMPTY}    ${confirm}=True
 383     [Documentation]    Convenience keyword that stops the specified member of the cluster.
 384     ...    The KW will return a list of available members: \${updated index_list}=\${original_index_list}-\${member}
 385     ${index_list} =    ClusterManagement__Build_List    ${member}
 386     ${updated_index_list} =    Stop_Members_From_List_Or_All    ${index_list}    ${original_index_list}    ${confirm}
 387     [Return]    ${updated_index_list}
 388
 389 Stop_Members_From_List_Or_All
 390     [Arguments]    ${member_index_list}=${EMPTY}    ${original_index_list}=${EMPTY}    ${confirm}=True    ${timeout}=120s
 391     [Documentation]    If the list is empty, stops all ODL instances. Otherwise stop members based on \${stop_index_list}
 392     ...    If \${confirm} is True, verify stopped instances are not there anymore.
 393     ...    The KW will return a list of available members: \${updated index_list}=\${original_index_list}-\${member_index_list}
 394     ${stop_index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 395     ${index_list} =    List_Indices_Or_All    given_list=${original_index_list}
 396     Run_Bash_Command_On_List_Or_All    command=${NODE_STOP_COMMAND}    member_index_list=${member_index_list}
 397     ${updated_index_list} =    BuiltIn.Create_List    @{index_list}
 398     Collections.Remove_Values_From_List    ${updated_index_list}    @{stop_index_list}
 399     BuiltIn.Return_From_Keyword_If    not ${confirm}    ${updated_index_list}
 400     : FOR    ${index}    IN    @{stop_index_list}
 401     \    BuiltIn.Wait Until Keyword Succeeds    ${timeout}    2s    Verify_Karaf_Is_Not_Running_On_Member    member_index=${index}
 402     [Return]    ${updated_index_list}
 403
 404 Start_Single_Member
 405     [Arguments]    ${member}    ${wait_for_sync}=True    ${timeout}=300s
 406     [Documentation]    Convenience keyword that starts the specified member of the cluster.
 407     ${index_list} =    ClusterManagement__Build_List    ${member}
 408     Start_Members_From_List_Or_All    ${index_list}    ${wait_for_sync}    ${timeout}
 409
 410 Start_Members_From_List_Or_All
 411     [Arguments]    ${member_index_list}=${EMPTY}    ${wait_for_sync}=True    ${timeout}=300s    ${karaf_home}=${EMPTY}    ${export_java_home}=${EMPTY}    ${gc_log_dir}=${EMPTY}
 412     [Documentation]    If the list is empty, start all cluster members. Otherwise, start members based on present indices.
 413     ...    If ${wait_for_sync}, wait for cluster sync on listed members.
 414     ...    Optionally karaf_home can be overriden. Optionally specific JAVA_HOME is used for starting.
 415     ...    Garbage collection is unconditionally logged to files. TODO: Make that reasonable conditional?
 416     ${base_command} =    BuiltIn.Set_Variable_If    """${karaf_home}""" != ""    ${karaf_home}/bin/start    ${NODE_START_COMMAND}
 417     ${command} =    BuiltIn.Set_Variable_If    """${export_java_home}""" != ""    export JAVA_HOME="${export_java_home}"; ${base_command}    ${base_command}
 418     ${epoch} =    DateTime.Get_Current_Date    time_zone=UTC    result_format=epoch    exclude_millis=False
 419     ${gc_filepath} =    BuiltIn.Set_Variable_If    """${karaf_home}""" != ""    ${karaf_home}/data/log/gc_${epoch}.log    ${GC_LOG_PATH}/gc_${epoch}.log
 420     ${gc_options} =    BuiltIn.Set_Variable    -XX:+PrintGCDetails -XX:+PrintGCDateStamps -Xloggc:${gc_filepath}
 421     Run_Bash_Command_On_List_Or_All    command=${command} ${gc_options}    member_index_list=${member_index_list}
 422     BuiltIn.Return_From_Keyword_If    not ${wait_for_sync}
 423     BuiltIn.Wait_Until_Keyword_Succeeds    ${timeout}    10s    Check_Cluster_Is_In_Sync    member_index_list=${member_index_list}
 424     # TODO: Do we also want to check Shard Leaders here?
 425
 426 Freeze_Single_Member
 427     [Arguments]    ${member}
 428     [Documentation]    Convenience keyword that stops the specified member of the cluster by freezing the jvm.
 429     ${index_list} =    ClusterManagement__Build_List    ${member}
 430     Freeze_Or_Unfreeze_Members_From_List_Or_All    ${NODE_FREEZE_COMMAND}    ${index_list}
 431
 432 Unfreeze_Single_Member
 433     [Arguments]    ${member}    ${wait_for_sync}=True    ${timeout}=60s
 434     [Documentation]    Convenience keyword that "continues" the specified member of the cluster by unfreezing the jvm.
 435     ${index_list} =    ClusterManagement__Build_List    ${member}
 436     Freeze_Or_Unfreeze_Members_From_List_Or_All    ${NODE_UNFREEZE_COMMAND}    ${index_list}
 437     BuiltIn.Wait_Until_Keyword_Succeeds    ${timeout}    10s    Check_Cluster_Is_In_Sync
 438
 439 Freeze_Or_Unfreeze_Members_From_List_Or_All
 440     [Arguments]    ${command}    ${member_index_list}=${EMPTY}
 441     [Documentation]    If the list is empty, stops/runs all ODL instances. Otherwise stop/run members based on \${stop_index_list}
 442     ...    For command parameter only ${NODE_FREEZE_COMMAND} and ${NODE_UNFREEZE_COMMAND} should be used
 443     ${freeze_index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 444     Run_Bash_Command_On_List_Or_All    command=${command}    member_index_list=${member_index_list}
 445
 446 Clean_Journals_And_Snapshots_On_List_Or_All
 447     [Arguments]    ${member_index_list}=${EMPTY}    ${karaf_home}=${KARAF_HOME}
 448     [Documentation]    Delete journal and snapshots directories on every node listed (or all).
 449     ...    BEWARE: If only a subset of members is cleaned, this causes RetiredGenerationException in Carbon after the affected node re-start.
 450     ...    See https://bugs.opendaylight.org/show_bug.cgi?id=8138
 451     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 452     ${command} =    Set Variable    rm -rf "${karaf_home}/journal" "${karaf_home}/snapshots"
 453     : FOR    ${index}    IN    @{index_list}    # usually: 1, 2, 3.
 454     \    Run_Bash_Command_On_Member    command=${command}    member_index=${index}
 455
 456 Verify_Karaf_Is_Not_Running_On_Member
 457     [Arguments]    ${member_index}
 458     [Documentation]    Fail if non-zero karaf instances are counted on member of given index.
 459     ${count} =    Count_Running_Karafs_On_Member    member_index=${member_index}
 460     BuiltIn.Should_Be_Equal    0    ${count}    Found running Karaf count: ${count}
 461
 462 Verify_Single_Karaf_Is_Running_On_Member
 463     [Arguments]    ${member_index}
 464     [Documentation]    Fail if number of karaf instances on member of given index is not one.
 465     ${count} =    Count_Running_Karafs_On_Member    member_index=${member_index}
 466     BuiltIn.Should_Be_Equal    1    ${count}    Wrong number of Karafs running: ${count}
 467
 468 Count_Running_Karafs_On_Member
 469     [Arguments]    ${member_index}
 470     [Documentation]    Remotely execute grep for karaf process, return count as string.
 471     ${command} =    BuiltIn.Set_Variable    ps axf | grep org.apache.karaf | grep -v grep | wc -l
 472     ${count} =    Run_Bash_Command_On_Member    command=${command}    member_index=${member_index}
 473     [Return]    ${count}
 474
 475 Isolate_Member_From_List_Or_All
 476     [Arguments]    ${isolate_member_index}    ${member_index_list}=${EMPTY}
 477     [Documentation]    If the list is empty, isolate member from all ODL instances. Otherwise, isolate member based on present indices.
 478     ...    The KW will return a list of available members: \${updated index_list}=\${member_index_list}-\${isolate_member_index}
 479     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 480     ${source} =    Collections.Get_From_Dictionary    ${ClusterManagement__index_to_ip_mapping}    ${isolate_member_index}
 481     : FOR    ${index}    IN    @{index_list}
 482     \    ${destination} =    Collections.Get_From_Dictionary    ${ClusterManagement__index_to_ip_mapping}    ${index}
 483     \    ${command} =    BuiltIn.Set_Variable    sudo /sbin/iptables -I OUTPUT -p all --source ${source} --destination ${destination} -j DROP
 484     \    BuiltIn.Run_Keyword_If    "${index}" != "${isolate_member_index}"    Run_Bash_Command_On_Member    command=${command}    member_index=${isolate_member_index}
 485     ${command} =    BuiltIn.Set_Variable    sudo /sbin/iptables -L -n
 486     ${output} =    Run_Bash_Command_On_Member    command=${command}    member_index=${isolate_member_index}
 487     BuiltIn.Log    ${output}
 488     ${updated_index_list} =    BuiltIn.Create_List    @{index_list}
 489     Collections.Remove_Values_From_List    ${updated_index_list}    ${isolate_member_index}
 490     [Return]    ${updated_index_list}
 491
 492 Rejoin_Member_From_List_Or_All
 493     [Arguments]    ${rejoin_member_index}    ${member_index_list}=${EMPTY}
 494     [Documentation]    If the list is empty, rejoin member from all ODL instances. Otherwise, rejoin member based on present indices.
 495     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 496     ${source} =    Collections.Get_From_Dictionary    ${ClusterManagement__index_to_ip_mapping}    ${rejoin_member_index}
 497     : FOR    ${index}    IN    @{index_list}
 498     \    ${destination} =    Collections.Get_From_Dictionary    ${ClusterManagement__index_to_ip_mapping}    ${index}
 499     \    ${command} =    BuiltIn.Set_Variable    sudo /sbin/iptables -D OUTPUT -p all --source ${source} --destination ${destination} -j DROP
 500     \    BuiltIn.Run_Keyword_If    "${index}" != "${rejoin_member_index}"    Run_Bash_Command_On_Member    command=${command}    member_index=${rejoin_member_index}
 501     ${command} =    BuiltIn.Set_Variable    sudo /sbin/iptables -L -n
 502     ${output} =    Run_Bash_Command_On_Member    command=${command}    member_index=${rejoin_member_index}
 503     BuiltIn.Log    ${output}
 504
 505 Flush_Iptables_From_List_Or_All
 506     [Arguments]    ${member_index_list}=${EMPTY}
 507     [Documentation]    If the list is empty, flush IPTables in all ODL instances. Otherwise, flush member based on present indices.
 508     ${command} =    BuiltIn.Set_Variable    sudo iptables -v -F
 509     ${output} =    Run_Bash_Command_On_List_Or_All    command=${command}    member_index_list=${member_index_list}
 510
 511 Check_Bash_Command_On_List_Or_All
 512     [Arguments]    ${command}    ${member_index_list}=${EMPTY}    ${return_success_only}=False    ${log_on_success}=True    ${log_on_failure}=True    ${stderr_must_be_empty}=True
 513     [Documentation]    Cycle through indices (or all), run bash command on each, using temporary SSH session and restoring the previously active one.
 514     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 515     : FOR    ${index}    IN    @{index_list}
 516     \    Check_Bash_Command_On_Member    command=${command}    member_index=${index}    return_success_only=${return_success_only}    log_on_success=${log_on_success}    log_on_failure=${log_on_failure}
 517     \    ...    stderr_must_be_empty=${stderr_must_be_empty}
 518
 519 Check_Bash_Command_On_Member
 520     [Arguments]    ${command}    ${member_index}    ${return_success_only}=False    ${log_on_success}=True    ${log_on_failure}=True    ${stderr_must_be_empty}=True
 521     [Documentation]    Open SSH session, call SSHKeywords.Execute_Command_Passes, close session, restore previously active session and return output.
 522     BuiltIn.Run_Keyword_And_Return    SSHKeywords.Run_Keyword_Preserve_Connection    Check_Unsafely_Bash_Command_On_Member    ${command}    ${member_index}    return_success_only=${return_success_only}    log_on_success=${log_on_success}
 523     ...    log_on_failure=${log_on_failure}    stderr_must_be_empty=${stderr_must_be_empty}
 524
 525 Check_Unsafely_Bash_Command_On_Member
 526     [Arguments]    ${command}    ${member_index}    ${return_success_only}=False    ${log_on_success}=True    ${log_on_failure}=True    ${stderr_must_be_empty}=True
 527     [Documentation]    Obtain Ip address, open session, call SSHKeywords.Execute_Command_Passes, close session and return output. This affects which SSH session is active.
 528     ${member_ip} =    Resolve_Ip_Address_For_Member    ${member_index}
 529     BuiltIn.Run_Keyword_And_Return    SSHKeywords.Run_Unsafely_Keyword_Over_Temporary_Odl_Session    ${member_ip}    Execute_Command_Passes    ${command}    return_success_only=${return_success_only}    log_on_success=${log_on_success}
 530     ...    log_on_failure=${log_on_failure}    stderr_must_be_empty=${stderr_must_be_empty}
 531
 532 Run_Bash_Command_On_List_Or_All
 533     [Arguments]    ${command}    ${member_index_list}=${EMPTY}
 534     [Documentation]    Cycle through indices (or all), run command on each.
 535     # TODO: Migrate callers to Check_Bash_Command_*
 536     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 537     : FOR    ${index}    IN    @{index_list}
 538     \    Run_Bash_Command_On_Member    command=${command}    member_index=${index}
 539
 540 Run_Bash_Command_On_Member
 541     [Arguments]    ${command}    ${member_index}
 542     [Documentation]    Obtain IP, call Utils and return output. This keeps previous ssh session active.
 543     # TODO: Migrate callers to Check_Bash_Command_*
 544     ${member_ip} =    Collections.Get_From_Dictionary    dictionary=${ClusterManagement__index_to_ip_mapping}    key=${member_index}
 545     ${output} =    SSHKeywords.Run_Keyword_Preserve_Connection    Utils.Run_Command_On_Controller    ${member_ip}    ${command}
 546     [Return]    ${output}
 547
 548 Run_Karaf_Command_On_List_Or_All
 549     [Arguments]    ${command}    ${member_index_list}=${EMPTY}    ${timeout}=10s
 550     [Documentation]    Cycle through indices (or all), run karaf command on each.
 551     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 552     : FOR    ${index}    IN    @{index_list}
 553     \    ${member_ip} =    Collections.Get_From_Dictionary    dictionary=${ClusterManagement__index_to_ip_mapping}    key=${index}
 554     \    KarafKeywords.Safe_Issue_Command_On_Karaf_Console    ${command}    ${member_ip}    timeout=${timeout}
 555
 556 Run_Karaf_Command_On_Member
 557     [Arguments]    ${command}    ${member_index}    ${timeout}=10s
 558     [Documentation]    Obtain IP address, call KarafKeywords and return output. This does not preserve active ssh session.
 559     ...    This keyword is not used by Run_Karaf_Command_On_List_Or_All, but returned output may be useful.
 560     ${member_ip} =    Collections.Get_From_Dictionary    dictionary=${ClusterManagement__index_to_ip_mapping}    key=${member_index}
 561     ${output} =    KarafKeywords.Safe_Issue_Command_On_Karaf_Console    ${command}    controller=${member_ip}    timeout=${timeout}
 562     [Return]    ${output}
 563
 564 Install_Feature_On_List_Or_All
 565     [Arguments]    ${feature_name}    ${member_index_list}=${EMPTY}    ${timeout}=60s
 566     [Documentation]    Attempt installation on each member from list (or all). Then look for failures.
 567     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 568     ${status_list} =    BuiltIn.Create_List
 569     : FOR    ${index}    IN    @{index_list}
 570     \    ${status}    ${text} =    BuiltIn.Run_Keyword_And_Ignore_Error    Install_Feature_On_Member    feature_name=${feature_name}    member_index=${index}
 571     \    ...    timeout=${timeout}
 572     \    BuiltIn.Log    ${text}
 573     \    Collections.Append_To_List    ${status_list}    ${status}
 574     : FOR    ${status}    IN    @{status_list}
 575     \    BuiltIn.Run_Keyword_If    "${status}" != "PASS"    BuiltIn.Fail    ${feature_name} installation failed, see log.
 576
 577 Install_Feature_On_Member
 578     [Arguments]    ${feature_name}    ${member_index}    ${timeout}=60s
 579     [Documentation]    Run feature:install karaf command, fail if installation was not successful. Return output.
 580     ${status}    ${output} =    BuiltIn.Run_Keyword_And_Ignore_Error    Run_Karaf_Command_On_Member    command=feature:install ${feature_name}    member_index=${member_index}    timeout=${timeout}
 581     BuiltIn.Run_Keyword_If    "${status}" != "PASS"    BuiltIn.Fail    Failed to install ${feature_name}: ${output}
 582     BuiltIn.Should_Not_Contain    ${output}    Can't install    Failed to install ${feature_name}: ${output}
 583     [Return]    ${output}
 584
 585 With_Ssh_To_List_Or_All_Run_Keyword
 586     [Arguments]    ${member_index_list}    ${keyword_name}    @{args}    &{kwargs}
 587     [Documentation]    For each index in given list (or all): activate SSH connection, run given Keyword, close active connection. Return None.
 588     ...    Beware that in order to avoid "got positional argument after named arguments", first two arguments in the call should not be named.
 589     BuiltIn.Comment    This keyword is experimental and there is high risk of being replaced by another approach.
 590     # TODO: For_Index_From_List_Or_All_Run_Keyword applied to With_Ssh_To_Member_Run_Keyword?
 591     # TODO: Imagine another keyword, using ScalarClosures and adding member index as first argument for each call. Worth it?
 592     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 593     : FOR    ${member_index}    IN    @{index_list}
 594     \    ${member_ip} =    Resolve_IP_Address_For_Member    ${member_index}
 595     \    SSHKeywords.Run_Unsafely_Keyword_Over_Temporary_Odl_Session    ${member_ip}    ${keyword_name}    @{args}    &{kwargs}
 596
 597 Safe_With_Ssh_To_List_Or_All_Run_Keyword
 598     [Arguments]    ${member_index_list}    ${keyword_name}    @{args}    &{kwargs}
 599     [Documentation]    Remember active ssh connection index, call With_Ssh_To_List_Or_All_Run_Keyword, return None. Restore the conection index on teardown.
 600     SSHKeywords.Run_Keyword_Preserve_Connection    With_Ssh_To_List_Or_All_Run_Keyword    ${member_index_list}    ${keyword_name}    @{args}    &{kwargs}
 601
 602 Clean_Directories_On_List_Or_All
 603     [Arguments]    ${member_index_list}=${EMPTY}    ${directory_list}=${EMPTY}    ${karaf_home}=${KARAF_HOME}    ${tmp_dir}=${EMPTY}
 604     [Documentation]    Clear @{directory_list} or @{ODL_DEFAULT_DATA_PATHS} for members in given list or all. Return None.
 605     ...    If \${tmp_dir} is nonempty, use that location to preserve data/log/.
 606     ...    This is intended to return Karaf (offline) to the state it was upon the first boot.
 607     ${path_list} =    Builtin.Set Variable If    "${directory_list}" == "${EMPTY}"    ${ODL_DEFAULT_DATA_PATHS}    ${directory_list}
 608     BuiltIn.Run_Keyword_If    """${tmp_dir}""" != ""    Check_Bash_Command_On_List_Or_All    mkdir -p '${tmp_dir}' && rm -vrf '${tmp_dir}/log' && mv -vf '${karaf_home}/data/log' '${tmp_dir}/'    ${member_index_list}
 609     Safe_With_Ssh_To_List_Or_All_Run_Keyword    ${member_index_list}    ClusterManagement__Clean_Directories    ${path_list}    ${karaf_home}
 610     BuiltIn.Run_Keyword_If    """${tmp_dir}""" != ""    Check_Bash_Command_On_List_Or_All    mkdir -p '${karaf_home}/data' && rm -vrf '${karaf_home}/log' && mv -vf '${tmp_dir}/log' '${karaf_home}/data/'    ${member_index_list}
 611
 612 Store_Karaf_Log_On_List_Or_All
 613     [Arguments]    ${member_index_list}=${EMPTY}    ${dst_dir}=/tmp    ${karaf_home}=${KARAF_HOME}
 614     [Documentation]    Saves karaf.log to the ${dst_dir} for members in given list or all. Return None.
 615     Safe_With_Ssh_To_List_Or_All_Run_Keyword    ${member_index_list}    SSHKeywords.Execute_Command_Should_Pass    cp ${karaf_home}/data/log/karaf.log ${dst_dir}
 616
 617 Restore_Karaf_Log_On_List_Or_All
 618     [Arguments]    ${member_index_list}=${EMPTY}    ${src_dir}=/tmp    ${karaf_home}=${KARAF_HOME}
 619     [Documentation]    Places stored karaf.log to the ${karaf_home}/data/log for members in given list or all. Return None.
 620     Safe_With_Ssh_To_List_Or_All_Run_Keyword    ${member_index_list}    SSHKeywords.Execute_Command_Should_Pass    cp ${src_dir}/karaf.log ${karaf_home}/data/log/
 621
 622 ClusterManagement__Clean_Directories
 623     [Arguments]    ${relative_path_list}    ${karaf_home}
 624     [Documentation]    For each relative path, remove files with respect to ${karaf_home}. Return None.
 625     : FOR    ${relative_path}    IN    @{relative_path_list}
 626     \    SSHLibrary.Execute_Command    rm -rf ${karaf_home}${/}${relative_path}
 627
 628 Put_As_Json_And_Check_Member_List_Or_All
 629     [Arguments]    ${uri}    ${data}    ${member_index}    ${member_index_list}=${EMPTY}
 630     [Documentation]    Send a PUT with the supplied uri ${uri} and body ${data} to member ${member_index}.
 631     ...    Then check data is replicated in all or some members defined in ${member_index_list}.
 632     ${response_text} =    Put_As_Json_To_Member    uri=${uri}    data=${data}    member_index=${member_index}
 633     Wait Until Keyword Succeeds    5s    1s    Check_Json_Member_List_Or_All    uri=${uri}    expected_data=${data}    member_index_list=${member_index_list}
 634     [Return]    ${response_text}
 635
 636 Put_As_Json_To_Member
 637     [Arguments]    ${uri}    ${data}    ${member_index}
 638     [Documentation]    Send a PUT with the supplied uri and data to member ${member_index}.
 639     ${session} =    Resolve_Http_Session_For_Member    member_index=${member_index}
 640     ${response_text} =    TemplatedRequests.Put_As_Json_To_Uri    uri=${uri}    data=${data}    session=${session}
 641     [Return]    ${response_text}
 642
 643 Post_As_Json_To_Member
 644     [Arguments]    ${uri}    ${data}    ${member_index}
 645     [Documentation]    Send a POST with the supplied uri and data to member ${member_index}.
 646     ${session} =    Resolve_Http_Session_For_Member    member_index=${member_index}
 647     ${response_text} =    TemplatedRequests.Post_As_Json_To_Uri    uri=${uri}    data=${data}    session=${session}
 648     [Return]    ${response_text}
 649
 650 Delete_And_Check_Member_List_Or_All
 651     [Arguments]    ${uri}    ${member_index}    ${member_index_list}=${EMPTY}
 652     [Documentation]    Send a DELETE with the supplied uri to the member ${member_index}.
 653     ...    Then check the data is removed from all members in ${member_index_list}.
 654     ${response_text} =    Delete_From_Member    ${uri}    ${member_index}
 655     BuiltIn.Wait_Until_Keyword_Succeeds    5s    1s    Check_No_Content_Member_List_Or_All    uri=${uri}    member_index_list=${member_index_list}
 656     [Return]    ${response_text}
 657
 658 Delete_From_Member
 659     [Arguments]    ${uri}    ${member_index}
 660     [Documentation]    Send a DELETE with the supplied uri to member ${member_index}.
 661     ${session} =    Resolve_Http_Session_For_Member    member_index=${member_index}
 662     ${response_text} =    TemplatedRequests.Delete_From_Uri    uri=${uri}    session=${session}
 663     [Return]    ${response_text}
 664
 665 Check_Json_Member_List_Or_All
 666     [Arguments]    ${uri}    ${expected_data}    ${member_index_list}=${EMPTY}
 667     [Documentation]    Send a GET with the supplied uri to all or some members defined in ${member_index_list}.
 668     ...    Then check received data is = ${expected data}.
 669     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 670     : FOR    ${index}    IN    @{index_list}
 671     \    ${data} =    Get_From_Member    uri=${uri}    member_index=${index}
 672     \    TemplatedRequests.Normalize_Jsons_And_Compare    ${expected_data}    ${data}
 673
 674 Check_Item_Occurrence_Member_List_Or_All
 675     [Arguments]    ${uri}    ${dictionary}    ${member_index_list}=${EMPTY}
 676     [Documentation]    Send a GET with the supplied uri to all or some members defined in ${member_index_list}.
 677     ...    Then check received for occurrences of items expressed in a dictionary ${dictionary}.
 678     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 679     : FOR    ${index}    IN    @{index_list}
 680     \    ${data} =    Get_From_Member    uri=${uri}    member_index=${index}
 681     \    Utils.Check Item Occurrence    ${data}    ${dictionary}
 682
 683 Check_No_Content_Member_List_Or_All
 684     [Arguments]    ${uri}    ${member_index_list}=${EMPTY}
 685     [Documentation]    Send a GET with the supplied uri to all or some members defined in ${member_index_list}.
 686     ...    Then check there is no content.
 687     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 688     : FOR    ${index}    IN    @{index_list}
 689     \    ${session} =    Resolve_Http_Session_For_Member    member_index=${index}
 690     \    Utils.No_Content_From_URI    ${session}    ${uri}
 691
 692 Get_From_Member
 693     [Arguments]    ${uri}    ${member_index}    ${access}=${ACCEPT_EMPTY}
 694     [Documentation]    Send a GET with the supplied uri to member ${member_index}.
 695     ${session} =    Resolve_Http_Session_For_Member    member_index=${member_index}
 696     ${response_text} =    TemplatedRequests.Get_From_Uri    uri=${uri}    accept=${access}    session=${session}
 697     [Return]    ${response_text}
 698
 699 Resolve_IP_Address_For_Member
 700     [Arguments]    ${member_index}
 701     [Documentation]    Return node IP address of given index.
 702     ${ip_address} =    Collections.Get From Dictionary    dictionary=${ClusterManagement__index_to_ip_mapping}    key=${member_index}
 703     [Return]    ${ip_address}
 704
 705 Resolve_IP_Address_For_Members
 706     [Arguments]    ${member_index_list}
 707     [Documentation]    Return a list of IP address of given indexes.
 708     ${member_ip_list} =    BuiltIn.Create_List
 709     : FOR    ${index}    IN    @{member_index_list}
 710     \    ${ip_address} =    Collections.Get From Dictionary    dictionary=${ClusterManagement__index_to_ip_mapping}    key=${index}
 711     \    Collections.Append_To_List    ${member_ip_list}    ${ip_address}
 712     [Return]    ${member_ip_list}
 713
 714 Resolve_Http_Session_For_Member
 715     [Arguments]    ${member_index}
 716     [Documentation]    Return RequestsLibrary session alias pointing to node of given index.
 717     ${session} =    BuiltIn.Set_Variable    ClusterManagement__session_${member_index}
 718     [Return]    ${session}
 719
 720 Resolve_Shard_Type_Class
 721     [Arguments]    ${shard_type}
 722     [Documentation]    Simple lookup for class name corresponding to desired type.
 723     BuiltIn.Run_Keyword_If    '${shard_type}' == 'config'    BuiltIn.Return_From_Keyword    DistributedConfigDatastore
 724     ...    ELSE IF    '${shard_type}' == 'operational'    BuiltIn.Return_From_Keyword    DistributedOperationalDatastore
 725     BuiltIn.Fail    Unrecognized shard type: ${shard_type}
 726
 727 ClusterManagement__Build_List
 728     [Arguments]    ${member}
 729     ${member_int} =    BuiltIn.Convert_To_Integer    ${member}
 730     ${index_list} =    BuiltIn.Create_List    ${member_int}
 731     [Return]    ${index_list}
 732
 733 ClusterManagement__Parse_Sync_Status
 734     [Arguments]    ${shard_manager_text}
 735     [Documentation]    Return sync status parsed out of given text. Called twice by Get_Sync_Status_Of_Member.
 736     BuiltIn.Log    ${shard_manager_text}
 737     ${manager_object} =    RequestsLibrary.To_Json    ${shard_manager_text}
 738     ${value_object} =    Collections.Get_From_Dictionary    dictionary=${manager_object}    key=value
 739     ${sync_status} =    Collections.Get_From_Dictionary    dictionary=${value_object}    key=SyncStatus
 740     [Return]    ${sync_status}
 741
 742 List_All_Indices
 743     [Documentation]    Create a new list of all indices.
 744     BuiltIn.Run_Keyword_And_Return    List_Indices_Or_All
 745
 746 List_Indices_Or_All
 747     [Arguments]    ${given_list}=${EMPTY}
 748     [Documentation]    Utility to allow \${EMPTY} as default argument value, as the internal list is computed at runtime.
 749     ...    This keyword always returns a (shallow) copy of given or default list,
 750     ...    so operations with the returned list should not affect other lists.
 751     ...    Also note that this keyword does not consider empty list to be \${EMPTY}.
 752     ${return_list_reference} =    BuiltIn.Set_Variable_If    """${given_list}""" != ""    ${given_list}    ${ClusterManagement__member_index_list}
 753     ${return_list_copy} =    BuiltIn.Create_List    @{return_list_reference}
 754     [Return]    ${return_list_copy}
 755
 756 List_Indices_Minus_Member
 757     [Arguments]    ${member_index}    ${member_index_list}=${EMPTY}
 758     [Documentation]    Create a new list which contains indices from ${member_index_list} (or all) without ${member_index}.
 759     ${index_list} =    List_Indices_Or_All    ${member_index_list}
 760     Collections.Remove Values From List    ${index_list}    ${member_index}
 761     [Return]    ${index_list}
 762
 763 ClusterManagement__Compute_Derived_Variables
 764     [Arguments]    ${int_of_members}    ${http_timeout}=1    ${http_retries}=0
 765     [Documentation]    Construct index list, session list and IP mapping, publish them as suite variables.
 766     @{member_index_list} =    BuiltIn.Create_List
 767     @{session_list} =    BuiltIn.Create_List
 768     &{index_to_ip_mapping} =    BuiltIn.Create_Dictionary
 769     : FOR    ${index}    IN RANGE    1    ${int_of_members+1}
 770     \    ClusterManagement__Include_Member_Index    ${index}    ${member_index_list}    ${session_list}    ${index_to_ip_mapping}    http_timeout=${http_timeout}
 771     \    ...    http_retries=${http_retries}
 772     BuiltIn.Set_Suite_Variable    \${ClusterManagement__member_index_list}    ${member_index_list}
 773     BuiltIn.Set_Suite_Variable    \${ClusterManagement__index_to_ip_mapping}    ${index_to_ip_mapping}
 774     BuiltIn.Set_Suite_Variable    \${ClusterManagement__session_list}    ${session_list}
 775
 776 ClusterManagement__Include_Member_Index
 777     [Arguments]    ${index}    ${member_index_list}    ${session_list}    ${index_to_ip_mapping}    ${http_timeout}=1    ${http_retries}=0
 778     [Documentation]    Add a corresponding item based on index into the last three arguments.
 779     ...    Create the Http session whose alias is added to list.
 780     Collections.Append_To_List    ${member_index_list}    ${index}
 781     ${member_ip} =    BuiltIn.Set_Variable    ${ODL_SYSTEM_${index}_IP}
 782     # ${index} is int (not string) so "key=value" syntax does not work in the following line.
 783     Collections.Set_To_Dictionary    ${index_to_ip_mapping}    ${index}    ${member_ip}
 784     # Http session, with ${AUTH}, without headers.
 785     ${session_alias} =    Resolve_Http_Session_For_Member    member_index=${index}
 786     RequestsLibrary.Create_Session    ${session_alias}    http://${member_ip}:${RESTCONFPORT}    auth=${AUTH}    timeout=${http_timeout}    max_retries=${http_retries}
 787     Collections.Append_To_List    ${session_list}    ${session_alias}
 788
 789 Sync_Status_Should_Be_False
 790     [Arguments]    ${controller_index}
 791     [Documentation]    Verify that cluster node is not in sync with others
 792     ${status}    Get_Sync_Status_Of_Member    ${controller_index}
 793     BuiltIn.Should_Not_Be_True    ${status}
 794
 795 Sync_Status_Should_Be_True
 796     [Arguments]    ${controller_index}
 797     [Documentation]    Verify that cluster node is in sync with others
 798     ${status}    Get_Sync_Status_Of_Member    ${controller_index}
 799     BuiltIn.Should_Be_True    ${status}
 800
 801 Return_Member_IP
 802     [Arguments]    ${member_index}
 803     [Documentation]    Return the IP address of the member given the member_index.
 804     ${member_int} =    BuiltIn.Convert_To_Integer    ${member_index}
 805     ${member_ip} =    Collections.Get_From_Dictionary    dictionary=${ClusterManagement__index_to_ip_mapping}    key=${member_int}
 806     [Return]    ${member_ip}