csit/libraries/ClusterManagement.robot

   1 *** Settings ***
   2 Documentation     Resource housing Keywords common to several suites for cluster functional testing.
   3 ...
   4 ...               Copyright (c) 2016 Cisco Systems, Inc. and others. All rights reserved.
   5 ...               Copyright (c) 2016 Brocade Communications Systems, Inc. and others. All rights reserved.
   6 ...
   7 ...               This program and the accompanying materials are made available under the
   8 ...               terms of the Eclipse Public License v1.0 which accompanies this distribution,
   9 ...               and is available at http://www.eclipse.org/legal/epl-v10.html
  10 ...
  11 ...
  12 ...               This resource holds private state (in suite variables),
  13 ...               which is generated once at Setup with ClusterManagement_Setup KW.
  14 ...               The state includes member indexes, IP addresses and Http (RequestsLibrary) sessions.
  15 ...               Cluster Keywords normally use member index, member list or nothing (all members) as argument.
  16 ...
  17 ...               All index lists returned should be sorted numerically, fix if not.
  18 ...
  19 ...               Requirements:
  20 ...               odl-jolokia is assumed to be installed.
  21 ...
  22 ...               Keywords are ordered as follows:
  23 ...               - Cluster Setup
  24 ...               - Shard state, leader and followers
  25 ...               - Entity Owner, candidates and successors
  26 ...               - Kill, Stop and Start Member
  27 ...               - Isolate and Rejoin Member
  28 ...               - Run Commands On Member
  29 ...               - REST requests and checks on Members
  30 ...
  31 ...               TODO: Unify capitalization of Leaders and Followers.
  32 Library           RequestsLibrary    # for Create_Session and To_Json
  33 Library           Collections
  34 Resource          ${CURDIR}/CompareStream.robot
  35 Resource          ${CURDIR}/KarafKeywords.robot
  36 Resource          ${CURDIR}/SSHKeywords.robot
  37 Resource          ${CURDIR}/TemplatedRequests.robot    # for Get_As_Json_From_Uri
  38 Resource          ${CURDIR}/Utils.robot    # for Run_Command_On_Controller
  39 Resource          ../variables/Variables.robot
  40
  41 *** Variables ***
  42 ${ENTITY_OWNER_URI}    restconf/operational/entity-owners:entity-owners
  43 ${GC_LOG_PATH}    ${KARAF_HOME}/data/log
  44 ${JAVA_HOME}      ${EMPTY}    # releng/builder scripts should provide correct value
  45 ${JOLOKIA_CONF_SHARD_MANAGER_URI}    jolokia/read/org.opendaylight.controller:Category=ShardManager,name=shard-manager-config,type=DistributedConfigDatastore
  46 ${JOLOKIA_OPER_SHARD_MANAGER_URI}    jolokia/read/org.opendaylight.controller:Category=ShardManager,name=shard-manager-operational,type=DistributedOperationalDatastore
  47 ${JOLOKIA_CONFIG_LOCAL_SHARDS_URI}    jolokia/read/org.opendaylight.controller:type=DistributedConfigDatastore,Category=ShardManager,name=shard-manager-config/LocalShards
  48 ${JOLOKIA_OPER_LOCAL_SHARDS_URI}    jolokia/read/org.opendaylight.controller:type=DistributedOperationalDatastore,Category=ShardManager,name=shard-manager-operational/LocalShards
  49 ${JOLOKIA_READ_URI}    jolokia/read/org.opendaylight.controller
  50 # Bug 9044 workaround: delete etc/host.key before restart.
  51 @{ODL_DEFAULT_DATA_PATHS}    tmp/    data/    cache/    snapshots/    journal/    etc/opendaylight/current/    etc/host.key
  52 ${RESTCONF_MODULES_DIR}    ${CURDIR}/../variables/restconf/modules
  53 ${SINGLETON_NETCONF_DEVICE_ID_PREFIX}    /odl-general-entity:entity[odl-general-entity:name='KeyedInstanceIdentifier{targetType=interface org.opendaylight.yang.gen.v1.urn.tbd.params.xml.ns.yang.network.topology.rev131021.network.topology.topology.Node, path=[org.opendaylight.yang.gen.v1.urn.tbd.params.xml.ns.yang.network.topology.rev131021.NetworkTopology, org.opendaylight.yang.gen.v1.urn.tbd.params.xml.ns.yang.network.topology.rev131021.network.topology.Topology[key=TopologyKey [_topologyId=Uri [_value=topology-netconf]]], org.opendaylight.yang.gen.v1.urn.tbd.params.xml.ns.yang.network.topology.rev131021.network.topology.topology.Node[key=NodeKey [_nodeId=Uri [_value=
  54 ${SINGLETON_NETCONF_DEVICE_ID_SUFFIX}    ]]]]}']
  55 ${SINGLETON_BGPCEP_DEVICE_ID_PREFIX}    /odl-general-entity:entity[odl-general-entity:name='
  56 ${SINGLETON_BGPCEP_DEVICE_ID_SUFFIX}    -service-group']
  57 ${SINGLETON_SXP_DEVICE_ID_PREFIX}    /odl-general-entity:entity[odl-general-entity:name='
  58 ${SINGLETON_SXP_DEVICE_ID_SUFFIX}    ']
  59 ${SINGLETON_ELECTION_ENTITY_TYPE}    org.opendaylight.mdsal.ServiceEntityType
  60 ${SINGLETON_CHANGE_OWNERSHIP_ENTITY_TYPE}    org.opendaylight.mdsal.AsyncServiceCloseEntityType
  61 ${NODE_ROLE_INDEX_START}    1
  62 ${NODE_START_COMMAND}    ${KARAF_HOME}/bin/start
  63 ${NODE_STOP_COMMAND}    ${KARAF_HOME}/bin/stop
  64 ${NODE_KARAF_COUNT_COMMAND}    ps axf | grep org.apache.karaf | grep -v grep | wc -l
  65 ${NODE_KILL_COMMAND}    ps axf | grep org.apache.karaf | grep -v grep | awk '{print \"kill -9 \" $1}' | sh
  66 ${NODE_FREEZE_COMMAND}    ps axf | grep org.apache.karaf | grep -v grep | awk '{print \"kill -STOP \" $1}' | sh
  67 ${NODE_UNFREEZE_COMMAND}    ps axf | grep org.apache.karaf | grep -v grep | awk '{print \"kill -CONT \" $1}' | sh
  68
  69 *** Keywords ***
  70 ClusterManagement_Setup
  71     [Arguments]    ${http_timeout}=${DEFAULT_TIMEOUT_HTTP}    ${http_retries}=0
  72     [Documentation]    Detect repeated call, or detect number of members and initialize derived suite variables.
  73     ...    Http sessions are created with parameters to not waste time when ODL is no accepting connections properly.
  74     # Avoid multiple initialization by several downstream libraries.
  75     ${already_done} =    BuiltIn.Get_Variable_Value    \${ClusterManagement__has_setup_run}    False
  76     BuiltIn.Return_From_Keyword_If    ${already_done}
  77     BuiltIn.Set_Suite_Variable    \${ClusterManagement__has_setup_run}    True
  78     ${cluster_size} =    BuiltIn.Get_Variable_Value    \${NUM_ODL_SYSTEM}    1
  79     ${status}    ${possibly_int_of_members} =    BuiltIn.Run_Keyword_And_Ignore_Error    BuiltIn.Convert_To_Integer    ${cluster_size}
  80     ${int_of_members} =    BuiltIn.Set_Variable_If    '${status}' != 'PASS'    ${1}    ${possibly_int_of_members}
  81     ClusterManagement__Compute_Derived_Variables    int_of_members=${int_of_members}    http_timeout=${http_timeout}    http_retries=${http_retries}
  82
  83 Check_Cluster_Is_In_Sync
  84     [Arguments]    ${member_index_list}=${EMPTY}
  85     [Documentation]    Fail if no-sync is detected on a member from list (or any).
  86     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
  87     : FOR    ${index}    IN    @{index_list}    # usually: 1, 2, 3.
  88     \    ${status} =    Get_Sync_Status_Of_Member    member_index=${index}
  89     \    BuiltIn.Continue_For_Loop_If    'True' == '${status}'
  90     \    BuiltIn.Fail    Index ${index} has incorrect status: ${status}
  91
  92 Get_Sync_Status_Of_Member
  93     [Arguments]    ${member_index}
  94     [Documentation]    Obtain IP, two GETs from jolokia URIs, return combined sync status as string.
  95     ${session} =    Resolve_Http_Session_For_Member    member_index=${member_index}
  96     ${conf_text} =    TemplatedRequests.Get_As_Json_From_Uri    uri=${JOLOKIA_CONF_SHARD_MANAGER_URI}    session=${session}
  97     ${conf_status} =    ClusterManagement__Parse_Sync_Status    shard_manager_text=${conf_text}
  98     BuiltIn.Return_From_Keyword_If    'False' == ${conf_status}    False
  99     ${oper_text} =    TemplatedRequests.Get_As_Json_From_Uri    uri=${JOLOKIA_OPER_SHARD_MANAGER_URI}    session=${session}
 100     ${oper_status} =    ClusterManagement__Parse_Sync_Status    shard_manager_text=${oper_text}
 101     [Return]    ${oper_status}
 102
 103 Verify_Leader_Exists_For_Each_Shard
 104     [Arguments]    ${shard_name_list}    ${shard_type}=operational    ${member_index_list}=${EMPTY}    ${verify_restconf}=True
 105     [Documentation]    For each shard name, call Get_Leader_And_Followers_For_Shard.
 106     ...    Not much logic there, but single Keyword is useful when using BuiltIn.Wait_Until_Keyword_Succeeds.
 107     : FOR    ${shard_name}    IN    @{shard_name_list}
 108     \    Get_Leader_And_Followers_For_Shard    shard_name=${shard_name}    shard_type=${shard_type}    validate=True    member_index_list=${member_index_list}    verify_restconf=${verify_restconf}
 109
 110 Get_Leader_And_Followers_For_Shard
 111     [Arguments]    ${shard_name}=default    ${shard_type}=operational    ${validate}=True    ${member_index_list}=${EMPTY}    ${verify_restconf}=True    ${http_timeout}=${EMPTY}
 112     [Documentation]    Get role lists, validate there is one leader, return the leader and list of followers.
 113     ...    Optionally, issue GET to a simple restconf URL to make sure subsequent operations will not encounter 503.
 114     ${leader_list}    ${follower_list} =    Get_State_Info_For_Shard    shard_name=${shard_name}    shard_type=${shard_type}    validate=True    member_index_list=${member_index_list}
 115     ...    verify_restconf=${verify_restconf}    http_timeout=${http_timeout}
 116     ${leader_count} =    BuiltIn.Get_Length    ${leader_list}
 117     BuiltIn.Run_Keyword_If    ${leader_count} < 1    BuiltIn.Fail    No leader found.
 118     BuiltIn.Length_Should_Be    ${leader_list}    ${1}    Too many Leaders.
 119     ${leader} =    Collections.Get_From_List    ${leader_list}    0
 120     [Return]    ${leader}    ${follower_list}
 121
 122 Get_State_Info_For_Shard
 123     [Arguments]    ${shard_name}=default    ${shard_type}=operational    ${validate}=False    ${member_index_list}=${EMPTY}    ${verify_restconf}=False    ${http_timeout}=${EMPTY}
 124     [Documentation]    Return lists of Leader and Follower member indices from a given member index list
 125     ...    (or from the full list if empty). If \${shard_type} is not 'config', 'operational' is assumed.
 126     ...    If \${validate}, Fail if raft state is not Leader or Follower (for example on Candidate).
 127     ...    The biggest difference from Get_Leader_And_Followers_For_Shard
 128     ...    is that no check on number of Leaders is performed.
 129     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 130     Collections.Sort_List    ${index_list}    # to guarantee return values are also sorted lists
 131     # TODO: Support alternative capitalization of 'config'?
 132     ${ds_type} =    BuiltIn.Set_Variable_If    '${shard_type}' != 'config'    operational    config
 133     ${leader_list} =    BuiltIn.Create_List
 134     ${follower_list} =    BuiltIn.Create_List
 135     : FOR    ${index}    IN    @{index_list}    # usually: 1, 2, 3.
 136     \    ${raft_state} =    Get_Raft_State_Of_Shard_At_Member    shard_name=${shard_name}    shard_type=${ds_type}    member_index=${index}    verify_restconf=${verify_restconf}
 137     \    ...    http_timeout=${http_timeout}
 138     \    BuiltIn.Run_Keyword_If    'Follower' == '${raft_state}'    Collections.Append_To_List    ${follower_list}    ${index}
 139     \    ...    ELSE IF    'Leader' == '${raft_state}'    Collections.Append_To_List    ${leader_list}    ${index}
 140     \    ...    ELSE IF    ${validate}    BuiltIn.Fail    Unrecognized Raft state: ${raft_state}
 141     [Return]    ${leader_list}    ${follower_list}
 142
 143 Get_Raft_State_Of_Shard_At_Member
 144     [Arguments]    ${shard_name}    ${shard_type}    ${member_index}    ${verify_restconf}=False    ${http_timeout}=${EMPTY}
 145     [Documentation]    Send request to Jolokia on indexed member, return extracted Raft status.
 146     ...    Optionally, check restconf works.
 147     ${raft_state} =    Get_Raft_Property_From_Shard_Member    RaftState    ${shard_name}    ${shard_type}    ${member_index}    verify_restconf=${verify_restconf}
 148     ...    http_timeout=${http_timeout}
 149     [Return]    ${raft_state}
 150
 151 Get_Raft_Property_From_Shard_Member
 152     [Arguments]    ${property}    ${shard_name}    ${shard_type}    ${member_index}    ${verify_restconf}=False    ${http_timeout}=${EMPTY}
 153     [Documentation]    Send request to Jolokia on indexed member, return extracted Raft property.
 154     ...    Optionally, check restconf works.
 155     ${session} =    Resolve_Http_Session_For_Member    member_index=${member_index}
 156     # TODO: Does the used URI tend to generate large data which floods log.html?
 157     BuiltIn.Run_Keyword_If    ${verify_restconf}    TemplatedRequests.Get_As_Json_Templated    session=${session}    folder=${RESTCONF_MODULES_DIR}    verify=False    http_timeout=${http_timeout}
 158     ${type_class} =    Resolve_Shard_Type_Class    shard_type=${shard_type}
 159     ${cluster_index} =    Evaluate    ${member_index}+${NODE_ROLE_INDEX_START}-1
 160     ${uri} =    BuiltIn.Set_Variable    ${JOLOKIA_READ_URI}:Category=Shards,name=member-${cluster_index}-shard-${shard_name}-${shard_type},type=${type_class}
 161     ${data_text} =    TemplatedRequests.Get_As_Json_From_Uri    uri=${uri}    session=${session}    http_timeout=${http_timeout}
 162     ${data_object} =    RequestsLibrary.To_Json    ${data_text}
 163     ${value} =    Collections.Get_From_Dictionary    ${data_object}    value
 164     ${raft_property} =    Collections.Get_From_Dictionary    ${value}    ${property}
 165     [Return]    ${raft_property}
 166
 167 Verify_Shard_Leader_Elected
 168     [Arguments]    ${shard_name}    ${shard_type}    ${new_elected}    ${old_leader}    ${member_index_list}=${EMPTY}    ${verify_restconf}=True
 169     [Documentation]    Verify new leader was elected or remained the same. Bool paramter ${new_elected} indicates if
 170     ...    new leader is elected or should remained the same as ${old_leader}
 171     ${leader}    ${followers}=    Get_Leader_And_Followers_For_Shard    shard_name=${shard_name}    shard_type=${shard_type}    member_index_list=${member_index_list}    verify_restconf=${verify_restconf}
 172     BuiltIn.Run_Keyword_If    ${new_elected}    BuiltIn.Should_Not_Be_Equal_As_Numbers    ${old_leader}    ${leader}
 173     BuiltIn.Run_Keyword_Unless    ${new_elected}    BuiltIn.Should_Be_Equal_As_numbers    ${old_leader}    ${leader}
 174     BuiltIn.Return_From_Keyword    ${leader}    ${followers}
 175
 176 Verify_Owner_And_Successors_For_Device
 177     [Arguments]    ${device_name}    ${device_type}    ${member_index}    ${candidate_list}=${EMPTY}    ${after_stop}=False
 178     [Documentation]    Returns the owner and successors for the SB device ${device_name} of type ${device_type}. Request is sent to member ${member_index}.
 179     ...    For Boron and beyond, candidates are not removed on node down or isolation,
 180     ...    so this keyword expects candidates to be all members from Boron on.
 181     ...    Extra check is done to verify owner and successors are within the ${candidate_list}. This KW is useful when combined with WUKS.
 182     ...    ${candidate_list} minus owner is returned as ${successor list}.
 183     ...    Users can still use Get_Owner_And_Successors_For_Device if they are interested in downed candidates,
 184     ...    or for testing heterogeneous clusters.
 185     ${index_list} =    List_Indices_Or_All    given_list=${candidate_list}
 186     ${owner}    ${successor_list} =    Get_Owner_And_Successors_For_Device    device_name=${device_name}    device_type=${device_type}    member_index=${member_index}
 187     Collections.List_Should_Contain_Value    ${index_list}    ${owner}    Owner ${owner} is not in candidate list ${index_list}
 188     # In Beryllium or after stopping an instance, the removed instance does not show in the candidate list.
 189     ${expected_candidate_list_origin} =    BuiltIn.Set_Variable_If    ${after_stop}    ${index_list}    ${ClusterManagement__member_index_list}
 190     # We do not want to manipulate either origin list.
 191     ${expected_successor_list} =    BuiltIn.Create_List    @{expected_candidate_list_origin}
 192     Collections.Remove_Values_From_List    ${expected_successor_list}    ${owner}
 193     Collections.Lists_Should_Be_Equal    ${expected_successor_list}    ${successor_list}    Successor list ${successor_list} is not the came as expected ${expected_successor_list}
 194     # User expects the returned successor list to be the provided candidate list minus the owner.
 195     Collections.Remove_Values_From_List    ${index_list}    ${owner}
 196     [Return]    ${owner}    ${index_list}
 197
 198 Get_Owner_And_Successors_For_Device
 199     [Arguments]    ${device_name}    ${device_type}    ${member_index}    ${http_timeout}=${EMPTY}
 200     [Documentation]    Returns the owner and a list of successors for the SB device ${device_name} of type ${device_type}. Request is sent to member ${member_index}.
 201     ...    Successors are those device candidates not elected as owner. The list of successors = (list of candidates) - (owner).
 202     ...    The returned successor list is sorted numerically.
 203     ...    Note that "candidate list" definition currently differs between Beryllium and Boron.
 204     ...    Use Verify_Owner_And_Successors_For_Device if you want the older semantics (inaccessible nodes not present in the list).
 205     # TODO: somewhere to introduce ${DEFAULT_RESTCONF_DATASTORE_TIMEOUT}. Value may depend on protocol (ask vs tell) and perhaps stream.
 206     ${owner}    ${candidate_list} =    Get_Owner_And_Candidates_For_Device    device_name=${device_name}    device_type=${device_type}    member_index=${member_index}    http_timeout=${http_timeout}
 207     ${successor_list} =    BuiltIn.Create_List    @{candidate_list}    # Copy operation is not required, but new variable name requires a line anyway.
 208     Collections.Remove_Values_From_List    ${successor_list}    ${owner}
 209     [Return]    ${owner}    ${successor_list}
 210
 211 Get_Owner_And_Candidates_For_Device_Old
 212     [Arguments]    ${device_name}    ${device_type}    ${member_index}    ${http_timeout}=${EMPTY}
 213     [Documentation]    Returns the owner and a list of candidates for the SB device ${device_name} of type ${device_type}. Request is sent to member ${member_index}.
 214     ...    Candidates are all members that register to own a device, so the list of candiates includes the owner.
 215     ...    The returned candidate list is sorted numerically.
 216     ...    Note that "candidate list" definition currently differs between Beryllium and Boron.
 217     ...    It is recommended to use Get_Owner_And_Successors_For_Device instead of this keyword, see documentation there.
 218     BuiltIn.Comment    TODO: Can this implementation be changed to call Get_Owner_And_Candidates_For_Type_And_Id?
 219     ${session} =    Resolve_Http_Session_For_Member    member_index=${member_index}
 220     ${data} =    TemplatedRequests.Get_As_Json_From_Uri    uri=${ENTITY_OWNER_URI}    session=${session}    http_timeout=${http_timeout}
 221     ${candidate_list} =    BuiltIn.Create_List
 222     ${entity_type} =    BuiltIn.Set_Variable_If    '${device_type}' == 'netconf'    netconf-node/${device_name}    ${device_type}
 223     ${clear_data} =    BuiltIn.Run_Keyword_If    '${device_type}' == 'openflow' or '${device_type}' == 'netconf'    Extract_OpenFlow_Device_Data    ${data}
 224     ...    ELSE IF    '${device_type}' == 'ovsdb'    Extract_Ovsdb_Device_Data    ${data}
 225     ...    ELSE IF    '${device_type}' == 'org.opendaylight.mdsal.ServiceEntityType'    Extract_Service_Entity_Type    ${data}
 226     ...    ELSE    Fail    Not recognized device type: ${device_type}
 227     ${json} =    RequestsLibrary.To_Json    ${clear_data}
 228     ${entity_type_list} =    Collections.Get_From_Dictionary    &{json}[entity-owners]    entity-type
 229     ${entity_type_index} =    Utils.Get_Index_From_List_Of_Dictionaries    ${entity_type_list}    type    ${entity_type}
 230     BuiltIn.Should_Not_Be_Equal_As_Integers    ${entity_type_index}    -1    No Entity Owner found for ${device_type}
 231     ${entity_list} =    Collections.Get_From_Dictionary    @{entity_type_list}[${entity_type_index}]    entity
 232     ${entity_index} =    Utils.Get_Index_From_List_Of_Dictionaries    ${entity_list}    id    ${device_name}
 233     BuiltIn.Should_Not_Be_Equal_As_Integers    ${entity_index}    -1    Device ${device_name} not found in Entity Owner ${device_type}
 234     ${entity_owner} =    Collections.Get_From_Dictionary    @{entity_list}[${entity_index}]    owner
 235     BuiltIn.Should_Not_Be_Empty    ${entity_owner}    No owner found for ${device_name}
 236     ${owner} =    String.Replace_String    ${entity_owner}    member-    ${EMPTY}
 237     ${owner} =    BuiltIn.Convert_To_Integer    ${owner}
 238     ${entity_candidates_list} =    Collections.Get_From_Dictionary    @{entity_list}[${entity_index}]    candidate
 239     : FOR    ${entity_candidate}    IN    @{entity_candidates_list}
 240     \    ${candidate} =    String.Replace_String    &{entity_candidate}[name]    member-    ${EMPTY}
 241     \    ${candidate} =    BuiltIn.Convert_To_Integer    ${candidate}
 242     \    Collections.Append_To_List    ${candidate_list}    ${candidate}
 243     Collections.Sort_List    ${candidate_list}
 244     [Return]    ${owner}    ${candidate_list}
 245
 246 Get_Owner_And_Candidates_For_Device_Singleton
 247     [Arguments]    ${device_name}    ${device_type}    ${member_index}    ${http_timeout}=${EMPTY}
 248     [Documentation]    Returns the owner and a list of candidates for the SB device ${device_name} of type ${device_type}. Request is sent to member ${member_index}.
 249     ...    Parsing method is selected by device type
 250     ...    Separate kw for every supported device type must be defined
 251     BuiltIn.Keyword_Should_Exist    Get_Owner_And_Candidates_For_Device_Singleton_${device_type}
 252     BuiltIn.Run_Keyword_And_Return    Get_Owner_And_Candidates_For_Device_Singleton_${device_type}    ${device_name}    ${member_index}    http_timeout=${http_timeout}
 253
 254 Get_Owner_And_Candidates_For_Device_Singleton_Netconf
 255     [Arguments]    ${device_name}    ${member_index}    ${http_timeout}=${EMPTY}
 256     [Documentation]    Returns the owner and a list of candidates for the SB device ${device_name} of type netconf. Request is sent to member ${member_index}.
 257     ...    Parsing method is set as netconf (using netconf device id prefix and suffix)
 258     # Get election entity type results
 259     ${type} =    BuiltIn.Set_Variable    ${SINGLETON_ELECTION_ENTITY_TYPE}
 260     ${id} =    BuiltIn.Set_Variable    ${SINGLETON_NETCONF_DEVICE_ID_PREFIX}${device_name}${SINGLETON_NETCONF_DEVICE_ID_SUFFIX}
 261     ${owner_1}    ${candidate_list_1} =    Get_Owner_And_Candidates_For_Type_And_Id    ${type}    ${id}    ${member_index}    http_timeout=${http_timeout}
 262     # Get change ownership entity type results
 263     ${type} =    BuiltIn.Set_Variable    ${SINGLETON_CHANGE_OWNERSHIP_ENTITY_TYPE}
 264     ${id} =    BuiltIn.Set_Variable    ${SINGLETON_NETCONF_DEVICE_ID_PREFIX}${device_name}${SINGLETON_NETCONF_DEVICE_ID_SUFFIX}
 265     ${owner_2}    ${candidate_list_2} =    Get_Owner_And_Candidates_For_Type_And_Id    ${type}    ${id}    ${member_index}    http_timeout=${http_timeout}
 266     # Owners must be same, if not, there is still some election or change ownership in progress
 267     BuiltIn.Should_Be_Equal_As_Integers    ${owner_1}    ${owner_2}    Owners for device ${device_name} are not same
 268     [Return]    ${owner_1}    ${candidate_list_1}
 269
 270 Get_Owner_And_Candidates_For_Device_Singleton_Bgpcep
 271     [Arguments]    ${device_name}    ${member_index}    ${http_timeout}=${EMPTY}
 272     [Documentation]    Returns the owner and a list of candidates for the SB device ${device_name}. Request is sent to member ${member_index}.
 273     # Get election entity type results
 274     ${type} =    BuiltIn.Set_Variable    ${SINGLETON_ELECTION_ENTITY_TYPE}
 275     ${id} =    BuiltIn.Set_Variable    ${SINGLETON_BGPCEP_DEVICE_ID_PREFIX}${device_name}${SINGLETON_BGPCEP_DEVICE_ID_SUFFIX}
 276     ${owner_1}    ${candidate_list_1} =    Get_Owner_And_Candidates_For_Type_And_Id    ${type}    ${id}    ${member_index}    http_timeout=${http_timeout}
 277     # Get change ownership entity type results
 278     ${type} =    BuiltIn.Set_Variable    ${SINGLETON_CHANGE_OWNERSHIP_ENTITY_TYPE}
 279     ${id} =    BuiltIn.Set_Variable    ${SINGLETON_BGPCEP_DEVICE_ID_PREFIX}${device_name}${SINGLETON_BGPCEP_DEVICE_ID_SUFFIX}
 280     ${owner_2}    ${candidate_list_2} =    Get_Owner_And_Candidates_For_Type_And_Id    ${type}    ${id}    ${member_index}    http_timeout=${http_timeout}
 281     # Owners must be same, if not, there is still some election or change ownership in progress
 282     BuiltIn.Should_Be_Equal_As_Integers    ${owner_1}    ${owner_2}    Owners for device ${device_name} are not same
 283     [Return]    ${owner_1}    ${candidate_list_1}
 284
 285 Get_Owner_And_Candidates_For_Device_Singleton_Sxp
 286     [Arguments]    ${device_name}    ${member_index}    ${http_timeout}=${EMPTY}
 287     [Documentation]    Returns the owner and a list of candidates for the SB device ${device_name}. Request is sent to member ${member_index}.
 288     # Get election entity type results
 289     ${type} =    BuiltIn.Set_Variable    ${SINGLETON_ELECTION_ENTITY_TYPE}
 290     ${id} =    BuiltIn.Set_Variable    ${SINGLETON_SXP_DEVICE_ID_PREFIX}${device_name}${SINGLETON_SXP_DEVICE_ID_SUFFIX}
 291     ${owner_1}    ${candidate_list_1} =    Get_Owner_And_Candidates_For_Type_And_Id    ${type}    ${id}    ${member_index}    http_timeout=${http_timeout}
 292     # Get change ownership entity type results
 293     ${type} =    BuiltIn.Set_Variable    ${SINGLETON_CHANGE_OWNERSHIP_ENTITY_TYPE}
 294     ${id} =    BuiltIn.Set_Variable    ${SINGLETON_SXP_DEVICE_ID_PREFIX}${device_name}${SINGLETON_SXP_DEVICE_ID_SUFFIX}
 295     ${owner_2}    ${candidate_list_2} =    Get_Owner_And_Candidates_For_Type_And_Id    ${type}    ${id}    ${member_index}    http_timeout=${http_timeout}
 296     # Owners must be same, if not, there is still some election or change ownership in progress
 297     BuiltIn.Should_Be_Equal_As_Integers    ${owner_1}    ${owner_2}    Owners for device ${device_name} are not same
 298     [Return]    ${owner_1}    ${candidate_list_1}
 299
 300 Get_Owner_And_Candidates_For_Device
 301     [Arguments]    ${device_name}    ${device_type}    ${member_index}    ${http_timeout}=${EMPTY}
 302     [Documentation]    Returns the owner and a list of candidates for the SB device ${device_name} of type ${device_type}. Request is sent to member ${member_index}.
 303     ...    If parsing as singleton failed, kw try to parse data in old way (without singleton).
 304     ...    Candidates are all members that register to own a device, so the list of candiates includes the owner.
 305     ...    The returned candidate list is sorted numerically.
 306     ...    Note that "candidate list" definition currently differs between Beryllium and Boron.
 307     ...    It is recommended to use Get_Owner_And_Successors_For_Device instead of this keyword, see documentation there.
 308     # Try singleton
 309     ${status}    ${results} =    BuiltIn.Run_Keyword_And_Ignore_Error    Get_Owner_And_Candidates_For_Device_Singleton    device_name=${device_name}    device_type=${device_type}    member_index=${member_index}
 310     ...    http_timeout=${http_timeout}
 311     BuiltIn.Return_From_Keyword_If    "${status}"=="PASS"    ${results}
 312     # If singleton failed, try parsing in old way
 313     ${status}    ${results} =    BuiltIn.Run_Keyword_And_Ignore_Error    Get_Owner_And_Candidates_For_Device_Old    device_name=${device_name}    device_type=${device_type}    member_index=${member_index}
 314     ...    http_timeout=${http_timeout}
 315     # previous 3 lines (BuilIn.Return.., # If singleton..., ${status}....) could be deleted when old way will not be supported anymore
 316     BuiltIn.Run_Keyword_If    '${status}'=='FAIL'    BuiltIn.Fail    Could not parse owner and candidates for device ${device_name}
 317     [Return]    @{results}
 318
 319 Check_Old_Owner_Stays_Elected_For_Device
 320     [Arguments]    ${device_name}    ${device_type}    ${old_owner}    ${node_to_ask}    ${http_timeout}=${EMPTY}
 321     [Documentation]    Verify the owner remain the same as ${old_owner}
 322     ${owner}    ${candidates} =    Get_Owner_And_Candidates_For_Device    ${device_name}    ${device_type}    ${node_to_ask}    http_timeout=${http_timeout}
 323     BuiltIn.Should_Be_Equal_As_numbers    ${old_owner}    ${owner}
 324     BuiltIn.Return_From_Keyword    ${owner}    ${candidates}
 325
 326 Check_New_Owner_Got_Elected_For_Device
 327     [Arguments]    ${device_name}    ${device_type}    ${old_owner}    ${node_to_ask}    ${http_timeout}=${EMPTY}
 328     [Documentation]    Verify new owner was elected comparing to ${old_owner}
 329     ${owner}    ${candidates} =    Get_Owner_And_Candidates_For_Device    ${device_name}    ${device_type}    ${node_to_ask}    http_timeout=${http_timeout}
 330     BuiltIn.Should_Not_Be_Equal_As_Numbers    ${old_owner}    ${owner}
 331     BuiltIn.Return_From_Keyword    ${owner}    ${candidates}
 332
 333 Get_Owner_And_Candidates_For_Type_And_Id
 334     [Arguments]    ${type}    ${id}    ${member_index}    ${require_candidate_list}=${EMPTY}    ${http_timeout}=${EMPTY}
 335     [Documentation]    Returns the owner and a list of candidates for entity specified by ${type} and ${id}
 336     ...    Request is sent to member ${member_index}.
 337     ...    Candidates are all members that register to own a device, so the list of candiates includes the owner.
 338     ...    Bear in mind that for Boron and beyond, candidates are not removed on node down or isolation.
 339     ...    If ${require_candidate_list} is not \${EMPTY}, check whether the actual list of candidates matches.
 340     ...    Note that differs from "given list" semantics used in other keywords,
 341     ...    namely you cannot use \${EMPTY} to stand for "full list" in this keyword.
 342     BuiltIn.Comment    TODO: Find a way to unify and deduplicate code blocks in Get_Owner_And_Candidates_* keywords.
 343     ${session} =    Resolve_Http_Session_For_Member    member_index=${member_index}
 344     ${data} =    TemplatedRequests.Get_As_Json_From_Uri    uri=${ENTITY_OWNER_URI}    session=${session}    http_timeout=${http_timeout}
 345     ${candidate_list} =    BuiltIn.Create_List
 346     ${json} =    RequestsLibrary.To_Json    ${data}
 347     ${entity_type_list} =    Collections.Get_From_Dictionary    &{json}[entity-owners]    entity-type
 348     ${entity_type_index} =    Utils.Get_Index_From_List_Of_Dictionaries    ${entity_type_list}    type    ${type}
 349     BuiltIn.Should_Not_Be_Equal_As_Integers    ${entity_type_index}    -1    No Entity Owner found for ${type}
 350     ${entity_list} =    Collections.Get_From_Dictionary    @{entity_type_list}[${entity_type_index}]    entity
 351     ${entity_index} =    Utils.Get_Index_From_List_Of_Dictionaries    ${entity_list}    id    ${id}
 352     BuiltIn.Should Not_Be_Equal_As_Integers    ${entity_index}    -1    Id ${id} not found in Entity Owner ${type}
 353     ${entity_owner} =    Collections.Get_From_Dictionary    @{entity_list}[${entity_index}]    owner
 354     BuiltIn.Should_Not_Be_Empty    ${entity_owner}    No owner found for type=${type} id=${id}
 355     ${owner} =    String.Replace_String    ${entity_owner}    member-    ${EMPTY}
 356     ${owner} =    BuiltIn.Convert_To_Integer    ${owner}
 357     ${entity_candidates_list} =    Collections.Get_From_Dictionary    @{entity_list}[${entity_index}]    candidate
 358     : FOR    ${entity_candidate}    IN    @{entity_candidates_list}
 359     \    ${candidate} =    String.Replace_String    &{entity_candidate}[name]    member-    ${EMPTY}
 360     \    ${candidate} =    BuiltIn.Convert_To_Integer    ${candidate}
 361     \    Collections.Append_To_List    ${candidate_list}    ${candidate}
 362     Collections.Sort_List    ${candidate_list}
 363     BuiltIn.Comment    TODO: Separate check lines into Verify_Owner_And_Candidates_For_Type_And_Id
 364     BuiltIn.Run_Keyword_If    """${require_candidate_list}"""    BuiltIn.Should_Be_Equal    ${require_candidate_list}    ${candidate_list}    Candidate list does not match: ${candidate_list} is not ${require_candidate_list}
 365     [Return]    ${owner}    ${candidate_list}
 366
 367 Extract_Service_Entity_Type
 368     [Arguments]    ${data}
 369     [Documentation]    Remove superfluous device data from Entity Owner printout.
 370     ${clear_data} =    String.Replace_String    ${data}    /odl-general-entity:entity[odl-general-entity:name='    ${EMPTY}
 371     ${clear_data} =    String.Replace_String    ${clear_data}    -service-group']    ${EMPTY}
 372     Log    ${clear_data}
 373     [Return]    ${clear_data}
 374
 375 Extract_OpenFlow_Device_Data
 376     [Arguments]    ${data}
 377     [Documentation]    Remove superfluous OpenFlow device data from Entity Owner printout.
 378     ${clear_data} =    String.Replace_String    ${data}    org.opendaylight.mdsal.ServiceEntityType    openflow
 379     ${clear_data} =    String.Replace_String    ${clear_data}    /odl-general-entity:entity[odl-general-entity:name='    ${EMPTY}
 380     ${clear_data} =    String.Replace_String    ${clear_data}    /general-entity:entity[general-entity:name='    ${EMPTY}
 381     ${clear_data} =    String.Replace_String    ${clear_data}    ']    ${EMPTY}
 382     Log    ${clear_data}
 383     [Return]    ${clear_data}
 384
 385 Extract_Ovsdb_Device_Data
 386     [Arguments]    ${data}
 387     [Documentation]    Remove superfluous OVSDB device data from Entity Owner printout.
 388     ${clear_data} =    String.Replace_String    ${data}    /network-topology:network-topology/network-topology:topology[network-topology:topology-id='ovsdb:1']/network-topology:node[network-topology:node-id='    ${EMPTY}
 389     ${clear_data} =    String.Replace_String    ${clear_data}    ']    ${EMPTY}
 390     Log    ${clear_data}
 391     [Return]    ${clear_data}
 392
 393 Kill_Single_Member
 394     [Arguments]    ${member}    ${original_index_list}=${EMPTY}    ${confirm}=True
 395     [Documentation]    Convenience keyword that kills the specified member of the cluster.
 396     ...    The KW will return a list of available members: \${updated index_list}=\${original_index_list}-\${member}
 397     ${index_list} =    ClusterManagement__Build_List    ${member}
 398     ${member_ip} =    Return_Member_IP    ${member}
 399     KarafKeywords.Log_Message_To_Controller_Karaf    Killing ODL${member} ${member_ip}
 400     ${updated_index_list} =    Kill_Members_From_List_Or_All    ${index_list}    ${original_index_list}    ${confirm}
 401     [Return]    ${updated_index_list}
 402
 403 Kill_Members_From_List_Or_All
 404     [Arguments]    ${member_index_list}=${EMPTY}    ${original_index_list}=${EMPTY}    ${confirm}=True
 405     [Documentation]    If the list is empty, kill all ODL instances. Otherwise, kill members based on \${kill_index_list}
 406     ...    If \${confirm} is True, sleep 1 second and verify killed instances are not there anymore.
 407     ...    The KW will return a list of available members: \${updated index_list}=\${original_index_list}-\${member_index_list}
 408     ${kill_index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 409     ${index_list} =    List_Indices_Or_All    given_list=${original_index_list}
 410     Run_Bash_Command_On_List_Or_All    command=${NODE_KILL_COMMAND}    member_index_list=${member_index_list}
 411     ${updated_index_list} =    BuiltIn.Create_List    @{index_list}
 412     Collections.Remove_Values_From_List    ${updated_index_list}    @{kill_index_list}
 413     BuiltIn.Return_From_Keyword_If    not ${confirm}    ${updated_index_list}
 414     # TODO: Convert to WUKS with configurable timeout if it turns out 1 second is not enough.
 415     BuiltIn.Sleep    1s    Kill -9 closes open files, which may take longer than ssh overhead, but not long enough to warrant WUKS.
 416     : FOR    ${index}    IN    @{kill_index_list}
 417     \    Verify_Karaf_Is_Not_Running_On_Member    member_index=${index}
 418     Run_Bash_Command_On_List_Or_All    command=netstat -pnatu | grep 2550
 419     [Return]    ${updated_index_list}
 420
 421 Stop_Single_Member
 422     [Arguments]    ${member}    ${original_index_list}=${EMPTY}    ${confirm}=True    ${msg}=${EMPTY}
 423     [Documentation]    Convenience keyword that stops the specified member of the cluster.
 424     ...    The KW will return a list of available members: \${updated index_list}=\${original_index_list}-\${member}
 425     ${index_list} =    ClusterManagement__Build_List    ${member}
 426     ${member_ip} =    Return_Member_IP    ${member}
 427     ${msg} =    Builtin.Set Variable If    "${msg}" == "${EMPTY}"    Stopping ODL${member} ${member_ip}    Stopping ODL${member} ${member_ip}, ${msg}
 428     KarafKeywords.Log_Message_To_Controller_Karaf    ${msg}
 429     ${updated_index_list} =    Stop_Members_From_List_Or_All    ${index_list}    ${original_index_list}    ${confirm}
 430     [Return]    ${updated_index_list}
 431
 432 Stop_Members_From_List_Or_All
 433     [Arguments]    ${member_index_list}=${EMPTY}    ${original_index_list}=${EMPTY}    ${confirm}=True    ${timeout}=120s
 434     [Documentation]    If the list is empty, stops all ODL instances. Otherwise stop members based on \${stop_index_list}
 435     ...    If \${confirm} is True, verify stopped instances are not there anymore.
 436     ...    The KW will return a list of available members: \${updated index_list}=\${original_index_list}-\${member_index_list}
 437     ${stop_index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 438     ${index_list} =    List_Indices_Or_All    given_list=${original_index_list}
 439     Run_Bash_Command_On_List_Or_All    command=${NODE_STOP_COMMAND}    member_index_list=${member_index_list}
 440     ${updated_index_list} =    BuiltIn.Create_List    @{index_list}
 441     Collections.Remove_Values_From_List    ${updated_index_list}    @{stop_index_list}
 442     BuiltIn.Return_From_Keyword_If    not ${confirm}    ${updated_index_list}
 443     : FOR    ${index}    IN    @{stop_index_list}
 444     \    BuiltIn.Wait Until Keyword Succeeds    ${timeout}    2s    Verify_Karaf_Is_Not_Running_On_Member    member_index=${index}
 445     Run_Bash_Command_On_List_Or_All    command=netstat -pnatu | grep 2550
 446     [Return]    ${updated_index_list}
 447
 448 Start_Single_Member
 449     [Arguments]    ${member}    ${wait_for_sync}=True    ${timeout}=300s    ${msg}=${EMPTY}    ${check_system_status}=False    ${service_list}=@{EMPTY}
 450     [Documentation]    Convenience keyword that starts the specified member of the cluster.
 451     ${index_list} =    ClusterManagement__Build_List    ${member}
 452     ${member_ip} =    Return_Member_IP    ${member}
 453     ${msg} =    Builtin.Set Variable If    "${msg}" == "${EMPTY}"    Starting ODL${member} ${member_ip}    Starting ODL${member} ${member_ip}, ${msg}
 454     KarafKeywords.Log_Message_To_Controller_Karaf    ${msg}
 455     Start_Members_From_List_Or_All    ${index_list}    ${wait_for_sync}    ${timeout}    check_system_status=${check_system_status}    service_list=@{service_list}
 456
 457 Start_Members_From_List_Or_All
 458     [Arguments]    ${member_index_list}=${EMPTY}    ${wait_for_sync}=True    ${timeout}=300s    ${karaf_home}=${EMPTY}    ${export_java_home}=${EMPTY}    ${gc_log_dir}=${EMPTY}
 459     ...    ${check_system_status}=False    ${service_list}=@{EMPTY}
 460     [Documentation]    If the list is empty, start all cluster members. Otherwise, start members based on present indices.
 461     ...    If ${wait_for_sync}, wait for cluster sync on listed members.
 462     ...    Optionally karaf_home can be overriden. Optionally specific JAVA_HOME is used for starting.
 463     ...    Garbage collection is unconditionally logged to files. TODO: Make that reasonable conditional?
 464     ${base_command} =    BuiltIn.Set_Variable_If    """${karaf_home}""" != ""    ${karaf_home}/bin/start    ${NODE_START_COMMAND}
 465     ${command} =    BuiltIn.Set_Variable_If    """${export_java_home}""" != ""    export JAVA_HOME="${export_java_home}"; ${base_command}    ${base_command}
 466     ${epoch} =    DateTime.Get_Current_Date    time_zone=UTC    result_format=epoch    exclude_millis=False
 467     ${gc_filepath} =    BuiltIn.Set_Variable_If    """${karaf_home}""" != ""    ${karaf_home}/data/log/gc_${epoch}.log    ${GC_LOG_PATH}/gc_${epoch}.log
 468     ${gc_options} =    BuiltIn.Set_Variable_If    "docker" not in """${node_start_command}"""    -XX:+PrintGCDetails -XX:+PrintGCDateStamps -Xloggc:${gc_filepath}    ${EMPTY}
 469     Run_Bash_Command_On_List_Or_All    command=${command} ${gc_options}    member_index_list=${member_index_list}
 470     BuiltIn.Return_From_Keyword_If    not ${wait_for_sync}
 471     BuiltIn.Wait_Until_Keyword_Succeeds    ${timeout}    10s    Check_Cluster_Is_In_Sync    member_index_list=${member_index_list}
 472     BuiltIn.Return_From_Keyword_If    not ${check_system_status}
 473     CompareStream.Run_Keyword_If_At_Least_Oxygen    Wait Until Keyword Succeeds    60    2    ClusterManagement.Check Status Of Services Is OPERATIONAL    @{service_list}
 474     [Teardown]    Run_Bash_Command_On_List_Or_All    command=netstat -pnatu | grep 2550
 475
 476 Freeze_Single_Member
 477     [Arguments]    ${member}
 478     [Documentation]    Convenience keyword that stops the specified member of the cluster by freezing the jvm.
 479     ${index_list} =    ClusterManagement__Build_List    ${member}
 480     Freeze_Or_Unfreeze_Members_From_List_Or_All    ${NODE_FREEZE_COMMAND}    ${index_list}
 481
 482 Unfreeze_Single_Member
 483     [Arguments]    ${member}    ${wait_for_sync}=True    ${timeout}=60s
 484     [Documentation]    Convenience keyword that "continues" the specified member of the cluster by unfreezing the jvm.
 485     ${index_list} =    ClusterManagement__Build_List    ${member}
 486     Freeze_Or_Unfreeze_Members_From_List_Or_All    ${NODE_UNFREEZE_COMMAND}    ${index_list}
 487     BuiltIn.Wait_Until_Keyword_Succeeds    ${timeout}    10s    Check_Cluster_Is_In_Sync
 488
 489 Freeze_Or_Unfreeze_Members_From_List_Or_All
 490     [Arguments]    ${command}    ${member_index_list}=${EMPTY}
 491     [Documentation]    If the list is empty, stops/runs all ODL instances. Otherwise stop/run members based on \${stop_index_list}
 492     ...    For command parameter only ${NODE_FREEZE_COMMAND} and ${NODE_UNFREEZE_COMMAND} should be used
 493     ${freeze_index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 494     Run_Bash_Command_On_List_Or_All    command=${command}    member_index_list=${member_index_list}
 495
 496 Clean_Journals_Data_And_Snapshots_On_List_Or_All
 497     [Arguments]    ${member_index_list}=${EMPTY}    ${karaf_home}=${KARAF_HOME}
 498     [Documentation]    Delete journal and snapshots directories on every node listed (or all).
 499     ...    BEWARE: If only a subset of members is cleaned, this causes RetiredGenerationException in Carbon after the affected node re-start.
 500     ...    See https://bugs.opendaylight.org/show_bug.cgi?id=8138
 501     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 502     ${command} =    Set Variable    rm -rf "${karaf_home}/journal" "${karaf_home}/snapshots" "${karaf_home}/data"
 503     : FOR    ${index}    IN    @{index_list}    # usually: 1, 2, 3.
 504     \    Run_Bash_Command_On_Member    command=${command}    member_index=${index}
 505
 506 Verify_Karaf_Is_Not_Running_On_Member
 507     [Arguments]    ${member_index}
 508     [Documentation]    Fail if non-zero karaf instances are counted on member of given index.
 509     ${count} =    Count_Running_Karafs_On_Member    member_index=${member_index}
 510     BuiltIn.Should_Be_Equal    0    ${count}    Found running Karaf count: ${count}
 511
 512 Verify_Single_Karaf_Is_Running_On_Member
 513     [Arguments]    ${member_index}
 514     [Documentation]    Fail if number of karaf instances on member of given index is not one.
 515     ${count} =    Count_Running_Karafs_On_Member    member_index=${member_index}
 516     BuiltIn.Should_Be_Equal    1    ${count}    Wrong number of Karafs running: ${count}
 517
 518 Count_Running_Karafs_On_Member
 519     [Arguments]    ${member_index}
 520     [Documentation]    Remotely execute grep for karaf process, return count as string.
 521     ${command} =    BuiltIn.Set_Variable    ${NODE_KARAF_COUNT_COMMAND}
 522     ${count} =    Run_Bash_Command_On_Member    command=${command}    member_index=${member_index}
 523     [Return]    ${count}
 524
 525 Isolate_Member_From_List_Or_All
 526     [Arguments]    ${isolate_member_index}    ${member_index_list}=${EMPTY}    ${protocol}=all    ${port}=${EMPTY}
 527     [Documentation]    If the list is empty, isolate member from all ODL instances. Otherwise, isolate member based on present indices.
 528     ...    The KW will return a list of available members: \${updated index_list}=\${member_index_list}-\${isolate_member_index}
 529     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 530     ${source} =    Collections.Get_From_Dictionary    ${ClusterManagement__index_to_ip_mapping}    ${isolate_member_index}
 531     ${dport} =    BuiltIn.Set_Variable_If    '${port}' != '${EMPTY}'    --dport ${port}    ${EMPTY}
 532     : FOR    ${index}    IN    @{index_list}
 533     \    ${destination} =    Collections.Get_From_Dictionary    ${ClusterManagement__index_to_ip_mapping}    ${index}
 534     \    ${command} =    BuiltIn.Set_Variable    sudo /sbin/iptables -I OUTPUT -p ${protocol} ${dport} --source ${source} --destination ${destination} -j DROP
 535     \    BuiltIn.Run_Keyword_If    "${index}" != "${isolate_member_index}"    Run_Bash_Command_On_Member    command=${command}    member_index=${isolate_member_index}
 536     ${command} =    BuiltIn.Set_Variable    sudo /sbin/iptables -L -n
 537     ${output} =    Run_Bash_Command_On_Member    command=${command}    member_index=${isolate_member_index}
 538     BuiltIn.Log    ${output}
 539     ${updated_index_list} =    BuiltIn.Create_List    @{index_list}
 540     Collections.Remove_Values_From_List    ${updated_index_list}    ${isolate_member_index}
 541     [Return]    ${updated_index_list}
 542
 543 Rejoin_Member_From_List_Or_All
 544     [Arguments]    ${rejoin_member_index}    ${member_index_list}=${EMPTY}    ${protocol}=all    ${port}=${EMPTY}    ${timeout}=60s
 545     [Documentation]    If the list is empty, rejoin member from all ODL instances. Otherwise, rejoin member based on present indices.
 546     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 547     ${source} =    Collections.Get_From_Dictionary    ${ClusterManagement__index_to_ip_mapping}    ${rejoin_member_index}
 548     ${dport} =    BuiltIn.Set_Variable_If    '${port}' != '${EMPTY}'    --dport ${port}    ${EMPTY}
 549     : FOR    ${index}    IN    @{index_list}
 550     \    ${destination} =    Collections.Get_From_Dictionary    ${ClusterManagement__index_to_ip_mapping}    ${index}
 551     \    ${command} =    BuiltIn.Set_Variable    sudo /sbin/iptables -D OUTPUT -p ${protocol} ${dport} --source ${source} --destination ${destination} -j DROP
 552     \    BuiltIn.Run_Keyword_If    "${index}" != "${rejoin_member_index}"    Run_Bash_Command_On_Member    command=${command}    member_index=${rejoin_member_index}
 553     ${command} =    BuiltIn.Set_Variable    sudo /sbin/iptables -L -n
 554     ${output} =    Run_Bash_Command_On_Member    command=${command}    member_index=${rejoin_member_index}
 555     BuiltIn.Log    ${output}
 556     BuiltIn.Wait_Until_Keyword_Succeeds    ${timeout}    10s    Check_Cluster_Is_In_Sync
 557
 558 Flush_Iptables_From_List_Or_All
 559     [Arguments]    ${member_index_list}=${EMPTY}
 560     [Documentation]    If the list is empty, flush IPTables in all ODL instances. Otherwise, flush member based on present indices.
 561     ${command} =    BuiltIn.Set_Variable    sudo iptables -v -F
 562     ${output} =    Run_Bash_Command_On_List_Or_All    command=${command}    member_index_list=${member_index_list}
 563
 564 Check_Bash_Command_On_List_Or_All
 565     [Arguments]    ${command}    ${member_index_list}=${EMPTY}    ${return_success_only}=False    ${log_on_success}=True    ${log_on_failure}=True    ${stderr_must_be_empty}=True
 566     [Documentation]    Cycle through indices (or all), run bash command on each, using temporary SSH session and restoring the previously active one.
 567     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 568     : FOR    ${index}    IN    @{index_list}
 569     \    Check_Bash_Command_On_Member    command=${command}    member_index=${index}    return_success_only=${return_success_only}    log_on_success=${log_on_success}    log_on_failure=${log_on_failure}
 570     \    ...    stderr_must_be_empty=${stderr_must_be_empty}
 571
 572 Check_Bash_Command_On_Member
 573     [Arguments]    ${command}    ${member_index}    ${return_success_only}=False    ${log_on_success}=True    ${log_on_failure}=True    ${stderr_must_be_empty}=True
 574     [Documentation]    Open SSH session, call SSHKeywords.Execute_Command_Passes, close session, restore previously active session and return output.
 575     BuiltIn.Run_Keyword_And_Return    SSHKeywords.Run_Keyword_Preserve_Connection    Check_Unsafely_Bash_Command_On_Member    ${command}    ${member_index}    return_success_only=${return_success_only}    log_on_success=${log_on_success}
 576     ...    log_on_failure=${log_on_failure}    stderr_must_be_empty=${stderr_must_be_empty}
 577
 578 Check_Unsafely_Bash_Command_On_Member
 579     [Arguments]    ${command}    ${member_index}    ${return_success_only}=False    ${log_on_success}=True    ${log_on_failure}=True    ${stderr_must_be_empty}=True
 580     [Documentation]    Obtain Ip address, open session, call SSHKeywords.Execute_Command_Passes, close session and return output. This affects which SSH session is active.
 581     ${member_ip} =    Resolve_Ip_Address_For_Member    ${member_index}
 582     BuiltIn.Run_Keyword_And_Return    SSHKeywords.Run_Unsafely_Keyword_Over_Temporary_Odl_Session    ${member_ip}    Execute_Command_Passes    ${command}    return_success_only=${return_success_only}    log_on_success=${log_on_success}
 583     ...    log_on_failure=${log_on_failure}    stderr_must_be_empty=${stderr_must_be_empty}
 584
 585 Run_Bash_Command_On_List_Or_All
 586     [Arguments]    ${command}    ${member_index_list}=${EMPTY}
 587     [Documentation]    Cycle through indices (or all), run command on each.
 588     # TODO: Migrate callers to Check_Bash_Command_*
 589     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 590     : FOR    ${index}    IN    @{index_list}
 591     \    Run_Bash_Command_On_Member    command=${command}    member_index=${index}
 592
 593 Run_Bash_Command_On_Member
 594     [Arguments]    ${command}    ${member_index}
 595     [Documentation]    Obtain IP, call Utils and return output. This keeps previous ssh session active.
 596     # TODO: Migrate callers to Check_Bash_Command_*
 597     ${member_ip} =    Collections.Get_From_Dictionary    dictionary=${ClusterManagement__index_to_ip_mapping}    key=${member_index}
 598     ${output} =    SSHKeywords.Run_Keyword_Preserve_Connection    Utils.Run_Command_On_Controller    ${member_ip}    ${command}
 599     Log    ${output}
 600     [Return]    ${output}
 601
 602 Run_Karaf_Command_On_List_Or_All
 603     [Arguments]    ${command}    ${member_index_list}=${EMPTY}    ${timeout}=10s
 604     [Documentation]    Cycle through indices (or all), run karaf command on each.
 605     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 606     : FOR    ${index}    IN    @{index_list}
 607     \    ${member_ip} =    Collections.Get_From_Dictionary    dictionary=${ClusterManagement__index_to_ip_mapping}    key=${index}
 608     \    KarafKeywords.Safe_Issue_Command_On_Karaf_Console    ${command}    ${member_ip}    timeout=${timeout}
 609
 610 Run_Karaf_Command_On_Member
 611     [Arguments]    ${command}    ${member_index}    ${timeout}=10s
 612     [Documentation]    Obtain IP address, call KarafKeywords and return output. This does not preserve active ssh session.
 613     ...    This keyword is not used by Run_Karaf_Command_On_List_Or_All, but returned output may be useful.
 614     ${member_ip} =    Collections.Get_From_Dictionary    dictionary=${ClusterManagement__index_to_ip_mapping}    key=${member_index}
 615     ${output} =    KarafKeywords.Safe_Issue_Command_On_Karaf_Console    ${command}    controller=${member_ip}    timeout=${timeout}
 616     [Return]    ${output}
 617
 618 Install_Feature_On_List_Or_All
 619     [Arguments]    ${feature_name}    ${member_index_list}=${EMPTY}    ${timeout}=60s
 620     [Documentation]    Attempt installation on each member from list (or all). Then look for failures.
 621     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 622     ${status_list} =    BuiltIn.Create_List
 623     : FOR    ${index}    IN    @{index_list}
 624     \    ${status}    ${text} =    BuiltIn.Run_Keyword_And_Ignore_Error    Install_Feature_On_Member    feature_name=${feature_name}    member_index=${index}
 625     \    ...    timeout=${timeout}
 626     \    BuiltIn.Log    ${text}
 627     \    Collections.Append_To_List    ${status_list}    ${status}
 628     : FOR    ${status}    IN    @{status_list}
 629     \    BuiltIn.Run_Keyword_If    "${status}" != "PASS"    BuiltIn.Fail    ${feature_name} installation failed, see log.
 630
 631 Install_Feature_On_Member
 632     [Arguments]    ${feature_name}    ${member_index}    ${timeout}=60s
 633     [Documentation]    Run feature:install karaf command, fail if installation was not successful. Return output.
 634     ${status}    ${output} =    BuiltIn.Run_Keyword_And_Ignore_Error    Run_Karaf_Command_On_Member    command=feature:install ${feature_name}    member_index=${member_index}    timeout=${timeout}
 635     BuiltIn.Run_Keyword_If    "${status}" != "PASS"    BuiltIn.Fail    Failed to install ${feature_name}: ${output}
 636     BuiltIn.Should_Not_Contain    ${output}    Can't install    Failed to install ${feature_name}: ${output}
 637     [Return]    ${output}
 638
 639 With_Ssh_To_List_Or_All_Run_Keyword
 640     [Arguments]    ${member_index_list}    ${keyword_name}    @{args}    &{kwargs}
 641     [Documentation]    For each index in given list (or all): activate SSH connection, run given Keyword, close active connection. Return None.
 642     ...    Beware that in order to avoid "got positional argument after named arguments", first two arguments in the call should not be named.
 643     BuiltIn.Comment    This keyword is experimental and there is high risk of being replaced by another approach.
 644     # TODO: For_Index_From_List_Or_All_Run_Keyword applied to With_Ssh_To_Member_Run_Keyword?
 645     # TODO: Imagine another keyword, using ScalarClosures and adding member index as first argument for each call. Worth it?
 646     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 647     : FOR    ${member_index}    IN    @{index_list}
 648     \    ${member_ip} =    Resolve_IP_Address_For_Member    ${member_index}
 649     \    SSHKeywords.Run_Unsafely_Keyword_Over_Temporary_Odl_Session    ${member_ip}    ${keyword_name}    @{args}    &{kwargs}
 650
 651 Safe_With_Ssh_To_List_Or_All_Run_Keyword
 652     [Arguments]    ${member_index_list}    ${keyword_name}    @{args}    &{kwargs}
 653     [Documentation]    Remember active ssh connection index, call With_Ssh_To_List_Or_All_Run_Keyword, return None. Restore the conection index on teardown.
 654     SSHKeywords.Run_Keyword_Preserve_Connection    With_Ssh_To_List_Or_All_Run_Keyword    ${member_index_list}    ${keyword_name}    @{args}    &{kwargs}
 655
 656 Clean_Directories_On_List_Or_All
 657     [Arguments]    ${member_index_list}=${EMPTY}    ${directory_list}=${EMPTY}    ${karaf_home}=${KARAF_HOME}    ${tmp_dir}=${EMPTY}
 658     [Documentation]    Clear @{directory_list} or @{ODL_DEFAULT_DATA_PATHS} for members in given list or all. Return None.
 659     ...    If \${tmp_dir} is nonempty, use that location to preserve data/log/.
 660     ...    This is intended to return Karaf (offline) to the state it was upon the first boot.
 661     ${path_list} =    Builtin.Set Variable If    "${directory_list}" == "${EMPTY}"    ${ODL_DEFAULT_DATA_PATHS}    ${directory_list}
 662     BuiltIn.Run_Keyword_If    """${tmp_dir}""" != ""    Check_Bash_Command_On_List_Or_All    mkdir -p '${tmp_dir}' && rm -vrf '${tmp_dir}/log' && mv -vf '${karaf_home}/data/log' '${tmp_dir}/'    ${member_index_list}
 663     Safe_With_Ssh_To_List_Or_All_Run_Keyword    ${member_index_list}    ClusterManagement__Clean_Directories    ${path_list}    ${karaf_home}
 664     BuiltIn.Run_Keyword_If    """${tmp_dir}""" != ""    Check_Bash_Command_On_List_Or_All    mkdir -p '${karaf_home}/data' && rm -vrf '${karaf_home}/log' && mv -vf '${tmp_dir}/log' '${karaf_home}/data/'    ${member_index_list}
 665
 666 Store_Karaf_Log_On_List_Or_All
 667     [Arguments]    ${member_index_list}=${EMPTY}    ${dst_dir}=/tmp    ${karaf_home}=${KARAF_HOME}
 668     [Documentation]    Saves karaf.log to the ${dst_dir} for members in given list or all. Return None.
 669     Safe_With_Ssh_To_List_Or_All_Run_Keyword    ${member_index_list}    SSHKeywords.Execute_Command_Should_Pass    cp ${karaf_home}/data/log/karaf.log ${dst_dir}
 670
 671 Restore_Karaf_Log_On_List_Or_All
 672     [Arguments]    ${member_index_list}=${EMPTY}    ${src_dir}=/tmp    ${karaf_home}=${KARAF_HOME}
 673     [Documentation]    Places stored karaf.log to the ${karaf_home}/data/log for members in given list or all. Return None.
 674     Safe_With_Ssh_To_List_Or_All_Run_Keyword    ${member_index_list}    SSHKeywords.Execute_Command_Should_Pass    cp ${src_dir}/karaf.log ${karaf_home}/data/log/
 675
 676 ClusterManagement__Clean_Directories
 677     [Arguments]    ${relative_path_list}    ${karaf_home}
 678     [Documentation]    For each relative path, remove files with respect to ${karaf_home}. Return None.
 679     : FOR    ${relative_path}    IN    @{relative_path_list}
 680     \    SSHLibrary.Execute_Command    rm -rf ${karaf_home}${/}${relative_path}
 681
 682 Put_As_Json_And_Check_Member_List_Or_All
 683     [Arguments]    ${uri}    ${data}    ${member_index}    ${member_index_list}=${EMPTY}
 684     [Documentation]    Send a PUT with the supplied uri ${uri} and body ${data} to member ${member_index}.
 685     ...    Then check data is replicated in all or some members defined in ${member_index_list}.
 686     ${response_text} =    Put_As_Json_To_Member    uri=${uri}    data=${data}    member_index=${member_index}
 687     Wait Until Keyword Succeeds    5s    1s    Check_Json_Member_List_Or_All    uri=${uri}    expected_data=${data}    member_index_list=${member_index_list}
 688     [Return]    ${response_text}
 689
 690 Put_As_Json_To_Member
 691     [Arguments]    ${uri}    ${data}    ${member_index}
 692     [Documentation]    Send a PUT with the supplied uri and data to member ${member_index}.
 693     ${session} =    Resolve_Http_Session_For_Member    member_index=${member_index}
 694     ${response_text} =    TemplatedRequests.Put_As_Json_To_Uri    uri=${uri}    data=${data}    session=${session}
 695     [Return]    ${response_text}
 696
 697 Post_As_Json_To_Member
 698     [Arguments]    ${uri}    ${data}    ${member_index}
 699     [Documentation]    Send a POST with the supplied uri and data to member ${member_index}.
 700     ${session} =    Resolve_Http_Session_For_Member    member_index=${member_index}
 701     ${response_text} =    TemplatedRequests.Post_As_Json_To_Uri    uri=${uri}    data=${data}    session=${session}
 702     [Return]    ${response_text}
 703
 704 Delete_And_Check_Member_List_Or_All
 705     [Arguments]    ${uri}    ${member_index}    ${member_index_list}=${EMPTY}
 706     [Documentation]    Send a DELETE with the supplied uri to the member ${member_index}.
 707     ...    Then check the data is removed from all members in ${member_index_list}.
 708     ${response_text} =    Delete_From_Member    ${uri}    ${member_index}
 709     BuiltIn.Wait_Until_Keyword_Succeeds    5s    1s    Check_No_Content_Member_List_Or_All    uri=${uri}    member_index_list=${member_index_list}
 710     [Return]    ${response_text}
 711
 712 Delete_From_Member
 713     [Arguments]    ${uri}    ${member_index}
 714     [Documentation]    Send a DELETE with the supplied uri to member ${member_index}.
 715     ${session} =    Resolve_Http_Session_For_Member    member_index=${member_index}
 716     ${response_text} =    TemplatedRequests.Delete_From_Uri    uri=${uri}    session=${session}
 717     [Return]    ${response_text}
 718
 719 Check_Json_Member_List_Or_All
 720     [Arguments]    ${uri}    ${expected_data}    ${member_index_list}=${EMPTY}
 721     [Documentation]    Send a GET with the supplied uri to all or some members defined in ${member_index_list}.
 722     ...    Then check received data is = ${expected data}.
 723     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 724     : FOR    ${index}    IN    @{index_list}
 725     \    ${data} =    Get_From_Member    uri=${uri}    member_index=${index}
 726     \    TemplatedRequests.Normalize_Jsons_And_Compare    ${expected_data}    ${data}
 727
 728 Check_Item_Occurrence_Member_List_Or_All
 729     [Arguments]    ${uri}    ${dictionary}    ${member_index_list}=${EMPTY}
 730     [Documentation]    Send a GET with the supplied uri to all or some members defined in ${member_index_list}.
 731     ...    Then check received for occurrences of items expressed in a dictionary ${dictionary}.
 732     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 733     : FOR    ${index}    IN    @{index_list}
 734     \    ${data} =    Get_From_Member    uri=${uri}    member_index=${index}
 735     \    Utils.Check Item Occurrence    ${data}    ${dictionary}
 736
 737 Check_No_Content_Member_List_Or_All
 738     [Arguments]    ${uri}    ${member_index_list}=${EMPTY}
 739     [Documentation]    Send a GET with the supplied uri to all or some members defined in ${member_index_list}.
 740     ...    Then check there is no content.
 741     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 742     : FOR    ${index}    IN    @{index_list}
 743     \    ${session} =    Resolve_Http_Session_For_Member    member_index=${index}
 744     \    Utils.No_Content_From_URI    ${session}    ${uri}
 745
 746 Get_From_Member
 747     [Arguments]    ${uri}    ${member_index}    ${access}=${ACCEPT_EMPTY}
 748     [Documentation]    Send a GET with the supplied uri to member ${member_index}.
 749     ${session} =    Resolve_Http_Session_For_Member    member_index=${member_index}
 750     ${response_text} =    TemplatedRequests.Get_From_Uri    uri=${uri}    accept=${access}    session=${session}
 751     [Return]    ${response_text}
 752
 753 Resolve_IP_Address_For_Member
 754     [Arguments]    ${member_index}
 755     [Documentation]    Return node IP address of given index.
 756     ${ip_address} =    Collections.Get From Dictionary    dictionary=${ClusterManagement__index_to_ip_mapping}    key=${member_index}
 757     [Return]    ${ip_address}
 758
 759 Resolve_IP_Address_For_Members
 760     [Arguments]    ${member_index_list}
 761     [Documentation]    Return a list of IP address of given indexes.
 762     ${member_ip_list} =    BuiltIn.Create_List
 763     : FOR    ${index}    IN    @{member_index_list}
 764     \    ${ip_address} =    Collections.Get From Dictionary    dictionary=${ClusterManagement__index_to_ip_mapping}    key=${index}
 765     \    Collections.Append_To_List    ${member_ip_list}    ${ip_address}
 766     [Return]    ${member_ip_list}
 767
 768 Resolve_Http_Session_For_Member
 769     [Arguments]    ${member_index}
 770     [Documentation]    Return RequestsLibrary session alias pointing to node of given index.
 771     ${session} =    BuiltIn.Set_Variable    ClusterManagement__session_${member_index}
 772     [Return]    ${session}
 773
 774 Resolve_Shard_Type_Class
 775     [Arguments]    ${shard_type}
 776     [Documentation]    Simple lookup for class name corresponding to desired type.
 777     BuiltIn.Run_Keyword_If    '${shard_type}' == 'config'    BuiltIn.Return_From_Keyword    DistributedConfigDatastore
 778     ...    ELSE IF    '${shard_type}' == 'operational'    BuiltIn.Return_From_Keyword    DistributedOperationalDatastore
 779     BuiltIn.Fail    Unrecognized shard type: ${shard_type}
 780
 781 ClusterManagement__Build_List
 782     [Arguments]    ${member}
 783     ${member_int} =    BuiltIn.Convert_To_Integer    ${member}
 784     ${index_list} =    BuiltIn.Create_List    ${member_int}
 785     [Return]    ${index_list}
 786
 787 ClusterManagement__Parse_Sync_Status
 788     [Arguments]    ${shard_manager_text}
 789     [Documentation]    Return sync status parsed out of given text. Called twice by Get_Sync_Status_Of_Member.
 790     BuiltIn.Log    ${shard_manager_text}
 791     ${manager_object} =    RequestsLibrary.To_Json    ${shard_manager_text}
 792     ${value_object} =    Collections.Get_From_Dictionary    dictionary=${manager_object}    key=value
 793     ${sync_status} =    Collections.Get_From_Dictionary    dictionary=${value_object}    key=SyncStatus
 794     [Return]    ${sync_status}
 795
 796 List_All_Indices
 797     [Documentation]    Create a new list of all indices.
 798     BuiltIn.Run_Keyword_And_Return    List_Indices_Or_All
 799
 800 List_Indices_Or_All
 801     [Arguments]    ${given_list}=${EMPTY}
 802     [Documentation]    Utility to allow \${EMPTY} as default argument value, as the internal list is computed at runtime.
 803     ...    This keyword always returns a (shallow) copy of given or default list,
 804     ...    so operations with the returned list should not affect other lists.
 805     ...    Also note that this keyword does not consider empty list to be \${EMPTY}.
 806     ${return_list_reference} =    BuiltIn.Set_Variable_If    """${given_list}""" != ""    ${given_list}    ${ClusterManagement__member_index_list}
 807     ${return_list_copy} =    BuiltIn.Create_List    @{return_list_reference}
 808     [Return]    ${return_list_copy}
 809
 810 List_Indices_Minus_Member
 811     [Arguments]    ${member_index}    ${member_index_list}=${EMPTY}
 812     [Documentation]    Create a new list which contains indices from ${member_index_list} (or all) without ${member_index}.
 813     ${index_list} =    List_Indices_Or_All    ${member_index_list}
 814     Collections.Remove Values From List    ${index_list}    ${member_index}
 815     [Return]    ${index_list}
 816
 817 ClusterManagement__Compute_Derived_Variables
 818     [Arguments]    ${int_of_members}    ${http_timeout}=${DEFAULT_TIMEOUT_HTTP}    ${http_retries}=0
 819     [Documentation]    Construct index list, session list and IP mapping, publish them as suite variables.
 820     @{member_index_list} =    BuiltIn.Create_List
 821     @{session_list} =    BuiltIn.Create_List
 822     &{index_to_ip_mapping} =    BuiltIn.Create_Dictionary
 823     : FOR    ${index}    IN RANGE    1    ${int_of_members+1}
 824     \    ClusterManagement__Include_Member_Index    ${index}    ${member_index_list}    ${session_list}    ${index_to_ip_mapping}    http_timeout=${http_timeout}
 825     \    ...    http_retries=${http_retries}
 826     BuiltIn.Set_Suite_Variable    \${ClusterManagement__member_index_list}    ${member_index_list}
 827     BuiltIn.Set_Suite_Variable    \${ClusterManagement__index_to_ip_mapping}    ${index_to_ip_mapping}
 828     BuiltIn.Set_Suite_Variable    \${ClusterManagement__session_list}    ${session_list}
 829
 830 ClusterManagement__Include_Member_Index
 831     [Arguments]    ${index}    ${member_index_list}    ${session_list}    ${index_to_ip_mapping}    ${http_timeout}=${DEFAULT_TIMEOUT_HTTP}    ${http_retries}=0
 832     [Documentation]    Add a corresponding item based on index into the last three arguments.
 833     ...    Create the Http session whose alias is added to list.
 834     Collections.Append_To_List    ${member_index_list}    ${index}
 835     ${member_ip} =    BuiltIn.Set_Variable    ${ODL_SYSTEM_${index}_IP}
 836     # ${index} is int (not string) so "key=value" syntax does not work in the following line.
 837     Collections.Set_To_Dictionary    ${index_to_ip_mapping}    ${index}    ${member_ip}
 838     # Http session, with ${AUTH}, without headers.
 839     ${session_alias} =    Resolve_Http_Session_For_Member    member_index=${index}
 840     RequestsLibrary.Create_Session    ${session_alias}    http://${member_ip}:${RESTCONFPORT}    auth=${AUTH}    timeout=${http_timeout}    max_retries=${http_retries}
 841     Collections.Append_To_List    ${session_list}    ${session_alias}
 842
 843 Sync_Status_Should_Be_False
 844     [Arguments]    ${controller_index}
 845     [Documentation]    Verify that cluster node is not in sync with others
 846     ${status}    Get_Sync_Status_Of_Member    ${controller_index}
 847     BuiltIn.Should_Not_Be_True    ${status}
 848
 849 Sync_Status_Should_Be_True
 850     [Arguments]    ${controller_index}
 851     [Documentation]    Verify that cluster node is in sync with others
 852     ${status}    Get_Sync_Status_Of_Member    ${controller_index}
 853     BuiltIn.Should_Be_True    ${status}
 854
 855 Return_Member_IP
 856     [Arguments]    ${member_index}
 857     [Documentation]    Return the IP address of the member given the member_index.
 858     ${member_int} =    BuiltIn.Convert_To_Integer    ${member_index}
 859     ${member_ip} =    Collections.Get_From_Dictionary    dictionary=${ClusterManagement__index_to_ip_mapping}    key=${member_int}
 860     [Return]    ${member_ip}
 861
 862 Check Service Status
 863     [Arguments]    ${odl_ip}    ${system_ready_state}    ${service_state}    @{service_list}
 864     [Documentation]    Issues the karaf shell command showSvcStatus to verify the ready and service states are the same as the arguments passed
 865     ${service_status_output} =    BuiltIn.Run Keyword If    ${NUM_ODL_SYSTEM} > 1    KarafKeywords.Issue_Command_On_Karaf_Console    showSvcStatus -n ${odl_ip}    ${odl_ip}    ${KARAF_SHELL_PORT}
 866     ...    ELSE    KarafKeywords.Issue_Command_On_Karaf_Console    showSvcStatus    ${odl_ip}    ${KARAF_SHELL_PORT}
 867     BuiltIn.Should Contain    ${service_status_output}    ${system_ready_state}
 868     : FOR    ${service}    IN    @{service_list}
 869     \    BuiltIn.Should Match Regexp    ${service_status_output}    ${service} +: ${service_state}
 870
 871 Check Status Of Services Is OPERATIONAL
 872     [Arguments]    @{service_list}
 873     [Documentation]    This keyword will verify whether all the services are operational in all the ODL nodes
 874     : FOR    ${i}    IN RANGE    ${NUM_ODL_SYSTEM}
 875     \    ClusterManagement.Check Service Status    ${ODL_SYSTEM_${i+1}_IP}    ACTIVE    OPERATIONAL    @{service_list}