csit/libraries/ClusterManagement.robot

   1 *** Settings ***
   2 Documentation     Resource housing Keywords common to several suites for cluster functional testing.
   3 ...
   4 ...               Copyright (c) 2016 Cisco Systems, Inc. and others. All rights reserved.
   5 ...               Copyright (c) 2016 Brocade Communications Systems, Inc. and others. All rights reserved.
   6 ...
   7 ...               This program and the accompanying materials are made available under the
   8 ...               terms of the Eclipse Public License v1.0 which accompanies this distribution,
   9 ...               and is available at http://www.eclipse.org/legal/epl-v10.html
  10 ...
  11 ...
  12 ...               This resource holds private state (in suite variables),
  13 ...               which is generated once at Setup with ClusterManagement_Setup KW.
  14 ...               The state includes member indexes, IP addresses and Http (RequestsLibrary) sessions.
  15 ...               Cluster Keywords normally use member index, member list or nothing (all members) as argument.
  16 ...
  17 ...               All index lists returned should be sorted numerically, fix if not.
  18 ...
  19 ...               Requirements:
  20 ...               odl-jolokia is assumed to be installed.
  21 ...
  22 ...               Keywords are ordered as follows:
  23 ...               - Cluster Setup
  24 ...               - Shard state, leader and followers
  25 ...               - Entity Owner, candidates and successors
  26 ...               - Kill, Stop and Start Member
  27 ...               - Isolate and Rejoin Member
  28 ...               - Run Commands On Member
  29 ...               - REST requests and checks on Members
  30 ...
  31 ...               TODO: Unify capitalization of Leaders and Followers.
  32 Library           RequestsLibrary    # for Create_Session and To_Json
  33 Library           Collections
  34 Resource          ${CURDIR}/CompareStream.robot
  35 Resource          ${CURDIR}/KarafKeywords.robot
  36 Resource          ${CURDIR}/SSHKeywords.robot
  37 Resource          ${CURDIR}/TemplatedRequests.robot    # for Get_As_Json_From_Uri
  38 Resource          ${CURDIR}/Utils.robot    # for Run_Command_On_Controller
  39 Resource          ${CURDIR}/Variables.robot
  40
  41 *** Variables ***
  42 ${ENTITY_OWNER_URI}    restconf/operational/entity-owners:entity-owners
  43 ${GC_LOG_PATH}    ${KARAF_HOME}/data/log
  44 ${JAVA_HOME}      ${EMPTY}    # releng/builder scripts should provide correct value
  45 ${JOLOKIA_CONF_SHARD_MANAGER_URI}    jolokia/read/org.opendaylight.controller:Category=ShardManager,name=shard-manager-config,type=DistributedConfigDatastore
  46 ${JOLOKIA_OPER_SHARD_MANAGER_URI}    jolokia/read/org.opendaylight.controller:Category=ShardManager,name=shard-manager-operational,type=DistributedOperationalDatastore
  47 ${JOLOKIA_READ_URI}    jolokia/read/org.opendaylight.controller
  48 ${KARAF_HOME}     ${WORKSPACE}${/}${BUNDLEFOLDER}    # TODO: Migrate to Variables.robot
  49 # Bug 9044 workaround: delete etc/host.key before restart.
  50 @{ODL_DEFAULT_DATA_PATHS}    tmp/    data/    cache/    snapshots/    journal/    etc/opendaylight/current/    etc/host.key
  51 ${RESTCONF_MODULES_DIR}    ${CURDIR}/../variables/restconf/modules
  52 ${SINGLETON_NETCONF_DEVICE_ID_PREFIX}    /odl-general-entity:entity[odl-general-entity:name='KeyedInstanceIdentifier{targetType=interface org.opendaylight.yang.gen.v1.urn.tbd.params.xml.ns.yang.network.topology.rev131021.network.topology.topology.Node, path=[org.opendaylight.yang.gen.v1.urn.tbd.params.xml.ns.yang.network.topology.rev131021.NetworkTopology, org.opendaylight.yang.gen.v1.urn.tbd.params.xml.ns.yang.network.topology.rev131021.network.topology.Topology[key=TopologyKey [_topologyId=Uri [_value=topology-netconf]]], org.opendaylight.yang.gen.v1.urn.tbd.params.xml.ns.yang.network.topology.rev131021.network.topology.topology.Node[key=NodeKey [_nodeId=Uri [_value=
  53 ${SINGLETON_NETCONF_DEVICE_ID_SUFFIX}    ]]]]}']
  54 ${SINGLETON_BGPCEP_DEVICE_ID_PREFIX}    /odl-general-entity:entity[odl-general-entity:name='
  55 ${SINGLETON_BGPCEP_DEVICE_ID_SUFFIX}    -service-group']
  56 ${SINGLETON_ELECTION_ENTITY_TYPE}    org.opendaylight.mdsal.ServiceEntityType
  57 ${SINGLETON_CHANGE_OWNERSHIP_ENTITY_TYPE}    org.opendaylight.mdsal.AsyncServiceCloseEntityType
  58 ${NODE_START_COMMAND}    ${KARAF_HOME}/bin/start
  59 ${NODE_STOP_COMMAND}    ${KARAF_HOME}/bin/stop
  60 ${NODE_KARAF_COUNT_COMMAND}    ps axf | grep org.apache.karaf | grep -v grep | wc -l
  61 ${NODE_KILL_COMMAND}    ps axf | grep org.apache.karaf | grep -v grep | awk '{print \"kill -9 \" $1}' | sh
  62 ${NODE_FREEZE_COMMAND}    ps axf | grep org.apache.karaf | grep -v grep | awk '{print \"kill -STOP \" $1}' | sh
  63 ${NODE_UNFREEZE_COMMAND}    ps axf | grep org.apache.karaf | grep -v grep | awk '{print \"kill -CONT \" $1}' | sh
  64
  65 *** Keywords ***
  66 ClusterManagement_Setup
  67     [Arguments]    ${http_timeout}=${DEFAULT_TIMEOUT_HTTP}    ${http_retries}=0
  68     [Documentation]    Detect repeated call, or detect number of members and initialize derived suite variables.
  69     ...    Http sessions are created with parameters to not waste time when ODL is no accepting connections properly.
  70     # Avoid multiple initialization by several downstream libraries.
  71     ${already_done} =    BuiltIn.Get_Variable_Value    \${ClusterManagement__has_setup_run}    False
  72     BuiltIn.Return_From_Keyword_If    ${already_done}
  73     BuiltIn.Set_Suite_Variable    \${ClusterManagement__has_setup_run}    True
  74     ${cluster_size} =    BuiltIn.Get_Variable_Value    \${NUM_ODL_SYSTEM}    1
  75     ${status}    ${possibly_int_of_members} =    BuiltIn.Run_Keyword_And_Ignore_Error    BuiltIn.Convert_To_Integer    ${cluster_size}
  76     ${int_of_members} =    BuiltIn.Set_Variable_If    '${status}' != 'PASS'    ${1}    ${possibly_int_of_members}
  77     ClusterManagement__Compute_Derived_Variables    int_of_members=${int_of_members}    http_timeout=${http_timeout}    http_retries=${http_retries}
  78
  79 Check_Cluster_Is_In_Sync
  80     [Arguments]    ${member_index_list}=${EMPTY}
  81     [Documentation]    Fail if no-sync is detected on a member from list (or any).
  82     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
  83     : FOR    ${index}    IN    @{index_list}    # usually: 1, 2, 3.
  84     \    ${status} =    Get_Sync_Status_Of_Member    member_index=${index}
  85     \    BuiltIn.Continue_For_Loop_If    'True' == '${status}'
  86     \    BuiltIn.Fail    Index ${index} has incorrect status: ${status}
  87
  88 Get_Sync_Status_Of_Member
  89     [Arguments]    ${member_index}
  90     [Documentation]    Obtain IP, two GETs from jolokia URIs, return combined sync status as string.
  91     ${session} =    Resolve_Http_Session_For_Member    member_index=${member_index}
  92     ${conf_text} =    TemplatedRequests.Get_As_Json_From_Uri    uri=${JOLOKIA_CONF_SHARD_MANAGER_URI}    session=${session}
  93     ${conf_status} =    ClusterManagement__Parse_Sync_Status    shard_manager_text=${conf_text}
  94     BuiltIn.Return_From_Keyword_If    'False' == ${conf_status}    False
  95     ${oper_text} =    TemplatedRequests.Get_As_Json_From_Uri    uri=${JOLOKIA_OPER_SHARD_MANAGER_URI}    session=${session}
  96     ${oper_status} =    ClusterManagement__Parse_Sync_Status    shard_manager_text=${oper_text}
  97     [Return]    ${oper_status}
  98
  99 Verify_Leader_Exists_For_Each_Shard
 100     [Arguments]    ${shard_name_list}    ${shard_type}=operational    ${member_index_list}=${EMPTY}    ${verify_restconf}=True
 101     [Documentation]    For each shard name, call Get_Leader_And_Followers_For_Shard.
 102     ...    Not much logic there, but single Keyword is useful when using BuiltIn.Wait_Until_Keyword_Succeeds.
 103     : FOR    ${shard_name}    IN    @{shard_name_list}
 104     \    Get_Leader_And_Followers_For_Shard    shard_name=${shard_name}    shard_type=${shard_type}    validate=True    member_index_list=${member_index_list}    verify_restconf=${verify_restconf}
 105
 106 Get_Leader_And_Followers_For_Shard
 107     [Arguments]    ${shard_name}=default    ${shard_type}=operational    ${validate}=True    ${member_index_list}=${EMPTY}    ${verify_restconf}=True    ${http_timeout}=${EMPTY}
 108     [Documentation]    Get role lists, validate there is one leader, return the leader and list of followers.
 109     ...    Optionally, issue GET to a simple restconf URL to make sure subsequent operations will not encounter 503.
 110     ${leader_list}    ${follower_list} =    Get_State_Info_For_Shard    shard_name=${shard_name}    shard_type=${shard_type}    validate=True    member_index_list=${member_index_list}
 111     ...    verify_restconf=${verify_restconf}    http_timeout=${http_timeout}
 112     ${leader_count} =    BuiltIn.Get_Length    ${leader_list}
 113     BuiltIn.Run_Keyword_If    ${leader_count} < 1    BuiltIn.Fail    No leader found.
 114     BuiltIn.Length_Should_Be    ${leader_list}    ${1}    Too many Leaders.
 115     ${leader} =    Collections.Get_From_List    ${leader_list}    0
 116     [Return]    ${leader}    ${follower_list}
 117
 118 Get_State_Info_For_Shard
 119     [Arguments]    ${shard_name}=default    ${shard_type}=operational    ${validate}=False    ${member_index_list}=${EMPTY}    ${verify_restconf}=False    ${http_timeout}=${EMPTY}
 120     [Documentation]    Return lists of Leader and Follower member indices from a given member index list
 121     ...    (or from the full list if empty). If \${shard_type} is not 'config', 'operational' is assumed.
 122     ...    If \${validate}, Fail if raft state is not Leader or Follower (for example on Candidate).
 123     ...    The biggest difference from Get_Leader_And_Followers_For_Shard
 124     ...    is that no check on number of Leaders is performed.
 125     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 126     Collections.Sort_List    ${index_list}    # to guarantee return values are also sorted lists
 127     # TODO: Support alternative capitalization of 'config'?
 128     ${ds_type} =    BuiltIn.Set_Variable_If    '${shard_type}' != 'config'    operational    config
 129     ${leader_list} =    BuiltIn.Create_List
 130     ${follower_list} =    BuiltIn.Create_List
 131     : FOR    ${index}    IN    @{index_list}    # usually: 1, 2, 3.
 132     \    ${raft_state} =    Get_Raft_State_Of_Shard_At_Member    shard_name=${shard_name}    shard_type=${ds_type}    member_index=${index}    verify_restconf=${verify_restconf}
 133     \    ...    http_timeout=${http_timeout}
 134     \    BuiltIn.Run_Keyword_If    'Follower' == '${raft_state}'    Collections.Append_To_List    ${follower_list}    ${index}
 135     \    ...    ELSE IF    'Leader' == '${raft_state}'    Collections.Append_To_List    ${leader_list}    ${index}
 136     \    ...    ELSE IF    ${validate}    BuiltIn.Fail    Unrecognized Raft state: ${raft_state}
 137     [Return]    ${leader_list}    ${follower_list}
 138
 139 Get_Raft_State_Of_Shard_At_Member
 140     [Arguments]    ${shard_name}    ${shard_type}    ${member_index}    ${verify_restconf}=False    ${http_timeout}=${EMPTY}
 141     [Documentation]    Send request to Jolokia on indexed member, return extracted Raft status.
 142     ...    Optionally, check restconf works.
 143     ${raft_state} =    Get_Raft_Property_From_Shard_Member    RaftState    ${shard_name}    ${shard_type}    ${member_index}    verify_restconf=${verify_restconf}
 144     ...    http_timeout=${http_timeout}
 145     [Return]    ${raft_state}
 146
 147 Get_Raft_Property_From_Shard_Member
 148     [Arguments]    ${property}    ${shard_name}    ${shard_type}    ${member_index}    ${verify_restconf}=False    ${http_timeout}=${EMPTY}
 149     [Documentation]    Send request to Jolokia on indexed member, return extracted Raft property.
 150     ...    Optionally, check restconf works.
 151     ${session} =    Resolve_Http_Session_For_Member    member_index=${member_index}
 152     # TODO: Does the used URI tend to generate large data which floods log.html?
 153     BuiltIn.Run_Keyword_If    ${verify_restconf}    TemplatedRequests.Get_As_Json_Templated    session=${session}    folder=${RESTCONF_MODULES_DIR}    verify=False    http_timeout=${http_timeout}
 154     ${type_class} =    Resolve_Shard_Type_Class    shard_type=${shard_type}
 155     ${uri} =    BuiltIn.Set_Variable    ${JOLOKIA_READ_URI}:Category=Shards,name=member-${member_index}-shard-${shard_name}-${shard_type},type=${type_class}
 156     ${data_text} =    TemplatedRequests.Get_As_Json_From_Uri    uri=${uri}    session=${session}    http_timeout=${http_timeout}
 157     ${data_object} =    RequestsLibrary.To_Json    ${data_text}
 158     ${value} =    Collections.Get_From_Dictionary    ${data_object}    value
 159     ${raft_property} =    Collections.Get_From_Dictionary    ${value}    ${property}
 160     [Return]    ${raft_property}
 161
 162 Verify_Shard_Leader_Elected
 163     [Arguments]    ${shard_name}    ${shard_type}    ${new_elected}    ${old_leader}    ${member_index_list}=${EMPTY}    ${verify_restconf}=True
 164     [Documentation]    Verify new leader was elected or remained the same. Bool paramter ${new_elected} indicates if
 165     ...    new leader is elected or should remained the same as ${old_leader}
 166     ${leader}    ${followers}=    Get_Leader_And_Followers_For_Shard    shard_name=${shard_name}    shard_type=${shard_type}    member_index_list=${member_index_list}    verify_restconf=${verify_restconf}
 167     BuiltIn.Run_Keyword_If    ${new_elected}    BuiltIn.Should_Not_Be_Equal_As_Numbers    ${old_leader}    ${leader}
 168     BuiltIn.Run_Keyword_Unless    ${new_elected}    BuiltIn.Should_Be_Equal_As_numbers    ${old_leader}    ${leader}
 169     BuiltIn.Return_From_Keyword    ${leader}    ${followers}
 170
 171 Verify_Owner_And_Successors_For_Device
 172     [Arguments]    ${device_name}    ${device_type}    ${member_index}    ${candidate_list}=${EMPTY}    ${after_stop}=False
 173     [Documentation]    Returns the owner and successors for the SB device ${device_name} of type ${device_type}. Request is sent to member ${member_index}.
 174     ...    For Boron and beyond, candidates are not removed on node down or isolation,
 175     ...    so this keyword expects candidates to be all members from Boron on.
 176     ...    Extra check is done to verify owner and successors are within the ${candidate_list}. This KW is useful when combined with WUKS.
 177     ...    ${candidate_list} minus owner is returned as ${successor list}.
 178     ...    Users can still use Get_Owner_And_Successors_For_Device if they are interested in downed candidates,
 179     ...    or for testing heterogeneous clusters.
 180     ${index_list} =    List_Indices_Or_All    given_list=${candidate_list}
 181     ${owner}    ${successor_list} =    Get_Owner_And_Successors_For_Device    device_name=${device_name}    device_type=${device_type}    member_index=${member_index}
 182     Collections.List_Should_Contain_Value    ${index_list}    ${owner}    Owner ${owner} is not in candidate list ${index_list}
 183     # In Beryllium or after stopping an instance, the removed instance does not show in the candidate list.
 184     ${expected_candidate_list_origin} =    BuiltIn.Set_Variable_If    ${after_stop}    ${index_list}    ${ClusterManagement__member_index_list}
 185     # We do not want to manipulate either origin list.
 186     ${expected_successor_list} =    BuiltIn.Create_List    @{expected_candidate_list_origin}
 187     Collections.Remove_Values_From_List    ${expected_successor_list}    ${owner}
 188     Collections.Lists_Should_Be_Equal    ${expected_successor_list}    ${successor_list}    Successor list ${successor_list} is not the came as expected ${expected_successor_list}
 189     # User expects the returned successor list to be the provided candidate list minus the owner.
 190     Collections.Remove_Values_From_List    ${index_list}    ${owner}
 191     [Return]    ${owner}    ${index_list}
 192
 193 Get_Owner_And_Successors_For_Device
 194     [Arguments]    ${device_name}    ${device_type}    ${member_index}    ${http_timeout}=${EMPTY}
 195     [Documentation]    Returns the owner and a list of successors for the SB device ${device_name} of type ${device_type}. Request is sent to member ${member_index}.
 196     ...    Successors are those device candidates not elected as owner. The list of successors = (list of candidates) - (owner).
 197     ...    The returned successor list is sorted numerically.
 198     ...    Note that "candidate list" definition currently differs between Beryllium and Boron.
 199     ...    Use Verify_Owner_And_Successors_For_Device if you want the older semantics (inaccessible nodes not present in the list).
 200     # TODO: somewhere to introduce ${DEFAULT_RESTCONF_DATASTORE_TIMEOUT}. Value may depend on protocol (ask vs tell) and perhaps stream.
 201     ${owner}    ${candidate_list} =    Get_Owner_And_Candidates_For_Device    device_name=${device_name}    device_type=${device_type}    member_index=${member_index}    http_timeout=${http_timeout}
 202     ${successor_list} =    BuiltIn.Create_List    @{candidate_list}    # Copy operation is not required, but new variable name requires a line anyway.
 203     Collections.Remove_Values_From_List    ${successor_list}    ${owner}
 204     [Return]    ${owner}    ${successor_list}
 205
 206 Get_Owner_And_Candidates_For_Device_Old
 207     [Arguments]    ${device_name}    ${device_type}    ${member_index}    ${http_timeout}=${EMPTY}
 208     [Documentation]    Returns the owner and a list of candidates for the SB device ${device_name} of type ${device_type}. Request is sent to member ${member_index}.
 209     ...    Candidates are all members that register to own a device, so the list of candiates includes the owner.
 210     ...    The returned candidate list is sorted numerically.
 211     ...    Note that "candidate list" definition currently differs between Beryllium and Boron.
 212     ...    It is recommended to use Get_Owner_And_Successors_For_Device instead of this keyword, see documentation there.
 213     BuiltIn.Comment    TODO: Can this implementation be changed to call Get_Owner_And_Candidates_For_Type_And_Id?
 214     ${session} =    Resolve_Http_Session_For_Member    member_index=${member_index}
 215     ${data} =    TemplatedRequests.Get_As_Json_From_Uri    uri=${ENTITY_OWNER_URI}    session=${session}    http_timeout=${http_timeout}
 216     ${candidate_list} =    BuiltIn.Create_List
 217     ${entity_type} =    BuiltIn.Set_Variable_If    '${device_type}' == 'netconf'    netconf-node/${device_name}    ${device_type}
 218     ${clear_data} =    BuiltIn.Run_Keyword_If    '${device_type}' == 'openflow' or '${device_type}' == 'netconf'    Extract_OpenFlow_Device_Data    ${data}
 219     ...    ELSE IF    '${device_type}' == 'ovsdb'    Extract_Ovsdb_Device_Data    ${data}
 220     ...    ELSE IF    '${device_type}' == 'org.opendaylight.mdsal.ServiceEntityType'    Extract_Service_Entity_Type    ${data}
 221     ...    ELSE    Fail    Not recognized device type: ${device_type}
 222     ${json} =    RequestsLibrary.To_Json    ${clear_data}
 223     ${entity_type_list} =    Collections.Get_From_Dictionary    &{json}[entity-owners]    entity-type
 224     ${entity_type_index} =    Utils.Get_Index_From_List_Of_Dictionaries    ${entity_type_list}    type    ${entity_type}
 225     BuiltIn.Should_Not_Be_Equal_As_Integers    ${entity_type_index}    -1    No Entity Owner found for ${device_type}
 226     ${entity_list} =    Collections.Get_From_Dictionary    @{entity_type_list}[${entity_type_index}]    entity
 227     ${entity_index} =    Utils.Get_Index_From_List_Of_Dictionaries    ${entity_list}    id    ${device_name}
 228     BuiltIn.Should_Not_Be_Equal_As_Integers    ${entity_index}    -1    Device ${device_name} not found in Entity Owner ${device_type}
 229     ${entity_owner} =    Collections.Get_From_Dictionary    @{entity_list}[${entity_index}]    owner
 230     BuiltIn.Should_Not_Be_Empty    ${entity_owner}    No owner found for ${device_name}
 231     ${owner} =    String.Replace_String    ${entity_owner}    member-    ${EMPTY}
 232     ${owner} =    BuiltIn.Convert_To_Integer    ${owner}
 233     ${entity_candidates_list} =    Collections.Get_From_Dictionary    @{entity_list}[${entity_index}]    candidate
 234     : FOR    ${entity_candidate}    IN    @{entity_candidates_list}
 235     \    ${candidate} =    String.Replace_String    &{entity_candidate}[name]    member-    ${EMPTY}
 236     \    ${candidate} =    BuiltIn.Convert_To_Integer    ${candidate}
 237     \    Collections.Append_To_List    ${candidate_list}    ${candidate}
 238     Collections.Sort_List    ${candidate_list}
 239     [Return]    ${owner}    ${candidate_list}
 240
 241 Get_Owner_And_Candidates_For_Device_Singleton
 242     [Arguments]    ${device_name}    ${device_type}    ${member_index}    ${http_timeout}=${EMPTY}
 243     [Documentation]    Returns the owner and a list of candidates for the SB device ${device_name} of type ${device_type}. Request is sent to member ${member_index}.
 244     ...    Parsing method is selected by device type
 245     ...    Separate kw for every supported device type must be defined
 246     BuiltIn.Keyword_Should_Exist    Get_Owner_And_Candidates_For_Device_Singleton_${device_type}
 247     BuiltIn.Run_Keyword_And_Return    Get_Owner_And_Candidates_For_Device_Singleton_${device_type}    ${device_name}    ${member_index}    http_timeout=${http_timeout}
 248
 249 Get_Owner_And_Candidates_For_Device_Singleton_Netconf
 250     [Arguments]    ${device_name}    ${member_index}    ${http_timeout}=${EMPTY}
 251     [Documentation]    Returns the owner and a list of candidates for the SB device ${device_name} of type netconf. Request is sent to member ${member_index}.
 252     ...    Parsing method is set as netconf (using netconf device id prefix and suffix)
 253     # Get election entity type results
 254     ${type} =    BuiltIn.Set_Variable    ${SINGLETON_ELECTION_ENTITY_TYPE}
 255     ${id} =    BuiltIn.Set_Variable    ${SINGLETON_NETCONF_DEVICE_ID_PREFIX}${device_name}${SINGLETON_NETCONF_DEVICE_ID_SUFFIX}
 256     ${owner_1}    ${candidate_list_1} =    Get_Owner_And_Candidates_For_Type_And_Id    ${type}    ${id}    ${member_index}    http_timeout=${http_timeout}
 257     # Get change ownership entity type results
 258     ${type} =    BuiltIn.Set_Variable    ${SINGLETON_CHANGE_OWNERSHIP_ENTITY_TYPE}
 259     ${id} =    BuiltIn.Set_Variable    ${SINGLETON_NETCONF_DEVICE_ID_PREFIX}${device_name}${SINGLETON_NETCONF_DEVICE_ID_SUFFIX}
 260     ${owner_2}    ${candidate_list_2} =    Get_Owner_And_Candidates_For_Type_And_Id    ${type}    ${id}    ${member_index}    http_timeout=${http_timeout}
 261     # Owners must be same, if not, there is still some election or change ownership in progress
 262     BuiltIn.Should_Be_Equal_As_Integers    ${owner_1}    ${owner_2}    Owners for device ${device_name} are not same
 263     [Return]    ${owner_1}    ${candidate_list_1}
 264
 265 Get_Owner_And_Candidates_For_Device_Singleton_Bgpcep
 266     [Arguments]    ${device_name}    ${member_index}    ${http_timeout}=${EMPTY}
 267     [Documentation]    Returns the owner and a list of candidates for the SB device ${device_name}. Request is sent to member ${member_index}.
 268     # Get election entity type results
 269     ${type} =    BuiltIn.Set_Variable    ${SINGLETON_ELECTION_ENTITY_TYPE}
 270     ${id} =    BuiltIn.Set_Variable    ${SINGLETON_BGPCEP_DEVICE_ID_PREFIX}${device_name}${SINGLETON_BGPCEP_DEVICE_ID_SUFFIX}
 271     ${owner_1}    ${candidate_list_1} =    Get_Owner_And_Candidates_For_Type_And_Id    ${type}    ${id}    ${member_index}    http_timeout=${http_timeout}
 272     # Get change ownership entity type results
 273     ${type} =    BuiltIn.Set_Variable    ${SINGLETON_CHANGE_OWNERSHIP_ENTITY_TYPE}
 274     ${id} =    BuiltIn.Set_Variable    ${SINGLETON_BGPCEP_DEVICE_ID_PREFIX}${device_name}${SINGLETON_BGPCEP_DEVICE_ID_SUFFIX}
 275     ${owner_2}    ${candidate_list_2} =    Get_Owner_And_Candidates_For_Type_And_Id    ${type}    ${id}    ${member_index}    http_timeout=${http_timeout}
 276     # Owners must be same, if not, there is still some election or change ownership in progress
 277     BuiltIn.Should_Be_Equal_As_Integers    ${owner_1}    ${owner_2}    Owners for device ${device_name} are not same
 278     [Return]    ${owner_1}    ${candidate_list_1}
 279
 280 Get_Owner_And_Candidates_For_Device
 281     [Arguments]    ${device_name}    ${device_type}    ${member_index}    ${http_timeout}=${EMPTY}
 282     [Documentation]    Returns the owner and a list of candidates for the SB device ${device_name} of type ${device_type}. Request is sent to member ${member_index}.
 283     ...    If parsing as singleton failed, kw try to parse data in old way (without singleton).
 284     ...    Candidates are all members that register to own a device, so the list of candiates includes the owner.
 285     ...    The returned candidate list is sorted numerically.
 286     ...    Note that "candidate list" definition currently differs between Beryllium and Boron.
 287     ...    It is recommended to use Get_Owner_And_Successors_For_Device instead of this keyword, see documentation there.
 288     # Try singleton
 289     ${status}    ${results} =    BuiltIn.Run_Keyword_And_Ignore_Error    Get_Owner_And_Candidates_For_Device_Singleton    device_name=${device_name}    device_type=${device_type}    member_index=${member_index}
 290     ...    http_timeout=${http_timeout}
 291     BuiltIn.Return_From_Keyword_If    "${status}"=="PASS"    ${results}
 292     # If singleton failed, try parsing in old way
 293     ${status}    ${results} =    BuiltIn.Run_Keyword_And_Ignore_Error    Get_Owner_And_Candidates_For_Device_Old    device_name=${device_name}    device_type=${device_type}    member_index=${member_index}
 294     ...    http_timeout=${http_timeout}
 295     # previous 3 lines (BuilIn.Return.., # If singleton..., ${status}....) could be deleted when old way will not be supported anymore
 296     BuiltIn.Run_Keyword_If    '${status}'=='FAIL'    BuiltIn.Fail    Could not parse owner and candidates for device ${device_name}
 297     [Return]    @{results}
 298
 299 Check_Old_Owner_Stays_Elected_For_Device
 300     [Arguments]    ${device_name}    ${device_type}    ${old_owner}    ${node_to_ask}    ${http_timeout}=${EMPTY}
 301     [Documentation]    Verify the owner remain the same as ${old_owner}
 302     ${owner}    ${candidates} =    Get_Owner_And_Candidates_For_Device    ${device_name}    ${device_type}    ${node_to_ask}    http_timeout=${http_timeout}
 303     BuiltIn.Should_Be_Equal_As_numbers    ${old_owner}    ${owner}
 304     BuiltIn.Return_From_Keyword    ${owner}    ${candidates}
 305
 306 Check_New_Owner_Got_Elected_For_Device
 307     [Arguments]    ${device_name}    ${device_type}    ${old_owner}    ${node_to_ask}    ${http_timeout}=${EMPTY}
 308     [Documentation]    Verify new owner was elected comparing to ${old_owner}
 309     ${owner}    ${candidates} =    Get_Owner_And_Candidates_For_Device    ${device_name}    ${device_type}    ${node_to_ask}    http_timeout=${http_timeout}
 310     BuiltIn.Should_Not_Be_Equal_As_Numbers    ${old_owner}    ${owner}
 311     BuiltIn.Return_From_Keyword    ${owner}    ${candidates}
 312
 313 Get_Owner_And_Candidates_For_Type_And_Id
 314     [Arguments]    ${type}    ${id}    ${member_index}    ${require_candidate_list}=${EMPTY}    ${http_timeout}=${EMPTY}
 315     [Documentation]    Returns the owner and a list of candidates for entity specified by ${type} and ${id}
 316     ...    Request is sent to member ${member_index}.
 317     ...    Candidates are all members that register to own a device, so the list of candiates includes the owner.
 318     ...    Bear in mind that for Boron and beyond, candidates are not removed on node down or isolation.
 319     ...    If ${require_candidate_list} is not \${EMPTY}, check whether the actual list of candidates matches.
 320     ...    Note that differs from "given list" semantics used in other keywords,
 321     ...    namely you cannot use \${EMPTY} to stand for "full list" in this keyword.
 322     BuiltIn.Comment    TODO: Find a way to unify and deduplicate code blocks in Get_Owner_And_Candidates_* keywords.
 323     ${session} =    Resolve_Http_Session_For_Member    member_index=${member_index}
 324     ${data} =    TemplatedRequests.Get_As_Json_From_Uri    uri=${ENTITY_OWNER_URI}    session=${session}    http_timeout=${http_timeout}
 325     ${candidate_list} =    BuiltIn.Create_List
 326     ${json} =    RequestsLibrary.To_Json    ${data}
 327     ${entity_type_list} =    Collections.Get_From_Dictionary    &{json}[entity-owners]    entity-type
 328     ${entity_type_index} =    Utils.Get_Index_From_List_Of_Dictionaries    ${entity_type_list}    type    ${type}
 329     BuiltIn.Should_Not_Be_Equal_As_Integers    ${entity_type_index}    -1    No Entity Owner found for ${type}
 330     ${entity_list} =    Collections.Get_From_Dictionary    @{entity_type_list}[${entity_type_index}]    entity
 331     ${entity_index} =    Utils.Get_Index_From_List_Of_Dictionaries    ${entity_list}    id    ${id}
 332     BuiltIn.Should Not_Be_Equal_As_Integers    ${entity_index}    -1    Id ${id} not found in Entity Owner ${type}
 333     ${entity_owner} =    Collections.Get_From_Dictionary    @{entity_list}[${entity_index}]    owner
 334     BuiltIn.Should_Not_Be_Empty    ${entity_owner}    No owner found for type=${type} id=${id}
 335     ${owner} =    String.Replace_String    ${entity_owner}    member-    ${EMPTY}
 336     ${owner} =    BuiltIn.Convert_To_Integer    ${owner}
 337     ${entity_candidates_list} =    Collections.Get_From_Dictionary    @{entity_list}[${entity_index}]    candidate
 338     : FOR    ${entity_candidate}    IN    @{entity_candidates_list}
 339     \    ${candidate} =    String.Replace_String    &{entity_candidate}[name]    member-    ${EMPTY}
 340     \    ${candidate} =    BuiltIn.Convert_To_Integer    ${candidate}
 341     \    Collections.Append_To_List    ${candidate_list}    ${candidate}
 342     Collections.Sort_List    ${candidate_list}
 343     BuiltIn.Comment    TODO: Separate check lines into Verify_Owner_And_Candidates_For_Type_And_Id
 344     BuiltIn.Run_Keyword_If    """${require_candidate_list}"""    BuiltIn.Should_Be_Equal    ${require_candidate_list}    ${candidate_list}    Candidate list does not match: ${candidate_list} is not ${require_candidate_list}
 345     [Return]    ${owner}    ${candidate_list}
 346
 347 Extract_Service_Entity_Type
 348     [Arguments]    ${data}
 349     [Documentation]    Remove superfluous device data from Entity Owner printout.
 350     ${clear_data} =    String.Replace_String    ${data}    /odl-general-entity:entity[odl-general-entity:name='    ${EMPTY}
 351     ${clear_data} =    String.Replace_String    ${clear_data}    -service-group']    ${EMPTY}
 352     Log    ${clear_data}
 353     [Return]    ${clear_data}
 354
 355 Extract_OpenFlow_Device_Data
 356     [Arguments]    ${data}
 357     [Documentation]    Remove superfluous OpenFlow device data from Entity Owner printout.
 358     ${clear_data} =    String.Replace_String    ${data}    org.opendaylight.mdsal.ServiceEntityType    openflow
 359     ${clear_data} =    String.Replace_String    ${clear_data}    /odl-general-entity:entity[odl-general-entity:name='    ${EMPTY}
 360     ${clear_data} =    String.Replace_String    ${clear_data}    /general-entity:entity[general-entity:name='    ${EMPTY}
 361     ${clear_data} =    String.Replace_String    ${clear_data}    ']    ${EMPTY}
 362     Log    ${clear_data}
 363     [Return]    ${clear_data}
 364
 365 Extract_Ovsdb_Device_Data
 366     [Arguments]    ${data}
 367     [Documentation]    Remove superfluous OVSDB device data from Entity Owner printout.
 368     ${clear_data} =    String.Replace_String    ${data}    /network-topology:network-topology/network-topology:topology[network-topology:topology-id='ovsdb:1']/network-topology:node[network-topology:node-id='    ${EMPTY}
 369     ${clear_data} =    String.Replace_String    ${clear_data}    ']    ${EMPTY}
 370     Log    ${clear_data}
 371     [Return]    ${clear_data}
 372
 373 Kill_Single_Member
 374     [Arguments]    ${member}    ${original_index_list}=${EMPTY}    ${confirm}=True
 375     [Documentation]    Convenience keyword that kills the specified member of the cluster.
 376     ...    The KW will return a list of available members: \${updated index_list}=\${original_index_list}-\${member}
 377     ${index_list} =    ClusterManagement__Build_List    ${member}
 378     ${member_ip} =    Return_Member_IP    ${member}
 379     KarafKeywords.Log_Message_To_Controller_Karaf    Killing ODL${member} ${member_ip}
 380     ${updated_index_list} =    Kill_Members_From_List_Or_All    ${index_list}    ${original_index_list}    ${confirm}
 381     [Return]    ${updated_index_list}
 382
 383 Kill_Members_From_List_Or_All
 384     [Arguments]    ${member_index_list}=${EMPTY}    ${original_index_list}=${EMPTY}    ${confirm}=True
 385     [Documentation]    If the list is empty, kill all ODL instances. Otherwise, kill members based on \${kill_index_list}
 386     ...    If \${confirm} is True, sleep 1 second and verify killed instances are not there anymore.
 387     ...    The KW will return a list of available members: \${updated index_list}=\${original_index_list}-\${member_index_list}
 388     ${kill_index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 389     ${index_list} =    List_Indices_Or_All    given_list=${original_index_list}
 390     Run_Bash_Command_On_List_Or_All    command=${NODE_KILL_COMMAND}    member_index_list=${member_index_list}
 391     ${updated_index_list} =    BuiltIn.Create_List    @{index_list}
 392     Collections.Remove_Values_From_List    ${updated_index_list}    @{kill_index_list}
 393     BuiltIn.Return_From_Keyword_If    not ${confirm}    ${updated_index_list}
 394     # TODO: Convert to WUKS with configurable timeout if it turns out 1 second is not enough.
 395     BuiltIn.Sleep    1s    Kill -9 closes open files, which may take longer than ssh overhead, but not long enough to warrant WUKS.
 396     : FOR    ${index}    IN    @{kill_index_list}
 397     \    Verify_Karaf_Is_Not_Running_On_Member    member_index=${index}
 398     Run_Bash_Command_On_List_Or_All    command=netstat -pnatu | grep 2550
 399     [Return]    ${updated_index_list}
 400
 401 Stop_Single_Member
 402     [Arguments]    ${member}    ${original_index_list}=${EMPTY}    ${confirm}=True
 403     [Documentation]    Convenience keyword that stops the specified member of the cluster.
 404     ...    The KW will return a list of available members: \${updated index_list}=\${original_index_list}-\${member}
 405     ${index_list} =    ClusterManagement__Build_List    ${member}
 406     ${updated_index_list} =    Stop_Members_From_List_Or_All    ${index_list}    ${original_index_list}    ${confirm}
 407     [Return]    ${updated_index_list}
 408
 409 Stop_Members_From_List_Or_All
 410     [Arguments]    ${member_index_list}=${EMPTY}    ${original_index_list}=${EMPTY}    ${confirm}=True    ${timeout}=120s
 411     [Documentation]    If the list is empty, stops all ODL instances. Otherwise stop members based on \${stop_index_list}
 412     ...    If \${confirm} is True, verify stopped instances are not there anymore.
 413     ...    The KW will return a list of available members: \${updated index_list}=\${original_index_list}-\${member_index_list}
 414     ${stop_index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 415     ${index_list} =    List_Indices_Or_All    given_list=${original_index_list}
 416     Run_Bash_Command_On_List_Or_All    command=${NODE_STOP_COMMAND}    member_index_list=${member_index_list}
 417     ${updated_index_list} =    BuiltIn.Create_List    @{index_list}
 418     Collections.Remove_Values_From_List    ${updated_index_list}    @{stop_index_list}
 419     BuiltIn.Return_From_Keyword_If    not ${confirm}    ${updated_index_list}
 420     : FOR    ${index}    IN    @{stop_index_list}
 421     \    BuiltIn.Wait Until Keyword Succeeds    ${timeout}    2s    Verify_Karaf_Is_Not_Running_On_Member    member_index=${index}
 422     Run_Bash_Command_On_List_Or_All    command=netstat -pnatu | grep 2550
 423     [Return]    ${updated_index_list}
 424
 425 Start_Single_Member
 426     [Arguments]    ${member}    ${wait_for_sync}=True    ${timeout}=300s
 427     [Documentation]    Convenience keyword that starts the specified member of the cluster.
 428     ${index_list} =    ClusterManagement__Build_List    ${member}
 429     Start_Members_From_List_Or_All    ${index_list}    ${wait_for_sync}    ${timeout}
 430
 431 Start_Members_From_List_Or_All
 432     [Arguments]    ${member_index_list}=${EMPTY}    ${wait_for_sync}=True    ${timeout}=300s    ${karaf_home}=${EMPTY}    ${export_java_home}=${EMPTY}    ${gc_log_dir}=${EMPTY}
 433     [Documentation]    If the list is empty, start all cluster members. Otherwise, start members based on present indices.
 434     ...    If ${wait_for_sync}, wait for cluster sync on listed members.
 435     ...    Optionally karaf_home can be overriden. Optionally specific JAVA_HOME is used for starting.
 436     ...    Garbage collection is unconditionally logged to files. TODO: Make that reasonable conditional?
 437     ${base_command} =    BuiltIn.Set_Variable_If    """${karaf_home}""" != ""    ${karaf_home}/bin/start    ${NODE_START_COMMAND}
 438     ${command} =    BuiltIn.Set_Variable_If    """${export_java_home}""" != ""    export JAVA_HOME="${export_java_home}"; ${base_command}    ${base_command}
 439     ${epoch} =    DateTime.Get_Current_Date    time_zone=UTC    result_format=epoch    exclude_millis=False
 440     ${gc_filepath} =    BuiltIn.Set_Variable_If    """${karaf_home}""" != ""    ${karaf_home}/data/log/gc_${epoch}.log    ${GC_LOG_PATH}/gc_${epoch}.log
 441     ${gc_options} =    BuiltIn.Set_Variable_If    "docker" not in """${node_start_command}"""    -XX:+PrintGCDetails -XX:+PrintGCDateStamps -Xloggc:${gc_filepath}    ${EMPTY}
 442     Run_Bash_Command_On_List_Or_All    command=${command} ${gc_options}    member_index_list=${member_index_list}
 443     BuiltIn.Return_From_Keyword_If    not ${wait_for_sync}
 444     BuiltIn.Wait_Until_Keyword_Succeeds    ${timeout}    10s    Check_Cluster_Is_In_Sync    member_index_list=${member_index_list}
 445     # TODO: Do we also want to check Shard Leaders here?
 446     [Teardown]    Run_Bash_Command_On_List_Or_All    command=netstat -pnatu | grep 2550
 447
 448 Freeze_Single_Member
 449     [Arguments]    ${member}
 450     [Documentation]    Convenience keyword that stops the specified member of the cluster by freezing the jvm.
 451     ${index_list} =    ClusterManagement__Build_List    ${member}
 452     Freeze_Or_Unfreeze_Members_From_List_Or_All    ${NODE_FREEZE_COMMAND}    ${index_list}
 453
 454 Unfreeze_Single_Member
 455     [Arguments]    ${member}    ${wait_for_sync}=True    ${timeout}=60s
 456     [Documentation]    Convenience keyword that "continues" the specified member of the cluster by unfreezing the jvm.
 457     ${index_list} =    ClusterManagement__Build_List    ${member}
 458     Freeze_Or_Unfreeze_Members_From_List_Or_All    ${NODE_UNFREEZE_COMMAND}    ${index_list}
 459     BuiltIn.Wait_Until_Keyword_Succeeds    ${timeout}    10s    Check_Cluster_Is_In_Sync
 460
 461 Freeze_Or_Unfreeze_Members_From_List_Or_All
 462     [Arguments]    ${command}    ${member_index_list}=${EMPTY}
 463     [Documentation]    If the list is empty, stops/runs all ODL instances. Otherwise stop/run members based on \${stop_index_list}
 464     ...    For command parameter only ${NODE_FREEZE_COMMAND} and ${NODE_UNFREEZE_COMMAND} should be used
 465     ${freeze_index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 466     Run_Bash_Command_On_List_Or_All    command=${command}    member_index_list=${member_index_list}
 467
 468 Clean_Journals_Data_And_Snapshots_On_List_Or_All
 469     [Arguments]    ${member_index_list}=${EMPTY}    ${karaf_home}=${KARAF_HOME}
 470     [Documentation]    Delete journal and snapshots directories on every node listed (or all).
 471     ...    BEWARE: If only a subset of members is cleaned, this causes RetiredGenerationException in Carbon after the affected node re-start.
 472     ...    See https://bugs.opendaylight.org/show_bug.cgi?id=8138
 473     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 474     ${command} =    Set Variable    rm -rf "${karaf_home}/journal" "${karaf_home}/snapshots" "${karaf_home}/data"
 475     : FOR    ${index}    IN    @{index_list}    # usually: 1, 2, 3.
 476     \    Run_Bash_Command_On_Member    command=${command}    member_index=${index}
 477
 478 Verify_Karaf_Is_Not_Running_On_Member
 479     [Arguments]    ${member_index}
 480     [Documentation]    Fail if non-zero karaf instances are counted on member of given index.
 481     ${count} =    Count_Running_Karafs_On_Member    member_index=${member_index}
 482     BuiltIn.Should_Be_Equal    0    ${count}    Found running Karaf count: ${count}
 483
 484 Verify_Single_Karaf_Is_Running_On_Member
 485     [Arguments]    ${member_index}
 486     [Documentation]    Fail if number of karaf instances on member of given index is not one.
 487     ${count} =    Count_Running_Karafs_On_Member    member_index=${member_index}
 488     BuiltIn.Should_Be_Equal    1    ${count}    Wrong number of Karafs running: ${count}
 489
 490 Count_Running_Karafs_On_Member
 491     [Arguments]    ${member_index}
 492     [Documentation]    Remotely execute grep for karaf process, return count as string.
 493     ${command} =    BuiltIn.Set_Variable    ${NODE_KARAF_COUNT_COMMAND}
 494     ${count} =    Run_Bash_Command_On_Member    command=${command}    member_index=${member_index}
 495     [Return]    ${count}
 496
 497 Isolate_Member_From_List_Or_All
 498     [Arguments]    ${isolate_member_index}    ${member_index_list}=${EMPTY}    ${protocol}=all    ${port}=${EMPTY}
 499     [Documentation]    If the list is empty, isolate member from all ODL instances. Otherwise, isolate member based on present indices.
 500     ...    The KW will return a list of available members: \${updated index_list}=\${member_index_list}-\${isolate_member_index}
 501     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 502     ${source} =    Collections.Get_From_Dictionary    ${ClusterManagement__index_to_ip_mapping}    ${isolate_member_index}
 503     ${dport} =    BuiltIn.Set_Variable_If    '${port}' != '${EMPTY}'    --dport ${port}    ${EMPTY}
 504     : FOR    ${index}    IN    @{index_list}
 505     \    ${destination} =    Collections.Get_From_Dictionary    ${ClusterManagement__index_to_ip_mapping}    ${index}
 506     \    ${command} =    BuiltIn.Set_Variable    sudo /sbin/iptables -I OUTPUT -p ${protocol} ${dport} --source ${source} --destination ${destination} -j DROP
 507     \    BuiltIn.Run_Keyword_If    "${index}" != "${isolate_member_index}"    Run_Bash_Command_On_Member    command=${command}    member_index=${isolate_member_index}
 508     ${command} =    BuiltIn.Set_Variable    sudo /sbin/iptables -L -n
 509     ${output} =    Run_Bash_Command_On_Member    command=${command}    member_index=${isolate_member_index}
 510     BuiltIn.Log    ${output}
 511     ${updated_index_list} =    BuiltIn.Create_List    @{index_list}
 512     Collections.Remove_Values_From_List    ${updated_index_list}    ${isolate_member_index}
 513     [Return]    ${updated_index_list}
 514
 515 Rejoin_Member_From_List_Or_All
 516     [Arguments]    ${rejoin_member_index}    ${member_index_list}=${EMPTY}    ${protocol}=all    ${port}=${EMPTY}    ${timeout}=60s
 517     [Documentation]    If the list is empty, rejoin member from all ODL instances. Otherwise, rejoin member based on present indices.
 518     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 519     ${source} =    Collections.Get_From_Dictionary    ${ClusterManagement__index_to_ip_mapping}    ${rejoin_member_index}
 520     ${dport} =    BuiltIn.Set_Variable_If    '${port}' != '${EMPTY}'    --dport ${port}    ${EMPTY}
 521     : FOR    ${index}    IN    @{index_list}
 522     \    ${destination} =    Collections.Get_From_Dictionary    ${ClusterManagement__index_to_ip_mapping}    ${index}
 523     \    ${command} =    BuiltIn.Set_Variable    sudo /sbin/iptables -D OUTPUT -p ${protocol} ${dport} --source ${source} --destination ${destination} -j DROP
 524     \    BuiltIn.Run_Keyword_If    "${index}" != "${rejoin_member_index}"    Run_Bash_Command_On_Member    command=${command}    member_index=${rejoin_member_index}
 525     ${command} =    BuiltIn.Set_Variable    sudo /sbin/iptables -L -n
 526     ${output} =    Run_Bash_Command_On_Member    command=${command}    member_index=${rejoin_member_index}
 527     BuiltIn.Log    ${output}
 528     BuiltIn.Wait_Until_Keyword_Succeeds    ${timeout}    10s    Check_Cluster_Is_In_Sync
 529
 530 Flush_Iptables_From_List_Or_All
 531     [Arguments]    ${member_index_list}=${EMPTY}
 532     [Documentation]    If the list is empty, flush IPTables in all ODL instances. Otherwise, flush member based on present indices.
 533     ${command} =    BuiltIn.Set_Variable    sudo iptables -v -F
 534     ${output} =    Run_Bash_Command_On_List_Or_All    command=${command}    member_index_list=${member_index_list}
 535
 536 Check_Bash_Command_On_List_Or_All
 537     [Arguments]    ${command}    ${member_index_list}=${EMPTY}    ${return_success_only}=False    ${log_on_success}=True    ${log_on_failure}=True    ${stderr_must_be_empty}=True
 538     [Documentation]    Cycle through indices (or all), run bash command on each, using temporary SSH session and restoring the previously active one.
 539     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 540     : FOR    ${index}    IN    @{index_list}
 541     \    Check_Bash_Command_On_Member    command=${command}    member_index=${index}    return_success_only=${return_success_only}    log_on_success=${log_on_success}    log_on_failure=${log_on_failure}
 542     \    ...    stderr_must_be_empty=${stderr_must_be_empty}
 543
 544 Check_Bash_Command_On_Member
 545     [Arguments]    ${command}    ${member_index}    ${return_success_only}=False    ${log_on_success}=True    ${log_on_failure}=True    ${stderr_must_be_empty}=True
 546     [Documentation]    Open SSH session, call SSHKeywords.Execute_Command_Passes, close session, restore previously active session and return output.
 547     BuiltIn.Run_Keyword_And_Return    SSHKeywords.Run_Keyword_Preserve_Connection    Check_Unsafely_Bash_Command_On_Member    ${command}    ${member_index}    return_success_only=${return_success_only}    log_on_success=${log_on_success}
 548     ...    log_on_failure=${log_on_failure}    stderr_must_be_empty=${stderr_must_be_empty}
 549
 550 Check_Unsafely_Bash_Command_On_Member
 551     [Arguments]    ${command}    ${member_index}    ${return_success_only}=False    ${log_on_success}=True    ${log_on_failure}=True    ${stderr_must_be_empty}=True
 552     [Documentation]    Obtain Ip address, open session, call SSHKeywords.Execute_Command_Passes, close session and return output. This affects which SSH session is active.
 553     ${member_ip} =    Resolve_Ip_Address_For_Member    ${member_index}
 554     BuiltIn.Run_Keyword_And_Return    SSHKeywords.Run_Unsafely_Keyword_Over_Temporary_Odl_Session    ${member_ip}    Execute_Command_Passes    ${command}    return_success_only=${return_success_only}    log_on_success=${log_on_success}
 555     ...    log_on_failure=${log_on_failure}    stderr_must_be_empty=${stderr_must_be_empty}
 556
 557 Run_Bash_Command_On_List_Or_All
 558     [Arguments]    ${command}    ${member_index_list}=${EMPTY}
 559     [Documentation]    Cycle through indices (or all), run command on each.
 560     # TODO: Migrate callers to Check_Bash_Command_*
 561     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 562     : FOR    ${index}    IN    @{index_list}
 563     \    Run_Bash_Command_On_Member    command=${command}    member_index=${index}
 564
 565 Run_Bash_Command_On_Member
 566     [Arguments]    ${command}    ${member_index}
 567     [Documentation]    Obtain IP, call Utils and return output. This keeps previous ssh session active.
 568     # TODO: Migrate callers to Check_Bash_Command_*
 569     ${member_ip} =    Collections.Get_From_Dictionary    dictionary=${ClusterManagement__index_to_ip_mapping}    key=${member_index}
 570     ${output} =    SSHKeywords.Run_Keyword_Preserve_Connection    Utils.Run_Command_On_Controller    ${member_ip}    ${command}
 571     Log    ${output}
 572     [Return]    ${output}
 573
 574 Run_Karaf_Command_On_List_Or_All
 575     [Arguments]    ${command}    ${member_index_list}=${EMPTY}    ${timeout}=10s
 576     [Documentation]    Cycle through indices (or all), run karaf command on each.
 577     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 578     : FOR    ${index}    IN    @{index_list}
 579     \    ${member_ip} =    Collections.Get_From_Dictionary    dictionary=${ClusterManagement__index_to_ip_mapping}    key=${index}
 580     \    KarafKeywords.Safe_Issue_Command_On_Karaf_Console    ${command}    ${member_ip}    timeout=${timeout}
 581
 582 Run_Karaf_Command_On_Member
 583     [Arguments]    ${command}    ${member_index}    ${timeout}=10s
 584     [Documentation]    Obtain IP address, call KarafKeywords and return output. This does not preserve active ssh session.
 585     ...    This keyword is not used by Run_Karaf_Command_On_List_Or_All, but returned output may be useful.
 586     ${member_ip} =    Collections.Get_From_Dictionary    dictionary=${ClusterManagement__index_to_ip_mapping}    key=${member_index}
 587     ${output} =    KarafKeywords.Safe_Issue_Command_On_Karaf_Console    ${command}    controller=${member_ip}    timeout=${timeout}
 588     [Return]    ${output}
 589
 590 Install_Feature_On_List_Or_All
 591     [Arguments]    ${feature_name}    ${member_index_list}=${EMPTY}    ${timeout}=60s
 592     [Documentation]    Attempt installation on each member from list (or all). Then look for failures.
 593     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 594     ${status_list} =    BuiltIn.Create_List
 595     : FOR    ${index}    IN    @{index_list}
 596     \    ${status}    ${text} =    BuiltIn.Run_Keyword_And_Ignore_Error    Install_Feature_On_Member    feature_name=${feature_name}    member_index=${index}
 597     \    ...    timeout=${timeout}
 598     \    BuiltIn.Log    ${text}
 599     \    Collections.Append_To_List    ${status_list}    ${status}
 600     : FOR    ${status}    IN    @{status_list}
 601     \    BuiltIn.Run_Keyword_If    "${status}" != "PASS"    BuiltIn.Fail    ${feature_name} installation failed, see log.
 602
 603 Install_Feature_On_Member
 604     [Arguments]    ${feature_name}    ${member_index}    ${timeout}=60s
 605     [Documentation]    Run feature:install karaf command, fail if installation was not successful. Return output.
 606     ${status}    ${output} =    BuiltIn.Run_Keyword_And_Ignore_Error    Run_Karaf_Command_On_Member    command=feature:install ${feature_name}    member_index=${member_index}    timeout=${timeout}
 607     BuiltIn.Run_Keyword_If    "${status}" != "PASS"    BuiltIn.Fail    Failed to install ${feature_name}: ${output}
 608     BuiltIn.Should_Not_Contain    ${output}    Can't install    Failed to install ${feature_name}: ${output}
 609     [Return]    ${output}
 610
 611 With_Ssh_To_List_Or_All_Run_Keyword
 612     [Arguments]    ${member_index_list}    ${keyword_name}    @{args}    &{kwargs}
 613     [Documentation]    For each index in given list (or all): activate SSH connection, run given Keyword, close active connection. Return None.
 614     ...    Beware that in order to avoid "got positional argument after named arguments", first two arguments in the call should not be named.
 615     BuiltIn.Comment    This keyword is experimental and there is high risk of being replaced by another approach.
 616     # TODO: For_Index_From_List_Or_All_Run_Keyword applied to With_Ssh_To_Member_Run_Keyword?
 617     # TODO: Imagine another keyword, using ScalarClosures and adding member index as first argument for each call. Worth it?
 618     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 619     : FOR    ${member_index}    IN    @{index_list}
 620     \    ${member_ip} =    Resolve_IP_Address_For_Member    ${member_index}
 621     \    SSHKeywords.Run_Unsafely_Keyword_Over_Temporary_Odl_Session    ${member_ip}    ${keyword_name}    @{args}    &{kwargs}
 622
 623 Safe_With_Ssh_To_List_Or_All_Run_Keyword
 624     [Arguments]    ${member_index_list}    ${keyword_name}    @{args}    &{kwargs}
 625     [Documentation]    Remember active ssh connection index, call With_Ssh_To_List_Or_All_Run_Keyword, return None. Restore the conection index on teardown.
 626     SSHKeywords.Run_Keyword_Preserve_Connection    With_Ssh_To_List_Or_All_Run_Keyword    ${member_index_list}    ${keyword_name}    @{args}    &{kwargs}
 627
 628 Clean_Directories_On_List_Or_All
 629     [Arguments]    ${member_index_list}=${EMPTY}    ${directory_list}=${EMPTY}    ${karaf_home}=${KARAF_HOME}    ${tmp_dir}=${EMPTY}
 630     [Documentation]    Clear @{directory_list} or @{ODL_DEFAULT_DATA_PATHS} for members in given list or all. Return None.
 631     ...    If \${tmp_dir} is nonempty, use that location to preserve data/log/.
 632     ...    This is intended to return Karaf (offline) to the state it was upon the first boot.
 633     ${path_list} =    Builtin.Set Variable If    "${directory_list}" == "${EMPTY}"    ${ODL_DEFAULT_DATA_PATHS}    ${directory_list}
 634     BuiltIn.Run_Keyword_If    """${tmp_dir}""" != ""    Check_Bash_Command_On_List_Or_All    mkdir -p '${tmp_dir}' && rm -vrf '${tmp_dir}/log' && mv -vf '${karaf_home}/data/log' '${tmp_dir}/'    ${member_index_list}
 635     Safe_With_Ssh_To_List_Or_All_Run_Keyword    ${member_index_list}    ClusterManagement__Clean_Directories    ${path_list}    ${karaf_home}
 636     BuiltIn.Run_Keyword_If    """${tmp_dir}""" != ""    Check_Bash_Command_On_List_Or_All    mkdir -p '${karaf_home}/data' && rm -vrf '${karaf_home}/log' && mv -vf '${tmp_dir}/log' '${karaf_home}/data/'    ${member_index_list}
 637
 638 Store_Karaf_Log_On_List_Or_All
 639     [Arguments]    ${member_index_list}=${EMPTY}    ${dst_dir}=/tmp    ${karaf_home}=${KARAF_HOME}
 640     [Documentation]    Saves karaf.log to the ${dst_dir} for members in given list or all. Return None.
 641     Safe_With_Ssh_To_List_Or_All_Run_Keyword    ${member_index_list}    SSHKeywords.Execute_Command_Should_Pass    cp ${karaf_home}/data/log/karaf.log ${dst_dir}
 642
 643 Restore_Karaf_Log_On_List_Or_All
 644     [Arguments]    ${member_index_list}=${EMPTY}    ${src_dir}=/tmp    ${karaf_home}=${KARAF_HOME}
 645     [Documentation]    Places stored karaf.log to the ${karaf_home}/data/log for members in given list or all. Return None.
 646     Safe_With_Ssh_To_List_Or_All_Run_Keyword    ${member_index_list}    SSHKeywords.Execute_Command_Should_Pass    cp ${src_dir}/karaf.log ${karaf_home}/data/log/
 647
 648 ClusterManagement__Clean_Directories
 649     [Arguments]    ${relative_path_list}    ${karaf_home}
 650     [Documentation]    For each relative path, remove files with respect to ${karaf_home}. Return None.
 651     : FOR    ${relative_path}    IN    @{relative_path_list}
 652     \    SSHLibrary.Execute_Command    rm -rf ${karaf_home}${/}${relative_path}
 653
 654 Put_As_Json_And_Check_Member_List_Or_All
 655     [Arguments]    ${uri}    ${data}    ${member_index}    ${member_index_list}=${EMPTY}
 656     [Documentation]    Send a PUT with the supplied uri ${uri} and body ${data} to member ${member_index}.
 657     ...    Then check data is replicated in all or some members defined in ${member_index_list}.
 658     ${response_text} =    Put_As_Json_To_Member    uri=${uri}    data=${data}    member_index=${member_index}
 659     Wait Until Keyword Succeeds    5s    1s    Check_Json_Member_List_Or_All    uri=${uri}    expected_data=${data}    member_index_list=${member_index_list}
 660     [Return]    ${response_text}
 661
 662 Put_As_Json_To_Member
 663     [Arguments]    ${uri}    ${data}    ${member_index}
 664     [Documentation]    Send a PUT with the supplied uri and data to member ${member_index}.
 665     ${session} =    Resolve_Http_Session_For_Member    member_index=${member_index}
 666     ${response_text} =    TemplatedRequests.Put_As_Json_To_Uri    uri=${uri}    data=${data}    session=${session}
 667     [Return]    ${response_text}
 668
 669 Post_As_Json_To_Member
 670     [Arguments]    ${uri}    ${data}    ${member_index}
 671     [Documentation]    Send a POST with the supplied uri and data to member ${member_index}.
 672     ${session} =    Resolve_Http_Session_For_Member    member_index=${member_index}
 673     ${response_text} =    TemplatedRequests.Post_As_Json_To_Uri    uri=${uri}    data=${data}    session=${session}
 674     [Return]    ${response_text}
 675
 676 Delete_And_Check_Member_List_Or_All
 677     [Arguments]    ${uri}    ${member_index}    ${member_index_list}=${EMPTY}
 678     [Documentation]    Send a DELETE with the supplied uri to the member ${member_index}.
 679     ...    Then check the data is removed from all members in ${member_index_list}.
 680     ${response_text} =    Delete_From_Member    ${uri}    ${member_index}
 681     BuiltIn.Wait_Until_Keyword_Succeeds    5s    1s    Check_No_Content_Member_List_Or_All    uri=${uri}    member_index_list=${member_index_list}
 682     [Return]    ${response_text}
 683
 684 Delete_From_Member
 685     [Arguments]    ${uri}    ${member_index}
 686     [Documentation]    Send a DELETE with the supplied uri to member ${member_index}.
 687     ${session} =    Resolve_Http_Session_For_Member    member_index=${member_index}
 688     ${response_text} =    TemplatedRequests.Delete_From_Uri    uri=${uri}    session=${session}
 689     [Return]    ${response_text}
 690
 691 Check_Json_Member_List_Or_All
 692     [Arguments]    ${uri}    ${expected_data}    ${member_index_list}=${EMPTY}
 693     [Documentation]    Send a GET with the supplied uri to all or some members defined in ${member_index_list}.
 694     ...    Then check received data is = ${expected data}.
 695     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 696     : FOR    ${index}    IN    @{index_list}
 697     \    ${data} =    Get_From_Member    uri=${uri}    member_index=${index}
 698     \    TemplatedRequests.Normalize_Jsons_And_Compare    ${expected_data}    ${data}
 699
 700 Check_Item_Occurrence_Member_List_Or_All
 701     [Arguments]    ${uri}    ${dictionary}    ${member_index_list}=${EMPTY}
 702     [Documentation]    Send a GET with the supplied uri to all or some members defined in ${member_index_list}.
 703     ...    Then check received for occurrences of items expressed in a dictionary ${dictionary}.
 704     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 705     : FOR    ${index}    IN    @{index_list}
 706     \    ${data} =    Get_From_Member    uri=${uri}    member_index=${index}
 707     \    Utils.Check Item Occurrence    ${data}    ${dictionary}
 708
 709 Check_No_Content_Member_List_Or_All
 710     [Arguments]    ${uri}    ${member_index_list}=${EMPTY}
 711     [Documentation]    Send a GET with the supplied uri to all or some members defined in ${member_index_list}.
 712     ...    Then check there is no content.
 713     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 714     : FOR    ${index}    IN    @{index_list}
 715     \    ${session} =    Resolve_Http_Session_For_Member    member_index=${index}
 716     \    Utils.No_Content_From_URI    ${session}    ${uri}
 717
 718 Get_From_Member
 719     [Arguments]    ${uri}    ${member_index}    ${access}=${ACCEPT_EMPTY}
 720     [Documentation]    Send a GET with the supplied uri to member ${member_index}.
 721     ${session} =    Resolve_Http_Session_For_Member    member_index=${member_index}
 722     ${response_text} =    TemplatedRequests.Get_From_Uri    uri=${uri}    accept=${access}    session=${session}
 723     [Return]    ${response_text}
 724
 725 Resolve_IP_Address_For_Member
 726     [Arguments]    ${member_index}
 727     [Documentation]    Return node IP address of given index.
 728     ${ip_address} =    Collections.Get From Dictionary    dictionary=${ClusterManagement__index_to_ip_mapping}    key=${member_index}
 729     [Return]    ${ip_address}
 730
 731 Resolve_IP_Address_For_Members
 732     [Arguments]    ${member_index_list}
 733     [Documentation]    Return a list of IP address of given indexes.
 734     ${member_ip_list} =    BuiltIn.Create_List
 735     : FOR    ${index}    IN    @{member_index_list}
 736     \    ${ip_address} =    Collections.Get From Dictionary    dictionary=${ClusterManagement__index_to_ip_mapping}    key=${index}
 737     \    Collections.Append_To_List    ${member_ip_list}    ${ip_address}
 738     [Return]    ${member_ip_list}
 739
 740 Resolve_Http_Session_For_Member
 741     [Arguments]    ${member_index}
 742     [Documentation]    Return RequestsLibrary session alias pointing to node of given index.
 743     ${session} =    BuiltIn.Set_Variable    ClusterManagement__session_${member_index}
 744     [Return]    ${session}
 745
 746 Resolve_Shard_Type_Class
 747     [Arguments]    ${shard_type}
 748     [Documentation]    Simple lookup for class name corresponding to desired type.
 749     BuiltIn.Run_Keyword_If    '${shard_type}' == 'config'    BuiltIn.Return_From_Keyword    DistributedConfigDatastore
 750     ...    ELSE IF    '${shard_type}' == 'operational'    BuiltIn.Return_From_Keyword    DistributedOperationalDatastore
 751     BuiltIn.Fail    Unrecognized shard type: ${shard_type}
 752
 753 ClusterManagement__Build_List
 754     [Arguments]    ${member}
 755     ${member_int} =    BuiltIn.Convert_To_Integer    ${member}
 756     ${index_list} =    BuiltIn.Create_List    ${member_int}
 757     [Return]    ${index_list}
 758
 759 ClusterManagement__Parse_Sync_Status
 760     [Arguments]    ${shard_manager_text}
 761     [Documentation]    Return sync status parsed out of given text. Called twice by Get_Sync_Status_Of_Member.
 762     BuiltIn.Log    ${shard_manager_text}
 763     ${manager_object} =    RequestsLibrary.To_Json    ${shard_manager_text}
 764     ${value_object} =    Collections.Get_From_Dictionary    dictionary=${manager_object}    key=value
 765     ${sync_status} =    Collections.Get_From_Dictionary    dictionary=${value_object}    key=SyncStatus
 766     [Return]    ${sync_status}
 767
 768 List_All_Indices
 769     [Documentation]    Create a new list of all indices.
 770     BuiltIn.Run_Keyword_And_Return    List_Indices_Or_All
 771
 772 List_Indices_Or_All
 773     [Arguments]    ${given_list}=${EMPTY}
 774     [Documentation]    Utility to allow \${EMPTY} as default argument value, as the internal list is computed at runtime.
 775     ...    This keyword always returns a (shallow) copy of given or default list,
 776     ...    so operations with the returned list should not affect other lists.
 777     ...    Also note that this keyword does not consider empty list to be \${EMPTY}.
 778     ${return_list_reference} =    BuiltIn.Set_Variable_If    """${given_list}""" != ""    ${given_list}    ${ClusterManagement__member_index_list}
 779     ${return_list_copy} =    BuiltIn.Create_List    @{return_list_reference}
 780     [Return]    ${return_list_copy}
 781
 782 List_Indices_Minus_Member
 783     [Arguments]    ${member_index}    ${member_index_list}=${EMPTY}
 784     [Documentation]    Create a new list which contains indices from ${member_index_list} (or all) without ${member_index}.
 785     ${index_list} =    List_Indices_Or_All    ${member_index_list}
 786     Collections.Remove Values From List    ${index_list}    ${member_index}
 787     [Return]    ${index_list}
 788
 789 ClusterManagement__Compute_Derived_Variables
 790     [Arguments]    ${int_of_members}    ${http_timeout}=${DEFAULT_TIMEOUT_HTTP}    ${http_retries}=0
 791     [Documentation]    Construct index list, session list and IP mapping, publish them as suite variables.
 792     @{member_index_list} =    BuiltIn.Create_List
 793     @{session_list} =    BuiltIn.Create_List
 794     &{index_to_ip_mapping} =    BuiltIn.Create_Dictionary
 795     : FOR    ${index}    IN RANGE    1    ${int_of_members+1}
 796     \    ClusterManagement__Include_Member_Index    ${index}    ${member_index_list}    ${session_list}    ${index_to_ip_mapping}    http_timeout=${http_timeout}
 797     \    ...    http_retries=${http_retries}
 798     BuiltIn.Set_Suite_Variable    \${ClusterManagement__member_index_list}    ${member_index_list}
 799     BuiltIn.Set_Suite_Variable    \${ClusterManagement__index_to_ip_mapping}    ${index_to_ip_mapping}
 800     BuiltIn.Set_Suite_Variable    \${ClusterManagement__session_list}    ${session_list}
 801
 802 ClusterManagement__Include_Member_Index
 803     [Arguments]    ${index}    ${member_index_list}    ${session_list}    ${index_to_ip_mapping}    ${http_timeout}=${DEFAULT_TIMEOUT_HTTP}    ${http_retries}=0
 804     [Documentation]    Add a corresponding item based on index into the last three arguments.
 805     ...    Create the Http session whose alias is added to list.
 806     Collections.Append_To_List    ${member_index_list}    ${index}
 807     ${member_ip} =    BuiltIn.Set_Variable    ${ODL_SYSTEM_${index}_IP}
 808     # ${index} is int (not string) so "key=value" syntax does not work in the following line.
 809     Collections.Set_To_Dictionary    ${index_to_ip_mapping}    ${index}    ${member_ip}
 810     # Http session, with ${AUTH}, without headers.
 811     ${session_alias} =    Resolve_Http_Session_For_Member    member_index=${index}
 812     RequestsLibrary.Create_Session    ${session_alias}    http://${member_ip}:${RESTCONFPORT}    auth=${AUTH}    timeout=${http_timeout}    max_retries=${http_retries}
 813     Collections.Append_To_List    ${session_list}    ${session_alias}
 814
 815 Sync_Status_Should_Be_False
 816     [Arguments]    ${controller_index}
 817     [Documentation]    Verify that cluster node is not in sync with others
 818     ${status}    Get_Sync_Status_Of_Member    ${controller_index}
 819     BuiltIn.Should_Not_Be_True    ${status}
 820
 821 Sync_Status_Should_Be_True
 822     [Arguments]    ${controller_index}
 823     [Documentation]    Verify that cluster node is in sync with others
 824     ${status}    Get_Sync_Status_Of_Member    ${controller_index}
 825     BuiltIn.Should_Be_True    ${status}
 826
 827 Return_Member_IP
 828     [Arguments]    ${member_index}
 829     [Documentation]    Return the IP address of the member given the member_index.
 830     ${member_int} =    BuiltIn.Convert_To_Integer    ${member_index}
 831     ${member_ip} =    Collections.Get_From_Dictionary    dictionary=${ClusterManagement__index_to_ip_mapping}    key=${member_int}
 832     [Return]    ${member_ip}