csit/libraries/ClusterManagement.robot

   1 *** Settings ***
   2 Documentation     Resource housing Keywords common to several suites for cluster functional testing.
   3 ...
   4 ...               Copyright (c) 2016 Cisco Systems, Inc. and others. All rights reserved.
   5 ...               Copyright (c) 2016 Brocade Communications Systems, Inc. and others. All rights reserved.
   6 ...
   7 ...               This program and the accompanying materials are made available under the
   8 ...               terms of the Eclipse Public License v1.0 which accompanies this distribution,
   9 ...               and is available at http://www.eclipse.org/legal/epl-v10.html
  10 ...
  11 ...
  12 ...               This resource holds private state (in suite variables),
  13 ...               which is generated once at Setup with ClusterManagement_Setup KW.
  14 ...               The state includes member indexes, IP addresses and Http (RequestsLibrary) sessions.
  15 ...               Cluster Keywords normally use member index, member list or nothing (all members) as argument.
  16 ...
  17 ...               All index lists returned should be sorted numerically, fix if not.
  18 ...
  19 ...               Requirements:
  20 ...               odl-jolokia is assumed to be installed.
  21 ...
  22 ...               Keywords are ordered as follows:
  23 ...               - Cluster Setup
  24 ...               - Shard state, leader and followers
  25 ...               - Entity Owner, candidates and successors
  26 ...               - Kill, Stop and Start Member
  27 ...               - Isolate and Rejoin Member
  28 ...               - Run Commands On Member
  29 ...               - REST requests and checks on Members
  30 ...
  31 ...               TODO: Unify capitalization of Leaders and Followers.
  32 Library           RequestsLibrary    # for Create_Session and To_Json
  33 Library           Collections
  34 Resource          ${CURDIR}/CompareStream.robot
  35 Resource          ${CURDIR}/KarafKeywords.robot
  36 Resource          ${CURDIR}/SSHKeywords.robot
  37 Resource          ${CURDIR}/TemplatedRequests.robot    # for Get_As_Json_From_Uri
  38 Resource          ${CURDIR}/Utils.robot    # for Run_Command_On_Controller
  39
  40 *** Variables ***
  41 ${ENTITY_OWNER_URI}    restconf/operational/entity-owners:entity-owners
  42 ${GC_LOG_PATH}    ${KARAF_HOME}/data/log
  43 ${JAVA_HOME}      ${EMPTY}    # releng/builder scripts should provide correct value
  44 ${JOLOKIA_CONF_SHARD_MANAGER_URI}    jolokia/read/org.opendaylight.controller:Category=ShardManager,name=shard-manager-config,type=DistributedConfigDatastore
  45 ${JOLOKIA_OPER_SHARD_MANAGER_URI}    jolokia/read/org.opendaylight.controller:Category=ShardManager,name=shard-manager-operational,type=DistributedOperationalDatastore
  46 ${JOLOKIA_READ_URI}    jolokia/read/org.opendaylight.controller
  47 ${KARAF_HOME}     ${WORKSPACE}${/}${BUNDLEFOLDER}    # TODO: Migrate to Variables.robot
  48 # Bug 9044 workaround: delete etc/host.key before restart.
  49 @{ODL_DEFAULT_DATA_PATHS}    tmp/    data/    cache/    snapshots/    journal/    etc/opendaylight/current/    etc/host.key
  50 ${RESTCONF_MODULES_DIR}    ${CURDIR}/../variables/restconf/modules
  51 ${SINGLETON_NETCONF_DEVICE_ID_PREFIX}    /odl-general-entity:entity[odl-general-entity:name='KeyedInstanceIdentifier{targetType=interface org.opendaylight.yang.gen.v1.urn.tbd.params.xml.ns.yang.network.topology.rev131021.network.topology.topology.Node, path=[org.opendaylight.yang.gen.v1.urn.tbd.params.xml.ns.yang.network.topology.rev131021.NetworkTopology, org.opendaylight.yang.gen.v1.urn.tbd.params.xml.ns.yang.network.topology.rev131021.network.topology.Topology[key=TopologyKey [_topologyId=Uri [_value=topology-netconf]]], org.opendaylight.yang.gen.v1.urn.tbd.params.xml.ns.yang.network.topology.rev131021.network.topology.topology.Node[key=NodeKey [_nodeId=Uri [_value=
  52 ${SINGLETON_NETCONF_DEVICE_ID_SUFFIX}    ]]]]}']
  53 ${SINGLETON_ELECTION_ENTITY_TYPE}    org.opendaylight.mdsal.ServiceEntityType
  54 ${SINGLETON_CHANGE_OWNERSHIP_ENTITY_TYPE}    org.opendaylight.mdsal.AsyncServiceCloseEntityType
  55 ${NODE_START_COMMAND}    ${KARAF_HOME}/bin/start
  56 ${NODE_STOP_COMMAND}    ${KARAF_HOME}/bin/stop
  57 ${NODE_KARAF_COUNT_COMMAND}    ps axf | grep org.apache.karaf | grep -v grep | wc -l
  58 ${NODE_KILL_COMMAND}    ps axf | grep org.apache.karaf | grep -v grep | awk '{print \"kill -9 \" $1}' | sh
  59 ${NODE_FREEZE_COMMAND}    ps axf | grep org.apache.karaf | grep -v grep | awk '{print \"kill -STOP \" $1}' | sh
  60 ${NODE_UNFREEZE_COMMAND}    ps axf | grep org.apache.karaf | grep -v grep | awk '{print \"kill -CONT \" $1}' | sh
  61
  62 *** Keywords ***
  63 ClusterManagement_Setup
  64     [Arguments]    ${http_timeout}=1    ${http_retries}=0
  65     [Documentation]    Detect repeated call, or detect number of members and initialize derived suite variables.
  66     ...    Http sessions are created with parameters to not waste time when ODL is no accepting connections properly.
  67     # Avoid multiple initialization by several downstream libraries.
  68     ${already_done} =    BuiltIn.Get_Variable_Value    \${ClusterManagement__has_setup_run}    False
  69     BuiltIn.Return_From_Keyword_If    ${already_done}
  70     BuiltIn.Set_Suite_Variable    \${ClusterManagement__has_setup_run}    True
  71     ${cluster_size} =    BuiltIn.Get_Variable_Value    \${NUM_ODL_SYSTEM}    1
  72     ${status}    ${possibly_int_of_members} =    BuiltIn.Run_Keyword_And_Ignore_Error    BuiltIn.Convert_To_Integer    ${cluster_size}
  73     ${int_of_members} =    BuiltIn.Set_Variable_If    '${status}' != 'PASS'    ${1}    ${possibly_int_of_members}
  74     ClusterManagement__Compute_Derived_Variables    int_of_members=${int_of_members}    http_timeout=${http_timeout}    http_retries=${http_retries}
  75
  76 Check_Cluster_Is_In_Sync
  77     [Arguments]    ${member_index_list}=${EMPTY}
  78     [Documentation]    Fail if no-sync is detected on a member from list (or any).
  79     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
  80     : FOR    ${index}    IN    @{index_list}    # usually: 1, 2, 3.
  81     \    ${status} =    Get_Sync_Status_Of_Member    member_index=${index}
  82     \    BuiltIn.Continue_For_Loop_If    'True' == '${status}'
  83     \    BuiltIn.Fail    Index ${index} has incorrect status: ${status}
  84
  85 Get_Sync_Status_Of_Member
  86     [Arguments]    ${member_index}
  87     [Documentation]    Obtain IP, two GETs from jolokia URIs, return combined sync status as string.
  88     ${session} =    Resolve_Http_Session_For_Member    member_index=${member_index}
  89     ${conf_text} =    TemplatedRequests.Get_As_Json_From_Uri    uri=${JOLOKIA_CONF_SHARD_MANAGER_URI}    session=${session}
  90     ${conf_status} =    ClusterManagement__Parse_Sync_Status    shard_manager_text=${conf_text}
  91     BuiltIn.Return_From_Keyword_If    'False' == ${conf_status}    False
  92     ${oper_text} =    TemplatedRequests.Get_As_Json_From_Uri    uri=${JOLOKIA_OPER_SHARD_MANAGER_URI}    session=${session}
  93     ${oper_status} =    ClusterManagement__Parse_Sync_Status    shard_manager_text=${oper_text}
  94     [Return]    ${oper_status}
  95
  96 Verify_Leader_Exists_For_Each_Shard
  97     [Arguments]    ${shard_name_list}    ${shard_type}=operational    ${member_index_list}=${EMPTY}    ${verify_restconf}=True
  98     [Documentation]    For each shard name, call Get_Leader_And_Followers_For_Shard.
  99     ...    Not much logic there, but single Keyword is useful when using BuiltIn.Wait_Until_Keyword_Succeeds.
 100     : FOR    ${shard_name}    IN    @{shard_name_list}
 101     \    Get_Leader_And_Followers_For_Shard    shard_name=${shard_name}    shard_type=${shard_type}    validate=True    member_index_list=${member_index_list}    verify_restconf=${verify_restconf}
 102
 103 Get_Leader_And_Followers_For_Shard
 104     [Arguments]    ${shard_name}=default    ${shard_type}=operational    ${validate}=True    ${member_index_list}=${EMPTY}    ${verify_restconf}=True    ${http_timeout}=5
 105     [Documentation]    Get role lists, validate there is one leader, return the leader and list of followers.
 106     ...    Optionally, issue GET to a simple restconf URL to make sure subsequent operations will not encounter 503.
 107     ${leader_list}    ${follower_list} =    Get_State_Info_For_Shard    shard_name=${shard_name}    shard_type=${shard_type}    validate=True    member_index_list=${member_index_list}
 108     ...    verify_restconf=${verify_restconf}    http_timeout=${http_timeout}
 109     ${leader_count} =    BuiltIn.Get_Length    ${leader_list}
 110     BuiltIn.Run_Keyword_If    ${leader_count} < 1    BuiltIn.Fail    No leader found.
 111     BuiltIn.Length_Should_Be    ${leader_list}    ${1}    Too many Leaders.
 112     ${leader} =    Collections.Get_From_List    ${leader_list}    0
 113     [Return]    ${leader}    ${follower_list}
 114
 115 Get_State_Info_For_Shard
 116     [Arguments]    ${shard_name}=default    ${shard_type}=operational    ${validate}=False    ${member_index_list}=${EMPTY}    ${verify_restconf}=False    ${http_timeout}=5
 117     [Documentation]    Return lists of Leader and Follower member indices from a given member index list
 118     ...    (or from the full list if empty). If \${shard_type} is not 'config', 'operational' is assumed.
 119     ...    If \${validate}, Fail if raft state is not Leader or Follower (for example on Candidate).
 120     ...    The biggest difference from Get_Leader_And_Followers_For_Shard
 121     ...    is that no check on number of Leaders is performed.
 122     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 123     Collections.Sort_List    ${index_list}    # to guarantee return values are also sorted lists
 124     # TODO: Support alternative capitalization of 'config'?
 125     ${ds_type} =    BuiltIn.Set_Variable_If    '${shard_type}' != 'config'    operational    config
 126     ${leader_list} =    BuiltIn.Create_List
 127     ${follower_list} =    BuiltIn.Create_List
 128     : FOR    ${index}    IN    @{index_list}    # usually: 1, 2, 3.
 129     \    ${raft_state} =    Get_Raft_State_Of_Shard_At_Member    shard_name=${shard_name}    shard_type=${ds_type}    member_index=${index}    verify_restconf=${verify_restconf}
 130     \    ...    http_timeout=${http_timeout}
 131     \    BuiltIn.Run_Keyword_If    'Follower' == '${raft_state}'    Collections.Append_To_List    ${follower_list}    ${index}
 132     \    ...    ELSE IF    'Leader' == '${raft_state}'    Collections.Append_To_List    ${leader_list}    ${index}
 133     \    ...    ELSE IF    ${validate}    BuiltIn.Fail    Unrecognized Raft state: ${raft_state}
 134     [Return]    ${leader_list}    ${follower_list}
 135
 136 Get_Raft_State_Of_Shard_At_Member
 137     [Arguments]    ${shard_name}    ${shard_type}    ${member_index}    ${verify_restconf}=False    ${http_timeout}=5
 138     [Documentation]    Send request to Jolokia on indexed member, return extracted Raft status.
 139     ...    Optionally, check restconf works.
 140     ${raft_state} =    Get_Raft_Property_From_Shard_Member    RaftState    ${shard_name}    ${shard_type}    ${member_index}    verify_restconf=${verify_restconf}
 141     ...    http_timeout=${http_timeout}
 142     [Return]    ${raft_state}
 143
 144 Get_Raft_Property_From_Shard_Member
 145     [Arguments]    ${property}    ${shard_name}    ${shard_type}    ${member_index}    ${verify_restconf}=False    ${http_timeout}=5
 146     [Documentation]    Send request to Jolokia on indexed member, return extracted Raft property.
 147     ...    Optionally, check restconf works.
 148     ${session} =    Resolve_Http_Session_For_Member    member_index=${member_index}
 149     # TODO: Does the used URI tend to generate large data which floods log.html?
 150     BuiltIn.Run_Keyword_If    ${verify_restconf}    TemplatedRequests.Get_As_Json_Templated    session=${session}    folder=${RESTCONF_MODULES_DIR}    verify=False    http_timeout=${http_timeout}
 151     ${type_class} =    Resolve_Shard_Type_Class    shard_type=${shard_type}
 152     ${uri} =    BuiltIn.Set_Variable    ${JOLOKIA_READ_URI}:Category=Shards,name=member-${member_index}-shard-${shard_name}-${shard_type},type=${type_class}
 153     ${data_text} =    TemplatedRequests.Get_As_Json_From_Uri    uri=${uri}    session=${session}    http_timeout=${http_timeout}
 154     ${data_object} =    RequestsLibrary.To_Json    ${data_text}
 155     ${value} =    Collections.Get_From_Dictionary    ${data_object}    value
 156     ${raft_property} =    Collections.Get_From_Dictionary    ${value}    ${property}
 157     [Return]    ${raft_property}
 158
 159 Verify_Shard_Leader_Elected
 160     [Arguments]    ${shard_name}    ${shard_type}    ${new_elected}    ${old_leader}    ${member_index_list}=${EMPTY}    ${verify_restconf}=True
 161     [Documentation]    Verify new leader was elected or remained the same. Bool paramter ${new_elected} indicates if
 162     ...    new leader is elected or should remained the same as ${old_leader}
 163     ${leader}    ${followers}=    Get_Leader_And_Followers_For_Shard    shard_name=${shard_name}    shard_type=${shard_type}    member_index_list=${member_index_list}    verify_restconf=${verify_restconf}
 164     BuiltIn.Run_Keyword_If    ${new_elected}    BuiltIn.Should_Not_Be_Equal_As_Numbers    ${old_leader}    ${leader}
 165     BuiltIn.Run_Keyword_Unless    ${new_elected}    BuiltIn.Should_Be_Equal_As_numbers    ${old_leader}    ${leader}
 166     BuiltIn.Return_From_Keyword    ${leader}    ${followers}
 167
 168 Verify_Owner_And_Successors_For_Device
 169     [Arguments]    ${device_name}    ${device_type}    ${member_index}    ${candidate_list}=${EMPTY}    ${after_stop}=False
 170     [Documentation]    Returns the owner and successors for the SB device ${device_name} of type ${device_type}. Request is sent to member ${member_index}.
 171     ...    For Boron and beyond, candidates are not removed on node down or isolation,
 172     ...    so this keyword expects candidates to be all members from Boron on.
 173     ...    Extra check is done to verify owner and successors are within the ${candidate_list}. This KW is useful when combined with WUKS.
 174     ...    ${candidate_list} minus owner is returned as ${successor list}.
 175     ...    Users can still use Get_Owner_And_Successors_For_Device if they are interested in downed candidates,
 176     ...    or for testing heterogeneous clusters.
 177     ${index_list} =    List_Indices_Or_All    given_list=${candidate_list}
 178     ${owner}    ${successor_list} =    Get_Owner_And_Successors_For_Device    device_name=${device_name}    device_type=${device_type}    member_index=${member_index}
 179     Collections.List_Should_Contain_Value    ${index_list}    ${owner}    Owner ${owner} is not in candidate list ${index_list}
 180     # In Beryllium or after stopping an instance, the removed instance does not show in the candidate list.
 181     ${expected_candidate_list_origin} =    BuiltIn.Set_Variable_If    ${after_stop}    ${index_list}    ${ClusterManagement__member_index_list}
 182     # We do not want to manipulate either origin list.
 183     ${expected_successor_list} =    BuiltIn.Create_List    @{expected_candidate_list_origin}
 184     Collections.Remove_Values_From_List    ${expected_successor_list}    ${owner}
 185     Collections.Lists_Should_Be_Equal    ${expected_successor_list}    ${successor_list}    Successor list ${successor_list} is not the came as expected ${expected_successor_list}
 186     # User expects the returned successor list to be the provided candidate list minus the owner.
 187     Collections.Remove_Values_From_List    ${index_list}    ${owner}
 188     [Return]    ${owner}    ${index_list}
 189
 190 Get_Owner_And_Successors_For_Device
 191     [Arguments]    ${device_name}    ${device_type}    ${member_index}    ${http_timeout}=${EMPTY}
 192     [Documentation]    Returns the owner and a list of successors for the SB device ${device_name} of type ${device_type}. Request is sent to member ${member_index}.
 193     ...    Successors are those device candidates not elected as owner. The list of successors = (list of candidates) - (owner).
 194     ...    The returned successor list is sorted numerically.
 195     ...    Note that "candidate list" definition currently differs between Beryllium and Boron.
 196     ...    Use Verify_Owner_And_Successors_For_Device if you want the older semantics (inaccessible nodes not present in the list).
 197     # TODO: somewhere to introduce ${DEFAULT_RESTCONF_DATASTORE_TIMEOUT}. Value may depend on protocol (ask vs tell) and perhaps stream.
 198     ${owner}    ${candidate_list} =    Get_Owner_And_Candidates_For_Device    device_name=${device_name}    device_type=${device_type}    member_index=${member_index}    http_timeout=${http_timeout}
 199     ${successor_list} =    BuiltIn.Create_List    @{candidate_list}    # Copy operation is not required, but new variable name requires a line anyway.
 200     Collections.Remove_Values_From_List    ${successor_list}    ${owner}
 201     [Return]    ${owner}    ${successor_list}
 202
 203 Get_Owner_And_Candidates_For_Device_Old
 204     [Arguments]    ${device_name}    ${device_type}    ${member_index}    ${http_timeout}=${EMPTY}
 205     [Documentation]    Returns the owner and a list of candidates for the SB device ${device_name} of type ${device_type}. Request is sent to member ${member_index}.
 206     ...    Candidates are all members that register to own a device, so the list of candiates includes the owner.
 207     ...    The returned candidate list is sorted numerically.
 208     ...    Note that "candidate list" definition currently differs between Beryllium and Boron.
 209     ...    It is recommended to use Get_Owner_And_Successors_For_Device instead of this keyword, see documentation there.
 210     BuiltIn.Comment    TODO: Can this implementation be changed to call Get_Owner_And_Candidates_For_Type_And_Id?
 211     ${session} =    Resolve_Http_Session_For_Member    member_index=${member_index}
 212     ${data} =    TemplatedRequests.Get_As_Json_From_Uri    uri=${ENTITY_OWNER_URI}    session=${session}    http_timeout=${http_timeout}
 213     ${candidate_list} =    BuiltIn.Create_List
 214     ${entity_type} =    BuiltIn.Set_Variable_If    '${device_type}' == 'netconf'    netconf-node/${device_name}    ${device_type}
 215     ${clear_data} =    BuiltIn.Run_Keyword_If    '${device_type}' == 'openflow' or '${device_type}' == 'netconf'    Extract_OpenFlow_Device_Data    ${data}
 216     ...    ELSE IF    '${device_type}' == 'ovsdb'    Extract_Ovsdb_Device_Data    ${data}
 217     ...    ELSE IF    '${device_type}' == 'org.opendaylight.mdsal.ServiceEntityType'    Extract_Service_Entity_Type    ${data}
 218     ...    ELSE    Fail    Not recognized device type: ${device_type}
 219     ${json} =    RequestsLibrary.To_Json    ${clear_data}
 220     ${entity_type_list} =    Collections.Get_From_Dictionary    &{json}[entity-owners]    entity-type
 221     ${entity_type_index} =    Utils.Get_Index_From_List_Of_Dictionaries    ${entity_type_list}    type    ${entity_type}
 222     BuiltIn.Should_Not_Be_Equal_As_Integers    ${entity_type_index}    -1    No Entity Owner found for ${device_type}
 223     ${entity_list} =    Collections.Get_From_Dictionary    @{entity_type_list}[${entity_type_index}]    entity
 224     ${entity_index} =    Utils.Get_Index_From_List_Of_Dictionaries    ${entity_list}    id    ${device_name}
 225     BuiltIn.Should_Not_Be_Equal_As_Integers    ${entity_index}    -1    Device ${device_name} not found in Entity Owner ${device_type}
 226     ${entity_owner} =    Collections.Get_From_Dictionary    @{entity_list}[${entity_index}]    owner
 227     BuiltIn.Should_Not_Be_Empty    ${entity_owner}    No owner found for ${device_name}
 228     ${owner} =    String.Replace_String    ${entity_owner}    member-    ${EMPTY}
 229     ${owner} =    BuiltIn.Convert_To_Integer    ${owner}
 230     ${entity_candidates_list} =    Collections.Get_From_Dictionary    @{entity_list}[${entity_index}]    candidate
 231     : FOR    ${entity_candidate}    IN    @{entity_candidates_list}
 232     \    ${candidate} =    String.Replace_String    &{entity_candidate}[name]    member-    ${EMPTY}
 233     \    ${candidate} =    BuiltIn.Convert_To_Integer    ${candidate}
 234     \    Collections.Append_To_List    ${candidate_list}    ${candidate}
 235     Collections.Sort_List    ${candidate_list}
 236     [Return]    ${owner}    ${candidate_list}
 237
 238 Get_Owner_And_Candidates_For_Device_Singleton
 239     [Arguments]    ${device_name}    ${device_type}    ${member_index}    ${http_timeout}=${EMPTY}
 240     [Documentation]    Returns the owner and a list of candidates for the SB device ${device_name} of type ${device_type}. Request is sent to member ${member_index}.
 241     ...    Parsing method is selected by device type
 242     ...    Separate kw for every supported device type must be defined
 243     BuiltIn.Keyword_Should_Exist    Get_Owner_And_Candidates_For_Device_Singleton_${device_type}
 244     BuiltIn.Run_Keyword_And_Return    Get_Owner_And_Candidates_For_Device_Singleton_${device_type}    ${device_name}    ${member_index}    http_timeout=${http_timeout}
 245
 246 Get_Owner_And_Candidates_For_Device_Singleton_Netconf
 247     [Arguments]    ${device_name}    ${member_index}    ${http_timeout}=${EMPTY}
 248     [Documentation]    Returns the owner and a list of candidates for the SB device ${device_name} of type netconf. Request is sent to member ${member_index}.
 249     ...    Parsing method is set as netconf (using netconf device id prefix and suffix)
 250     # Get election entity type results
 251     ${type} =    BuiltIn.Set_Variable    ${SINGLETON_ELECTION_ENTITY_TYPE}
 252     ${id} =    BuiltIn.Set_Variable    ${SINGLETON_NETCONF_DEVICE_ID_PREFIX}${device_name}${SINGLETON_NETCONF_DEVICE_ID_SUFFIX}
 253     ${owner_1}    ${candidate_list_1} =    Get_Owner_And_Candidates_For_Type_And_Id    ${type}    ${id}    ${member_index}    http_timeout=${http_timeout}
 254     # Get change ownership entity type results
 255     ${type} =    BuiltIn.Set_Variable    ${SINGLETON_CHANGE_OWNERSHIP_ENTITY_TYPE}
 256     ${id} =    BuiltIn.Set_Variable    ${SINGLETON_NETCONF_DEVICE_ID_PREFIX}${device_name}${SINGLETON_NETCONF_DEVICE_ID_SUFFIX}
 257     ${owner_2}    ${candidate_list_2} =    Get_Owner_And_Candidates_For_Type_And_Id    ${type}    ${id}    ${member_index}    http_timeout=${http_timeout}
 258     # Owners must be same, if not, there is still some election or change ownership in progress
 259     BuiltIn.Should_Be_Equal_As_Integers    ${owner_1}    ${owner_2}    Owners for device ${device_name} are not same
 260     [Return]    ${owner_1}    ${candidate_list_1}
 261
 262 Get_Owner_And_Candidates_For_Device
 263     [Arguments]    ${device_name}    ${device_type}    ${member_index}    ${http_timeout}=${EMPTY}
 264     [Documentation]    Returns the owner and a list of candidates for the SB device ${device_name} of type ${device_type}. Request is sent to member ${member_index}.
 265     ...    If parsing as singleton failed, kw try to parse data in old way (without singleton).
 266     ...    Candidates are all members that register to own a device, so the list of candiates includes the owner.
 267     ...    The returned candidate list is sorted numerically.
 268     ...    Note that "candidate list" definition currently differs between Beryllium and Boron.
 269     ...    It is recommended to use Get_Owner_And_Successors_For_Device instead of this keyword, see documentation there.
 270     # Try singleton
 271     ${status}    ${results} =    BuiltIn.Run_Keyword_And_Ignore_Error    Get_Owner_And_Candidates_For_Device_Singleton    device_name=${device_name}    device_type=${device_type}    member_index=${member_index}
 272     ...    http_timeout=${http_timeout}
 273     BuiltIn.Return_From_Keyword_If    "${status}"=="PASS"    ${results}
 274     # If singleton failed, try parsing in old way
 275     ${status}    ${results} =    BuiltIn.Run_Keyword_And_Ignore_Error    Get_Owner_And_Candidates_For_Device_Old    device_name=${device_name}    device_type=${device_type}    member_index=${member_index}
 276     ...    http_timeout=${http_timeout}
 277     # previous 3 lines (BuilIn.Return.., # If singleton..., ${status}....) could be deleted when old way will not be supported anymore
 278     BuiltIn.Run_Keyword_If    '${status}'=='FAIL'    BuiltIn.Fail    Could not parse owner and candidates for device ${device_name}
 279     [Return]    @{results}
 280
 281 Check_Old_Owner_Stays_Elected_For_Device
 282     [Arguments]    ${device_name}    ${device_type}    ${old_owner}    ${node_to_ask}    ${http_timeout}=${EMPTY}
 283     [Documentation]    Verify the owner remain the same as ${old_owner}
 284     ${owner}    ${candidates} =    Get_Owner_And_Candidates_For_Device    ${device_name}    ${device_type}    ${node_to_ask}    http_timeout=${http_timeout}
 285     BuiltIn.Should_Be_Equal_As_numbers    ${old_owner}    ${owner}
 286     BuiltIn.Return_From_Keyword    ${owner}    ${candidates}
 287
 288 Check_New_Owner_Got_Elected_For_Device
 289     [Arguments]    ${device_name}    ${device_type}    ${old_owner}    ${node_to_ask}    ${http_timeout}=${EMPTY}
 290     [Documentation]    Verify new owner was elected comparing to ${old_owner}
 291     ${owner}    ${candidates} =    Get_Owner_And_Candidates_For_Device    ${device_name}    ${device_type}    ${node_to_ask}    http_timeout=${http_timeout}
 292     BuiltIn.Should_Not_Be_Equal_As_Numbers    ${old_owner}    ${owner}
 293     BuiltIn.Return_From_Keyword    ${owner}    ${candidates}
 294
 295 Get_Owner_And_Candidates_For_Type_And_Id
 296     [Arguments]    ${type}    ${id}    ${member_index}    ${require_candidate_list}=${EMPTY}    ${http_timeout}=${EMPTY}
 297     [Documentation]    Returns the owner and a list of candidates for entity specified by ${type} and ${id}
 298     ...    Request is sent to member ${member_index}.
 299     ...    Candidates are all members that register to own a device, so the list of candiates includes the owner.
 300     ...    Bear in mind that for Boron and beyond, candidates are not removed on node down or isolation.
 301     ...    If ${require_candidate_list} is not \${EMPTY}, check whether the actual list of candidates matches.
 302     ...    Note that differs from "given list" semantics used in other keywords,
 303     ...    namely you cannot use \${EMPTY} to stand for "full list" in this keyword.
 304     BuiltIn.Comment    TODO: Find a way to unify and deduplicate code blocks in Get_Owner_And_Candidates_* keywords.
 305     ${session} =    Resolve_Http_Session_For_Member    member_index=${member_index}
 306     ${data} =    TemplatedRequests.Get_As_Json_From_Uri    uri=${ENTITY_OWNER_URI}    session=${session}    http_timeout=${http_timeout}
 307     ${candidate_list} =    BuiltIn.Create_List
 308     ${json} =    RequestsLibrary.To_Json    ${data}
 309     ${entity_type_list} =    Collections.Get_From_Dictionary    &{json}[entity-owners]    entity-type
 310     ${entity_type_index} =    Utils.Get_Index_From_List_Of_Dictionaries    ${entity_type_list}    type    ${type}
 311     BuiltIn.Should_Not_Be_Equal_As_Integers    ${entity_type_index}    -1    No Entity Owner found for ${type}
 312     ${entity_list} =    Collections.Get_From_Dictionary    @{entity_type_list}[${entity_type_index}]    entity
 313     ${entity_index} =    Utils.Get_Index_From_List_Of_Dictionaries    ${entity_list}    id    ${id}
 314     BuiltIn.Should Not_Be_Equal_As_Integers    ${entity_index}    -1    Id ${id} not found in Entity Owner ${type}
 315     ${entity_owner} =    Collections.Get_From_Dictionary    @{entity_list}[${entity_index}]    owner
 316     BuiltIn.Should_Not_Be_Empty    ${entity_owner}    No owner found for type=${type} id=${id}
 317     ${owner} =    String.Replace_String    ${entity_owner}    member-    ${EMPTY}
 318     ${owner} =    BuiltIn.Convert_To_Integer    ${owner}
 319     ${entity_candidates_list} =    Collections.Get_From_Dictionary    @{entity_list}[${entity_index}]    candidate
 320     : FOR    ${entity_candidate}    IN    @{entity_candidates_list}
 321     \    ${candidate} =    String.Replace_String    &{entity_candidate}[name]    member-    ${EMPTY}
 322     \    ${candidate} =    BuiltIn.Convert_To_Integer    ${candidate}
 323     \    Collections.Append_To_List    ${candidate_list}    ${candidate}
 324     Collections.Sort_List    ${candidate_list}
 325     BuiltIn.Comment    TODO: Separate check lines into Verify_Owner_And_Candidates_For_Type_And_Id
 326     BuiltIn.Run_Keyword_If    """${require_candidate_list}"""    BuiltIn.Should_Be_Equal    ${require_candidate_list}    ${candidate_list}    Candidate list does not match: ${candidate_list} is not ${require_candidate_list}
 327     [Return]    ${owner}    ${candidate_list}
 328
 329 Extract_Service_Entity_Type
 330     [Arguments]    ${data}
 331     [Documentation]    Remove superfluous device data from Entity Owner printout.
 332     ${clear_data} =    String.Replace_String    ${data}    /odl-general-entity:entity[odl-general-entity:name='    ${EMPTY}
 333     ${clear_data} =    String.Replace_String    ${clear_data}    -service-group']    ${EMPTY}
 334     Log    ${clear_data}
 335     [Return]    ${clear_data}
 336
 337 Extract_OpenFlow_Device_Data
 338     [Arguments]    ${data}
 339     [Documentation]    Remove superfluous OpenFlow device data from Entity Owner printout.
 340     ${clear_data} =    String.Replace_String    ${data}    org.opendaylight.mdsal.ServiceEntityType    openflow
 341     ${clear_data} =    String.Replace_String    ${clear_data}    /odl-general-entity:entity[odl-general-entity:name='    ${EMPTY}
 342     ${clear_data} =    String.Replace_String    ${clear_data}    /general-entity:entity[general-entity:name='    ${EMPTY}
 343     ${clear_data} =    String.Replace_String    ${clear_data}    ']    ${EMPTY}
 344     Log    ${clear_data}
 345     [Return]    ${clear_data}
 346
 347 Extract_Ovsdb_Device_Data
 348     [Arguments]    ${data}
 349     [Documentation]    Remove superfluous OVSDB device data from Entity Owner printout.
 350     ${clear_data} =    String.Replace_String    ${data}    /network-topology:network-topology/network-topology:topology[network-topology:topology-id='ovsdb:1']/network-topology:node[network-topology:node-id='    ${EMPTY}
 351     ${clear_data} =    String.Replace_String    ${clear_data}    ']    ${EMPTY}
 352     Log    ${clear_data}
 353     [Return]    ${clear_data}
 354
 355 Kill_Single_Member
 356     [Arguments]    ${member}    ${original_index_list}=${EMPTY}    ${confirm}=True
 357     [Documentation]    Convenience keyword that kills the specified member of the cluster.
 358     ...    The KW will return a list of available members: \${updated index_list}=\${original_index_list}-\${member}
 359     ${index_list} =    ClusterManagement__Build_List    ${member}
 360     ${member_ip} =    Return_Member_IP    ${member}
 361     KarafKeywords.Log_Message_To_Controller_Karaf    Killing ODL${member} ${member_ip}
 362     ${updated_index_list} =    Kill_Members_From_List_Or_All    ${index_list}    ${original_index_list}    ${confirm}
 363     [Return]    ${updated_index_list}
 364
 365 Kill_Members_From_List_Or_All
 366     [Arguments]    ${member_index_list}=${EMPTY}    ${original_index_list}=${EMPTY}    ${confirm}=True
 367     [Documentation]    If the list is empty, kill all ODL instances. Otherwise, kill members based on \${kill_index_list}
 368     ...    If \${confirm} is True, sleep 1 second and verify killed instances are not there anymore.
 369     ...    The KW will return a list of available members: \${updated index_list}=\${original_index_list}-\${member_index_list}
 370     ${kill_index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 371     ${index_list} =    List_Indices_Or_All    given_list=${original_index_list}
 372     Run_Bash_Command_On_List_Or_All    command=${NODE_KILL_COMMAND}    member_index_list=${member_index_list}
 373     ${updated_index_list} =    BuiltIn.Create_List    @{index_list}
 374     Collections.Remove_Values_From_List    ${updated_index_list}    @{kill_index_list}
 375     BuiltIn.Return_From_Keyword_If    not ${confirm}    ${updated_index_list}
 376     # TODO: Convert to WUKS with configurable timeout if it turns out 1 second is not enough.
 377     BuiltIn.Sleep    1s    Kill -9 closes open files, which may take longer than ssh overhead, but not long enough to warrant WUKS.
 378     : FOR    ${index}    IN    @{kill_index_list}
 379     \    Verify_Karaf_Is_Not_Running_On_Member    member_index=${index}
 380     Run_Bash_Command_On_List_Or_All    command=netstat -pnatu | grep 2550
 381     [Return]    ${updated_index_list}
 382
 383 Stop_Single_Member
 384     [Arguments]    ${member}    ${original_index_list}=${EMPTY}    ${confirm}=True
 385     [Documentation]    Convenience keyword that stops the specified member of the cluster.
 386     ...    The KW will return a list of available members: \${updated index_list}=\${original_index_list}-\${member}
 387     ${index_list} =    ClusterManagement__Build_List    ${member}
 388     ${updated_index_list} =    Stop_Members_From_List_Or_All    ${index_list}    ${original_index_list}    ${confirm}
 389     [Return]    ${updated_index_list}
 390
 391 Stop_Members_From_List_Or_All
 392     [Arguments]    ${member_index_list}=${EMPTY}    ${original_index_list}=${EMPTY}    ${confirm}=True    ${timeout}=120s
 393     [Documentation]    If the list is empty, stops all ODL instances. Otherwise stop members based on \${stop_index_list}
 394     ...    If \${confirm} is True, verify stopped instances are not there anymore.
 395     ...    The KW will return a list of available members: \${updated index_list}=\${original_index_list}-\${member_index_list}
 396     ${stop_index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 397     ${index_list} =    List_Indices_Or_All    given_list=${original_index_list}
 398     Run_Bash_Command_On_List_Or_All    command=${NODE_STOP_COMMAND}    member_index_list=${member_index_list}
 399     ${updated_index_list} =    BuiltIn.Create_List    @{index_list}
 400     Collections.Remove_Values_From_List    ${updated_index_list}    @{stop_index_list}
 401     BuiltIn.Return_From_Keyword_If    not ${confirm}    ${updated_index_list}
 402     : FOR    ${index}    IN    @{stop_index_list}
 403     \    BuiltIn.Wait Until Keyword Succeeds    ${timeout}    2s    Verify_Karaf_Is_Not_Running_On_Member    member_index=${index}
 404     Run_Bash_Command_On_List_Or_All    command=netstat -pnatu | grep 2550
 405     [Return]    ${updated_index_list}
 406
 407 Start_Single_Member
 408     [Arguments]    ${member}    ${wait_for_sync}=True    ${timeout}=300s
 409     [Documentation]    Convenience keyword that starts the specified member of the cluster.
 410     ${index_list} =    ClusterManagement__Build_List    ${member}
 411     Start_Members_From_List_Or_All    ${index_list}    ${wait_for_sync}    ${timeout}
 412
 413 Start_Members_From_List_Or_All
 414     [Arguments]    ${member_index_list}=${EMPTY}    ${wait_for_sync}=True    ${timeout}=300s    ${karaf_home}=${EMPTY}    ${export_java_home}=${EMPTY}    ${gc_log_dir}=${EMPTY}
 415     [Documentation]    If the list is empty, start all cluster members. Otherwise, start members based on present indices.
 416     ...    If ${wait_for_sync}, wait for cluster sync on listed members.
 417     ...    Optionally karaf_home can be overriden. Optionally specific JAVA_HOME is used for starting.
 418     ...    Garbage collection is unconditionally logged to files. TODO: Make that reasonable conditional?
 419     ${base_command} =    BuiltIn.Set_Variable_If    """${karaf_home}""" != ""    ${karaf_home}/bin/start    ${NODE_START_COMMAND}
 420     ${command} =    BuiltIn.Set_Variable_If    """${export_java_home}""" != ""    export JAVA_HOME="${export_java_home}"; ${base_command}    ${base_command}
 421     ${epoch} =    DateTime.Get_Current_Date    time_zone=UTC    result_format=epoch    exclude_millis=False
 422     ${gc_filepath} =    BuiltIn.Set_Variable_If    """${karaf_home}""" != ""    ${karaf_home}/data/log/gc_${epoch}.log    ${GC_LOG_PATH}/gc_${epoch}.log
 423     ${gc_options} =    BuiltIn.Set_Variable_If    "docker" not in """${node_start_command}"""    -XX:+PrintGCDetails -XX:+PrintGCDateStamps -Xloggc:${gc_filepath}    ${EMPTY}
 424     Run_Bash_Command_On_List_Or_All    command=${command} ${gc_options}    member_index_list=${member_index_list}
 425     BuiltIn.Return_From_Keyword_If    not ${wait_for_sync}
 426     BuiltIn.Wait_Until_Keyword_Succeeds    ${timeout}    10s    Check_Cluster_Is_In_Sync    member_index_list=${member_index_list}
 427     # TODO: Do we also want to check Shard Leaders here?
 428     [Teardown]    Run_Bash_Command_On_List_Or_All    command=netstat -pnatu | grep 2550
 429
 430 Freeze_Single_Member
 431     [Arguments]    ${member}
 432     [Documentation]    Convenience keyword that stops the specified member of the cluster by freezing the jvm.
 433     ${index_list} =    ClusterManagement__Build_List    ${member}
 434     Freeze_Or_Unfreeze_Members_From_List_Or_All    ${NODE_FREEZE_COMMAND}    ${index_list}
 435
 436 Unfreeze_Single_Member
 437     [Arguments]    ${member}    ${wait_for_sync}=True    ${timeout}=60s
 438     [Documentation]    Convenience keyword that "continues" the specified member of the cluster by unfreezing the jvm.
 439     ${index_list} =    ClusterManagement__Build_List    ${member}
 440     Freeze_Or_Unfreeze_Members_From_List_Or_All    ${NODE_UNFREEZE_COMMAND}    ${index_list}
 441     BuiltIn.Wait_Until_Keyword_Succeeds    ${timeout}    10s    Check_Cluster_Is_In_Sync
 442
 443 Freeze_Or_Unfreeze_Members_From_List_Or_All
 444     [Arguments]    ${command}    ${member_index_list}=${EMPTY}
 445     [Documentation]    If the list is empty, stops/runs all ODL instances. Otherwise stop/run members based on \${stop_index_list}
 446     ...    For command parameter only ${NODE_FREEZE_COMMAND} and ${NODE_UNFREEZE_COMMAND} should be used
 447     ${freeze_index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 448     Run_Bash_Command_On_List_Or_All    command=${command}    member_index_list=${member_index_list}
 449
 450 Clean_Journals_And_Snapshots_On_List_Or_All
 451     [Arguments]    ${member_index_list}=${EMPTY}    ${karaf_home}=${KARAF_HOME}
 452     [Documentation]    Delete journal and snapshots directories on every node listed (or all).
 453     ...    BEWARE: If only a subset of members is cleaned, this causes RetiredGenerationException in Carbon after the affected node re-start.
 454     ...    See https://bugs.opendaylight.org/show_bug.cgi?id=8138
 455     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 456     ${command} =    Set Variable    rm -rf "${karaf_home}/journal" "${karaf_home}/snapshots"
 457     : FOR    ${index}    IN    @{index_list}    # usually: 1, 2, 3.
 458     \    Run_Bash_Command_On_Member    command=${command}    member_index=${index}
 459
 460 Verify_Karaf_Is_Not_Running_On_Member
 461     [Arguments]    ${member_index}
 462     [Documentation]    Fail if non-zero karaf instances are counted on member of given index.
 463     ${count} =    Count_Running_Karafs_On_Member    member_index=${member_index}
 464     BuiltIn.Should_Be_Equal    0    ${count}    Found running Karaf count: ${count}
 465
 466 Verify_Single_Karaf_Is_Running_On_Member
 467     [Arguments]    ${member_index}
 468     [Documentation]    Fail if number of karaf instances on member of given index is not one.
 469     ${count} =    Count_Running_Karafs_On_Member    member_index=${member_index}
 470     BuiltIn.Should_Be_Equal    1    ${count}    Wrong number of Karafs running: ${count}
 471
 472 Count_Running_Karafs_On_Member
 473     [Arguments]    ${member_index}
 474     [Documentation]    Remotely execute grep for karaf process, return count as string.
 475     ${command} =    BuiltIn.Set_Variable    ${NODE_KARAF_COUNT_COMMAND}
 476     ${count} =    Run_Bash_Command_On_Member    command=${command}    member_index=${member_index}
 477     [Return]    ${count}
 478
 479 Isolate_Member_From_List_Or_All
 480     [Arguments]    ${isolate_member_index}    ${member_index_list}=${EMPTY}
 481     [Documentation]    If the list is empty, isolate member from all ODL instances. Otherwise, isolate member based on present indices.
 482     ...    The KW will return a list of available members: \${updated index_list}=\${member_index_list}-\${isolate_member_index}
 483     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 484     ${source} =    Collections.Get_From_Dictionary    ${ClusterManagement__index_to_ip_mapping}    ${isolate_member_index}
 485     : FOR    ${index}    IN    @{index_list}
 486     \    ${destination} =    Collections.Get_From_Dictionary    ${ClusterManagement__index_to_ip_mapping}    ${index}
 487     \    ${command} =    BuiltIn.Set_Variable    sudo /sbin/iptables -I OUTPUT -p all --source ${source} --destination ${destination} -j DROP
 488     \    BuiltIn.Run_Keyword_If    "${index}" != "${isolate_member_index}"    Run_Bash_Command_On_Member    command=${command}    member_index=${isolate_member_index}
 489     ${command} =    BuiltIn.Set_Variable    sudo /sbin/iptables -L -n
 490     ${output} =    Run_Bash_Command_On_Member    command=${command}    member_index=${isolate_member_index}
 491     BuiltIn.Log    ${output}
 492     ${updated_index_list} =    BuiltIn.Create_List    @{index_list}
 493     Collections.Remove_Values_From_List    ${updated_index_list}    ${isolate_member_index}
 494     [Return]    ${updated_index_list}
 495
 496 Rejoin_Member_From_List_Or_All
 497     [Arguments]    ${rejoin_member_index}    ${member_index_list}=${EMPTY}
 498     [Documentation]    If the list is empty, rejoin member from all ODL instances. Otherwise, rejoin member based on present indices.
 499     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 500     ${source} =    Collections.Get_From_Dictionary    ${ClusterManagement__index_to_ip_mapping}    ${rejoin_member_index}
 501     : FOR    ${index}    IN    @{index_list}
 502     \    ${destination} =    Collections.Get_From_Dictionary    ${ClusterManagement__index_to_ip_mapping}    ${index}
 503     \    ${command} =    BuiltIn.Set_Variable    sudo /sbin/iptables -D OUTPUT -p all --source ${source} --destination ${destination} -j DROP
 504     \    BuiltIn.Run_Keyword_If    "${index}" != "${rejoin_member_index}"    Run_Bash_Command_On_Member    command=${command}    member_index=${rejoin_member_index}
 505     ${command} =    BuiltIn.Set_Variable    sudo /sbin/iptables -L -n
 506     ${output} =    Run_Bash_Command_On_Member    command=${command}    member_index=${rejoin_member_index}
 507     BuiltIn.Log    ${output}
 508
 509 Flush_Iptables_From_List_Or_All
 510     [Arguments]    ${member_index_list}=${EMPTY}
 511     [Documentation]    If the list is empty, flush IPTables in all ODL instances. Otherwise, flush member based on present indices.
 512     ${command} =    BuiltIn.Set_Variable    sudo iptables -v -F
 513     ${output} =    Run_Bash_Command_On_List_Or_All    command=${command}    member_index_list=${member_index_list}
 514
 515 Check_Bash_Command_On_List_Or_All
 516     [Arguments]    ${command}    ${member_index_list}=${EMPTY}    ${return_success_only}=False    ${log_on_success}=True    ${log_on_failure}=True    ${stderr_must_be_empty}=True
 517     [Documentation]    Cycle through indices (or all), run bash command on each, using temporary SSH session and restoring the previously active one.
 518     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 519     : FOR    ${index}    IN    @{index_list}
 520     \    Check_Bash_Command_On_Member    command=${command}    member_index=${index}    return_success_only=${return_success_only}    log_on_success=${log_on_success}    log_on_failure=${log_on_failure}
 521     \    ...    stderr_must_be_empty=${stderr_must_be_empty}
 522
 523 Check_Bash_Command_On_Member
 524     [Arguments]    ${command}    ${member_index}    ${return_success_only}=False    ${log_on_success}=True    ${log_on_failure}=True    ${stderr_must_be_empty}=True
 525     [Documentation]    Open SSH session, call SSHKeywords.Execute_Command_Passes, close session, restore previously active session and return output.
 526     BuiltIn.Run_Keyword_And_Return    SSHKeywords.Run_Keyword_Preserve_Connection    Check_Unsafely_Bash_Command_On_Member    ${command}    ${member_index}    return_success_only=${return_success_only}    log_on_success=${log_on_success}
 527     ...    log_on_failure=${log_on_failure}    stderr_must_be_empty=${stderr_must_be_empty}
 528
 529 Check_Unsafely_Bash_Command_On_Member
 530     [Arguments]    ${command}    ${member_index}    ${return_success_only}=False    ${log_on_success}=True    ${log_on_failure}=True    ${stderr_must_be_empty}=True
 531     [Documentation]    Obtain Ip address, open session, call SSHKeywords.Execute_Command_Passes, close session and return output. This affects which SSH session is active.
 532     ${member_ip} =    Resolve_Ip_Address_For_Member    ${member_index}
 533     BuiltIn.Run_Keyword_And_Return    SSHKeywords.Run_Unsafely_Keyword_Over_Temporary_Odl_Session    ${member_ip}    Execute_Command_Passes    ${command}    return_success_only=${return_success_only}    log_on_success=${log_on_success}
 534     ...    log_on_failure=${log_on_failure}    stderr_must_be_empty=${stderr_must_be_empty}
 535
 536 Run_Bash_Command_On_List_Or_All
 537     [Arguments]    ${command}    ${member_index_list}=${EMPTY}
 538     [Documentation]    Cycle through indices (or all), run command on each.
 539     # TODO: Migrate callers to Check_Bash_Command_*
 540     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 541     : FOR    ${index}    IN    @{index_list}
 542     \    Run_Bash_Command_On_Member    command=${command}    member_index=${index}
 543
 544 Run_Bash_Command_On_Member
 545     [Arguments]    ${command}    ${member_index}
 546     [Documentation]    Obtain IP, call Utils and return output. This keeps previous ssh session active.
 547     # TODO: Migrate callers to Check_Bash_Command_*
 548     ${member_ip} =    Collections.Get_From_Dictionary    dictionary=${ClusterManagement__index_to_ip_mapping}    key=${member_index}
 549     ${output} =    SSHKeywords.Run_Keyword_Preserve_Connection    Utils.Run_Command_On_Controller    ${member_ip}    ${command}
 550     Log    ${output}
 551     [Return]    ${output}
 552
 553 Run_Karaf_Command_On_List_Or_All
 554     [Arguments]    ${command}    ${member_index_list}=${EMPTY}    ${timeout}=10s
 555     [Documentation]    Cycle through indices (or all), run karaf command on each.
 556     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 557     : FOR    ${index}    IN    @{index_list}
 558     \    ${member_ip} =    Collections.Get_From_Dictionary    dictionary=${ClusterManagement__index_to_ip_mapping}    key=${index}
 559     \    KarafKeywords.Safe_Issue_Command_On_Karaf_Console    ${command}    ${member_ip}    timeout=${timeout}
 560
 561 Run_Karaf_Command_On_Member
 562     [Arguments]    ${command}    ${member_index}    ${timeout}=10s
 563     [Documentation]    Obtain IP address, call KarafKeywords and return output. This does not preserve active ssh session.
 564     ...    This keyword is not used by Run_Karaf_Command_On_List_Or_All, but returned output may be useful.
 565     ${member_ip} =    Collections.Get_From_Dictionary    dictionary=${ClusterManagement__index_to_ip_mapping}    key=${member_index}
 566     ${output} =    KarafKeywords.Safe_Issue_Command_On_Karaf_Console    ${command}    controller=${member_ip}    timeout=${timeout}
 567     [Return]    ${output}
 568
 569 Install_Feature_On_List_Or_All
 570     [Arguments]    ${feature_name}    ${member_index_list}=${EMPTY}    ${timeout}=60s
 571     [Documentation]    Attempt installation on each member from list (or all). Then look for failures.
 572     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 573     ${status_list} =    BuiltIn.Create_List
 574     : FOR    ${index}    IN    @{index_list}
 575     \    ${status}    ${text} =    BuiltIn.Run_Keyword_And_Ignore_Error    Install_Feature_On_Member    feature_name=${feature_name}    member_index=${index}
 576     \    ...    timeout=${timeout}
 577     \    BuiltIn.Log    ${text}
 578     \    Collections.Append_To_List    ${status_list}    ${status}
 579     : FOR    ${status}    IN    @{status_list}
 580     \    BuiltIn.Run_Keyword_If    "${status}" != "PASS"    BuiltIn.Fail    ${feature_name} installation failed, see log.
 581
 582 Install_Feature_On_Member
 583     [Arguments]    ${feature_name}    ${member_index}    ${timeout}=60s
 584     [Documentation]    Run feature:install karaf command, fail if installation was not successful. Return output.
 585     ${status}    ${output} =    BuiltIn.Run_Keyword_And_Ignore_Error    Run_Karaf_Command_On_Member    command=feature:install ${feature_name}    member_index=${member_index}    timeout=${timeout}
 586     BuiltIn.Run_Keyword_If    "${status}" != "PASS"    BuiltIn.Fail    Failed to install ${feature_name}: ${output}
 587     BuiltIn.Should_Not_Contain    ${output}    Can't install    Failed to install ${feature_name}: ${output}
 588     [Return]    ${output}
 589
 590 With_Ssh_To_List_Or_All_Run_Keyword
 591     [Arguments]    ${member_index_list}    ${keyword_name}    @{args}    &{kwargs}
 592     [Documentation]    For each index in given list (or all): activate SSH connection, run given Keyword, close active connection. Return None.
 593     ...    Beware that in order to avoid "got positional argument after named arguments", first two arguments in the call should not be named.
 594     BuiltIn.Comment    This keyword is experimental and there is high risk of being replaced by another approach.
 595     # TODO: For_Index_From_List_Or_All_Run_Keyword applied to With_Ssh_To_Member_Run_Keyword?
 596     # TODO: Imagine another keyword, using ScalarClosures and adding member index as first argument for each call. Worth it?
 597     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 598     : FOR    ${member_index}    IN    @{index_list}
 599     \    ${member_ip} =    Resolve_IP_Address_For_Member    ${member_index}
 600     \    SSHKeywords.Run_Unsafely_Keyword_Over_Temporary_Odl_Session    ${member_ip}    ${keyword_name}    @{args}    &{kwargs}
 601
 602 Safe_With_Ssh_To_List_Or_All_Run_Keyword
 603     [Arguments]    ${member_index_list}    ${keyword_name}    @{args}    &{kwargs}
 604     [Documentation]    Remember active ssh connection index, call With_Ssh_To_List_Or_All_Run_Keyword, return None. Restore the conection index on teardown.
 605     SSHKeywords.Run_Keyword_Preserve_Connection    With_Ssh_To_List_Or_All_Run_Keyword    ${member_index_list}    ${keyword_name}    @{args}    &{kwargs}
 606
 607 Clean_Directories_On_List_Or_All
 608     [Arguments]    ${member_index_list}=${EMPTY}    ${directory_list}=${EMPTY}    ${karaf_home}=${KARAF_HOME}    ${tmp_dir}=${EMPTY}
 609     [Documentation]    Clear @{directory_list} or @{ODL_DEFAULT_DATA_PATHS} for members in given list or all. Return None.
 610     ...    If \${tmp_dir} is nonempty, use that location to preserve data/log/.
 611     ...    This is intended to return Karaf (offline) to the state it was upon the first boot.
 612     ${path_list} =    Builtin.Set Variable If    "${directory_list}" == "${EMPTY}"    ${ODL_DEFAULT_DATA_PATHS}    ${directory_list}
 613     BuiltIn.Run_Keyword_If    """${tmp_dir}""" != ""    Check_Bash_Command_On_List_Or_All    mkdir -p '${tmp_dir}' && rm -vrf '${tmp_dir}/log' && mv -vf '${karaf_home}/data/log' '${tmp_dir}/'    ${member_index_list}
 614     Safe_With_Ssh_To_List_Or_All_Run_Keyword    ${member_index_list}    ClusterManagement__Clean_Directories    ${path_list}    ${karaf_home}
 615     BuiltIn.Run_Keyword_If    """${tmp_dir}""" != ""    Check_Bash_Command_On_List_Or_All    mkdir -p '${karaf_home}/data' && rm -vrf '${karaf_home}/log' && mv -vf '${tmp_dir}/log' '${karaf_home}/data/'    ${member_index_list}
 616
 617 Store_Karaf_Log_On_List_Or_All
 618     [Arguments]    ${member_index_list}=${EMPTY}    ${dst_dir}=/tmp    ${karaf_home}=${KARAF_HOME}
 619     [Documentation]    Saves karaf.log to the ${dst_dir} for members in given list or all. Return None.
 620     Safe_With_Ssh_To_List_Or_All_Run_Keyword    ${member_index_list}    SSHKeywords.Execute_Command_Should_Pass    cp ${karaf_home}/data/log/karaf.log ${dst_dir}
 621
 622 Restore_Karaf_Log_On_List_Or_All
 623     [Arguments]    ${member_index_list}=${EMPTY}    ${src_dir}=/tmp    ${karaf_home}=${KARAF_HOME}
 624     [Documentation]    Places stored karaf.log to the ${karaf_home}/data/log for members in given list or all. Return None.
 625     Safe_With_Ssh_To_List_Or_All_Run_Keyword    ${member_index_list}    SSHKeywords.Execute_Command_Should_Pass    cp ${src_dir}/karaf.log ${karaf_home}/data/log/
 626
 627 ClusterManagement__Clean_Directories
 628     [Arguments]    ${relative_path_list}    ${karaf_home}
 629     [Documentation]    For each relative path, remove files with respect to ${karaf_home}. Return None.
 630     : FOR    ${relative_path}    IN    @{relative_path_list}
 631     \    SSHLibrary.Execute_Command    rm -rf ${karaf_home}${/}${relative_path}
 632
 633 Put_As_Json_And_Check_Member_List_Or_All
 634     [Arguments]    ${uri}    ${data}    ${member_index}    ${member_index_list}=${EMPTY}
 635     [Documentation]    Send a PUT with the supplied uri ${uri} and body ${data} to member ${member_index}.
 636     ...    Then check data is replicated in all or some members defined in ${member_index_list}.
 637     ${response_text} =    Put_As_Json_To_Member    uri=${uri}    data=${data}    member_index=${member_index}
 638     Wait Until Keyword Succeeds    5s    1s    Check_Json_Member_List_Or_All    uri=${uri}    expected_data=${data}    member_index_list=${member_index_list}
 639     [Return]    ${response_text}
 640
 641 Put_As_Json_To_Member
 642     [Arguments]    ${uri}    ${data}    ${member_index}
 643     [Documentation]    Send a PUT with the supplied uri and data to member ${member_index}.
 644     ${session} =    Resolve_Http_Session_For_Member    member_index=${member_index}
 645     ${response_text} =    TemplatedRequests.Put_As_Json_To_Uri    uri=${uri}    data=${data}    session=${session}
 646     [Return]    ${response_text}
 647
 648 Post_As_Json_To_Member
 649     [Arguments]    ${uri}    ${data}    ${member_index}
 650     [Documentation]    Send a POST with the supplied uri and data to member ${member_index}.
 651     ${session} =    Resolve_Http_Session_For_Member    member_index=${member_index}
 652     ${response_text} =    TemplatedRequests.Post_As_Json_To_Uri    uri=${uri}    data=${data}    session=${session}
 653     [Return]    ${response_text}
 654
 655 Delete_And_Check_Member_List_Or_All
 656     [Arguments]    ${uri}    ${member_index}    ${member_index_list}=${EMPTY}
 657     [Documentation]    Send a DELETE with the supplied uri to the member ${member_index}.
 658     ...    Then check the data is removed from all members in ${member_index_list}.
 659     ${response_text} =    Delete_From_Member    ${uri}    ${member_index}
 660     BuiltIn.Wait_Until_Keyword_Succeeds    5s    1s    Check_No_Content_Member_List_Or_All    uri=${uri}    member_index_list=${member_index_list}
 661     [Return]    ${response_text}
 662
 663 Delete_From_Member
 664     [Arguments]    ${uri}    ${member_index}
 665     [Documentation]    Send a DELETE with the supplied uri to member ${member_index}.
 666     ${session} =    Resolve_Http_Session_For_Member    member_index=${member_index}
 667     ${response_text} =    TemplatedRequests.Delete_From_Uri    uri=${uri}    session=${session}
 668     [Return]    ${response_text}
 669
 670 Check_Json_Member_List_Or_All
 671     [Arguments]    ${uri}    ${expected_data}    ${member_index_list}=${EMPTY}
 672     [Documentation]    Send a GET with the supplied uri to all or some members defined in ${member_index_list}.
 673     ...    Then check received data is = ${expected data}.
 674     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 675     : FOR    ${index}    IN    @{index_list}
 676     \    ${data} =    Get_From_Member    uri=${uri}    member_index=${index}
 677     \    TemplatedRequests.Normalize_Jsons_And_Compare    ${expected_data}    ${data}
 678
 679 Check_Item_Occurrence_Member_List_Or_All
 680     [Arguments]    ${uri}    ${dictionary}    ${member_index_list}=${EMPTY}
 681     [Documentation]    Send a GET with the supplied uri to all or some members defined in ${member_index_list}.
 682     ...    Then check received for occurrences of items expressed in a dictionary ${dictionary}.
 683     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 684     : FOR    ${index}    IN    @{index_list}
 685     \    ${data} =    Get_From_Member    uri=${uri}    member_index=${index}
 686     \    Utils.Check Item Occurrence    ${data}    ${dictionary}
 687
 688 Check_No_Content_Member_List_Or_All
 689     [Arguments]    ${uri}    ${member_index_list}=${EMPTY}
 690     [Documentation]    Send a GET with the supplied uri to all or some members defined in ${member_index_list}.
 691     ...    Then check there is no content.
 692     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 693     : FOR    ${index}    IN    @{index_list}
 694     \    ${session} =    Resolve_Http_Session_For_Member    member_index=${index}
 695     \    Utils.No_Content_From_URI    ${session}    ${uri}
 696
 697 Get_From_Member
 698     [Arguments]    ${uri}    ${member_index}    ${access}=${ACCEPT_EMPTY}
 699     [Documentation]    Send a GET with the supplied uri to member ${member_index}.
 700     ${session} =    Resolve_Http_Session_For_Member    member_index=${member_index}
 701     ${response_text} =    TemplatedRequests.Get_From_Uri    uri=${uri}    accept=${access}    session=${session}
 702     [Return]    ${response_text}
 703
 704 Resolve_IP_Address_For_Member
 705     [Arguments]    ${member_index}
 706     [Documentation]    Return node IP address of given index.
 707     ${ip_address} =    Collections.Get From Dictionary    dictionary=${ClusterManagement__index_to_ip_mapping}    key=${member_index}
 708     [Return]    ${ip_address}
 709
 710 Resolve_IP_Address_For_Members
 711     [Arguments]    ${member_index_list}
 712     [Documentation]    Return a list of IP address of given indexes.
 713     ${member_ip_list} =    BuiltIn.Create_List
 714     : FOR    ${index}    IN    @{member_index_list}
 715     \    ${ip_address} =    Collections.Get From Dictionary    dictionary=${ClusterManagement__index_to_ip_mapping}    key=${index}
 716     \    Collections.Append_To_List    ${member_ip_list}    ${ip_address}
 717     [Return]    ${member_ip_list}
 718
 719 Resolve_Http_Session_For_Member
 720     [Arguments]    ${member_index}
 721     [Documentation]    Return RequestsLibrary session alias pointing to node of given index.
 722     ${session} =    BuiltIn.Set_Variable    ClusterManagement__session_${member_index}
 723     [Return]    ${session}
 724
 725 Resolve_Shard_Type_Class
 726     [Arguments]    ${shard_type}
 727     [Documentation]    Simple lookup for class name corresponding to desired type.
 728     BuiltIn.Run_Keyword_If    '${shard_type}' == 'config'    BuiltIn.Return_From_Keyword    DistributedConfigDatastore
 729     ...    ELSE IF    '${shard_type}' == 'operational'    BuiltIn.Return_From_Keyword    DistributedOperationalDatastore
 730     BuiltIn.Fail    Unrecognized shard type: ${shard_type}
 731
 732 ClusterManagement__Build_List
 733     [Arguments]    ${member}
 734     ${member_int} =    BuiltIn.Convert_To_Integer    ${member}
 735     ${index_list} =    BuiltIn.Create_List    ${member_int}
 736     [Return]    ${index_list}
 737
 738 ClusterManagement__Parse_Sync_Status
 739     [Arguments]    ${shard_manager_text}
 740     [Documentation]    Return sync status parsed out of given text. Called twice by Get_Sync_Status_Of_Member.
 741     BuiltIn.Log    ${shard_manager_text}
 742     ${manager_object} =    RequestsLibrary.To_Json    ${shard_manager_text}
 743     ${value_object} =    Collections.Get_From_Dictionary    dictionary=${manager_object}    key=value
 744     ${sync_status} =    Collections.Get_From_Dictionary    dictionary=${value_object}    key=SyncStatus
 745     [Return]    ${sync_status}
 746
 747 List_All_Indices
 748     [Documentation]    Create a new list of all indices.
 749     BuiltIn.Run_Keyword_And_Return    List_Indices_Or_All
 750
 751 List_Indices_Or_All
 752     [Arguments]    ${given_list}=${EMPTY}
 753     [Documentation]    Utility to allow \${EMPTY} as default argument value, as the internal list is computed at runtime.
 754     ...    This keyword always returns a (shallow) copy of given or default list,
 755     ...    so operations with the returned list should not affect other lists.
 756     ...    Also note that this keyword does not consider empty list to be \${EMPTY}.
 757     ${return_list_reference} =    BuiltIn.Set_Variable_If    """${given_list}""" != ""    ${given_list}    ${ClusterManagement__member_index_list}
 758     ${return_list_copy} =    BuiltIn.Create_List    @{return_list_reference}
 759     [Return]    ${return_list_copy}
 760
 761 List_Indices_Minus_Member
 762     [Arguments]    ${member_index}    ${member_index_list}=${EMPTY}
 763     [Documentation]    Create a new list which contains indices from ${member_index_list} (or all) without ${member_index}.
 764     ${index_list} =    List_Indices_Or_All    ${member_index_list}
 765     Collections.Remove Values From List    ${index_list}    ${member_index}
 766     [Return]    ${index_list}
 767
 768 ClusterManagement__Compute_Derived_Variables
 769     [Arguments]    ${int_of_members}    ${http_timeout}=1    ${http_retries}=0
 770     [Documentation]    Construct index list, session list and IP mapping, publish them as suite variables.
 771     @{member_index_list} =    BuiltIn.Create_List
 772     @{session_list} =    BuiltIn.Create_List
 773     &{index_to_ip_mapping} =    BuiltIn.Create_Dictionary
 774     : FOR    ${index}    IN RANGE    1    ${int_of_members+1}
 775     \    ClusterManagement__Include_Member_Index    ${index}    ${member_index_list}    ${session_list}    ${index_to_ip_mapping}    http_timeout=${http_timeout}
 776     \    ...    http_retries=${http_retries}
 777     BuiltIn.Set_Suite_Variable    \${ClusterManagement__member_index_list}    ${member_index_list}
 778     BuiltIn.Set_Suite_Variable    \${ClusterManagement__index_to_ip_mapping}    ${index_to_ip_mapping}
 779     BuiltIn.Set_Suite_Variable    \${ClusterManagement__session_list}    ${session_list}
 780
 781 ClusterManagement__Include_Member_Index
 782     [Arguments]    ${index}    ${member_index_list}    ${session_list}    ${index_to_ip_mapping}    ${http_timeout}=1    ${http_retries}=0
 783     [Documentation]    Add a corresponding item based on index into the last three arguments.
 784     ...    Create the Http session whose alias is added to list.
 785     Collections.Append_To_List    ${member_index_list}    ${index}
 786     ${member_ip} =    BuiltIn.Set_Variable    ${ODL_SYSTEM_${index}_IP}
 787     # ${index} is int (not string) so "key=value" syntax does not work in the following line.
 788     Collections.Set_To_Dictionary    ${index_to_ip_mapping}    ${index}    ${member_ip}
 789     # Http session, with ${AUTH}, without headers.
 790     ${session_alias} =    Resolve_Http_Session_For_Member    member_index=${index}
 791     RequestsLibrary.Create_Session    ${session_alias}    http://${member_ip}:${RESTCONFPORT}    auth=${AUTH}    timeout=${http_timeout}    max_retries=${http_retries}
 792     Collections.Append_To_List    ${session_list}    ${session_alias}
 793
 794 Sync_Status_Should_Be_False
 795     [Arguments]    ${controller_index}
 796     [Documentation]    Verify that cluster node is not in sync with others
 797     ${status}    Get_Sync_Status_Of_Member    ${controller_index}
 798     BuiltIn.Should_Not_Be_True    ${status}
 799
 800 Sync_Status_Should_Be_True
 801     [Arguments]    ${controller_index}
 802     [Documentation]    Verify that cluster node is in sync with others
 803     ${status}    Get_Sync_Status_Of_Member    ${controller_index}
 804     BuiltIn.Should_Be_True    ${status}
 805
 806 Return_Member_IP
 807     [Arguments]    ${member_index}
 808     [Documentation]    Return the IP address of the member given the member_index.
 809     ${member_int} =    BuiltIn.Convert_To_Integer    ${member_index}
 810     ${member_ip} =    Collections.Get_From_Dictionary    dictionary=${ClusterManagement__index_to_ip_mapping}    key=${member_int}
 811     [Return]    ${member_ip}