csit/libraries/ClusterManagement.robot

   1 *** Settings ***
   2 Documentation     Resource housing Keywords common to several suites for cluster functional testing.
   3 ...
   4 ...               Copyright (c) 2016 Cisco Systems, Inc. and others. All rights reserved.
   5 ...               Copyright (c) 2016 Brocade Communications Systems, Inc. and others. All rights reserved.
   6 ...
   7 ...               This program and the accompanying materials are made available under the
   8 ...               terms of the Eclipse Public License v1.0 which accompanies this distribution,
   9 ...               and is available at http://www.eclipse.org/legal/epl-v10.html
  10 ...
  11 ...
  12 ...               This resource holds private state (in suite variables),
  13 ...               which is generated once at Setup with ClusterManagement_Setup KW.
  14 ...               The state includes member indexes, IP addresses and Http (RequestsLibrary) sessions.
  15 ...               Cluster Keywords normally use member index, member list or nothing (all members) as argument.
  16 ...
  17 ...               All index lists returned should be sorted numerically, fix if not.
  18 ...
  19 ...               Requirements:
  20 ...               odl-jolokia is assumed to be installed.
  21 ...
  22 ...               Keywords are ordered as follows:
  23 ...               - Cluster Setup
  24 ...               - Shard state, leader and followers
  25 ...               - Entity Owner, candidates and successors
  26 ...               - Kill and Start Member
  27 ...               - Isolate and Rejoin Member
  28 ...               - Run Commands On Member
  29 ...               - REST requests and checks on Members
  30 ...
  31 ...               TODO: Unify capitalization of Leaders and Followers.
  32 Library           RequestsLibrary    # for Create_Session and To_Json
  33 Library           Collections
  34 Resource          ${CURDIR}/CompareStream.robot
  35 Resource          ${CURDIR}/KarafKeywords.robot
  36 Resource          ${CURDIR}/SSHKeywords.robot
  37 Resource          ${CURDIR}/TemplatedRequests.robot    # for Get_As_Json_From_Uri
  38 Resource          ${CURDIR}/Utils.robot    # for Run_Command_On_Controller
  39
  40 *** Variables ***
  41 ${ENTITY_OWNER_URI}    restconf/operational/entity-owners:entity-owners
  42 ${JAVA_HOME}      ${EMPTY}    # releng/builder scripts should provide correct value
  43 ${JOLOKIA_CONF_SHARD_MANAGER_URI}    jolokia/read/org.opendaylight.controller:Category=ShardManager,name=shard-manager-config,type=DistributedConfigDatastore
  44 ${JOLOKIA_OPER_SHARD_MANAGER_URI}    jolokia/read/org.opendaylight.controller:Category=ShardManager,name=shard-manager-operational,type=DistributedOperationalDatastore
  45 ${JOLOKIA_READ_URI}    jolokia/read/org.opendaylight.controller
  46 ${KARAF_HOME}     ${WORKSPACE}${/}${BUNDLEFOLDER}    # TODO: Migrate to Variables.robot
  47 @{ODL_DEFAULT_DATA_PATHS}    tmp/    data/    cache/    snapshots/    journal/    etc/opendaylight/current/
  48 ${RESTCONF_MODULES_DIR}    ${CURDIR}/../variables/restconf/modules
  49
  50 *** Keywords ***
  51 ClusterManagement_Setup
  52     [Documentation]    Detect repeated call, or detect number of members and initialize derived suite variables.
  53     # Avoid multiple initialization by several downstream libraries.
  54     ${already_done} =    BuiltIn.Get_Variable_Value    \${ClusterManagement__has_setup_run}    False
  55     BuiltIn.Return_From_Keyword_If    ${already_done}
  56     BuiltIn.Set_Suite_Variable    \${ClusterManagement__has_setup_run}    True
  57     ${cluster_size} =    BuiltIn.Get_Variable_Value    \${NUM_ODL_SYSTEM}    1
  58     ${status}    ${possibly_int_of_members} =    BuiltIn.Run_Keyword_And_Ignore_Error    BuiltIn.Convert_To_Integer    ${cluster_size}
  59     ${int_of_members} =    BuiltIn.Set_Variable_If    '${status}' != 'PASS'    ${1}    ${possibly_int_of_members}
  60     ClusterManagement__Compute_Derived_Variables    int_of_members=${int_of_members}
  61
  62 Check_Cluster_Is_In_Sync
  63     [Arguments]    ${member_index_list}=${EMPTY}
  64     [Documentation]    Fail if no-sync is detected on a member from list (or any).
  65     ${index_list} =    ClusterManagement__Given_Or_Internal_Index_List    given_list=${member_index_list}
  66     : FOR    ${index}    IN    @{index_list}    # usually: 1, 2, 3.
  67     \    ${status} =    Get_Sync_Status_Of_Member    member_index=${index}
  68     \    BuiltIn.Continue_For_Loop_If    'True' == '${status}'
  69     \    BuiltIn.Fail    Index ${index} has incorrect status: ${status}
  70
  71 Get_Sync_Status_Of_Member
  72     [Arguments]    ${member_index}
  73     [Documentation]    Obtain IP, two GETs from jolokia URIs, return combined sync status as string.
  74     ${session} =    Resolve_Http_Session_For_Member    member_index=${member_index}
  75     ${conf_text} =    TemplatedRequests.Get_As_Json_From_Uri    uri=${JOLOKIA_CONF_SHARD_MANAGER_URI}    session=${session}
  76     ${conf_status} =    ClusterManagement__Parse_Sync_Status    shard_manager_text=${conf_text}
  77     BuiltIn.Return_From_Keyword_If    'False' == ${conf_status}    False
  78     ${oper_text} =    TemplatedRequests.Get_As_Json_From_Uri    uri=${JOLOKIA_OPER_SHARD_MANAGER_URI}    session=${session}
  79     ${oper_status} =    ClusterManagement__Parse_Sync_Status    shard_manager_text=${oper_text}
  80     [Return]    ${oper_status}
  81
  82 Verify_Leader_Exists_For_Each_Shard
  83     [Arguments]    ${shard_name_list}    ${shard_type}=operational    ${member_index_list}=${EMPTY}    ${verify_restconf}=True
  84     [Documentation]    For each shard name, call Get_Leader_And_Followers_For_Shard.
  85     ...    Not much logic there, but single Keyword is useful when using BuiltIn.Wait_Until_Keyword_Succeeds.
  86     : FOR    ${shard_name}    IN    @{shard_name_list}
  87     \    Get_Leader_And_Followers_For_Shard    shard_name=${shard_name}    shard_type=${shard_type}    validate=True    member_index_list=${member_index_list}    verify_restconf=${verify_restconf}
  88
  89 Get_Leader_And_Followers_For_Shard
  90     [Arguments]    ${shard_name}=default    ${shard_type}=operational    ${validate}=True    ${member_index_list}=${EMPTY}    ${verify_restconf}=True
  91     [Documentation]    Get role lists, validate there is one leader, return the leader and list of followers.
  92     ...    Optionally, issue GET to a simple restconf URL to make sure subsequent operations will not encounter 503.
  93     ${leader_list}    ${follower_list} =    Get_State_Info_For_Shard    shard_name=${shard_name}    shard_type=${shard_type}    validate=True    member_index_list=${member_index_list}
  94     ...    verify_restconf=${verify_restconf}
  95     ${leader_count} =    BuiltIn.Get_Length    ${leader_list}
  96     BuiltIn.Run_Keyword_If    ${leader_count} < 1    BuiltIn.Fail    No leader found.
  97     BuiltIn.Length_Should_Be    ${leader_list}    ${1}    Too many Leaders.
  98     ${leader} =    Collections.Get_From_List    ${leader_list}    0
  99     [Return]    ${leader}    ${follower_list}
 100
 101 Get_State_Info_For_Shard
 102     [Arguments]    ${shard_name}=default    ${shard_type}=operational    ${validate}=False    ${member_index_list}=${EMPTY}    ${verify_restconf}=False
 103     [Documentation]    Return lists of Leader and Follower member indices from a given member index list
 104     ...    (or from the full list if empty). If \${shard_type} is not 'config', 'operational' is assumed.
 105     ...    If \${validate}, Fail if raft state is not Leader or Follower (for example on Candidate).
 106     ...    The biggest difference from Get_Leader_And_Followers_For_Shard
 107     ...    is that no check on number of Leaders is performed.
 108     ${index_list} =    ClusterManagement__Given_Or_Internal_Index_List    given_list=${member_index_list}
 109     Collections.Sort_List    ${index_list}    # to guarantee return values are also sorted lists
 110     # TODO: Support alternative capitalization of 'config'?
 111     ${ds_type} =    BuiltIn.Set_Variable_If    '${shard_type}' != 'config'    operational    config
 112     ${leader_list} =    BuiltIn.Create_List
 113     ${follower_list} =    BuiltIn.Create_List
 114     : FOR    ${index}    IN    @{index_list}    # usually: 1, 2, 3.
 115     \    ${raft_state} =    Get_Raft_State_Of_Shard_At_Member    shard_name=${shard_name}    shard_type=${ds_type}    member_index=${index}    verify_restconf=${verify_restconf}
 116     \    BuiltIn.Run_Keyword_If    'Follower' == '${raft_state}'    Collections.Append_To_List    ${follower_list}    ${index}
 117     \    ...    ELSE IF    'Leader' == '${raft_state}'    Collections.Append_To_List    ${leader_list}    ${index}
 118     \    ...    ELSE IF    ${validate}    BuiltIn.Fail    Unrecognized Raft state: ${raft_state}
 119     [Return]    ${leader_list}    ${follower_list}
 120
 121 Get_Raft_State_Of_Shard_At_Member
 122     [Arguments]    ${shard_name}    ${shard_type}    ${member_index}    ${verify_restconf}=False
 123     [Documentation]    Send request to Jolokia on indexed member, return extracted Raft status.
 124     ...    Optionally, check restconf works.
 125     ${session} =    Resolve_Http_Session_For_Member    member_index=${member_index}
 126     # TODO: Does the used URI tend to generate large data which floods log.html?
 127     BuiltIn.Run_Keyword_If    ${verify_restconf}    TemplatedRequests.Get_As_Json_Templated    session=${session}    folder=${RESTCONF_MODULES_DIR}    verify=False
 128     ${type_class} =    Resolve_Shard_Type_Class    shard_type=${shard_type}
 129     ${uri} =    BuiltIn.Set_Variable    ${JOLOKIA_READ_URI}:Category=Shards,name=member-${member_index}-shard-${shard_name}-${shard_type},type=${type_class}
 130     ${data_text} =    TemplatedRequests.Get_As_Json_From_Uri    uri=${uri}    session=${session}
 131     ${data_object} =    RequestsLibrary.To_Json    ${data_text}
 132     ${value} =    Collections.Get_From_Dictionary    ${data_object}    value
 133     ${raft_state} =    Collections.Get_From_Dictionary    ${value}    RaftState
 134     [Return]    ${raft_state}
 135
 136 Verify_Owner_And_Successors_For_Device
 137     [Arguments]    ${device_name}    ${device_type}    ${member_index}    ${candidate_list}=${EMPTY}
 138     [Documentation]    Returns the owner and successors for the SB device ${device_name} of type ${device_type}. Request is sent to member ${member_index}.
 139     ...    For Boron and beyond, candidates are not removed on node down or isolation,
 140     ...    so this keyword expects candidates to be all members from Boron on.
 141     ...    Extra check is done to verify owner and successors are within the ${candidate_list}. This KW is useful when combined with WUKS.
 142     ...    ${candidate_list} minus owner is returned as ${successor list}.
 143     ...    Users can still use Get_Owner_And_Successors_For_Device if they are interested in downed candidates,
 144     ...    or for testing heterogeneous clusters.
 145     ${index_list} =    ClusterManagement__Given_Or_Internal_Index_List    given_list=${candidate_list}
 146     ${owner}    ${successor_list} =    Get_Owner_And_Successors_For_Device    device_name=${device_name}    device_type=${device_type}    member_index=${member_index}
 147     Collections.List_Should_Contain_Value    ${index_list}    ${owner}    Owner ${owner} is not in candidate list ${index_list}
 148     ${expected_candidate_list_origin} =    CompareStream.Set_Variable_If_At_Least_Boron    ${ClusterManagement__member_index_list}    ${index_list}
 149     # We do not want to manipulate either origin list.
 150     ${expected_successor_list} =    BuiltIn.Create_List    @{expected_candidate_list_origin}
 151     Collections.Remove_Values_From_List    ${expected_successor_list}    ${owner}
 152     Collections.Lists_Should_Be_Equal    ${expected_successor_list}    ${successor_list}    Successor list ${successor_list} is not the came as expected ${expected_successor_list}
 153     # User expects the returned successor list to be the provided candidate list minus the owner.
 154     Collections.Remove_Values_From_List    ${index_list}    ${owner}
 155     [Return]    ${owner}    ${index_list}
 156
 157 Get_Owner_And_Successors_For_Device
 158     [Arguments]    ${device_name}    ${device_type}    ${member_index}
 159     [Documentation]    Returns the owner and a list of successors for the SB device ${device_name} of type ${device_type}. Request is sent to member ${member_index}.
 160     ...    Successors are those device candidates not elected as owner. The list of successors = (list of candidates) - (owner).
 161     ...    The returned successor list is sorted numerically.
 162     ...    Note that "candidate list" definition currently differs between Beryllium and Boron.
 163     ...    Use Verify_Owner_And_Successors_For_Device if you want the older semantics (inaccessible nodes not present in the list).
 164     ${owner}    ${candidate_list} =    Get_Owner_And_Candidates_For_Device    device_name=${device_name}    device_type=${device_type}    member_index=${member_index}
 165     ${successor_list} =    BuiltIn.Create_List    @{candidate_list}    # Copy operation is not required, but new variable name requires a line anyway.
 166     Collections.Remove_Values_From_List    ${successor_list}    ${owner}
 167     [Return]    ${owner}    ${successor_list}
 168
 169 Get_Owner_And_Candidates_For_Device
 170     [Arguments]    ${device_name}    ${device_type}    ${member_index}
 171     [Documentation]    Returns the owner and a list of candidates for the SB device ${device_name} of type ${device_type}. Request is sent to member ${member_index}.
 172     ...    Candidates are all members that register to own a device, so the list of candiates includes the owner.
 173     ...    The returned candidate list is sorted numerically.
 174     ...    Note that "candidate list" definition currently differs between Beryllium and Boron.
 175     ...    It is recommended to use Get_Owner_And_Successors_For_Device instead of this keyword, see documentation there.
 176     BuiltIn.Comment    TODO: Can this implementation be changed to call Get_Owner_And_Candidates_For_Type_And_Id?
 177     ${session} =    Resolve_Http_Session_For_Member    member_index=${member_index}
 178     ${data} =    TemplatedRequests.Get_As_Json_From_Uri    uri=${ENTITY_OWNER_URI}    session=${session}
 179     ${candidate_list} =    BuiltIn.Create_List
 180     ${entity_type} =    BuiltIn.Set_Variable_If    '${device_type}' == 'netconf'    netconf-node/${device_name}    ${device_type}
 181     ${clear_data} =    BuiltIn.Run_Keyword_If    '${device_type}' == 'openflow' or '${device_type}' == 'netconf'    Extract_OpenFlow_Device_Data    ${data}
 182     ...    ELSE IF    '${device_type}' == 'ovsdb'    Extract_Ovsdb_Device_Data    ${data}
 183     ...    ELSE IF    '${device_type}' == 'org.opendaylight.mdsal.ServiceEntityType'    Extract_Service_Entity_Type    ${data}
 184     ...    ELSE    Fail    Not recognized device type: ${device_type}
 185     ${json} =    RequestsLibrary.To_Json    ${clear_data}
 186     ${entity_type_list} =    Collections.Get_From_Dictionary    &{json}[entity-owners]    entity-type
 187     ${entity_type_index} =    Utils.Get_Index_From_List_Of_Dictionaries    ${entity_type_list}    type    ${entity_type}
 188     BuiltIn.Should_Not_Be_Equal    ${entity_type_index}    -1    No Entity Owner found for ${device_type}
 189     ${entity_list} =    Collections.Get_From_Dictionary    @{entity_type_list}[${entity_type_index}]    entity
 190     ${entity_index} =    Utils.Get_Index_From_List_Of_Dictionaries    ${entity_list}    id    ${device_name}
 191     BuiltIn.Should Not Be Equal    ${entity_index}    -1    Device ${device_name} not found in Entity Owner ${device_type}
 192     ${entity_owner} =    Collections.Get_From_Dictionary    @{entity_list}[${entity_index}]    owner
 193     BuiltIn.Should_Not_Be_Empty    ${entity_owner}    No owner found for ${device_name}
 194     ${owner} =    String.Replace_String    ${entity_owner}    member-    ${EMPTY}
 195     ${owner} =    BuiltIn.Convert_To_Integer    ${owner}
 196     ${entity_candidates_list} =    Collections.Get_From_Dictionary    @{entity_list}[${entity_index}]    candidate
 197     : FOR    ${entity_candidate}    IN    @{entity_candidates_list}
 198     \    ${candidate} =    String.Replace_String    &{entity_candidate}[name]    member-    ${EMPTY}
 199     \    ${candidate} =    BuiltIn.Convert_To_Integer    ${candidate}
 200     \    Collections.Append_To_List    ${candidate_list}    ${candidate}
 201     Collections.Sort_List    ${candidate_list}
 202     [Return]    ${owner}    ${candidate_list}
 203
 204 Get_Owner_And_Candidates_For_Type_And_Id
 205     [Arguments]    ${type}    ${id}    ${member_index}    ${require_candidate_list}=${EMPTY}
 206     [Documentation]    Returns the owner and a list of candidates for entity specified by ${type} and ${id}
 207     ...    Request is sent to member ${member_index}.
 208     ...    Candidates are all members that register to own a device, so the list of candiates includes the owner.
 209     ...    Bear in mind that for Boron and beyond, candidates are not removed on node down or isolation.
 210     ...    If ${require_candidate_list} is not \${EMPTY}, check whether the actual list of candidates matches.
 211     ...    Note that differs from "given list" semantics used in other keywords,
 212     ...    namely you cannot use \${EMPTY} to stand for "full list" in this keyword.
 213     BuiltIn.Comment    TODO: Find a way to unify and deduplicate code blocks in Get_Owner_And_Candidates_* keywords.
 214     ${session} =    Resolve_Http_Session_For_Member    member_index=${member_index}
 215     ${data} =    TemplatedRequests.Get_As_Json_From_Uri    uri=${ENTITY_OWNER_URI}    session=${session}
 216     ${candidate_list} =    BuiltIn.Create_List
 217     ${json} =    RequestsLibrary.To_Json    ${data}
 218     ${entity_type_list} =    Collections.Get_From_Dictionary    &{json}[entity-owners]    entity-type
 219     ${entity_type_index} =    Utils.Get_Index_From_List_Of_Dictionaries    ${entity_type_list}    type    ${type}
 220     BuiltIn.Should_Not_Be_Equal    ${entity_type_index}    -1    No Entity Owner found for ${type}
 221     ${entity_list} =    Collections.Get_From_Dictionary    @{entity_type_list}[${entity_type_index}]    entity
 222     ${entity_index} =    Utils.Get_Index_From_List_Of_Dictionaries    ${entity_list}    id    ${id}
 223     BuiltIn.Should Not Be Equal    ${entity_index}    -1    Id ${id} not found in Entity Owner ${type}
 224     ${entity_owner} =    Collections.Get_From_Dictionary    @{entity_list}[${entity_index}]    owner
 225     BuiltIn.Should_Not_Be_Empty    ${entity_owner}    No owner found for type=${type} id=${id}
 226     ${owner} =    String.Replace_String    ${entity_owner}    member-    ${EMPTY}
 227     ${owner} =    BuiltIn.Convert_To_Integer    ${owner}
 228     ${entity_candidates_list} =    Collections.Get_From_Dictionary    @{entity_list}[${entity_index}]    candidate
 229     : FOR    ${entity_candidate}    IN    @{entity_candidates_list}
 230     \    ${candidate} =    String.Replace_String    &{entity_candidate}[name]    member-    ${EMPTY}
 231     \    ${candidate} =    BuiltIn.Convert_To_Integer    ${candidate}
 232     \    Collections.Append_To_List    ${candidate_list}    ${candidate}
 233     Collections.Sort_List    ${candidate_list}
 234     BuiltIn.Comment    TODO: Separate check lines into Verify_Owner_And_Candidates_For_Type_And_Id
 235     BuiltIn.Run_Keyword_If    """${require_candidate_list}"""    BuiltIn.Should_Be_Equal    ${require_candidate_list}    ${candidate_list}    Candidate list does not match: ${candidate_list} is not ${require_candidate_list}
 236     [Return]    ${owner}    ${candidate_list}
 237
 238 Extract_Service_Entity_Type
 239     [Arguments]    ${data}
 240     [Documentation]    Remove superfluous device data from Entity Owner printout.
 241     ${clear_data} =    String.Replace_String    ${data}    /odl-general-entity:entity[odl-general-entity:name='    ${EMPTY}
 242     ${clear_data} =    String.Replace_String    ${clear_data}    -service-group']    ${EMPTY}
 243     Log    ${clear_data}
 244     [Return]    ${clear_data}
 245
 246 Extract_OpenFlow_Device_Data
 247     [Arguments]    ${data}
 248     [Documentation]    Remove superfluous OpenFlow device data from Entity Owner printout.
 249     ${clear_data} =    BuiltIn.Run Keyword If    '${ODL_STREAM}' != 'beryllium' and '${ODL_OF_PLUGIN}' == 'lithium'    String.Replace_String    ${data}    org.opendaylight.mdsal.ServiceEntityType    openflow
 250     ...    ELSE    BuiltIn.Set_Variable    ${data}
 251     ${clear_data} =    String.Replace_String    ${clear_data}    /odl-general-entity:entity[odl-general-entity:name='    ${EMPTY}
 252     ${clear_data} =    String.Replace_String    ${clear_data}    /general-entity:entity[general-entity:name='    ${EMPTY}
 253     ${clear_data} =    String.Replace_String    ${clear_data}    ']    ${EMPTY}
 254     Log    ${clear_data}
 255     [Return]    ${clear_data}
 256
 257 Extract_Ovsdb_Device_Data
 258     [Arguments]    ${data}
 259     [Documentation]    Remove superfluous OVSDB device data from Entity Owner printout.
 260     ${clear_data} =    String.Replace_String    ${data}    /network-topology:network-topology/network-topology:topology[network-topology:topology-id='ovsdb:1']/network-topology:node[network-topology:node-id='    ${EMPTY}
 261     ${clear_data} =    String.Replace_String    ${clear_data}    ']    ${EMPTY}
 262     Log    ${clear_data}
 263     [Return]    ${clear_data}
 264
 265 Kill_Single_Member
 266     [Arguments]    ${member}    ${original_index_list}=${EMPTY}    ${confirm}=True
 267     [Documentation]    Convenience keyword that kills the specified member of the cluster.
 268     ...    The KW will return a list of available members: \${updated index_list}=\${original_index_list}-\${member}
 269     ${index_list} =    ClusterManagement__Build_List    ${member}
 270     ${updated_index_list} =    Kill_Members_From_List_Or_All    ${index_list}    ${original_index_list}    ${confirm}
 271     [Return]    ${updated_index_list}
 272
 273 Kill_Members_From_List_Or_All
 274     [Arguments]    ${member_index_list}=${EMPTY}    ${original_index_list}=${EMPTY}    ${confirm}=True
 275     [Documentation]    If the list is empty, kill all ODL instances. Otherwise, kill members based on \${kill_index_list}
 276     ...    If \${confirm} is True, sleep 1 second and verify killed instances are not there anymore.
 277     ...    The KW will return a list of available members: \${updated index_list}=\${original_index_list}-\${member_index_list}
 278     ${kill_index_list} =    ClusterManagement__Given_Or_Internal_Index_List    given_list=${member_index_list}
 279     ${index_list} =    ClusterManagement__Given_Or_Internal_Index_List    given_list=${original_index_list}
 280     ${command} =    BuiltIn.Set_Variable    ps axf | grep karaf | grep -v grep | awk '{print \"kill -9 \" $1}' | sh
 281     Run_Bash_Command_On_List_Or_All    command=${command}    member_index_list=${member_index_list}
 282     ${updated_index_list} =    BuiltIn.Create_List    @{index_list}
 283     Collections.Remove_Values_From_List    ${updated_index_list}    @{kill_index_list}
 284     BuiltIn.Return_From_Keyword_If    not ${confirm}    ${updated_index_list}
 285     # TODO: Convert to WUKS with configurable timeout if it turns out 1 second is not enough.
 286     BuiltIn.Sleep    1s    Kill -9 closes open files, which may take longer than ssh overhead, but not long enough to warrant WUKS.
 287     : FOR    ${index}    IN    @{kill_index_list}
 288     \    Verify_Karaf_Is_Not_Running_On_Member    member_index=${index}
 289     [Return]    ${updated_index_list}
 290
 291 Start_Single_Member
 292     [Arguments]    ${member}    ${wait_for_sync}=True    ${timeout}=300s
 293     [Documentation]    Convenience keyword that starts the specified member of the cluster.
 294     ${index_list} =    ClusterManagement__Build_List    ${member}
 295     Start_Members_From_List_Or_All    ${index_list}    ${wait_for_sync}    ${timeout}
 296
 297 Start_Members_From_List_Or_All
 298     [Arguments]    ${member_index_list}=${EMPTY}    ${wait_for_sync}=True    ${timeout}=300s    ${karaf_home}=${KARAF_HOME}    ${export_java_home}=${JAVA_HOME}
 299     [Documentation]    If the list is empty, start all cluster members. Otherwise, start members based on present indices.
 300     ...    If ${wait_for_sync}, wait for cluster sync on listed members.
 301     ...    Optionally karaf_home can be overriden. Optionally specific JAVA_HOME is used for starting.
 302     ${base_command} =    BuiltIn.Set_Variable    ${karaf_home}/bin/start
 303     ${command} =    BuiltIn.Set_Variable_If    "${export_java_home}"    export JAVA_HOME="${export_java_home}"; ${base_command}    ${base_command}
 304     Run_Bash_Command_On_List_Or_All    command=${command}    member_index_list=${member_index_list}
 305     BuiltIn.Return_From_Keyword_If    not ${wait_for_sync}
 306     BuiltIn.Wait_Until_Keyword_Succeeds    ${timeout}    10s    Check_Cluster_Is_In_Sync    member_index_list=${member_index_list}
 307     # TODO: Do we also want to check Shard Leaders here?
 308
 309 Clean_Journals_And_Snapshots_On_List_Or_All
 310     [Arguments]    ${member_index_list}=${EMPTY}    ${karaf_home}=${KARAF_HOME}
 311     [Documentation]    Delete journal and snapshots directories on every node listed (or all).
 312     ${index_list} =    ClusterManagement__Given_Or_Internal_Index_List    given_list=${member_index_list}
 313     ${command} =    Set Variable    rm -rf "${karaf_home}/journal" "${karaf_home}/snapshots"
 314     : FOR    ${index}    IN    @{index_list}    # usually: 1, 2, 3.
 315     \    Run_Bash_Command_On_Member    command=${command}    member_index=${index}
 316
 317 Verify_Karaf_Is_Not_Running_On_Member
 318     [Arguments]    ${member_index}
 319     [Documentation]    Fail if non-zero karaf instances are counted on member of given index.
 320     ${count} =    Count_Running_Karafs_On_Member    member_index=${member_index}
 321     BuiltIn.Should_Be_Equal    0    ${count}    Found running Karaf count: ${count}
 322
 323 Verify_Single_Karaf_Is_Running_On_Member
 324     [Arguments]    ${member_index}
 325     [Documentation]    Fail if number of karaf instances on member of given index is not one.
 326     ${count} =    Count_Running_Karafs_On_Member    member_index=${member_index}
 327     BuiltIn.Should_Be_Equal    1    ${count}    Wrong number of Karafs running: ${count}
 328
 329 Count_Running_Karafs_On_Member
 330     [Arguments]    ${member_index}
 331     [Documentation]    Remotely execute grep for karaf process, return count as string.
 332     ${command} =    BuiltIn.Set_Variable    ps axf | grep karaf | grep -v grep | wc -l
 333     ${count} =    Run_Bash_Command_On_Member    command=${command}    member_index=${member_index}
 334     [Return]    ${count}
 335
 336 Isolate_Member_From_List_Or_All
 337     [Arguments]    ${isolate_member_index}    ${member_index_list}=${EMPTY}
 338     [Documentation]    If the list is empty, isolate member from all ODL instances. Otherwise, isolate member based on present indices.
 339     ...    The KW will return a list of available members: \${updated index_list}=\${member_index_list}-\${isolate_member_index}
 340     ${index_list} =    ClusterManagement__Given_Or_Internal_Index_List    given_list=${member_index_list}
 341     ${source} =    Collections.Get_From_Dictionary    ${ClusterManagement__index_to_ip_mapping}    ${isolate_member_index}
 342     : FOR    ${index}    IN    @{index_list}
 343     \    ${destination} =    Collections.Get_From_Dictionary    ${ClusterManagement__index_to_ip_mapping}    ${index}
 344     \    ${command} =    BuiltIn.Set_Variable    sudo /sbin/iptables -I OUTPUT -p all --source ${source} --destination ${destination} -j DROP
 345     \    BuiltIn.Run_Keyword_If    "${index}" != "${isolate_member_index}"    Run_Bash_Command_On_Member    command=${command}    member_index=${isolate_member_index}
 346     ${command} =    BuiltIn.Set_Variable    sudo /sbin/iptables -L -n
 347     ${output} =    Run_Bash_Command_On_Member    command=${command}    member_index=${isolate_member_index}
 348     BuiltIn.Log    ${output}
 349     ${updated_index_list} =    BuiltIn.Create_List    @{index_list}
 350     Collections.Remove_Values_From_List    ${updated_index_list}    ${isolate_member_index}
 351     [Return]    ${updated_index_list}
 352
 353 Rejoin_Member_From_List_Or_All
 354     [Arguments]    ${rejoin_member_index}    ${member_index_list}=${EMPTY}
 355     [Documentation]    If the list is empty, rejoin member from all ODL instances. Otherwise, rejoin member based on present indices.
 356     ${index_list} =    ClusterManagement__Given_Or_Internal_Index_List    given_list=${member_index_list}
 357     ${source} =    Collections.Get_From_Dictionary    ${ClusterManagement__index_to_ip_mapping}    ${rejoin_member_index}
 358     : FOR    ${index}    IN    @{index_list}
 359     \    ${destination} =    Collections.Get_From_Dictionary    ${ClusterManagement__index_to_ip_mapping}    ${index}
 360     \    ${command} =    BuiltIn.Set_Variable    sudo /sbin/iptables -D OUTPUT -p all --source ${source} --destination ${destination} -j DROP
 361     \    BuiltIn.Run_Keyword_If    "${index}" != "${rejoin_member_index}"    Run_Bash_Command_On_Member    command=${command}    member_index=${rejoin_member_index}
 362     ${command} =    BuiltIn.Set_Variable    sudo /sbin/iptables -L -n
 363     ${output} =    Run_Bash_Command_On_Member    command=${command}    member_index=${rejoin_member_index}
 364     BuiltIn.Log    ${output}
 365
 366 Flush_Iptables_From_List_Or_All
 367     [Arguments]    ${member_index_list}=${EMPTY}
 368     [Documentation]    If the list is empty, flush IPTables in all ODL instances. Otherwise, flush member based on present indices.
 369     ${command} =    BuiltIn.Set_Variable    sudo iptables -v -F
 370     ${output} =    Run_Bash_Command_On_List_Or_All    command=${command}    member_index_list=${member_index_list}
 371
 372 Run_Bash_Command_On_List_Or_All
 373     [Arguments]    ${command}    ${member_index_list}=${EMPTY}
 374     [Documentation]    Cycle through indices (or all), run command on each.
 375     ${index_list} =    ClusterManagement__Given_Or_Internal_Index_List    given_list=${member_index_list}
 376     : FOR    ${index}    IN    @{index_list}
 377     \    Run_Bash_Command_On_Member    command=${command}    member_index=${index}
 378
 379 Run_Bash_Command_On_Member
 380     [Arguments]    ${command}    ${member_index}
 381     [Documentation]    Obtain IP, call Utils and return output. This does not preserve active ssh session.
 382     # TODO: Rename these keyword to Run_Bash_Command_On_Member to distinguish from Karaf (or even Windows) commands.
 383     ${member_ip} =    Collections.Get_From_Dictionary    dictionary=${ClusterManagement__index_to_ip_mapping}    key=${member_index}
 384     ${output} =    SSHKeywords.Run_Keyword_Preserve_Connection    Utils.Run_Command_On_Controller    ${member_ip}    ${command}
 385     [Return]    ${output}
 386
 387 Run_Karaf_Command_On_List_Or_All
 388     [Arguments]    ${command}    ${member_index_list}=${EMPTY}    ${timeout}=10s
 389     [Documentation]    Cycle through indices (or all), run karaf command on each.
 390     ${index_list} =    ClusterManagement__Given_Or_Internal_Index_List    given_list=${member_index_list}
 391     : FOR    ${index}    IN    @{index_list}
 392     \    ${member_ip} =    Collections.Get_From_Dictionary    dictionary=${ClusterManagement__index_to_ip_mapping}    key=${index}
 393     \    KarafKeywords.Safe_Issue_Command_On_Karaf_Console    ${command}    ${member_ip}    timeout=${timeout}
 394
 395 Run_Karaf_Command_On_Member
 396     [Arguments]    ${command}    ${member_index}    ${timeout}=10s
 397     [Documentation]    Obtain IP address, call KarafKeywords and return output. This does not preserve active ssh session.
 398     ...    This keyword is not used by Run_Karaf_Command_On_List_Or_All, but returned output may be useful.
 399     ${member_ip} =    Collections.Get_From_Dictionary    dictionary=${ClusterManagement__index_to_ip_mapping}    key=${member_index}
 400     ${output} =    KarafKeywords.Safe_Issue_Command_On_Karaf_Console    ${command}    controller=${member_ip}    timeout=${timeout}
 401     [Return]    ${output}
 402
 403 Install_Feature_On_List_Or_All
 404     [Arguments]    ${feature_name}    ${member_index_list}=${EMPTY}    ${timeout}=60s
 405     [Documentation]    Attempt installation on each member from list (or all). Then look for failures.
 406     ${index_list} =    ClusterManagement__Given_Or_Internal_Index_List    given_list=${member_index_list}
 407     ${status_list} =    BuiltIn.Create_List
 408     : FOR    ${index}    IN    @{index_list}
 409     \    ${status}    ${text} =    BuiltIn.Run_Keyword_And_Ignore_Error    Install_Feature_On_Member    feature_name=${feature_name}    member_index=${index}
 410     \    ...    timeout=${timeout}
 411     \    BuiltIn.Log    ${text}
 412     \    Collections.Append_To_List    ${status_list}    ${status}
 413     : FOR    ${status}    IN    @{status_list}
 414     \    BuiltIn.Run_Keyword_If    "${status}" != "PASS"    BuiltIn.Fail    ${feature_name} installation failed, see log.
 415
 416 Install_Feature_On_Member
 417     [Arguments]    ${feature_name}    ${member_index}    ${timeout}=60s
 418     [Documentation]    Run feature:install karaf command, fail if installation was not successful. Return output.
 419     ${status}    ${output} =    BuiltIn.Run_Keyword_And_Ignore_Error    Run_Karaf_Command_On_Member    command=feature:install ${feature_name}    member_index=${member_index}    timeout=${timeout}
 420     BuiltIn.Run_Keyword_If    "${status}" != "PASS"    BuiltIn.Fail    Failed to install ${feature_name}: ${output}
 421     BuiltIn.Should_Not_Contain    ${output}    Can't install    Failed to install ${feature_name}: ${output}
 422     [Return]    ${output}
 423
 424 With_Ssh_To_List_Or_All_Run_Keyword
 425     [Arguments]    ${member_index_list}    ${keyword_name}    @{args}    &{kwargs}
 426     [Documentation]    For each index in given list (or all): activate SSH connection, run given Keyword, close active connection. Return None.
 427     ...    Note that if the Keyword affects SSH connections, results are still deterministic, but perhaps undesirable.
 428     ...    Beware that in order to avoid "got positional argument after named arguments", first two arguments in the call should not be named.
 429     BuiltIn.Comment    This keyword is experimental and there is high risk of being replaced by another approach.
 430     # TODO: For_Index_From_List_Or_All_Run_Keyword applied to With_Ssh_To_Member_Run_Keyword?
 431     ${index_list} =    ClusterManagement__Given_Or_Internal_Index_List    given_list=${member_index_list}
 432     : FOR    ${member_index}    IN    @{index_list}
 433     \    ${member_ip} =    Resolve_IP_Address_For_Member    ${member_index}
 434     \    SSHKeywords.Open_Connection_To_Odl_System    ip_address=${member_ip}
 435     \    BuiltIn.Run_Keyword    ${keyword_name}    @{args}    &{kwargs}
 436     \    SSHLibrary.Close_Connection
 437
 438 Safe_With_Ssh_To_List_Or_All_Run_Keyword
 439     [Arguments]    ${member_index_list}    ${keyword_name}    @{args}    &{kwargs}
 440     [Documentation]    Remember active ssh connection index, call With_Ssh_To_List_Or_All_Run_Keyword, return None. Restore the conection index on teardown.
 441     SSHKeywords.Run_Keyword_Preserve_Connection    With_Ssh_To_List_Or_All_Run_Keyword    ${member_index_list}    ${keyword_name}    @{args}    &{kwargs}
 442
 443 Clean_Directories_On_List_Or_All
 444     [Arguments]    ${member_index_list}=${EMPTY}    ${directory_list}=${EMPTY}    ${karaf_home}=${KARAF_HOME}
 445     [Documentation]    Clear @{directory_list} or @{ODL_DEFAULT_DATA_PATHS} for members in given list or all. Return None.
 446     ...    This is intended to return Karaf (offline) to the state it was upon the first boot.
 447     ${path_list} =    Builtin.Set Variable If    "${directory_list}" == "${EMPTY}"    ${ODL_DEFAULT_DATA_PATHS}    ${directory_list}
 448     Safe_With_Ssh_To_List_Or_All_Run_Keyword    ${member_index_list}    ClusterManagement__Clean_Directories    ${path_list}    ${karaf_home}
 449
 450 ClusterManagement__Clean_Directories
 451     [Arguments]    ${relative_path_list}    ${karaf_home}
 452     [Documentation]    For each relative path, remove files with respect to ${karaf_home}. Return None.
 453     : FOR    ${relative_path}    IN    @{relative_path_list}
 454     \    SSHLibrary.Execute_Command    rm -rf ${karaf_home}${/}${relative_path}
 455
 456 Put_As_Json_And_Check_Member_List_Or_All
 457     [Arguments]    ${uri}    ${data}    ${member_index}    ${member_index_list}=${EMPTY}
 458     [Documentation]    Send a PUT with the supplied uri ${uri} and body ${data} to member ${member_index}.
 459     ...    Then check data is replicated in all or some members defined in ${member_index_list}.
 460     ${response_text} =    Put_As_Json_To_Member    uri=${uri}    data=${data}    member_index=${member_index}
 461     Wait Until Keyword Succeeds    5s    1s    Check_Json_Member_List_Or_All    uri=${uri}    expected_data=${data}    member_index_list=${member_index_list}
 462     [Return]    ${response_text}
 463
 464 Put_As_Json_To_Member
 465     [Arguments]    ${uri}    ${data}    ${member_index}
 466     [Documentation]    Send a PUT with the supplied uri and data to member ${member_index}.
 467     ${session} =    Resolve_Http_Session_For_Member    member_index=${member_index}
 468     ${response_text} =    TemplatedRequests.Put_As_Json_To_Uri    uri=${uri}    data=${data}    session=${session}
 469     [Return]    ${response_text}
 470
 471 Post_As_Json_To_Member
 472     [Arguments]    ${uri}    ${data}    ${member_index}
 473     [Documentation]    Send a POST with the supplied uri and data to member ${member_index}.
 474     ${session} =    Resolve_Http_Session_For_Member    member_index=${member_index}
 475     ${response_text} =    TemplatedRequests.Post_As_Json_To_Uri    uri=${uri}    data=${data}    session=${session}
 476     [Return]    ${response_text}
 477
 478 Delete_And_Check_Member_List_Or_All
 479     [Arguments]    ${uri}    ${member_index}    ${member_index_list}=${EMPTY}
 480     [Documentation]    Send a DELETE with the supplied uri to the member ${member_index}.
 481     ...    Then check the data is removed from all members in ${member_index_list}.
 482     ${response_text} =    Delete_From_Member    ${uri}    ${member_index}
 483     BuiltIn.Wait_Until_Keyword_Succeeds    5s    1s    Check_No_Content_Member_List_Or_All    uri=${uri}    member_index_list=${member_index_list}
 484     [Return]    ${response_text}
 485
 486 Delete_From_Member
 487     [Arguments]    ${uri}    ${member_index}
 488     [Documentation]    Send a DELETE with the supplied uri to member ${member_index}.
 489     ${session} =    Resolve_Http_Session_For_Member    member_index=${member_index}
 490     ${response_text} =    TemplatedRequests.Delete_From_Uri    uri=${uri}    session=${session}
 491     [Return]    ${response_text}
 492
 493 Check_Json_Member_List_Or_All
 494     [Arguments]    ${uri}    ${expected_data}    ${member_index_list}=${EMPTY}
 495     [Documentation]    Send a GET with the supplied uri to all or some members defined in ${member_index_list}.
 496     ...    Then check received data is = ${expected data}.
 497     ${index_list} =    ClusterManagement__Given_Or_Internal_Index_List    given_list=${member_index_list}
 498     : FOR    ${index}    IN    @{index_list}
 499     \    ${data} =    Get_From_Member    uri=${uri}    member_index=${index}
 500     \    TemplatedRequests.Normalize_Jsons_And_Compare    ${expected_data}    ${data}
 501
 502 Check_Item_Occurrence_Member_List_Or_All
 503     [Arguments]    ${uri}    ${dictionary}    ${member_index_list}=${EMPTY}
 504     [Documentation]    Send a GET with the supplied uri to all or some members defined in ${member_index_list}.
 505     ...    Then check received for occurrences of items expressed in a dictionary ${dictionary}.
 506     ${index_list} =    ClusterManagement__Given_Or_Internal_Index_List    given_list=${member_index_list}
 507     : FOR    ${index}    IN    @{index_list}
 508     \    ${data} =    Get_From_Member    uri=${uri}    member_index=${index}
 509     \    Utils.Check Item Occurrence    ${data}    ${dictionary}
 510
 511 Check_No_Content_Member_List_Or_All
 512     [Arguments]    ${uri}    ${member_index_list}=${EMPTY}
 513     [Documentation]    Send a GET with the supplied uri to all or some members defined in ${member_index_list}.
 514     ...    Then check there is no content.
 515     ${index_list} =    ClusterManagement__Given_Or_Internal_Index_List    given_list=${member_index_list}
 516     : FOR    ${index}    IN    @{index_list}
 517     \    ${session} =    Resolve_Http_Session_For_Member    member_index=${index}
 518     \    Utils.No_Content_From_URI    ${session}    ${uri}
 519
 520 Get_From_Member
 521     [Arguments]    ${uri}    ${member_index}    ${access}=${ACCEPT_EMPTY}
 522     [Documentation]    Send a GET with the supplied uri to member ${member_index}.
 523     ${session} =    Resolve_Http_Session_For_Member    member_index=${member_index}
 524     ${response_text} =    TemplatedRequests.Get_From_Uri    uri=${uri}    accept=${access}    session=${session}
 525     [Return]    ${response_text}
 526
 527 Resolve_IP_Address_For_Member
 528     [Arguments]    ${member_index}
 529     [Documentation]    Return node IP address of given index.
 530     ${ip_address} =    Collections.Get From Dictionary    dictionary=${ClusterManagement__index_to_ip_mapping}    key=${member_index}
 531     [Return]    ${ip_address}
 532
 533 Resolve_Http_Session_For_Member
 534     [Arguments]    ${member_index}
 535     [Documentation]    Return RequestsLibrary session alias pointing to node of given index.
 536     ${session} =    BuiltIn.Set_Variable    ClusterManagement__session_${member_index}
 537     [Return]    ${session}
 538
 539 Resolve_Shard_Type_Class
 540     [Arguments]    ${shard_type}
 541     [Documentation]    Simple lookup for class name corresponding to desired type.
 542     BuiltIn.Run_Keyword_If    '${shard_type}' == 'config'    BuiltIn.Return_From_Keyword    DistributedConfigDatastore
 543     ...    ELSE IF    '${shard_type}' == 'operational'    BuiltIn.Return_From_Keyword    DistributedOperationalDatastore
 544     BuiltIn.Fail    Unrecognized shard type: ${shard_type}
 545
 546 ClusterManagement__Build_List
 547     [Arguments]    ${member}
 548     ${member_int} =    BuiltIn.Convert_To_Integer    ${member}
 549     ${index_list} =    BuiltIn.Create_List    ${member_int}
 550     [Return]    ${index_list}
 551
 552 ClusterManagement__Parse_Sync_Status
 553     [Arguments]    ${shard_manager_text}
 554     [Documentation]    Return sync status parsed out of given text. Called twice by Get_Sync_Status_Of_Member.
 555     BuiltIn.Log    ${shard_manager_text}
 556     ${manager_object} =    RequestsLibrary.To_Json    ${shard_manager_text}
 557     ${value_object} =    Collections.Get_From_Dictionary    dictionary=${manager_object}    key=value
 558     ${sync_status} =    Collections.Get_From_Dictionary    dictionary=${value_object}    key=SyncStatus
 559     [Return]    ${sync_status}
 560
 561 List_Indices_Minus_Member
 562     [Arguments]    ${member_index}    ${member_index_list}=${EMPTY}
 563     [Documentation]    Create a new list which contains indices from ${member_index_list} (or all) without ${member_index}.
 564     ${index_list} =    ClusterManagement__Given_Or_Empty_List    ${member_index_list}
 565     Collections.Remove Values From List    ${index_list}    ${member_index}
 566     [Return]    ${index_list}
 567
 568 ClusterManagement__Given_Or_Internal_Index_List
 569     [Arguments]    ${given_list}=${EMPTY}
 570     [Documentation]    Utility to allow \${EMPTY} as default argument value, as the internal list is computed at runtime.
 571     ...    This keyword always return a (shallow) copy of given or default list,
 572     ...    so operations with the returned list should not affect other lists.
 573     ...    Also note that this keyword does not consider empty list to be \${EMPTY}.
 574     ...    TODO: This keyword is frequently used for obtaining copy of ${ClusterManagement__member_index_list}. Give this keyword public name.
 575     ${return_list_reference} =    BuiltIn.Set_Variable_If    """${given_list}""" != ""    ${given_list}    ${ClusterManagement__member_index_list}
 576     ${return_list_copy} =    BuiltIn.Create_List    @{return_list_reference}
 577     [Return]    ${return_list_copy}
 578
 579 ClusterManagement__Given_Or_Empty_List
 580     [Arguments]    ${given_list}=${EMPTY}
 581     [Documentation]    Utility to allow \${EMPTY} as default argument value, as an empty list is computed at runtime.
 582     ${empty_list} =    BuiltIn.Create_List
 583     ${given_length} =    BuiltIn.Get_Length    ${given_list}
 584     ${return_list} =    BuiltIn.Set_Variable_If    ${given_length} > 0    ${given_list}    ${empty_list}
 585     [Return]    ${return_list}
 586
 587 ClusterManagement__Compute_Derived_Variables
 588     [Arguments]    ${int_of_members}
 589     [Documentation]    Construct index list, session list and IP mapping, publish them as suite variables.
 590     @{member_index_list} =    BuiltIn.Create_List
 591     @{session_list} =    BuiltIn.Create_List
 592     &{index_to_ip_mapping} =    BuiltIn.Create_Dictionary
 593     : FOR    ${index}    IN RANGE    1    ${int_of_members+1}
 594     \    ClusterManagement__Include_Member_Index    ${index}    ${member_index_list}    ${session_list}    ${index_to_ip_mapping}
 595     BuiltIn.Set_Suite_Variable    \${ClusterManagement__member_index_list}    ${member_index_list}
 596     BuiltIn.Set_Suite_Variable    \${ClusterManagement__index_to_ip_mapping}    ${index_to_ip_mapping}
 597     BuiltIn.Set_Suite_Variable    \${ClusterManagement__session_list}    ${session_list}
 598
 599 ClusterManagement__Include_Member_Index
 600     [Arguments]    ${index}    ${member_index_list}    ${session_list}    ${index_to_ip_mapping}
 601     [Documentation]    Add a corresponding item based on index into the last three arguments.
 602     ...    Create the Http session whose alias is added to list.
 603     Collections.Append_To_List    ${member_index_list}    ${index}
 604     ${member_ip} =    BuiltIn.Set_Variable    ${ODL_SYSTEM_${index}_IP}
 605     # ${index} is int (not string) so "key=value" syntax does not work in the following line.
 606     Collections.Set_To_Dictionary    ${index_to_ip_mapping}    ${index}    ${member_ip}
 607     # Http session, with ${AUTH}, without headers.
 608     ${session_alias} =    Resolve_Http_Session_For_Member    member_index=${index}
 609     RequestsLibrary.Create_Session    ${session_alias}    http://${member_ip}:${RESTCONFPORT}    auth=${AUTH}    max_retries=0
 610     Collections.Append_To_List    ${session_list}    ${session_alias}