csit/libraries/ClusterManagement.robot

   1 *** Settings ***
   2 Documentation     Resource housing Keywords common to several suites for cluster functional testing.
   3 ...
   4 ...               Copyright (c) 2016 Cisco Systems, Inc. and others. All rights reserved.
   5 ...               Copyright (c) 2016 Brocade Communications Systems, Inc. and others. All rights reserved.
   6 ...
   7 ...               This program and the accompanying materials are made available under the
   8 ...               terms of the Eclipse Public License v1.0 which accompanies this distribution,
   9 ...               and is available at http://www.eclipse.org/legal/epl-v10.html
  10 ...
  11 ...
  12 ...               This resource holds private state (in suite variables),
  13 ...               which is generated once at Setup with ClusterManagement_Setup KW.
  14 ...               The state includes member indexes, IP addresses and Http (RequestsLibrary) sessions.
  15 ...               Cluster Keywords normally use member index, member list or nothing (all members) as argument.
  16 ...
  17 ...               All index lists returned should be sorted numerically, fix if not.
  18 ...
  19 ...               Requirements:
  20 ...               odl-jolokia is assumed to be installed.
  21 ...
  22 ...               Keywords are ordered as follows:
  23 ...               - Cluster Setup
  24 ...               - Shard state, leader and followers
  25 ...               - Entity Owner, candidates and successors
  26 ...               - Kill, Stop and Start Member
  27 ...               - Isolate and Rejoin Member
  28 ...               - Run Commands On Member
  29 ...               - REST requests and checks on Members
  30 ...
  31 ...               TODO: Unify capitalization of Leaders and Followers.
  32 Library           RequestsLibrary    # for Create_Session and To_Json
  33 Library           Collections
  34 Resource          ${CURDIR}/CompareStream.robot
  35 Resource          ${CURDIR}/KarafKeywords.robot
  36 Resource          ${CURDIR}/SSHKeywords.robot
  37 Resource          ${CURDIR}/TemplatedRequests.robot    # for Get_As_Json_From_Uri
  38 Resource          ${CURDIR}/Utils.robot    # for Run_Command_On_Controller
  39
  40 *** Variables ***
  41 ${ENTITY_OWNER_URI}    restconf/operational/entity-owners:entity-owners
  42 ${JAVA_HOME}      ${EMPTY}    # releng/builder scripts should provide correct value
  43 ${JOLOKIA_CONF_SHARD_MANAGER_URI}    jolokia/read/org.opendaylight.controller:Category=ShardManager,name=shard-manager-config,type=DistributedConfigDatastore
  44 ${JOLOKIA_OPER_SHARD_MANAGER_URI}    jolokia/read/org.opendaylight.controller:Category=ShardManager,name=shard-manager-operational,type=DistributedOperationalDatastore
  45 ${JOLOKIA_READ_URI}    jolokia/read/org.opendaylight.controller
  46 ${KARAF_HOME}     ${WORKSPACE}${/}${BUNDLEFOLDER}    # TODO: Migrate to Variables.robot
  47 @{ODL_DEFAULT_DATA_PATHS}    tmp/    data/    cache/    snapshots/    journal/    etc/opendaylight/current/
  48 ${RESTCONF_MODULES_DIR}    ${CURDIR}/../variables/restconf/modules
  49 ${SINGLETON_NETCONF_DEVICE_ID_PREFIX}    /odl-general-entity:entity[odl-general-entity:name='KeyedInstanceIdentifier{targetType=interface org.opendaylight.yang.gen.v1.urn.tbd.params.xml.ns.yang.network.topology.rev131021.network.topology.topology.Node, path=[org.opendaylight.yang.gen.v1.urn.tbd.params.xml.ns.yang.network.topology.rev131021.NetworkTopology, org.opendaylight.yang.gen.v1.urn.tbd.params.xml.ns.yang.network.topology.rev131021.network.topology.Topology[key=TopologyKey [_topologyId=Uri [_value=topology-netconf]]], org.opendaylight.yang.gen.v1.urn.tbd.params.xml.ns.yang.network.topology.rev131021.network.topology.topology.Node[key=NodeKey [_nodeId=Uri [_value=
  50 ${SINGLETON_NETCONF_DEVICE_ID_SUFFIX}    ]]]]}']
  51 ${SINGLETON_ELECTION_ENTITY_TYPE}    org.opendaylight.mdsal.ServiceEntityType
  52 ${SINGLETON_CHANGE_OWNERSHIP_ENTITY_TYPE}    org.opendaylight.mdsal.AsyncServiceCloseEntityType
  53 ${NODE_START_COMMAND}    ${KARAF_HOME}/bin/start
  54 ${NODE_STOP_COMMAND}    ${KARAF_HOME}/bin/stop
  55 ${NODE_KILL_COMMAND}    ps axf | grep karaf | grep -v grep | awk '{print \"kill -9 \" $1}' | sh
  56
  57 *** Keywords ***
  58 ClusterManagement_Setup
  59     [Documentation]    Detect repeated call, or detect number of members and initialize derived suite variables.
  60     # Avoid multiple initialization by several downstream libraries.
  61     ${already_done} =    BuiltIn.Get_Variable_Value    \${ClusterManagement__has_setup_run}    False
  62     BuiltIn.Return_From_Keyword_If    ${already_done}
  63     BuiltIn.Set_Suite_Variable    \${ClusterManagement__has_setup_run}    True
  64     ${cluster_size} =    BuiltIn.Get_Variable_Value    \${NUM_ODL_SYSTEM}    1
  65     ${status}    ${possibly_int_of_members} =    BuiltIn.Run_Keyword_And_Ignore_Error    BuiltIn.Convert_To_Integer    ${cluster_size}
  66     ${int_of_members} =    BuiltIn.Set_Variable_If    '${status}' != 'PASS'    ${1}    ${possibly_int_of_members}
  67     ClusterManagement__Compute_Derived_Variables    int_of_members=${int_of_members}
  68
  69 Check_Cluster_Is_In_Sync
  70     [Arguments]    ${member_index_list}=${EMPTY}
  71     [Documentation]    Fail if no-sync is detected on a member from list (or any).
  72     ${index_list} =    ClusterManagement__Given_Or_Internal_Index_List    given_list=${member_index_list}
  73     : FOR    ${index}    IN    @{index_list}    # usually: 1, 2, 3.
  74     \    ${status} =    Get_Sync_Status_Of_Member    member_index=${index}
  75     \    BuiltIn.Continue_For_Loop_If    'True' == '${status}'
  76     \    BuiltIn.Fail    Index ${index} has incorrect status: ${status}
  77
  78 Get_Sync_Status_Of_Member
  79     [Arguments]    ${member_index}
  80     [Documentation]    Obtain IP, two GETs from jolokia URIs, return combined sync status as string.
  81     ${session} =    Resolve_Http_Session_For_Member    member_index=${member_index}
  82     ${conf_text} =    TemplatedRequests.Get_As_Json_From_Uri    uri=${JOLOKIA_CONF_SHARD_MANAGER_URI}    session=${session}
  83     ${conf_status} =    ClusterManagement__Parse_Sync_Status    shard_manager_text=${conf_text}
  84     BuiltIn.Return_From_Keyword_If    'False' == ${conf_status}    False
  85     ${oper_text} =    TemplatedRequests.Get_As_Json_From_Uri    uri=${JOLOKIA_OPER_SHARD_MANAGER_URI}    session=${session}
  86     ${oper_status} =    ClusterManagement__Parse_Sync_Status    shard_manager_text=${oper_text}
  87     [Return]    ${oper_status}
  88
  89 Verify_Leader_Exists_For_Each_Shard
  90     [Arguments]    ${shard_name_list}    ${shard_type}=operational    ${member_index_list}=${EMPTY}    ${verify_restconf}=True
  91     [Documentation]    For each shard name, call Get_Leader_And_Followers_For_Shard.
  92     ...    Not much logic there, but single Keyword is useful when using BuiltIn.Wait_Until_Keyword_Succeeds.
  93     : FOR    ${shard_name}    IN    @{shard_name_list}
  94     \    Get_Leader_And_Followers_For_Shard    shard_name=${shard_name}    shard_type=${shard_type}    validate=True    member_index_list=${member_index_list}    verify_restconf=${verify_restconf}
  95
  96 Get_Leader_And_Followers_For_Shard
  97     [Arguments]    ${shard_name}=default    ${shard_type}=operational    ${validate}=True    ${member_index_list}=${EMPTY}    ${verify_restconf}=True
  98     [Documentation]    Get role lists, validate there is one leader, return the leader and list of followers.
  99     ...    Optionally, issue GET to a simple restconf URL to make sure subsequent operations will not encounter 503.
 100     ${leader_list}    ${follower_list} =    Get_State_Info_For_Shard    shard_name=${shard_name}    shard_type=${shard_type}    validate=True    member_index_list=${member_index_list}
 101     ...    verify_restconf=${verify_restconf}
 102     ${leader_count} =    BuiltIn.Get_Length    ${leader_list}
 103     BuiltIn.Run_Keyword_If    ${leader_count} < 1    BuiltIn.Fail    No leader found.
 104     BuiltIn.Length_Should_Be    ${leader_list}    ${1}    Too many Leaders.
 105     ${leader} =    Collections.Get_From_List    ${leader_list}    0
 106     [Return]    ${leader}    ${follower_list}
 107
 108 Get_State_Info_For_Shard
 109     [Arguments]    ${shard_name}=default    ${shard_type}=operational    ${validate}=False    ${member_index_list}=${EMPTY}    ${verify_restconf}=False
 110     [Documentation]    Return lists of Leader and Follower member indices from a given member index list
 111     ...    (or from the full list if empty). If \${shard_type} is not 'config', 'operational' is assumed.
 112     ...    If \${validate}, Fail if raft state is not Leader or Follower (for example on Candidate).
 113     ...    The biggest difference from Get_Leader_And_Followers_For_Shard
 114     ...    is that no check on number of Leaders is performed.
 115     ${index_list} =    ClusterManagement__Given_Or_Internal_Index_List    given_list=${member_index_list}
 116     Collections.Sort_List    ${index_list}    # to guarantee return values are also sorted lists
 117     # TODO: Support alternative capitalization of 'config'?
 118     ${ds_type} =    BuiltIn.Set_Variable_If    '${shard_type}' != 'config'    operational    config
 119     ${leader_list} =    BuiltIn.Create_List
 120     ${follower_list} =    BuiltIn.Create_List
 121     : FOR    ${index}    IN    @{index_list}    # usually: 1, 2, 3.
 122     \    ${raft_state} =    Get_Raft_State_Of_Shard_At_Member    shard_name=${shard_name}    shard_type=${ds_type}    member_index=${index}    verify_restconf=${verify_restconf}
 123     \    BuiltIn.Run_Keyword_If    'Follower' == '${raft_state}'    Collections.Append_To_List    ${follower_list}    ${index}
 124     \    ...    ELSE IF    'Leader' == '${raft_state}'    Collections.Append_To_List    ${leader_list}    ${index}
 125     \    ...    ELSE IF    ${validate}    BuiltIn.Fail    Unrecognized Raft state: ${raft_state}
 126     [Return]    ${leader_list}    ${follower_list}
 127
 128 Get_Raft_State_Of_Shard_At_Member
 129     [Arguments]    ${shard_name}    ${shard_type}    ${member_index}    ${verify_restconf}=False
 130     [Documentation]    Send request to Jolokia on indexed member, return extracted Raft status.
 131     ...    Optionally, check restconf works.
 132     ${session} =    Resolve_Http_Session_For_Member    member_index=${member_index}
 133     # TODO: Does the used URI tend to generate large data which floods log.html?
 134     BuiltIn.Run_Keyword_If    ${verify_restconf}    TemplatedRequests.Get_As_Json_Templated    session=${session}    folder=${RESTCONF_MODULES_DIR}    verify=False
 135     ${type_class} =    Resolve_Shard_Type_Class    shard_type=${shard_type}
 136     ${uri} =    BuiltIn.Set_Variable    ${JOLOKIA_READ_URI}:Category=Shards,name=member-${member_index}-shard-${shard_name}-${shard_type},type=${type_class}
 137     ${data_text} =    TemplatedRequests.Get_As_Json_From_Uri    uri=${uri}    session=${session}
 138     ${data_object} =    RequestsLibrary.To_Json    ${data_text}
 139     ${value} =    Collections.Get_From_Dictionary    ${data_object}    value
 140     ${raft_state} =    Collections.Get_From_Dictionary    ${value}    RaftState
 141     [Return]    ${raft_state}
 142
 143 Verify_Owner_And_Successors_For_Device
 144     [Arguments]    ${device_name}    ${device_type}    ${member_index}    ${candidate_list}=${EMPTY}    ${after_stop}=False
 145     [Documentation]    Returns the owner and successors for the SB device ${device_name} of type ${device_type}. Request is sent to member ${member_index}.
 146     ...    For Boron and beyond, candidates are not removed on node down or isolation,
 147     ...    so this keyword expects candidates to be all members from Boron on.
 148     ...    Extra check is done to verify owner and successors are within the ${candidate_list}. This KW is useful when combined with WUKS.
 149     ...    ${candidate_list} minus owner is returned as ${successor list}.
 150     ...    Users can still use Get_Owner_And_Successors_For_Device if they are interested in downed candidates,
 151     ...    or for testing heterogeneous clusters.
 152     ${index_list} =    ClusterManagement__Given_Or_Internal_Index_List    given_list=${candidate_list}
 153     ${owner}    ${successor_list} =    Get_Owner_And_Successors_For_Device    device_name=${device_name}    device_type=${device_type}    member_index=${member_index}
 154     Collections.List_Should_Contain_Value    ${index_list}    ${owner}    Owner ${owner} is not in candidate list ${index_list}
 155     # In Beryllium or after stopping an instance, the removed instance does not show in the candidate list.
 156     ${expected_candidate_list_origin} =    BuiltIn.Set_Variable_If    '${ODL_STREAM}' == 'beryllium' or ${after_stop}    ${index_list}    ${ClusterManagement__member_index_list}
 157     # We do not want to manipulate either origin list.
 158     ${expected_successor_list} =    BuiltIn.Create_List    @{expected_candidate_list_origin}
 159     Collections.Remove_Values_From_List    ${expected_successor_list}    ${owner}
 160     Collections.Lists_Should_Be_Equal    ${expected_successor_list}    ${successor_list}    Successor list ${successor_list} is not the came as expected ${expected_successor_list}
 161     # User expects the returned successor list to be the provided candidate list minus the owner.
 162     Collections.Remove_Values_From_List    ${index_list}    ${owner}
 163     [Return]    ${owner}    ${index_list}
 164
 165 Get_Owner_And_Successors_For_Device
 166     [Arguments]    ${device_name}    ${device_type}    ${member_index}
 167     [Documentation]    Returns the owner and a list of successors for the SB device ${device_name} of type ${device_type}. Request is sent to member ${member_index}.
 168     ...    Successors are those device candidates not elected as owner. The list of successors = (list of candidates) - (owner).
 169     ...    The returned successor list is sorted numerically.
 170     ...    Note that "candidate list" definition currently differs between Beryllium and Boron.
 171     ...    Use Verify_Owner_And_Successors_For_Device if you want the older semantics (inaccessible nodes not present in the list).
 172     ${owner}    ${candidate_list} =    Get_Owner_And_Candidates_For_Device    device_name=${device_name}    device_type=${device_type}    member_index=${member_index}
 173     ${successor_list} =    BuiltIn.Create_List    @{candidate_list}    # Copy operation is not required, but new variable name requires a line anyway.
 174     Collections.Remove_Values_From_List    ${successor_list}    ${owner}
 175     [Return]    ${owner}    ${successor_list}
 176
 177 Get_Owner_And_Candidates_For_Device_Old
 178     [Arguments]    ${device_name}    ${device_type}    ${member_index}
 179     [Documentation]    Returns the owner and a list of candidates for the SB device ${device_name} of type ${device_type}. Request is sent to member ${member_index}.
 180     ...    Candidates are all members that register to own a device, so the list of candiates includes the owner.
 181     ...    The returned candidate list is sorted numerically.
 182     ...    Note that "candidate list" definition currently differs between Beryllium and Boron.
 183     ...    It is recommended to use Get_Owner_And_Successors_For_Device instead of this keyword, see documentation there.
 184     BuiltIn.Comment    TODO: Can this implementation be changed to call Get_Owner_And_Candidates_For_Type_And_Id?
 185     ${session} =    Resolve_Http_Session_For_Member    member_index=${member_index}
 186     ${data} =    TemplatedRequests.Get_As_Json_From_Uri    uri=${ENTITY_OWNER_URI}    session=${session}
 187     ${candidate_list} =    BuiltIn.Create_List
 188     ${entity_type} =    BuiltIn.Set_Variable_If    '${device_type}' == 'netconf'    netconf-node/${device_name}    ${device_type}
 189     ${clear_data} =    BuiltIn.Run_Keyword_If    '${device_type}' == 'openflow' or '${device_type}' == 'netconf'    Extract_OpenFlow_Device_Data    ${data}
 190     ...    ELSE IF    '${device_type}' == 'ovsdb'    Extract_Ovsdb_Device_Data    ${data}
 191     ...    ELSE IF    '${device_type}' == 'org.opendaylight.mdsal.ServiceEntityType'    Extract_Service_Entity_Type    ${data}
 192     ...    ELSE    Fail    Not recognized device type: ${device_type}
 193     ${json} =    RequestsLibrary.To_Json    ${clear_data}
 194     ${entity_type_list} =    Collections.Get_From_Dictionary    &{json}[entity-owners]    entity-type
 195     ${entity_type_index} =    Utils.Get_Index_From_List_Of_Dictionaries    ${entity_type_list}    type    ${entity_type}
 196     BuiltIn.Should_Not_Be_Equal_As_Integers    ${entity_type_index}    -1    No Entity Owner found for ${device_type}
 197     ${entity_list} =    Collections.Get_From_Dictionary    @{entity_type_list}[${entity_type_index}]    entity
 198     ${entity_index} =    Utils.Get_Index_From_List_Of_Dictionaries    ${entity_list}    id    ${device_name}
 199     BuiltIn.Should_Not_Be_Equal_As_Integers    ${entity_index}    -1    Device ${device_name} not found in Entity Owner ${device_type}
 200     ${entity_owner} =    Collections.Get_From_Dictionary    @{entity_list}[${entity_index}]    owner
 201     BuiltIn.Should_Not_Be_Empty    ${entity_owner}    No owner found for ${device_name}
 202     ${owner} =    String.Replace_String    ${entity_owner}    member-    ${EMPTY}
 203     ${owner} =    BuiltIn.Convert_To_Integer    ${owner}
 204     ${entity_candidates_list} =    Collections.Get_From_Dictionary    @{entity_list}[${entity_index}]    candidate
 205     : FOR    ${entity_candidate}    IN    @{entity_candidates_list}
 206     \    ${candidate} =    String.Replace_String    &{entity_candidate}[name]    member-    ${EMPTY}
 207     \    ${candidate} =    BuiltIn.Convert_To_Integer    ${candidate}
 208     \    Collections.Append_To_List    ${candidate_list}    ${candidate}
 209     Collections.Sort_List    ${candidate_list}
 210     [Return]    ${owner}    ${candidate_list}
 211
 212 Get_Owner_And_Candidates_For_Device_Singleton
 213     [Arguments]    ${device_name}    ${device_type}    ${member_index}
 214     [Documentation]    Returns the owner and a list of candidates for the SB device ${device_name} of type ${device_type}. Request is sent to member ${member_index}.
 215     ...    Parsing method is selected by device type
 216     ...    Separate kw for every supported device type must be defined
 217     BuiltIn.Keyword_Should_Exist    Get_Owner_And_Candidates_For_Device_Singleton_${device_type}
 218     BuiltIn.Run_Keyword_And_Return    Get_Owner_And_Candidates_For_Device_Singleton_${device_type}    ${device_name}    ${member_index}
 219
 220 Get_Owner_And_Candidates_For_Device_Singleton_Netconf
 221     [Arguments]    ${device_name}    ${member_index}
 222     [Documentation]    Returns the owner and a list of candidates for the SB device ${device_name} of type netconf. Request is sent to member ${member_index}.
 223     ...    Parsing method is set as netconf (using netconf device id prefix and suffix)
 224     # Get election entity type results
 225     ${type} =    BuiltIn.Set_Variable    ${SINGLETON_ELECTION_ENTITY_TYPE}
 226     ${id} =    BuiltIn.Set_Variable    ${SINGLETON_NETCONF_DEVICE_ID_PREFIX}${device_name}${SINGLETON_NETCONF_DEVICE_ID_SUFFIX}
 227     ${owner_1}    ${candidate_list_1} =    Get_Owner_And_Candidates_For_Type_And_Id    ${type}    ${id}    ${member_index}
 228     # Get change ownership entity type results
 229     ${type} =    BuiltIn.Set_Variable    ${SINGLETON_CHANGE_OWNERSHIP_ENTITY_TYPE}
 230     ${id} =    BuiltIn.Set_Variable    ${SINGLETON_NETCONF_DEVICE_ID_PREFIX}${device_name}${SINGLETON_NETCONF_DEVICE_ID_SUFFIX}
 231     ${owner_2}    ${candidate_list_2} =    Get_Owner_And_Candidates_For_Type_And_Id    ${type}    ${id}    ${member_index}
 232     # Owners must be same, if not, there is still some election or change ownership in progress
 233     BuiltIn.Should_Be_Equal_As_Integers    ${owner_1}    ${owner_2}    Owners for device ${device_name} are not same
 234     [Return]    ${owner_1}    ${candidate_list_1}
 235
 236 Get_Owner_And_Candidates_For_Device
 237     [Arguments]    ${device_name}    ${device_type}    ${member_index}
 238     [Documentation]    Returns the owner and a list of candidates for the SB device ${device_name} of type ${device_type}. Request is sent to member ${member_index}.
 239     ...    If parsing as singleton failed, kw try to parse data in old way (without singleton).
 240     ...    Candidates are all members that register to own a device, so the list of candiates includes the owner.
 241     ...    The returned candidate list is sorted numerically.
 242     ...    Note that "candidate list" definition currently differs between Beryllium and Boron.
 243     ...    It is recommended to use Get_Owner_And_Successors_For_Device instead of this keyword, see documentation there.
 244     # Try singleton
 245     ${status}    ${results} =    BuiltIn.Run_Keyword_And_Ignore_Error    Get_Owner_And_Candidates_For_Device_Singleton    device_name=${device_name}    device_type=${device_type}    member_index=${member_index}
 246     BuiltIn.Return_From_Keyword_If    "${status}"=="PASS"    ${results}
 247     # If singleton failed, try parsing in old way
 248     ${status}    ${results} =    BuiltIn.Run_Keyword_And_Ignore_Error    Get_Owner_And_Candidates_For_Device_Old    device_name=${device_name}    device_type=${device_type}    member_index=${member_index}
 249     # previous 3 lines (BuilIn.Return.., # If singleton..., ${status}....) could be deleted when old way will not be supported anymore
 250     BuiltIn.Run_Keyword_If    '${status}'=='FAIL'    BuiltIn.Fail    Could not parse owner and candidates for device ${device_name}
 251     [Return]    @{results}
 252
 253 Get_Owner_And_Candidates_For_Type_And_Id
 254     [Arguments]    ${type}    ${id}    ${member_index}    ${require_candidate_list}=${EMPTY}
 255     [Documentation]    Returns the owner and a list of candidates for entity specified by ${type} and ${id}
 256     ...    Request is sent to member ${member_index}.
 257     ...    Candidates are all members that register to own a device, so the list of candiates includes the owner.
 258     ...    Bear in mind that for Boron and beyond, candidates are not removed on node down or isolation.
 259     ...    If ${require_candidate_list} is not \${EMPTY}, check whether the actual list of candidates matches.
 260     ...    Note that differs from "given list" semantics used in other keywords,
 261     ...    namely you cannot use \${EMPTY} to stand for "full list" in this keyword.
 262     BuiltIn.Comment    TODO: Find a way to unify and deduplicate code blocks in Get_Owner_And_Candidates_* keywords.
 263     ${session} =    Resolve_Http_Session_For_Member    member_index=${member_index}
 264     ${data} =    TemplatedRequests.Get_As_Json_From_Uri    uri=${ENTITY_OWNER_URI}    session=${session}
 265     ${candidate_list} =    BuiltIn.Create_List
 266     ${json} =    RequestsLibrary.To_Json    ${data}
 267     ${entity_type_list} =    Collections.Get_From_Dictionary    &{json}[entity-owners]    entity-type
 268     ${entity_type_index} =    Utils.Get_Index_From_List_Of_Dictionaries    ${entity_type_list}    type    ${type}
 269     BuiltIn.Should_Not_Be_Equal_As_Integers    ${entity_type_index}    -1    No Entity Owner found for ${type}
 270     ${entity_list} =    Collections.Get_From_Dictionary    @{entity_type_list}[${entity_type_index}]    entity
 271     ${entity_index} =    Utils.Get_Index_From_List_Of_Dictionaries    ${entity_list}    id    ${id}
 272     BuiltIn.Should Not_Be_Equal_As_Integers    ${entity_index}    -1    Id ${id} not found in Entity Owner ${type}
 273     ${entity_owner} =    Collections.Get_From_Dictionary    @{entity_list}[${entity_index}]    owner
 274     BuiltIn.Should_Not_Be_Empty    ${entity_owner}    No owner found for type=${type} id=${id}
 275     ${owner} =    String.Replace_String    ${entity_owner}    member-    ${EMPTY}
 276     ${owner} =    BuiltIn.Convert_To_Integer    ${owner}
 277     ${entity_candidates_list} =    Collections.Get_From_Dictionary    @{entity_list}[${entity_index}]    candidate
 278     : FOR    ${entity_candidate}    IN    @{entity_candidates_list}
 279     \    ${candidate} =    String.Replace_String    &{entity_candidate}[name]    member-    ${EMPTY}
 280     \    ${candidate} =    BuiltIn.Convert_To_Integer    ${candidate}
 281     \    Collections.Append_To_List    ${candidate_list}    ${candidate}
 282     Collections.Sort_List    ${candidate_list}
 283     BuiltIn.Comment    TODO: Separate check lines into Verify_Owner_And_Candidates_For_Type_And_Id
 284     BuiltIn.Run_Keyword_If    """${require_candidate_list}"""    BuiltIn.Should_Be_Equal    ${require_candidate_list}    ${candidate_list}    Candidate list does not match: ${candidate_list} is not ${require_candidate_list}
 285     [Return]    ${owner}    ${candidate_list}
 286
 287 Extract_Service_Entity_Type
 288     [Arguments]    ${data}
 289     [Documentation]    Remove superfluous device data from Entity Owner printout.
 290     ${clear_data} =    String.Replace_String    ${data}    /odl-general-entity:entity[odl-general-entity:name='    ${EMPTY}
 291     ${clear_data} =    String.Replace_String    ${clear_data}    -service-group']    ${EMPTY}
 292     Log    ${clear_data}
 293     [Return]    ${clear_data}
 294
 295 Extract_OpenFlow_Device_Data
 296     [Arguments]    ${data}
 297     [Documentation]    Remove superfluous OpenFlow device data from Entity Owner printout.
 298     ${clear_data} =    BuiltIn.Run Keyword If    '${ODL_STREAM}' != 'beryllium' and '${ODL_OF_PLUGIN}' == 'lithium'    String.Replace_String    ${data}    org.opendaylight.mdsal.ServiceEntityType    openflow
 299     ...    ELSE    BuiltIn.Set_Variable    ${data}
 300     ${clear_data} =    String.Replace_String    ${clear_data}    /odl-general-entity:entity[odl-general-entity:name='    ${EMPTY}
 301     ${clear_data} =    String.Replace_String    ${clear_data}    /general-entity:entity[general-entity:name='    ${EMPTY}
 302     ${clear_data} =    String.Replace_String    ${clear_data}    ']    ${EMPTY}
 303     Log    ${clear_data}
 304     [Return]    ${clear_data}
 305
 306 Extract_Ovsdb_Device_Data
 307     [Arguments]    ${data}
 308     [Documentation]    Remove superfluous OVSDB device data from Entity Owner printout.
 309     ${clear_data} =    String.Replace_String    ${data}    /network-topology:network-topology/network-topology:topology[network-topology:topology-id='ovsdb:1']/network-topology:node[network-topology:node-id='    ${EMPTY}
 310     ${clear_data} =    String.Replace_String    ${clear_data}    ']    ${EMPTY}
 311     Log    ${clear_data}
 312     [Return]    ${clear_data}
 313
 314 Kill_Single_Member
 315     [Arguments]    ${member}    ${original_index_list}=${EMPTY}    ${confirm}=True
 316     [Documentation]    Convenience keyword that kills the specified member of the cluster.
 317     ...    The KW will return a list of available members: \${updated index_list}=\${original_index_list}-\${member}
 318     ${index_list} =    ClusterManagement__Build_List    ${member}
 319     ${updated_index_list} =    Kill_Members_From_List_Or_All    ${index_list}    ${original_index_list}    ${confirm}
 320     [Return]    ${updated_index_list}
 321
 322 Kill_Members_From_List_Or_All
 323     [Arguments]    ${member_index_list}=${EMPTY}    ${original_index_list}=${EMPTY}    ${confirm}=True
 324     [Documentation]    If the list is empty, kill all ODL instances. Otherwise, kill members based on \${kill_index_list}
 325     ...    If \${confirm} is True, sleep 1 second and verify killed instances are not there anymore.
 326     ...    The KW will return a list of available members: \${updated index_list}=\${original_index_list}-\${member_index_list}
 327     ${kill_index_list} =    ClusterManagement__Given_Or_Internal_Index_List    given_list=${member_index_list}
 328     ${index_list} =    ClusterManagement__Given_Or_Internal_Index_List    given_list=${original_index_list}
 329     Run_Bash_Command_On_List_Or_All    command=${NODE_KILL_COMMAND}    member_index_list=${member_index_list}
 330     ${updated_index_list} =    BuiltIn.Create_List    @{index_list}
 331     Collections.Remove_Values_From_List    ${updated_index_list}    @{kill_index_list}
 332     BuiltIn.Return_From_Keyword_If    not ${confirm}    ${updated_index_list}
 333     # TODO: Convert to WUKS with configurable timeout if it turns out 1 second is not enough.
 334     BuiltIn.Sleep    1s    Kill -9 closes open files, which may take longer than ssh overhead, but not long enough to warrant WUKS.
 335     : FOR    ${index}    IN    @{kill_index_list}
 336     \    Verify_Karaf_Is_Not_Running_On_Member    member_index=${index}
 337     [Return]    ${updated_index_list}
 338
 339 Stop_Single_Member
 340     [Arguments]    ${member}    ${original_index_list}=${EMPTY}    ${confirm}=True
 341     [Documentation]    Convenience keyword that stops the specified member of the cluster.
 342     ...    The KW will return a list of available members: \${updated index_list}=\${original_index_list}-\${member}
 343     ${index_list} =    ClusterManagement__Build_List    ${member}
 344     ${updated_index_list} =    Stop_Members_From_List_Or_All    ${index_list}    ${original_index_list}    ${confirm}
 345     [Return]    ${updated_index_list}
 346
 347 Stop_Members_From_List_Or_All
 348     [Arguments]    ${member_index_list}=${EMPTY}    ${original_index_list}=${EMPTY}    ${confirm}=True    ${timeout}=120s
 349     [Documentation]    If the list is empty, stops all ODL instances. Otherwise stop members based on \${stop_index_list}
 350     ...    If \${confirm} is True, verify stopped instances are not there anymore.
 351     ...    The KW will return a list of available members: \${updated index_list}=\${original_index_list}-\${member_index_list}
 352     ${stop_index_list} =    ClusterManagement__Given_Or_Internal_Index_List    given_list=${member_index_list}
 353     ${index_list} =    ClusterManagement__Given_Or_Internal_Index_List    given_list=${original_index_list}
 354     Run_Bash_Command_On_List_Or_All    command=${NODE_STOP_COMMAND}    member_index_list=${member_index_list}
 355     ${updated_index_list} =    BuiltIn.Create_List    @{index_list}
 356     Collections.Remove_Values_From_List    ${updated_index_list}    @{stop_index_list}
 357     BuiltIn.Return_From_Keyword_If    not ${confirm}    ${updated_index_list}
 358     : FOR    ${index}    IN    @{stop_index_list}
 359     \    BuiltIn.Wait Until Keyword Succeeds    ${timeout}    2s    Verify_Karaf_Is_Not_Running_On_Member    member_index=${index}
 360     [Return]    ${updated_index_list}
 361
 362 Start_Single_Member
 363     [Arguments]    ${member}    ${wait_for_sync}=True    ${timeout}=300s
 364     [Documentation]    Convenience keyword that starts the specified member of the cluster.
 365     ${index_list} =    ClusterManagement__Build_List    ${member}
 366     Start_Members_From_List_Or_All    ${index_list}    ${wait_for_sync}    ${timeout}
 367
 368 Start_Members_From_List_Or_All
 369     [Arguments]    ${member_index_list}=${EMPTY}    ${wait_for_sync}=True    ${timeout}=300s    ${karaf_home}=${EMPTY}    ${export_java_home}=${EMPTY}
 370     [Documentation]    If the list is empty, start all cluster members. Otherwise, start members based on present indices.
 371     ...    If ${wait_for_sync}, wait for cluster sync on listed members.
 372     ...    Optionally karaf_home can be overriden. Optionally specific JAVA_HOME is used for starting.
 373     ${base_command} =    BuiltIn.Set_Variable_If    "${karaf_home}"    ${karaf_home}/bin/start    ${NODE_START_COMMAND}
 374     ${command} =    BuiltIn.Set_Variable_If    "${export_java_home}"    export JAVA_HOME="${export_java_home}"; ${base_command}    ${base_command}
 375     Run_Bash_Command_On_List_Or_All    command=${command}    member_index_list=${member_index_list}
 376     BuiltIn.Return_From_Keyword_If    not ${wait_for_sync}
 377     BuiltIn.Wait_Until_Keyword_Succeeds    ${timeout}    10s    Check_Cluster_Is_In_Sync    member_index_list=${member_index_list}
 378     # TODO: Do we also want to check Shard Leaders here?
 379
 380 Clean_Journals_And_Snapshots_On_List_Or_All
 381     [Arguments]    ${member_index_list}=${EMPTY}    ${karaf_home}=${KARAF_HOME}
 382     [Documentation]    Delete journal and snapshots directories on every node listed (or all).
 383     ${index_list} =    ClusterManagement__Given_Or_Internal_Index_List    given_list=${member_index_list}
 384     ${command} =    Set Variable    rm -rf "${karaf_home}/journal" "${karaf_home}/snapshots"
 385     : FOR    ${index}    IN    @{index_list}    # usually: 1, 2, 3.
 386     \    Run_Bash_Command_On_Member    command=${command}    member_index=${index}
 387
 388 Verify_Karaf_Is_Not_Running_On_Member
 389     [Arguments]    ${member_index}
 390     [Documentation]    Fail if non-zero karaf instances are counted on member of given index.
 391     ${count} =    Count_Running_Karafs_On_Member    member_index=${member_index}
 392     BuiltIn.Should_Be_Equal    0    ${count}    Found running Karaf count: ${count}
 393
 394 Verify_Single_Karaf_Is_Running_On_Member
 395     [Arguments]    ${member_index}
 396     [Documentation]    Fail if number of karaf instances on member of given index is not one.
 397     ${count} =    Count_Running_Karafs_On_Member    member_index=${member_index}
 398     BuiltIn.Should_Be_Equal    1    ${count}    Wrong number of Karafs running: ${count}
 399
 400 Count_Running_Karafs_On_Member
 401     [Arguments]    ${member_index}
 402     [Documentation]    Remotely execute grep for karaf process, return count as string.
 403     ${command} =    BuiltIn.Set_Variable    ps axf | grep karaf | grep -v grep | wc -l
 404     ${count} =    Run_Bash_Command_On_Member    command=${command}    member_index=${member_index}
 405     [Return]    ${count}
 406
 407 Isolate_Member_From_List_Or_All
 408     [Arguments]    ${isolate_member_index}    ${member_index_list}=${EMPTY}
 409     [Documentation]    If the list is empty, isolate member from all ODL instances. Otherwise, isolate member based on present indices.
 410     ...    The KW will return a list of available members: \${updated index_list}=\${member_index_list}-\${isolate_member_index}
 411     ${index_list} =    ClusterManagement__Given_Or_Internal_Index_List    given_list=${member_index_list}
 412     ${source} =    Collections.Get_From_Dictionary    ${ClusterManagement__index_to_ip_mapping}    ${isolate_member_index}
 413     : FOR    ${index}    IN    @{index_list}
 414     \    ${destination} =    Collections.Get_From_Dictionary    ${ClusterManagement__index_to_ip_mapping}    ${index}
 415     \    ${command} =    BuiltIn.Set_Variable    sudo /sbin/iptables -I OUTPUT -p all --source ${source} --destination ${destination} -j DROP
 416     \    BuiltIn.Run_Keyword_If    "${index}" != "${isolate_member_index}"    Run_Bash_Command_On_Member    command=${command}    member_index=${isolate_member_index}
 417     ${command} =    BuiltIn.Set_Variable    sudo /sbin/iptables -L -n
 418     ${output} =    Run_Bash_Command_On_Member    command=${command}    member_index=${isolate_member_index}
 419     BuiltIn.Log    ${output}
 420     ${updated_index_list} =    BuiltIn.Create_List    @{index_list}
 421     Collections.Remove_Values_From_List    ${updated_index_list}    ${isolate_member_index}
 422     [Return]    ${updated_index_list}
 423
 424 Rejoin_Member_From_List_Or_All
 425     [Arguments]    ${rejoin_member_index}    ${member_index_list}=${EMPTY}
 426     [Documentation]    If the list is empty, rejoin member from all ODL instances. Otherwise, rejoin member based on present indices.
 427     ${index_list} =    ClusterManagement__Given_Or_Internal_Index_List    given_list=${member_index_list}
 428     ${source} =    Collections.Get_From_Dictionary    ${ClusterManagement__index_to_ip_mapping}    ${rejoin_member_index}
 429     : FOR    ${index}    IN    @{index_list}
 430     \    ${destination} =    Collections.Get_From_Dictionary    ${ClusterManagement__index_to_ip_mapping}    ${index}
 431     \    ${command} =    BuiltIn.Set_Variable    sudo /sbin/iptables -D OUTPUT -p all --source ${source} --destination ${destination} -j DROP
 432     \    BuiltIn.Run_Keyword_If    "${index}" != "${rejoin_member_index}"    Run_Bash_Command_On_Member    command=${command}    member_index=${rejoin_member_index}
 433     ${command} =    BuiltIn.Set_Variable    sudo /sbin/iptables -L -n
 434     ${output} =    Run_Bash_Command_On_Member    command=${command}    member_index=${rejoin_member_index}
 435     BuiltIn.Log    ${output}
 436
 437 Flush_Iptables_From_List_Or_All
 438     [Arguments]    ${member_index_list}=${EMPTY}
 439     [Documentation]    If the list is empty, flush IPTables in all ODL instances. Otherwise, flush member based on present indices.
 440     ${command} =    BuiltIn.Set_Variable    sudo iptables -v -F
 441     ${output} =    Run_Bash_Command_On_List_Or_All    command=${command}    member_index_list=${member_index_list}
 442
 443 Run_Bash_Command_On_List_Or_All
 444     [Arguments]    ${command}    ${member_index_list}=${EMPTY}
 445     [Documentation]    Cycle through indices (or all), run command on each.
 446     ${index_list} =    ClusterManagement__Given_Or_Internal_Index_List    given_list=${member_index_list}
 447     : FOR    ${index}    IN    @{index_list}
 448     \    Run_Bash_Command_On_Member    command=${command}    member_index=${index}
 449
 450 Run_Bash_Command_On_Member
 451     [Arguments]    ${command}    ${member_index}
 452     [Documentation]    Obtain IP, call Utils and return output. This does not preserve active ssh session.
 453     # TODO: Rename these keyword to Run_Bash_Command_On_Member to distinguish from Karaf (or even Windows) commands.
 454     ${member_ip} =    Collections.Get_From_Dictionary    dictionary=${ClusterManagement__index_to_ip_mapping}    key=${member_index}
 455     ${output}    ${rc} =    SSHKeywords.Run_Keyword_Preserve_Connection    Utils.Run_Command_On_Controller    ${member_ip}    ${command}
 456     [Return]    ${output}    ${rc}
 457
 458 Run_Karaf_Command_On_List_Or_All
 459     [Arguments]    ${command}    ${member_index_list}=${EMPTY}    ${timeout}=10s
 460     [Documentation]    Cycle through indices (or all), run karaf command on each.
 461     ${index_list} =    ClusterManagement__Given_Or_Internal_Index_List    given_list=${member_index_list}
 462     : FOR    ${index}    IN    @{index_list}
 463     \    ${member_ip} =    Collections.Get_From_Dictionary    dictionary=${ClusterManagement__index_to_ip_mapping}    key=${index}
 464     \    KarafKeywords.Safe_Issue_Command_On_Karaf_Console    ${command}    ${member_ip}    timeout=${timeout}
 465
 466 Run_Karaf_Command_On_Member
 467     [Arguments]    ${command}    ${member_index}    ${timeout}=10s
 468     [Documentation]    Obtain IP address, call KarafKeywords and return output. This does not preserve active ssh session.
 469     ...    This keyword is not used by Run_Karaf_Command_On_List_Or_All, but returned output may be useful.
 470     ${member_ip} =    Collections.Get_From_Dictionary    dictionary=${ClusterManagement__index_to_ip_mapping}    key=${member_index}
 471     ${output} =    KarafKeywords.Safe_Issue_Command_On_Karaf_Console    ${command}    controller=${member_ip}    timeout=${timeout}
 472     [Return]    ${output}
 473
 474 Install_Feature_On_List_Or_All
 475     [Arguments]    ${feature_name}    ${member_index_list}=${EMPTY}    ${timeout}=60s
 476     [Documentation]    Attempt installation on each member from list (or all). Then look for failures.
 477     ${index_list} =    ClusterManagement__Given_Or_Internal_Index_List    given_list=${member_index_list}
 478     ${status_list} =    BuiltIn.Create_List
 479     : FOR    ${index}    IN    @{index_list}
 480     \    ${status}    ${text} =    BuiltIn.Run_Keyword_And_Ignore_Error    Install_Feature_On_Member    feature_name=${feature_name}    member_index=${index}
 481     \    ...    timeout=${timeout}
 482     \    BuiltIn.Log    ${text}
 483     \    Collections.Append_To_List    ${status_list}    ${status}
 484     : FOR    ${status}    IN    @{status_list}
 485     \    BuiltIn.Run_Keyword_If    "${status}" != "PASS"    BuiltIn.Fail    ${feature_name} installation failed, see log.
 486
 487 Install_Feature_On_Member
 488     [Arguments]    ${feature_name}    ${member_index}    ${timeout}=60s
 489     [Documentation]    Run feature:install karaf command, fail if installation was not successful. Return output.
 490     ${status}    ${output} =    BuiltIn.Run_Keyword_And_Ignore_Error    Run_Karaf_Command_On_Member    command=feature:install ${feature_name}    member_index=${member_index}    timeout=${timeout}
 491     BuiltIn.Run_Keyword_If    "${status}" != "PASS"    BuiltIn.Fail    Failed to install ${feature_name}: ${output}
 492     BuiltIn.Should_Not_Contain    ${output}    Can't install    Failed to install ${feature_name}: ${output}
 493     [Return]    ${output}
 494
 495 With_Ssh_To_List_Or_All_Run_Keyword
 496     [Arguments]    ${member_index_list}    ${keyword_name}    @{args}    &{kwargs}
 497     [Documentation]    For each index in given list (or all): activate SSH connection, run given Keyword, close active connection. Return None.
 498     ...    Note that if the Keyword affects SSH connections, results are still deterministic, but perhaps undesirable.
 499     ...    Beware that in order to avoid "got positional argument after named arguments", first two arguments in the call should not be named.
 500     BuiltIn.Comment    This keyword is experimental and there is high risk of being replaced by another approach.
 501     # TODO: For_Index_From_List_Or_All_Run_Keyword applied to With_Ssh_To_Member_Run_Keyword?
 502     ${index_list} =    ClusterManagement__Given_Or_Internal_Index_List    given_list=${member_index_list}
 503     : FOR    ${member_index}    IN    @{index_list}
 504     \    ${member_ip} =    Resolve_IP_Address_For_Member    ${member_index}
 505     \    SSHKeywords.Open_Connection_To_Odl_System    ip_address=${member_ip}
 506     \    BuiltIn.Run_Keyword    ${keyword_name}    @{args}    &{kwargs}
 507     \    SSHLibrary.Close_Connection
 508
 509 Safe_With_Ssh_To_List_Or_All_Run_Keyword
 510     [Arguments]    ${member_index_list}    ${keyword_name}    @{args}    &{kwargs}
 511     [Documentation]    Remember active ssh connection index, call With_Ssh_To_List_Or_All_Run_Keyword, return None. Restore the conection index on teardown.
 512     SSHKeywords.Run_Keyword_Preserve_Connection    With_Ssh_To_List_Or_All_Run_Keyword    ${member_index_list}    ${keyword_name}    @{args}    &{kwargs}
 513
 514 Clean_Directories_On_List_Or_All
 515     [Arguments]    ${member_index_list}=${EMPTY}    ${directory_list}=${EMPTY}    ${karaf_home}=${KARAF_HOME}
 516     [Documentation]    Clear @{directory_list} or @{ODL_DEFAULT_DATA_PATHS} for members in given list or all. Return None.
 517     ...    This is intended to return Karaf (offline) to the state it was upon the first boot.
 518     ${path_list} =    Builtin.Set Variable If    "${directory_list}" == "${EMPTY}"    ${ODL_DEFAULT_DATA_PATHS}    ${directory_list}
 519     Safe_With_Ssh_To_List_Or_All_Run_Keyword    ${member_index_list}    ClusterManagement__Clean_Directories    ${path_list}    ${karaf_home}
 520
 521 Store_Karaf_Log_On_List_Or_All
 522     [Arguments]    ${member_index_list}=${EMPTY}    ${dst_dir}=/tmp    ${karaf_home}=${KARAF_HOME}
 523     [Documentation]    Saves karaf.log to the ${dst_dir} for members in given list or all. Return None.
 524     Safe_With_Ssh_To_List_Or_All_Run_Keyword    ${member_index_list}    SSHKeywords.Execute_Command_Should_Pass    cp ${karaf_home}/data/log/karaf.log ${dst_dir}
 525
 526 Restore_Karaf_Log_On_List_Or_All
 527     [Arguments]    ${member_index_list}=${EMPTY}    ${src_dir}=/tmp    ${karaf_home}=${KARAF_HOME}
 528     [Documentation]    Places stored karaf.log to the ${karaf_home}/data/log for members in given list or all. Return None.
 529     Safe_With_Ssh_To_List_Or_All_Run_Keyword    ${member_index_list}    SSHKeywords.Execute_Command_Should_Pass    cp ${src_dir}/karaf.log ${karaf_home}/data/log/
 530
 531 ClusterManagement__Clean_Directories
 532     [Arguments]    ${relative_path_list}    ${karaf_home}
 533     [Documentation]    For each relative path, remove files with respect to ${karaf_home}. Return None.
 534     : FOR    ${relative_path}    IN    @{relative_path_list}
 535     \    SSHLibrary.Execute_Command    rm -rf ${karaf_home}${/}${relative_path}
 536
 537 Put_As_Json_And_Check_Member_List_Or_All
 538     [Arguments]    ${uri}    ${data}    ${member_index}    ${member_index_list}=${EMPTY}
 539     [Documentation]    Send a PUT with the supplied uri ${uri} and body ${data} to member ${member_index}.
 540     ...    Then check data is replicated in all or some members defined in ${member_index_list}.
 541     ${response_text} =    Put_As_Json_To_Member    uri=${uri}    data=${data}    member_index=${member_index}
 542     Wait Until Keyword Succeeds    5s    1s    Check_Json_Member_List_Or_All    uri=${uri}    expected_data=${data}    member_index_list=${member_index_list}
 543     [Return]    ${response_text}
 544
 545 Put_As_Json_To_Member
 546     [Arguments]    ${uri}    ${data}    ${member_index}
 547     [Documentation]    Send a PUT with the supplied uri and data to member ${member_index}.
 548     ${session} =    Resolve_Http_Session_For_Member    member_index=${member_index}
 549     ${response_text} =    TemplatedRequests.Put_As_Json_To_Uri    uri=${uri}    data=${data}    session=${session}
 550     [Return]    ${response_text}
 551
 552 Post_As_Json_To_Member
 553     [Arguments]    ${uri}    ${data}    ${member_index}
 554     [Documentation]    Send a POST with the supplied uri and data to member ${member_index}.
 555     ${session} =    Resolve_Http_Session_For_Member    member_index=${member_index}
 556     ${response_text} =    TemplatedRequests.Post_As_Json_To_Uri    uri=${uri}    data=${data}    session=${session}
 557     [Return]    ${response_text}
 558
 559 Delete_And_Check_Member_List_Or_All
 560     [Arguments]    ${uri}    ${member_index}    ${member_index_list}=${EMPTY}
 561     [Documentation]    Send a DELETE with the supplied uri to the member ${member_index}.
 562     ...    Then check the data is removed from all members in ${member_index_list}.
 563     ${response_text} =    Delete_From_Member    ${uri}    ${member_index}
 564     BuiltIn.Wait_Until_Keyword_Succeeds    5s    1s    Check_No_Content_Member_List_Or_All    uri=${uri}    member_index_list=${member_index_list}
 565     [Return]    ${response_text}
 566
 567 Delete_From_Member
 568     [Arguments]    ${uri}    ${member_index}
 569     [Documentation]    Send a DELETE with the supplied uri to member ${member_index}.
 570     ${session} =    Resolve_Http_Session_For_Member    member_index=${member_index}
 571     ${response_text} =    TemplatedRequests.Delete_From_Uri    uri=${uri}    session=${session}
 572     [Return]    ${response_text}
 573
 574 Check_Json_Member_List_Or_All
 575     [Arguments]    ${uri}    ${expected_data}    ${member_index_list}=${EMPTY}
 576     [Documentation]    Send a GET with the supplied uri to all or some members defined in ${member_index_list}.
 577     ...    Then check received data is = ${expected data}.
 578     ${index_list} =    ClusterManagement__Given_Or_Internal_Index_List    given_list=${member_index_list}
 579     : FOR    ${index}    IN    @{index_list}
 580     \    ${data} =    Get_From_Member    uri=${uri}    member_index=${index}
 581     \    TemplatedRequests.Normalize_Jsons_And_Compare    ${expected_data}    ${data}
 582
 583 Check_Item_Occurrence_Member_List_Or_All
 584     [Arguments]    ${uri}    ${dictionary}    ${member_index_list}=${EMPTY}
 585     [Documentation]    Send a GET with the supplied uri to all or some members defined in ${member_index_list}.
 586     ...    Then check received for occurrences of items expressed in a dictionary ${dictionary}.
 587     ${index_list} =    ClusterManagement__Given_Or_Internal_Index_List    given_list=${member_index_list}
 588     : FOR    ${index}    IN    @{index_list}
 589     \    ${data} =    Get_From_Member    uri=${uri}    member_index=${index}
 590     \    Utils.Check Item Occurrence    ${data}    ${dictionary}
 591
 592 Check_No_Content_Member_List_Or_All
 593     [Arguments]    ${uri}    ${member_index_list}=${EMPTY}
 594     [Documentation]    Send a GET with the supplied uri to all or some members defined in ${member_index_list}.
 595     ...    Then check there is no content.
 596     ${index_list} =    ClusterManagement__Given_Or_Internal_Index_List    given_list=${member_index_list}
 597     : FOR    ${index}    IN    @{index_list}
 598     \    ${session} =    Resolve_Http_Session_For_Member    member_index=${index}
 599     \    Utils.No_Content_From_URI    ${session}    ${uri}
 600
 601 Get_From_Member
 602     [Arguments]    ${uri}    ${member_index}    ${access}=${ACCEPT_EMPTY}
 603     [Documentation]    Send a GET with the supplied uri to member ${member_index}.
 604     ${session} =    Resolve_Http_Session_For_Member    member_index=${member_index}
 605     ${response_text} =    TemplatedRequests.Get_From_Uri    uri=${uri}    accept=${access}    session=${session}
 606     [Return]    ${response_text}
 607
 608 Resolve_IP_Address_For_Member
 609     [Arguments]    ${member_index}
 610     [Documentation]    Return node IP address of given index.
 611     ${ip_address} =    Collections.Get From Dictionary    dictionary=${ClusterManagement__index_to_ip_mapping}    key=${member_index}
 612     [Return]    ${ip_address}
 613
 614 Resolve_Http_Session_For_Member
 615     [Arguments]    ${member_index}
 616     [Documentation]    Return RequestsLibrary session alias pointing to node of given index.
 617     ${session} =    BuiltIn.Set_Variable    ClusterManagement__session_${member_index}
 618     [Return]    ${session}
 619
 620 Resolve_Shard_Type_Class
 621     [Arguments]    ${shard_type}
 622     [Documentation]    Simple lookup for class name corresponding to desired type.
 623     BuiltIn.Run_Keyword_If    '${shard_type}' == 'config'    BuiltIn.Return_From_Keyword    DistributedConfigDatastore
 624     ...    ELSE IF    '${shard_type}' == 'operational'    BuiltIn.Return_From_Keyword    DistributedOperationalDatastore
 625     BuiltIn.Fail    Unrecognized shard type: ${shard_type}
 626
 627 ClusterManagement__Build_List
 628     [Arguments]    ${member}
 629     ${member_int} =    BuiltIn.Convert_To_Integer    ${member}
 630     ${index_list} =    BuiltIn.Create_List    ${member_int}
 631     [Return]    ${index_list}
 632
 633 ClusterManagement__Parse_Sync_Status
 634     [Arguments]    ${shard_manager_text}
 635     [Documentation]    Return sync status parsed out of given text. Called twice by Get_Sync_Status_Of_Member.
 636     BuiltIn.Log    ${shard_manager_text}
 637     ${manager_object} =    RequestsLibrary.To_Json    ${shard_manager_text}
 638     ${value_object} =    Collections.Get_From_Dictionary    dictionary=${manager_object}    key=value
 639     ${sync_status} =    Collections.Get_From_Dictionary    dictionary=${value_object}    key=SyncStatus
 640     [Return]    ${sync_status}
 641
 642 List_Indices_Minus_Member
 643     [Arguments]    ${member_index}    ${member_index_list}=${EMPTY}
 644     [Documentation]    Create a new list which contains indices from ${member_index_list} (or all) without ${member_index}.
 645     ${index_list} =    ClusterManagement__Given_Or_Empty_List    ${member_index_list}
 646     Collections.Remove Values From List    ${index_list}    ${member_index}
 647     [Return]    ${index_list}
 648
 649 ClusterManagement__Given_Or_Internal_Index_List
 650     [Arguments]    ${given_list}=${EMPTY}
 651     [Documentation]    Utility to allow \${EMPTY} as default argument value, as the internal list is computed at runtime.
 652     ...    This keyword always return a (shallow) copy of given or default list,
 653     ...    so operations with the returned list should not affect other lists.
 654     ...    Also note that this keyword does not consider empty list to be \${EMPTY}.
 655     ...    TODO: This keyword is frequently used for obtaining copy of ${ClusterManagement__member_index_list}. Give this keyword public name.
 656     ${return_list_reference} =    BuiltIn.Set_Variable_If    """${given_list}""" != ""    ${given_list}    ${ClusterManagement__member_index_list}
 657     ${return_list_copy} =    BuiltIn.Create_List    @{return_list_reference}
 658     [Return]    ${return_list_copy}
 659
 660 ClusterManagement__Given_Or_Empty_List
 661     [Arguments]    ${given_list}=${EMPTY}
 662     [Documentation]    Utility to allow \${EMPTY} as default argument value, as an empty list is computed at runtime.
 663     ${empty_list} =    BuiltIn.Create_List
 664     ${given_length} =    BuiltIn.Get_Length    ${given_list}
 665     ${return_list} =    BuiltIn.Set_Variable_If    ${given_length} > 0    ${given_list}    ${empty_list}
 666     [Return]    ${return_list}
 667
 668 ClusterManagement__Compute_Derived_Variables
 669     [Arguments]    ${int_of_members}
 670     [Documentation]    Construct index list, session list and IP mapping, publish them as suite variables.
 671     @{member_index_list} =    BuiltIn.Create_List
 672     @{session_list} =    BuiltIn.Create_List
 673     &{index_to_ip_mapping} =    BuiltIn.Create_Dictionary
 674     : FOR    ${index}    IN RANGE    1    ${int_of_members+1}
 675     \    ClusterManagement__Include_Member_Index    ${index}    ${member_index_list}    ${session_list}    ${index_to_ip_mapping}
 676     BuiltIn.Set_Suite_Variable    \${ClusterManagement__member_index_list}    ${member_index_list}
 677     BuiltIn.Set_Suite_Variable    \${ClusterManagement__index_to_ip_mapping}    ${index_to_ip_mapping}
 678     BuiltIn.Set_Suite_Variable    \${ClusterManagement__session_list}    ${session_list}
 679
 680 ClusterManagement__Include_Member_Index
 681     [Arguments]    ${index}    ${member_index_list}    ${session_list}    ${index_to_ip_mapping}
 682     [Documentation]    Add a corresponding item based on index into the last three arguments.
 683     ...    Create the Http session whose alias is added to list.
 684     Collections.Append_To_List    ${member_index_list}    ${index}
 685     ${member_ip} =    BuiltIn.Set_Variable    ${ODL_SYSTEM_${index}_IP}
 686     # ${index} is int (not string) so "key=value" syntax does not work in the following line.
 687     Collections.Set_To_Dictionary    ${index_to_ip_mapping}    ${index}    ${member_ip}
 688     # Http session, with ${AUTH}, without headers.
 689     ${session_alias} =    Resolve_Http_Session_For_Member    member_index=${index}
 690     RequestsLibrary.Create_Session    ${session_alias}    http://${member_ip}:${RESTCONFPORT}    auth=${AUTH}    max_retries=0
 691     Collections.Append_To_List    ${session_list}    ${session_alias}
 692
 693 Sync_Status_Should_Be_False
 694     [Arguments]    ${controller_index}
 695     [Documentation]    Verify that cluster node is not in sync with others
 696     ${status}    Get_Sync_Status_Of_Member    ${controller_index}
 697     BuiltIn.Should_Not_Be_True    ${status}
 698
 699 Sync_Status_Should_Be_True
 700     [Arguments]    ${controller_index}
 701     [Documentation]    Verify that cluster node is in sync with others
 702     ${status}    Get_Sync_Status_Of_Member    ${controller_index}
 703     BuiltIn.Should_Be_True    ${status}