csit/libraries/ClusterManagement.robot

   1 *** Settings ***
   2 Documentation     Resource housing Keywords common to several suites for cluster functional testing.
   3 ...
   4 ...               Copyright (c) 2016 Cisco Systems, Inc. and others. All rights reserved.
   5 ...               Copyright (c) 2016 Brocade Communications Systems, Inc. and others. All rights reserved.
   6 ...
   7 ...               This program and the accompanying materials are made available under the
   8 ...               terms of the Eclipse Public License v1.0 which accompanies this distribution,
   9 ...               and is available at http://www.eclipse.org/legal/epl-v10.html
  10 ...
  11 ...
  12 ...               This resource holds private state (in suite variables),
  13 ...               which is generated once at Setup with ClusterManagement_Setup KW.
  14 ...               The state includes member indexes, IP addresses and Http (RequestsLibrary) sessions.
  15 ...               Cluster Keywords normally use member index, member list or nothing (all members) as argument.
  16 ...
  17 ...               All index lists returned should be sorted numerically, fix if not.
  18 ...
  19 ...               Requirements:
  20 ...               odl-jolokia is assumed to be installed.
  21 ...
  22 ...               Keywords are ordered as follows:
  23 ...               - Cluster Setup
  24 ...               - Shard state, leader and followers
  25 ...               - Entity Owner, candidates and successors
  26 ...               - Kill and Start Member
  27 ...               - Isolate and Rejoin Member
  28 ...               - Run Commands On Member
  29 ...               - REST requests and checks on Members
  30 ...
  31 ...               TODO: Unify capitalization of Leaders and Followers.
  32 Library           RequestsLibrary    # for Create_Session and To_Json
  33 Library           Collections
  34 Resource          ${CURDIR}/CompareStream.robot
  35 Resource          ${CURDIR}/KarafKeywords.robot
  36 Resource          ${CURDIR}/SSHKeywords.robot
  37 Resource          ${CURDIR}/TemplatedRequests.robot    # for Get_As_Json_From_Uri
  38 Resource          ${CURDIR}/Utils.robot    # for Run_Command_On_Controller
  39
  40 *** Variables ***
  41 ${ENTITY_OWNER_URI}    restconf/operational/entity-owners:entity-owners
  42 ${JAVA_HOME}      ${EMPTY}    # releng/builder scripts should provide correct value
  43 ${JOLOKIA_CONF_SHARD_MANAGER_URI}    jolokia/read/org.opendaylight.controller:Category=ShardManager,name=shard-manager-config,type=DistributedConfigDatastore
  44 ${JOLOKIA_OPER_SHARD_MANAGER_URI}    jolokia/read/org.opendaylight.controller:Category=ShardManager,name=shard-manager-operational,type=DistributedOperationalDatastore
  45 ${JOLOKIA_READ_URI}    jolokia/read/org.opendaylight.controller
  46 ${KARAF_HOME}     ${WORKSPACE}${/}${BUNDLEFOLDER}    # TODO: Migrate to Variables.robot
  47 @{ODL_DEFAULT_DATA_PATHS}    tmp/    data/    cache/    snapshots/    journal/    etc/opendaylight/current/
  48 ${RESTCONF_MODULES_DIR}    ${CURDIR}/../variables/restconf/modules
  49 ${SINGLETON_NETCONF_DEVICE_ID_PREFIX}    /odl-general-entity:entity[odl-general-entity:name='KeyedInstanceIdentifier{targetType=interface org.opendaylight.yang.gen.v1.urn.tbd.params.xml.ns.yang.network.topology.rev131021.network.topology.topology.Node, path=[org.opendaylight.yang.gen.v1.urn.tbd.params.xml.ns.yang.network.topology.rev131021.NetworkTopology, org.opendaylight.yang.gen.v1.urn.tbd.params.xml.ns.yang.network.topology.rev131021.network.topology.Topology[key=TopologyKey [_topologyId=Uri [_value=topology-netconf]]], org.opendaylight.yang.gen.v1.urn.tbd.params.xml.ns.yang.network.topology.rev131021.network.topology.topology.Node[key=NodeKey [_nodeId=Uri [_value=
  50 ${SINGLETON_NETCONF_DEVICE_ID_SUFFIX}    ]]]]}']
  51 ${SINGLETON_ELECTION_ENTITY_TYPE}    org.opendaylight.mdsal.ServiceEntityType
  52 ${SINGLETON_CHANGE_OWNERSHIP_ENTITY_TYPE}    org.opendaylight.mdsal.AsyncServiceCloseEntityType
  53 ${NODE_START_COMMAND}    ${KARAF_HOME}/bin/start
  54 ${NODE_KILL_COMMAND}    ps axf | grep karaf | grep -v grep | awk '{print \"kill -9 \" $1}' | sh
  55
  56 *** Keywords ***
  57 ClusterManagement_Setup
  58     [Documentation]    Detect repeated call, or detect number of members and initialize derived suite variables.
  59     # Avoid multiple initialization by several downstream libraries.
  60     ${already_done} =    BuiltIn.Get_Variable_Value    \${ClusterManagement__has_setup_run}    False
  61     BuiltIn.Return_From_Keyword_If    ${already_done}
  62     BuiltIn.Set_Suite_Variable    \${ClusterManagement__has_setup_run}    True
  63     ${cluster_size} =    BuiltIn.Get_Variable_Value    \${NUM_ODL_SYSTEM}    1
  64     ${status}    ${possibly_int_of_members} =    BuiltIn.Run_Keyword_And_Ignore_Error    BuiltIn.Convert_To_Integer    ${cluster_size}
  65     ${int_of_members} =    BuiltIn.Set_Variable_If    '${status}' != 'PASS'    ${1}    ${possibly_int_of_members}
  66     ClusterManagement__Compute_Derived_Variables    int_of_members=${int_of_members}
  67
  68 Check_Cluster_Is_In_Sync
  69     [Arguments]    ${member_index_list}=${EMPTY}
  70     [Documentation]    Fail if no-sync is detected on a member from list (or any).
  71     ${index_list} =    ClusterManagement__Given_Or_Internal_Index_List    given_list=${member_index_list}
  72     : FOR    ${index}    IN    @{index_list}    # usually: 1, 2, 3.
  73     \    ${status} =    Get_Sync_Status_Of_Member    member_index=${index}
  74     \    BuiltIn.Continue_For_Loop_If    'True' == '${status}'
  75     \    BuiltIn.Fail    Index ${index} has incorrect status: ${status}
  76
  77 Get_Sync_Status_Of_Member
  78     [Arguments]    ${member_index}
  79     [Documentation]    Obtain IP, two GETs from jolokia URIs, return combined sync status as string.
  80     ${session} =    Resolve_Http_Session_For_Member    member_index=${member_index}
  81     ${conf_text} =    TemplatedRequests.Get_As_Json_From_Uri    uri=${JOLOKIA_CONF_SHARD_MANAGER_URI}    session=${session}
  82     ${conf_status} =    ClusterManagement__Parse_Sync_Status    shard_manager_text=${conf_text}
  83     BuiltIn.Return_From_Keyword_If    'False' == ${conf_status}    False
  84     ${oper_text} =    TemplatedRequests.Get_As_Json_From_Uri    uri=${JOLOKIA_OPER_SHARD_MANAGER_URI}    session=${session}
  85     ${oper_status} =    ClusterManagement__Parse_Sync_Status    shard_manager_text=${oper_text}
  86     [Return]    ${oper_status}
  87
  88 Verify_Leader_Exists_For_Each_Shard
  89     [Arguments]    ${shard_name_list}    ${shard_type}=operational    ${member_index_list}=${EMPTY}    ${verify_restconf}=True
  90     [Documentation]    For each shard name, call Get_Leader_And_Followers_For_Shard.
  91     ...    Not much logic there, but single Keyword is useful when using BuiltIn.Wait_Until_Keyword_Succeeds.
  92     : FOR    ${shard_name}    IN    @{shard_name_list}
  93     \    Get_Leader_And_Followers_For_Shard    shard_name=${shard_name}    shard_type=${shard_type}    validate=True    member_index_list=${member_index_list}    verify_restconf=${verify_restconf}
  94
  95 Get_Leader_And_Followers_For_Shard
  96     [Arguments]    ${shard_name}=default    ${shard_type}=operational    ${validate}=True    ${member_index_list}=${EMPTY}    ${verify_restconf}=True
  97     [Documentation]    Get role lists, validate there is one leader, return the leader and list of followers.
  98     ...    Optionally, issue GET to a simple restconf URL to make sure subsequent operations will not encounter 503.
  99     ${leader_list}    ${follower_list} =    Get_State_Info_For_Shard    shard_name=${shard_name}    shard_type=${shard_type}    validate=True    member_index_list=${member_index_list}
 100     ...    verify_restconf=${verify_restconf}
 101     ${leader_count} =    BuiltIn.Get_Length    ${leader_list}
 102     BuiltIn.Run_Keyword_If    ${leader_count} < 1    BuiltIn.Fail    No leader found.
 103     BuiltIn.Length_Should_Be    ${leader_list}    ${1}    Too many Leaders.
 104     ${leader} =    Collections.Get_From_List    ${leader_list}    0
 105     [Return]    ${leader}    ${follower_list}
 106
 107 Get_State_Info_For_Shard
 108     [Arguments]    ${shard_name}=default    ${shard_type}=operational    ${validate}=False    ${member_index_list}=${EMPTY}    ${verify_restconf}=False
 109     [Documentation]    Return lists of Leader and Follower member indices from a given member index list
 110     ...    (or from the full list if empty). If \${shard_type} is not 'config', 'operational' is assumed.
 111     ...    If \${validate}, Fail if raft state is not Leader or Follower (for example on Candidate).
 112     ...    The biggest difference from Get_Leader_And_Followers_For_Shard
 113     ...    is that no check on number of Leaders is performed.
 114     ${index_list} =    ClusterManagement__Given_Or_Internal_Index_List    given_list=${member_index_list}
 115     Collections.Sort_List    ${index_list}    # to guarantee return values are also sorted lists
 116     # TODO: Support alternative capitalization of 'config'?
 117     ${ds_type} =    BuiltIn.Set_Variable_If    '${shard_type}' != 'config'    operational    config
 118     ${leader_list} =    BuiltIn.Create_List
 119     ${follower_list} =    BuiltIn.Create_List
 120     : FOR    ${index}    IN    @{index_list}    # usually: 1, 2, 3.
 121     \    ${raft_state} =    Get_Raft_State_Of_Shard_At_Member    shard_name=${shard_name}    shard_type=${ds_type}    member_index=${index}    verify_restconf=${verify_restconf}
 122     \    BuiltIn.Run_Keyword_If    'Follower' == '${raft_state}'    Collections.Append_To_List    ${follower_list}    ${index}
 123     \    ...    ELSE IF    'Leader' == '${raft_state}'    Collections.Append_To_List    ${leader_list}    ${index}
 124     \    ...    ELSE IF    ${validate}    BuiltIn.Fail    Unrecognized Raft state: ${raft_state}
 125     [Return]    ${leader_list}    ${follower_list}
 126
 127 Get_Raft_State_Of_Shard_At_Member
 128     [Arguments]    ${shard_name}    ${shard_type}    ${member_index}    ${verify_restconf}=False
 129     [Documentation]    Send request to Jolokia on indexed member, return extracted Raft status.
 130     ...    Optionally, check restconf works.
 131     ${session} =    Resolve_Http_Session_For_Member    member_index=${member_index}
 132     # TODO: Does the used URI tend to generate large data which floods log.html?
 133     BuiltIn.Run_Keyword_If    ${verify_restconf}    TemplatedRequests.Get_As_Json_Templated    session=${session}    folder=${RESTCONF_MODULES_DIR}    verify=False
 134     ${type_class} =    Resolve_Shard_Type_Class    shard_type=${shard_type}
 135     ${uri} =    BuiltIn.Set_Variable    ${JOLOKIA_READ_URI}:Category=Shards,name=member-${member_index}-shard-${shard_name}-${shard_type},type=${type_class}
 136     ${data_text} =    TemplatedRequests.Get_As_Json_From_Uri    uri=${uri}    session=${session}
 137     ${data_object} =    RequestsLibrary.To_Json    ${data_text}
 138     ${value} =    Collections.Get_From_Dictionary    ${data_object}    value
 139     ${raft_state} =    Collections.Get_From_Dictionary    ${value}    RaftState
 140     [Return]    ${raft_state}
 141
 142 Verify_Owner_And_Successors_For_Device
 143     [Arguments]    ${device_name}    ${device_type}    ${member_index}    ${candidate_list}=${EMPTY}
 144     [Documentation]    Returns the owner and successors for the SB device ${device_name} of type ${device_type}. Request is sent to member ${member_index}.
 145     ...    For Boron and beyond, candidates are not removed on node down or isolation,
 146     ...    so this keyword expects candidates to be all members from Boron on.
 147     ...    Extra check is done to verify owner and successors are within the ${candidate_list}. This KW is useful when combined with WUKS.
 148     ...    ${candidate_list} minus owner is returned as ${successor list}.
 149     ...    Users can still use Get_Owner_And_Successors_For_Device if they are interested in downed candidates,
 150     ...    or for testing heterogeneous clusters.
 151     ${index_list} =    ClusterManagement__Given_Or_Internal_Index_List    given_list=${candidate_list}
 152     ${owner}    ${successor_list} =    Get_Owner_And_Successors_For_Device    device_name=${device_name}    device_type=${device_type}    member_index=${member_index}
 153     Collections.List_Should_Contain_Value    ${index_list}    ${owner}    Owner ${owner} is not in candidate list ${index_list}
 154     ${expected_candidate_list_origin} =    CompareStream.Set_Variable_If_At_Least_Boron    ${ClusterManagement__member_index_list}    ${index_list}
 155     # We do not want to manipulate either origin list.
 156     ${expected_successor_list} =    BuiltIn.Create_List    @{expected_candidate_list_origin}
 157     Collections.Remove_Values_From_List    ${expected_successor_list}    ${owner}
 158     Collections.Lists_Should_Be_Equal    ${expected_successor_list}    ${successor_list}    Successor list ${successor_list} is not the came as expected ${expected_successor_list}
 159     # User expects the returned successor list to be the provided candidate list minus the owner.
 160     Collections.Remove_Values_From_List    ${index_list}    ${owner}
 161     [Return]    ${owner}    ${index_list}
 162
 163 Get_Owner_And_Successors_For_Device
 164     [Arguments]    ${device_name}    ${device_type}    ${member_index}
 165     [Documentation]    Returns the owner and a list of successors for the SB device ${device_name} of type ${device_type}. Request is sent to member ${member_index}.
 166     ...    Successors are those device candidates not elected as owner. The list of successors = (list of candidates) - (owner).
 167     ...    The returned successor list is sorted numerically.
 168     ...    Note that "candidate list" definition currently differs between Beryllium and Boron.
 169     ...    Use Verify_Owner_And_Successors_For_Device if you want the older semantics (inaccessible nodes not present in the list).
 170     ${owner}    ${candidate_list} =    Get_Owner_And_Candidates_For_Device    device_name=${device_name}    device_type=${device_type}    member_index=${member_index}
 171     ${successor_list} =    BuiltIn.Create_List    @{candidate_list}    # Copy operation is not required, but new variable name requires a line anyway.
 172     Collections.Remove_Values_From_List    ${successor_list}    ${owner}
 173     [Return]    ${owner}    ${successor_list}
 174
 175 Get_Owner_And_Candidates_For_Device_Old
 176     [Arguments]    ${device_name}    ${device_type}    ${member_index}
 177     [Documentation]    Returns the owner and a list of candidates for the SB device ${device_name} of type ${device_type}. Request is sent to member ${member_index}.
 178     ...    Candidates are all members that register to own a device, so the list of candiates includes the owner.
 179     ...    The returned candidate list is sorted numerically.
 180     ...    Note that "candidate list" definition currently differs between Beryllium and Boron.
 181     ...    It is recommended to use Get_Owner_And_Successors_For_Device instead of this keyword, see documentation there.
 182     BuiltIn.Comment    TODO: Can this implementation be changed to call Get_Owner_And_Candidates_For_Type_And_Id?
 183     ${session} =    Resolve_Http_Session_For_Member    member_index=${member_index}
 184     ${data} =    TemplatedRequests.Get_As_Json_From_Uri    uri=${ENTITY_OWNER_URI}    session=${session}
 185     ${candidate_list} =    BuiltIn.Create_List
 186     ${entity_type} =    BuiltIn.Set_Variable_If    '${device_type}' == 'netconf'    netconf-node/${device_name}    ${device_type}
 187     ${clear_data} =    BuiltIn.Run_Keyword_If    '${device_type}' == 'openflow' or '${device_type}' == 'netconf'    Extract_OpenFlow_Device_Data    ${data}
 188     ...    ELSE IF    '${device_type}' == 'ovsdb'    Extract_Ovsdb_Device_Data    ${data}
 189     ...    ELSE IF    '${device_type}' == 'org.opendaylight.mdsal.ServiceEntityType'    Extract_Service_Entity_Type    ${data}
 190     ...    ELSE    Fail    Not recognized device type: ${device_type}
 191     ${json} =    RequestsLibrary.To_Json    ${clear_data}
 192     ${entity_type_list} =    Collections.Get_From_Dictionary    &{json}[entity-owners]    entity-type
 193     ${entity_type_index} =    Utils.Get_Index_From_List_Of_Dictionaries    ${entity_type_list}    type    ${entity_type}
 194     BuiltIn.Should_Not_Be_Equal_As_Integers    ${entity_type_index}    -1    No Entity Owner found for ${device_type}
 195     ${entity_list} =    Collections.Get_From_Dictionary    @{entity_type_list}[${entity_type_index}]    entity
 196     ${entity_index} =    Utils.Get_Index_From_List_Of_Dictionaries    ${entity_list}    id    ${device_name}
 197     BuiltIn.Should_Not_Be_Equal_As_Integers    ${entity_index}    -1    Device ${device_name} not found in Entity Owner ${device_type}
 198     ${entity_owner} =    Collections.Get_From_Dictionary    @{entity_list}[${entity_index}]    owner
 199     BuiltIn.Should_Not_Be_Empty    ${entity_owner}    No owner found for ${device_name}
 200     ${owner} =    String.Replace_String    ${entity_owner}    member-    ${EMPTY}
 201     ${owner} =    BuiltIn.Convert_To_Integer    ${owner}
 202     ${entity_candidates_list} =    Collections.Get_From_Dictionary    @{entity_list}[${entity_index}]    candidate
 203     : FOR    ${entity_candidate}    IN    @{entity_candidates_list}
 204     \    ${candidate} =    String.Replace_String    &{entity_candidate}[name]    member-    ${EMPTY}
 205     \    ${candidate} =    BuiltIn.Convert_To_Integer    ${candidate}
 206     \    Collections.Append_To_List    ${candidate_list}    ${candidate}
 207     Collections.Sort_List    ${candidate_list}
 208     [Return]    ${owner}    ${candidate_list}
 209
 210 Get_Owner_And_Candidates_For_Device_Singleton
 211     [Arguments]    ${device_name}    ${device_type}    ${member_index}
 212     [Documentation]    Returns the owner and a list of candidates for the SB device ${device_name} of type ${device_type}. Request is sent to member ${member_index}.
 213     ...    Parsing method is selected by device type
 214     ...    Separate kw for every supported device type must be defined
 215     BuiltIn.Keyword_Should_Exist    Get_Owner_And_Candidates_For_Device_Singleton_${device_type}
 216     BuiltIn.Run_Keyword_And_Return    Get_Owner_And_Candidates_For_Device_Singleton_${device_type}    ${device_name}    ${member_index}
 217
 218 Get_Owner_And_Candidates_For_Device_Singleton_Netconf
 219     [Arguments]    ${device_name}    ${member_index}
 220     [Documentation]    Returns the owner and a list of candidates for the SB device ${device_name} of type netconf. Request is sent to member ${member_index}.
 221     ...    Parsing method is set as netconf (using netconf device id prefix and suffix)
 222     # Get election entity type results
 223     ${type} =    BuiltIn.Set_Variable    ${SINGLETON_ELECTION_ENTITY_TYPE}
 224     ${id} =    BuiltIn.Set_Variable    ${SINGLETON_NETCONF_DEVICE_ID_PREFIX}${device_name}${SINGLETON_NETCONF_DEVICE_ID_SUFFIX}
 225     ${owner_1}    ${candidate_list_1} =    Get_Owner_And_Candidates_For_Type_And_Id    ${type}    ${id}    ${member_index}
 226     # Get change ownership entity type results
 227     ${type} =    BuiltIn.Set_Variable    ${SINGLETON_CHANGE_OWNERSHIP_ENTITY_TYPE}
 228     ${id} =    BuiltIn.Set_Variable    ${SINGLETON_NETCONF_DEVICE_ID_PREFIX}${device_name}${SINGLETON_NETCONF_DEVICE_ID_SUFFIX}
 229     ${owner_2}    ${candidate_list_2} =    Get_Owner_And_Candidates_For_Type_And_Id    ${type}    ${id}    ${member_index}
 230     # Owners must be same, if not, there is still some election or change ownership in progress
 231     BuiltIn.Should_Be_Equal_As_Integers    ${owner_1}    ${owner_2}    Owners for device ${device_name} are not same
 232     [Return]    ${owner_1}    ${candidate_list_1}
 233
 234 Get_Owner_And_Candidates_For_Device
 235     [Arguments]    ${device_name}    ${device_type}    ${member_index}
 236     [Documentation]    Returns the owner and a list of candidates for the SB device ${device_name} of type ${device_type}. Request is sent to member ${member_index}.
 237     ...    If parsing as singleton failed, kw try to parse data in old way (without singleton).
 238     ...    Candidates are all members that register to own a device, so the list of candiates includes the owner.
 239     ...    The returned candidate list is sorted numerically.
 240     ...    Note that "candidate list" definition currently differs between Beryllium and Boron.
 241     ...    It is recommended to use Get_Owner_And_Successors_For_Device instead of this keyword, see documentation there.
 242     # Try singleton
 243     ${status}    ${results} =    BuiltIn.Run_Keyword_And_Ignore_Error    Get_Owner_And_Candidates_For_Device_Singleton    device_name=${device_name}    device_type=${device_type}    member_index=${member_index}
 244     BuiltIn.Return_From_Keyword_If    "${status}"=="PASS"    ${results}
 245     # If singleton failed, try parsing in old way
 246     ${status}    ${results} =    BuiltIn.Run_Keyword_And_Ignore_Error    Get_Owner_And_Candidates_For_Device_Old    device_name=${device_name}    device_type=${device_type}    member_index=${member_index}
 247     # previous 3 lines (BuilIn.Return.., # If singleton..., ${status}....) could be deleted when old way will not be supported anymore
 248     BuiltIn.Run_Keyword_If    '${status}'=='FAIL'    BuiltIn.Fail    Could not parse owner and candidates for device ${device_name}
 249     [Return]    @{results}
 250
 251 Get_Owner_And_Candidates_For_Type_And_Id
 252     [Arguments]    ${type}    ${id}    ${member_index}    ${require_candidate_list}=${EMPTY}
 253     [Documentation]    Returns the owner and a list of candidates for entity specified by ${type} and ${id}
 254     ...    Request is sent to member ${member_index}.
 255     ...    Candidates are all members that register to own a device, so the list of candiates includes the owner.
 256     ...    Bear in mind that for Boron and beyond, candidates are not removed on node down or isolation.
 257     ...    If ${require_candidate_list} is not \${EMPTY}, check whether the actual list of candidates matches.
 258     ...    Note that differs from "given list" semantics used in other keywords,
 259     ...    namely you cannot use \${EMPTY} to stand for "full list" in this keyword.
 260     BuiltIn.Comment    TODO: Find a way to unify and deduplicate code blocks in Get_Owner_And_Candidates_* keywords.
 261     ${session} =    Resolve_Http_Session_For_Member    member_index=${member_index}
 262     ${data} =    TemplatedRequests.Get_As_Json_From_Uri    uri=${ENTITY_OWNER_URI}    session=${session}
 263     ${candidate_list} =    BuiltIn.Create_List
 264     ${json} =    RequestsLibrary.To_Json    ${data}
 265     ${entity_type_list} =    Collections.Get_From_Dictionary    &{json}[entity-owners]    entity-type
 266     ${entity_type_index} =    Utils.Get_Index_From_List_Of_Dictionaries    ${entity_type_list}    type    ${type}
 267     BuiltIn.Should_Not_Be_Equal_As_Integers    ${entity_type_index}    -1    No Entity Owner found for ${type}
 268     ${entity_list} =    Collections.Get_From_Dictionary    @{entity_type_list}[${entity_type_index}]    entity
 269     ${entity_index} =    Utils.Get_Index_From_List_Of_Dictionaries    ${entity_list}    id    ${id}
 270     BuiltIn.Should Not_Be_Equal_As_Integers    ${entity_index}    -1    Id ${id} not found in Entity Owner ${type}
 271     ${entity_owner} =    Collections.Get_From_Dictionary    @{entity_list}[${entity_index}]    owner
 272     BuiltIn.Should_Not_Be_Empty    ${entity_owner}    No owner found for type=${type} id=${id}
 273     ${owner} =    String.Replace_String    ${entity_owner}    member-    ${EMPTY}
 274     ${owner} =    BuiltIn.Convert_To_Integer    ${owner}
 275     ${entity_candidates_list} =    Collections.Get_From_Dictionary    @{entity_list}[${entity_index}]    candidate
 276     : FOR    ${entity_candidate}    IN    @{entity_candidates_list}
 277     \    ${candidate} =    String.Replace_String    &{entity_candidate}[name]    member-    ${EMPTY}
 278     \    ${candidate} =    BuiltIn.Convert_To_Integer    ${candidate}
 279     \    Collections.Append_To_List    ${candidate_list}    ${candidate}
 280     Collections.Sort_List    ${candidate_list}
 281     BuiltIn.Comment    TODO: Separate check lines into Verify_Owner_And_Candidates_For_Type_And_Id
 282     BuiltIn.Run_Keyword_If    """${require_candidate_list}"""    BuiltIn.Should_Be_Equal    ${require_candidate_list}    ${candidate_list}    Candidate list does not match: ${candidate_list} is not ${require_candidate_list}
 283     [Return]    ${owner}    ${candidate_list}
 284
 285 Extract_Service_Entity_Type
 286     [Arguments]    ${data}
 287     [Documentation]    Remove superfluous device data from Entity Owner printout.
 288     ${clear_data} =    String.Replace_String    ${data}    /odl-general-entity:entity[odl-general-entity:name='    ${EMPTY}
 289     ${clear_data} =    String.Replace_String    ${clear_data}    -service-group']    ${EMPTY}
 290     Log    ${clear_data}
 291     [Return]    ${clear_data}
 292
 293 Extract_OpenFlow_Device_Data
 294     [Arguments]    ${data}
 295     [Documentation]    Remove superfluous OpenFlow device data from Entity Owner printout.
 296     ${clear_data} =    BuiltIn.Run Keyword If    '${ODL_STREAM}' != 'beryllium' and '${ODL_OF_PLUGIN}' == 'lithium'    String.Replace_String    ${data}    org.opendaylight.mdsal.ServiceEntityType    openflow
 297     ...    ELSE    BuiltIn.Set_Variable    ${data}
 298     ${clear_data} =    String.Replace_String    ${clear_data}    /odl-general-entity:entity[odl-general-entity:name='    ${EMPTY}
 299     ${clear_data} =    String.Replace_String    ${clear_data}    /general-entity:entity[general-entity:name='    ${EMPTY}
 300     ${clear_data} =    String.Replace_String    ${clear_data}    ']    ${EMPTY}
 301     Log    ${clear_data}
 302     [Return]    ${clear_data}
 303
 304 Extract_Ovsdb_Device_Data
 305     [Arguments]    ${data}
 306     [Documentation]    Remove superfluous OVSDB device data from Entity Owner printout.
 307     ${clear_data} =    String.Replace_String    ${data}    /network-topology:network-topology/network-topology:topology[network-topology:topology-id='ovsdb:1']/network-topology:node[network-topology:node-id='    ${EMPTY}
 308     ${clear_data} =    String.Replace_String    ${clear_data}    ']    ${EMPTY}
 309     Log    ${clear_data}
 310     [Return]    ${clear_data}
 311
 312 Kill_Single_Member
 313     [Arguments]    ${member}    ${original_index_list}=${EMPTY}    ${confirm}=True
 314     [Documentation]    Convenience keyword that kills the specified member of the cluster.
 315     ...    The KW will return a list of available members: \${updated index_list}=\${original_index_list}-\${member}
 316     ${index_list} =    ClusterManagement__Build_List    ${member}
 317     ${updated_index_list} =    Kill_Members_From_List_Or_All    ${index_list}    ${original_index_list}    ${confirm}
 318     [Return]    ${updated_index_list}
 319
 320 Kill_Members_From_List_Or_All
 321     [Arguments]    ${member_index_list}=${EMPTY}    ${original_index_list}=${EMPTY}    ${confirm}=True
 322     [Documentation]    If the list is empty, kill all ODL instances. Otherwise, kill members based on \${kill_index_list}
 323     ...    If \${confirm} is True, sleep 1 second and verify killed instances are not there anymore.
 324     ...    The KW will return a list of available members: \${updated index_list}=\${original_index_list}-\${member_index_list}
 325     ${kill_index_list} =    ClusterManagement__Given_Or_Internal_Index_List    given_list=${member_index_list}
 326     ${index_list} =    ClusterManagement__Given_Or_Internal_Index_List    given_list=${original_index_list}
 327     Run_Bash_Command_On_List_Or_All    command=${NODE_KILL_COMMAND}    member_index_list=${member_index_list}
 328     ${updated_index_list} =    BuiltIn.Create_List    @{index_list}
 329     Collections.Remove_Values_From_List    ${updated_index_list}    @{kill_index_list}
 330     BuiltIn.Return_From_Keyword_If    not ${confirm}    ${updated_index_list}
 331     # TODO: Convert to WUKS with configurable timeout if it turns out 1 second is not enough.
 332     BuiltIn.Sleep    1s    Kill -9 closes open files, which may take longer than ssh overhead, but not long enough to warrant WUKS.
 333     : FOR    ${index}    IN    @{kill_index_list}
 334     \    Verify_Karaf_Is_Not_Running_On_Member    member_index=${index}
 335     [Return]    ${updated_index_list}
 336
 337 Start_Single_Member
 338     [Arguments]    ${member}    ${wait_for_sync}=True    ${timeout}=300s
 339     [Documentation]    Convenience keyword that starts the specified member of the cluster.
 340     ${index_list} =    ClusterManagement__Build_List    ${member}
 341     Start_Members_From_List_Or_All    ${index_list}    ${wait_for_sync}    ${timeout}
 342
 343 Start_Members_From_List_Or_All
 344     [Arguments]    ${member_index_list}=${EMPTY}    ${wait_for_sync}=True    ${timeout}=300s    ${karaf_home}=${EMPTY}    ${export_java_home}=${EMPTY}
 345     [Documentation]    If the list is empty, start all cluster members. Otherwise, start members based on present indices.
 346     ...    If ${wait_for_sync}, wait for cluster sync on listed members.
 347     ...    Optionally karaf_home can be overriden. Optionally specific JAVA_HOME is used for starting.
 348     ${base_command} =    BuiltIn.Set_Variable_If    "${karaf_home}"    ${karaf_home}/bin/start    ${NODE_START_COMMAND}
 349     ${command} =    BuiltIn.Set_Variable_If    "${export_java_home}"    export JAVA_HOME="${export_java_home}"; ${base_command}    ${base_command}
 350     Run_Bash_Command_On_List_Or_All    command=${command}    member_index_list=${member_index_list}
 351     BuiltIn.Return_From_Keyword_If    not ${wait_for_sync}
 352     BuiltIn.Wait_Until_Keyword_Succeeds    ${timeout}    10s    Check_Cluster_Is_In_Sync    member_index_list=${member_index_list}
 353     # TODO: Do we also want to check Shard Leaders here?
 354
 355 Clean_Journals_And_Snapshots_On_List_Or_All
 356     [Arguments]    ${member_index_list}=${EMPTY}    ${karaf_home}=${KARAF_HOME}
 357     [Documentation]    Delete journal and snapshots directories on every node listed (or all).
 358     ${index_list} =    ClusterManagement__Given_Or_Internal_Index_List    given_list=${member_index_list}
 359     ${command} =    Set Variable    rm -rf "${karaf_home}/journal" "${karaf_home}/snapshots"
 360     : FOR    ${index}    IN    @{index_list}    # usually: 1, 2, 3.
 361     \    Run_Bash_Command_On_Member    command=${command}    member_index=${index}
 362
 363 Verify_Karaf_Is_Not_Running_On_Member
 364     [Arguments]    ${member_index}
 365     [Documentation]    Fail if non-zero karaf instances are counted on member of given index.
 366     ${count} =    Count_Running_Karafs_On_Member    member_index=${member_index}
 367     BuiltIn.Should_Be_Equal    0    ${count}    Found running Karaf count: ${count}
 368
 369 Verify_Single_Karaf_Is_Running_On_Member
 370     [Arguments]    ${member_index}
 371     [Documentation]    Fail if number of karaf instances on member of given index is not one.
 372     ${count} =    Count_Running_Karafs_On_Member    member_index=${member_index}
 373     BuiltIn.Should_Be_Equal    1    ${count}    Wrong number of Karafs running: ${count}
 374
 375 Count_Running_Karafs_On_Member
 376     [Arguments]    ${member_index}
 377     [Documentation]    Remotely execute grep for karaf process, return count as string.
 378     ${command} =    BuiltIn.Set_Variable    ps axf | grep karaf | grep -v grep | wc -l
 379     ${count} =    Run_Bash_Command_On_Member    command=${command}    member_index=${member_index}
 380     [Return]    ${count}
 381
 382 Isolate_Member_From_List_Or_All
 383     [Arguments]    ${isolate_member_index}    ${member_index_list}=${EMPTY}
 384     [Documentation]    If the list is empty, isolate member from all ODL instances. Otherwise, isolate member based on present indices.
 385     ...    The KW will return a list of available members: \${updated index_list}=\${member_index_list}-\${isolate_member_index}
 386     ${index_list} =    ClusterManagement__Given_Or_Internal_Index_List    given_list=${member_index_list}
 387     ${source} =    Collections.Get_From_Dictionary    ${ClusterManagement__index_to_ip_mapping}    ${isolate_member_index}
 388     : FOR    ${index}    IN    @{index_list}
 389     \    ${destination} =    Collections.Get_From_Dictionary    ${ClusterManagement__index_to_ip_mapping}    ${index}
 390     \    ${command} =    BuiltIn.Set_Variable    sudo /sbin/iptables -I OUTPUT -p all --source ${source} --destination ${destination} -j DROP
 391     \    BuiltIn.Run_Keyword_If    "${index}" != "${isolate_member_index}"    Run_Bash_Command_On_Member    command=${command}    member_index=${isolate_member_index}
 392     ${command} =    BuiltIn.Set_Variable    sudo /sbin/iptables -L -n
 393     ${output} =    Run_Bash_Command_On_Member    command=${command}    member_index=${isolate_member_index}
 394     BuiltIn.Log    ${output}
 395     ${updated_index_list} =    BuiltIn.Create_List    @{index_list}
 396     Collections.Remove_Values_From_List    ${updated_index_list}    ${isolate_member_index}
 397     [Return]    ${updated_index_list}
 398
 399 Rejoin_Member_From_List_Or_All
 400     [Arguments]    ${rejoin_member_index}    ${member_index_list}=${EMPTY}
 401     [Documentation]    If the list is empty, rejoin member from all ODL instances. Otherwise, rejoin member based on present indices.
 402     ${index_list} =    ClusterManagement__Given_Or_Internal_Index_List    given_list=${member_index_list}
 403     ${source} =    Collections.Get_From_Dictionary    ${ClusterManagement__index_to_ip_mapping}    ${rejoin_member_index}
 404     : FOR    ${index}    IN    @{index_list}
 405     \    ${destination} =    Collections.Get_From_Dictionary    ${ClusterManagement__index_to_ip_mapping}    ${index}
 406     \    ${command} =    BuiltIn.Set_Variable    sudo /sbin/iptables -D OUTPUT -p all --source ${source} --destination ${destination} -j DROP
 407     \    BuiltIn.Run_Keyword_If    "${index}" != "${rejoin_member_index}"    Run_Bash_Command_On_Member    command=${command}    member_index=${rejoin_member_index}
 408     ${command} =    BuiltIn.Set_Variable    sudo /sbin/iptables -L -n
 409     ${output} =    Run_Bash_Command_On_Member    command=${command}    member_index=${rejoin_member_index}
 410     BuiltIn.Log    ${output}
 411
 412 Flush_Iptables_From_List_Or_All
 413     [Arguments]    ${member_index_list}=${EMPTY}
 414     [Documentation]    If the list is empty, flush IPTables in all ODL instances. Otherwise, flush member based on present indices.
 415     ${command} =    BuiltIn.Set_Variable    sudo iptables -v -F
 416     ${output} =    Run_Bash_Command_On_List_Or_All    command=${command}    member_index_list=${member_index_list}
 417
 418 Run_Bash_Command_On_List_Or_All
 419     [Arguments]    ${command}    ${member_index_list}=${EMPTY}
 420     [Documentation]    Cycle through indices (or all), run command on each.
 421     ${index_list} =    ClusterManagement__Given_Or_Internal_Index_List    given_list=${member_index_list}
 422     : FOR    ${index}    IN    @{index_list}
 423     \    Run_Bash_Command_On_Member    command=${command}    member_index=${index}
 424
 425 Run_Bash_Command_On_Member
 426     [Arguments]    ${command}    ${member_index}
 427     [Documentation]    Obtain IP, call Utils and return output. This does not preserve active ssh session.
 428     # TODO: Rename these keyword to Run_Bash_Command_On_Member to distinguish from Karaf (or even Windows) commands.
 429     ${member_ip} =    Collections.Get_From_Dictionary    dictionary=${ClusterManagement__index_to_ip_mapping}    key=${member_index}
 430     ${output}    ${rc} =    SSHKeywords.Run_Keyword_Preserve_Connection    Utils.Run_Command_On_Controller    ${member_ip}    ${command}
 431     [Return]    ${output}    ${rc}
 432
 433 Run_Karaf_Command_On_List_Or_All
 434     [Arguments]    ${command}    ${member_index_list}=${EMPTY}    ${timeout}=10s
 435     [Documentation]    Cycle through indices (or all), run karaf command on each.
 436     ${index_list} =    ClusterManagement__Given_Or_Internal_Index_List    given_list=${member_index_list}
 437     : FOR    ${index}    IN    @{index_list}
 438     \    ${member_ip} =    Collections.Get_From_Dictionary    dictionary=${ClusterManagement__index_to_ip_mapping}    key=${index}
 439     \    KarafKeywords.Safe_Issue_Command_On_Karaf_Console    ${command}    ${member_ip}    timeout=${timeout}
 440
 441 Run_Karaf_Command_On_Member
 442     [Arguments]    ${command}    ${member_index}    ${timeout}=10s
 443     [Documentation]    Obtain IP address, call KarafKeywords and return output. This does not preserve active ssh session.
 444     ...    This keyword is not used by Run_Karaf_Command_On_List_Or_All, but returned output may be useful.
 445     ${member_ip} =    Collections.Get_From_Dictionary    dictionary=${ClusterManagement__index_to_ip_mapping}    key=${member_index}
 446     ${output} =    KarafKeywords.Safe_Issue_Command_On_Karaf_Console    ${command}    controller=${member_ip}    timeout=${timeout}
 447     [Return]    ${output}
 448
 449 Install_Feature_On_List_Or_All
 450     [Arguments]    ${feature_name}    ${member_index_list}=${EMPTY}    ${timeout}=60s
 451     [Documentation]    Attempt installation on each member from list (or all). Then look for failures.
 452     ${index_list} =    ClusterManagement__Given_Or_Internal_Index_List    given_list=${member_index_list}
 453     ${status_list} =    BuiltIn.Create_List
 454     : FOR    ${index}    IN    @{index_list}
 455     \    ${status}    ${text} =    BuiltIn.Run_Keyword_And_Ignore_Error    Install_Feature_On_Member    feature_name=${feature_name}    member_index=${index}
 456     \    ...    timeout=${timeout}
 457     \    BuiltIn.Log    ${text}
 458     \    Collections.Append_To_List    ${status_list}    ${status}
 459     : FOR    ${status}    IN    @{status_list}
 460     \    BuiltIn.Run_Keyword_If    "${status}" != "PASS"    BuiltIn.Fail    ${feature_name} installation failed, see log.
 461
 462 Install_Feature_On_Member
 463     [Arguments]    ${feature_name}    ${member_index}    ${timeout}=60s
 464     [Documentation]    Run feature:install karaf command, fail if installation was not successful. Return output.
 465     ${status}    ${output} =    BuiltIn.Run_Keyword_And_Ignore_Error    Run_Karaf_Command_On_Member    command=feature:install ${feature_name}    member_index=${member_index}    timeout=${timeout}
 466     BuiltIn.Run_Keyword_If    "${status}" != "PASS"    BuiltIn.Fail    Failed to install ${feature_name}: ${output}
 467     BuiltIn.Should_Not_Contain    ${output}    Can't install    Failed to install ${feature_name}: ${output}
 468     [Return]    ${output}
 469
 470 With_Ssh_To_List_Or_All_Run_Keyword
 471     [Arguments]    ${member_index_list}    ${keyword_name}    @{args}    &{kwargs}
 472     [Documentation]    For each index in given list (or all): activate SSH connection, run given Keyword, close active connection. Return None.
 473     ...    Note that if the Keyword affects SSH connections, results are still deterministic, but perhaps undesirable.
 474     ...    Beware that in order to avoid "got positional argument after named arguments", first two arguments in the call should not be named.
 475     BuiltIn.Comment    This keyword is experimental and there is high risk of being replaced by another approach.
 476     # TODO: For_Index_From_List_Or_All_Run_Keyword applied to With_Ssh_To_Member_Run_Keyword?
 477     ${index_list} =    ClusterManagement__Given_Or_Internal_Index_List    given_list=${member_index_list}
 478     : FOR    ${member_index}    IN    @{index_list}
 479     \    ${member_ip} =    Resolve_IP_Address_For_Member    ${member_index}
 480     \    SSHKeywords.Open_Connection_To_Odl_System    ip_address=${member_ip}
 481     \    BuiltIn.Run_Keyword    ${keyword_name}    @{args}    &{kwargs}
 482     \    SSHLibrary.Close_Connection
 483
 484 Safe_With_Ssh_To_List_Or_All_Run_Keyword
 485     [Arguments]    ${member_index_list}    ${keyword_name}    @{args}    &{kwargs}
 486     [Documentation]    Remember active ssh connection index, call With_Ssh_To_List_Or_All_Run_Keyword, return None. Restore the conection index on teardown.
 487     SSHKeywords.Run_Keyword_Preserve_Connection    With_Ssh_To_List_Or_All_Run_Keyword    ${member_index_list}    ${keyword_name}    @{args}    &{kwargs}
 488
 489 Clean_Directories_On_List_Or_All
 490     [Arguments]    ${member_index_list}=${EMPTY}    ${directory_list}=${EMPTY}    ${karaf_home}=${KARAF_HOME}
 491     [Documentation]    Clear @{directory_list} or @{ODL_DEFAULT_DATA_PATHS} for members in given list or all. Return None.
 492     ...    This is intended to return Karaf (offline) to the state it was upon the first boot.
 493     ${path_list} =    Builtin.Set Variable If    "${directory_list}" == "${EMPTY}"    ${ODL_DEFAULT_DATA_PATHS}    ${directory_list}
 494     Safe_With_Ssh_To_List_Or_All_Run_Keyword    ${member_index_list}    ClusterManagement__Clean_Directories    ${path_list}    ${karaf_home}
 495
 496 Store_Karaf_Log_On_List_Or_All
 497     [Arguments]    ${member_index_list}=${EMPTY}    ${dst_dir}=/tmp    ${karaf_home}=${KARAF_HOME}
 498     [Documentation]    Saves karaf.log to the ${dst_dir} for members in given list or all. Return None.
 499     Safe_With_Ssh_To_List_Or_All_Run_Keyword    ${member_index_list}    SSHKeywords.Execute_Command_Should_Pass    cp ${karaf_home}/data/log/karaf.log ${dst_dir}
 500
 501 Restore_Karaf_Log_On_List_Or_All
 502     [Arguments]    ${member_index_list}=${EMPTY}    ${src_dir}=/tmp    ${karaf_home}=${KARAF_HOME}
 503     [Documentation]    Places stored karaf.log to the ${karaf_home}/data/log for members in given list or all. Return None.
 504     Safe_With_Ssh_To_List_Or_All_Run_Keyword    ${member_index_list}    SSHKeywords.Execute_Command_Should_Pass    cp ${src_dir}/karaf.log ${karaf_home}/data/log/
 505
 506 ClusterManagement__Clean_Directories
 507     [Arguments]    ${relative_path_list}    ${karaf_home}
 508     [Documentation]    For each relative path, remove files with respect to ${karaf_home}. Return None.
 509     : FOR    ${relative_path}    IN    @{relative_path_list}
 510     \    SSHLibrary.Execute_Command    rm -rf ${karaf_home}${/}${relative_path}
 511
 512 Put_As_Json_And_Check_Member_List_Or_All
 513     [Arguments]    ${uri}    ${data}    ${member_index}    ${member_index_list}=${EMPTY}
 514     [Documentation]    Send a PUT with the supplied uri ${uri} and body ${data} to member ${member_index}.
 515     ...    Then check data is replicated in all or some members defined in ${member_index_list}.
 516     ${response_text} =    Put_As_Json_To_Member    uri=${uri}    data=${data}    member_index=${member_index}
 517     Wait Until Keyword Succeeds    5s    1s    Check_Json_Member_List_Or_All    uri=${uri}    expected_data=${data}    member_index_list=${member_index_list}
 518     [Return]    ${response_text}
 519
 520 Put_As_Json_To_Member
 521     [Arguments]    ${uri}    ${data}    ${member_index}
 522     [Documentation]    Send a PUT with the supplied uri and data to member ${member_index}.
 523     ${session} =    Resolve_Http_Session_For_Member    member_index=${member_index}
 524     ${response_text} =    TemplatedRequests.Put_As_Json_To_Uri    uri=${uri}    data=${data}    session=${session}
 525     [Return]    ${response_text}
 526
 527 Post_As_Json_To_Member
 528     [Arguments]    ${uri}    ${data}    ${member_index}
 529     [Documentation]    Send a POST with the supplied uri and data to member ${member_index}.
 530     ${session} =    Resolve_Http_Session_For_Member    member_index=${member_index}
 531     ${response_text} =    TemplatedRequests.Post_As_Json_To_Uri    uri=${uri}    data=${data}    session=${session}
 532     [Return]    ${response_text}
 533
 534 Delete_And_Check_Member_List_Or_All
 535     [Arguments]    ${uri}    ${member_index}    ${member_index_list}=${EMPTY}
 536     [Documentation]    Send a DELETE with the supplied uri to the member ${member_index}.
 537     ...    Then check the data is removed from all members in ${member_index_list}.
 538     ${response_text} =    Delete_From_Member    ${uri}    ${member_index}
 539     BuiltIn.Wait_Until_Keyword_Succeeds    5s    1s    Check_No_Content_Member_List_Or_All    uri=${uri}    member_index_list=${member_index_list}
 540     [Return]    ${response_text}
 541
 542 Delete_From_Member
 543     [Arguments]    ${uri}    ${member_index}
 544     [Documentation]    Send a DELETE with the supplied uri to member ${member_index}.
 545     ${session} =    Resolve_Http_Session_For_Member    member_index=${member_index}
 546     ${response_text} =    TemplatedRequests.Delete_From_Uri    uri=${uri}    session=${session}
 547     [Return]    ${response_text}
 548
 549 Check_Json_Member_List_Or_All
 550     [Arguments]    ${uri}    ${expected_data}    ${member_index_list}=${EMPTY}
 551     [Documentation]    Send a GET with the supplied uri to all or some members defined in ${member_index_list}.
 552     ...    Then check received data is = ${expected data}.
 553     ${index_list} =    ClusterManagement__Given_Or_Internal_Index_List    given_list=${member_index_list}
 554     : FOR    ${index}    IN    @{index_list}
 555     \    ${data} =    Get_From_Member    uri=${uri}    member_index=${index}
 556     \    TemplatedRequests.Normalize_Jsons_And_Compare    ${expected_data}    ${data}
 557
 558 Check_Item_Occurrence_Member_List_Or_All
 559     [Arguments]    ${uri}    ${dictionary}    ${member_index_list}=${EMPTY}
 560     [Documentation]    Send a GET with the supplied uri to all or some members defined in ${member_index_list}.
 561     ...    Then check received for occurrences of items expressed in a dictionary ${dictionary}.
 562     ${index_list} =    ClusterManagement__Given_Or_Internal_Index_List    given_list=${member_index_list}
 563     : FOR    ${index}    IN    @{index_list}
 564     \    ${data} =    Get_From_Member    uri=${uri}    member_index=${index}
 565     \    Utils.Check Item Occurrence    ${data}    ${dictionary}
 566
 567 Check_No_Content_Member_List_Or_All
 568     [Arguments]    ${uri}    ${member_index_list}=${EMPTY}
 569     [Documentation]    Send a GET with the supplied uri to all or some members defined in ${member_index_list}.
 570     ...    Then check there is no content.
 571     ${index_list} =    ClusterManagement__Given_Or_Internal_Index_List    given_list=${member_index_list}
 572     : FOR    ${index}    IN    @{index_list}
 573     \    ${session} =    Resolve_Http_Session_For_Member    member_index=${index}
 574     \    Utils.No_Content_From_URI    ${session}    ${uri}
 575
 576 Get_From_Member
 577     [Arguments]    ${uri}    ${member_index}    ${access}=${ACCEPT_EMPTY}
 578     [Documentation]    Send a GET with the supplied uri to member ${member_index}.
 579     ${session} =    Resolve_Http_Session_For_Member    member_index=${member_index}
 580     ${response_text} =    TemplatedRequests.Get_From_Uri    uri=${uri}    accept=${access}    session=${session}
 581     [Return]    ${response_text}
 582
 583 Resolve_IP_Address_For_Member
 584     [Arguments]    ${member_index}
 585     [Documentation]    Return node IP address of given index.
 586     ${ip_address} =    Collections.Get From Dictionary    dictionary=${ClusterManagement__index_to_ip_mapping}    key=${member_index}
 587     [Return]    ${ip_address}
 588
 589 Resolve_Http_Session_For_Member
 590     [Arguments]    ${member_index}
 591     [Documentation]    Return RequestsLibrary session alias pointing to node of given index.
 592     ${session} =    BuiltIn.Set_Variable    ClusterManagement__session_${member_index}
 593     [Return]    ${session}
 594
 595 Resolve_Shard_Type_Class
 596     [Arguments]    ${shard_type}
 597     [Documentation]    Simple lookup for class name corresponding to desired type.
 598     BuiltIn.Run_Keyword_If    '${shard_type}' == 'config'    BuiltIn.Return_From_Keyword    DistributedConfigDatastore
 599     ...    ELSE IF    '${shard_type}' == 'operational'    BuiltIn.Return_From_Keyword    DistributedOperationalDatastore
 600     BuiltIn.Fail    Unrecognized shard type: ${shard_type}
 601
 602 ClusterManagement__Build_List
 603     [Arguments]    ${member}
 604     ${member_int} =    BuiltIn.Convert_To_Integer    ${member}
 605     ${index_list} =    BuiltIn.Create_List    ${member_int}
 606     [Return]    ${index_list}
 607
 608 ClusterManagement__Parse_Sync_Status
 609     [Arguments]    ${shard_manager_text}
 610     [Documentation]    Return sync status parsed out of given text. Called twice by Get_Sync_Status_Of_Member.
 611     BuiltIn.Log    ${shard_manager_text}
 612     ${manager_object} =    RequestsLibrary.To_Json    ${shard_manager_text}
 613     ${value_object} =    Collections.Get_From_Dictionary    dictionary=${manager_object}    key=value
 614     ${sync_status} =    Collections.Get_From_Dictionary    dictionary=${value_object}    key=SyncStatus
 615     [Return]    ${sync_status}
 616
 617 List_Indices_Minus_Member
 618     [Arguments]    ${member_index}    ${member_index_list}=${EMPTY}
 619     [Documentation]    Create a new list which contains indices from ${member_index_list} (or all) without ${member_index}.
 620     ${index_list} =    ClusterManagement__Given_Or_Empty_List    ${member_index_list}
 621     Collections.Remove Values From List    ${index_list}    ${member_index}
 622     [Return]    ${index_list}
 623
 624 ClusterManagement__Given_Or_Internal_Index_List
 625     [Arguments]    ${given_list}=${EMPTY}
 626     [Documentation]    Utility to allow \${EMPTY} as default argument value, as the internal list is computed at runtime.
 627     ...    This keyword always return a (shallow) copy of given or default list,
 628     ...    so operations with the returned list should not affect other lists.
 629     ...    Also note that this keyword does not consider empty list to be \${EMPTY}.
 630     ...    TODO: This keyword is frequently used for obtaining copy of ${ClusterManagement__member_index_list}. Give this keyword public name.
 631     ${return_list_reference} =    BuiltIn.Set_Variable_If    """${given_list}""" != ""    ${given_list}    ${ClusterManagement__member_index_list}
 632     ${return_list_copy} =    BuiltIn.Create_List    @{return_list_reference}
 633     [Return]    ${return_list_copy}
 634
 635 ClusterManagement__Given_Or_Empty_List
 636     [Arguments]    ${given_list}=${EMPTY}
 637     [Documentation]    Utility to allow \${EMPTY} as default argument value, as an empty list is computed at runtime.
 638     ${empty_list} =    BuiltIn.Create_List
 639     ${given_length} =    BuiltIn.Get_Length    ${given_list}
 640     ${return_list} =    BuiltIn.Set_Variable_If    ${given_length} > 0    ${given_list}    ${empty_list}
 641     [Return]    ${return_list}
 642
 643 ClusterManagement__Compute_Derived_Variables
 644     [Arguments]    ${int_of_members}
 645     [Documentation]    Construct index list, session list and IP mapping, publish them as suite variables.
 646     @{member_index_list} =    BuiltIn.Create_List
 647     @{session_list} =    BuiltIn.Create_List
 648     &{index_to_ip_mapping} =    BuiltIn.Create_Dictionary
 649     : FOR    ${index}    IN RANGE    1    ${int_of_members+1}
 650     \    ClusterManagement__Include_Member_Index    ${index}    ${member_index_list}    ${session_list}    ${index_to_ip_mapping}
 651     BuiltIn.Set_Suite_Variable    \${ClusterManagement__member_index_list}    ${member_index_list}
 652     BuiltIn.Set_Suite_Variable    \${ClusterManagement__index_to_ip_mapping}    ${index_to_ip_mapping}
 653     BuiltIn.Set_Suite_Variable    \${ClusterManagement__session_list}    ${session_list}
 654
 655 ClusterManagement__Include_Member_Index
 656     [Arguments]    ${index}    ${member_index_list}    ${session_list}    ${index_to_ip_mapping}
 657     [Documentation]    Add a corresponding item based on index into the last three arguments.
 658     ...    Create the Http session whose alias is added to list.
 659     Collections.Append_To_List    ${member_index_list}    ${index}
 660     ${member_ip} =    BuiltIn.Set_Variable    ${ODL_SYSTEM_${index}_IP}
 661     # ${index} is int (not string) so "key=value" syntax does not work in the following line.
 662     Collections.Set_To_Dictionary    ${index_to_ip_mapping}    ${index}    ${member_ip}
 663     # Http session, with ${AUTH}, without headers.
 664     ${session_alias} =    Resolve_Http_Session_For_Member    member_index=${index}
 665     RequestsLibrary.Create_Session    ${session_alias}    http://${member_ip}:${RESTCONFPORT}    auth=${AUTH}    max_retries=0
 666     Collections.Append_To_List    ${session_list}    ${session_alias}
 667
 668 Sync_Status_Should_Be_False
 669     [Arguments]    ${controller_index}
 670     [Documentation]    Verify that cluster node is not in sync with others
 671     ${status}    Get_Sync_Status_Of_Member    ${controller_index}
 672     BuiltIn.Should_Not_Be_True    ${status}
 673
 674 Sync_Status_Should_Be_True
 675     [Arguments]    ${controller_index}
 676     [Documentation]    Verify that cluster node is in sync with others
 677     ${status}    Get_Sync_Status_Of_Member    ${controller_index}
 678     BuiltIn.Should_Be_True    ${status}