csit/libraries/ClusterManagement.robot

   1 *** Settings ***
   2 Documentation     Resource housing Keywords common to several suites for cluster functional testing.
   3 ...
   4 ...               Copyright (c) 2016 Cisco Systems, Inc. and others. All rights reserved.
   5 ...               Copyright (c) 2016 Brocade Communications Systems, Inc. and others. All rights reserved.
   6 ...
   7 ...               This program and the accompanying materials are made available under the
   8 ...               terms of the Eclipse Public License v1.0 which accompanies this distribution,
   9 ...               and is available at http://www.eclipse.org/legal/epl-v10.html
  10 ...
  11 ...
  12 ...               This resource holds private state (in suite variables),
  13 ...               which is generated once at Setup with ClusterManagement_Setup KW.
  14 ...               The state includes member indexes, IP addresses and Http (RequestsLibrary) sessions.
  15 ...               Cluster Keywords normally use member index, member list or nothing (all members) as argument.
  16 ...
  17 ...               All index lists returned should be sorted numerically, fix if not.
  18 ...
  19 ...               Requirements:
  20 ...               odl-jolokia is assumed to be installed.
  21 ...
  22 ...               Keywords are ordered as follows:
  23 ...               - Cluster Setup
  24 ...               - Shard state, leader and followers
  25 ...               - Entity Owner, candidates and successors
  26 ...               - Kill, Stop and Start Member
  27 ...               - Isolate and Rejoin Member
  28 ...               - Run Commands On Member
  29 ...               - REST requests and checks on Members
  30 ...
  31 ...               TODO: Unify capitalization of Leaders and Followers.
  32 Library           RequestsLibrary    # for Create_Session and To_Json
  33 Library           Collections
  34 Resource          ${CURDIR}/CompareStream.robot
  35 Resource          ${CURDIR}/KarafKeywords.robot
  36 Resource          ${CURDIR}/SSHKeywords.robot
  37 Resource          ${CURDIR}/TemplatedRequests.robot    # for Get_As_Json_From_Uri
  38 Resource          ${CURDIR}/Utils.robot    # for Run_Command_On_Controller
  39
  40 *** Variables ***
  41 ${ENTITY_OWNER_URI}    restconf/operational/entity-owners:entity-owners
  42 ${GC_LOG_PATH}    ${KARAF_HOME}/data/log
  43 ${JAVA_HOME}      ${EMPTY}    # releng/builder scripts should provide correct value
  44 ${JOLOKIA_CONF_SHARD_MANAGER_URI}    jolokia/read/org.opendaylight.controller:Category=ShardManager,name=shard-manager-config,type=DistributedConfigDatastore
  45 ${JOLOKIA_OPER_SHARD_MANAGER_URI}    jolokia/read/org.opendaylight.controller:Category=ShardManager,name=shard-manager-operational,type=DistributedOperationalDatastore
  46 ${JOLOKIA_READ_URI}    jolokia/read/org.opendaylight.controller
  47 ${KARAF_HOME}     ${WORKSPACE}${/}${BUNDLEFOLDER}    # TODO: Migrate to Variables.robot
  48 # Bug 9044 workaround: delete etc/host.key before restart.
  49 @{ODL_DEFAULT_DATA_PATHS}    tmp/    data/    cache/    snapshots/    journal/    etc/opendaylight/current/    etc/host.key
  50 ${RESTCONF_MODULES_DIR}    ${CURDIR}/../variables/restconf/modules
  51 ${SINGLETON_NETCONF_DEVICE_ID_PREFIX}    /odl-general-entity:entity[odl-general-entity:name='KeyedInstanceIdentifier{targetType=interface org.opendaylight.yang.gen.v1.urn.tbd.params.xml.ns.yang.network.topology.rev131021.network.topology.topology.Node, path=[org.opendaylight.yang.gen.v1.urn.tbd.params.xml.ns.yang.network.topology.rev131021.NetworkTopology, org.opendaylight.yang.gen.v1.urn.tbd.params.xml.ns.yang.network.topology.rev131021.network.topology.Topology[key=TopologyKey [_topologyId=Uri [_value=topology-netconf]]], org.opendaylight.yang.gen.v1.urn.tbd.params.xml.ns.yang.network.topology.rev131021.network.topology.topology.Node[key=NodeKey [_nodeId=Uri [_value=
  52 ${SINGLETON_NETCONF_DEVICE_ID_SUFFIX}    ]]]]}']
  53 ${SINGLETON_ELECTION_ENTITY_TYPE}    org.opendaylight.mdsal.ServiceEntityType
  54 ${SINGLETON_CHANGE_OWNERSHIP_ENTITY_TYPE}    org.opendaylight.mdsal.AsyncServiceCloseEntityType
  55 ${NODE_START_COMMAND}    ${KARAF_HOME}/bin/start
  56 ${NODE_STOP_COMMAND}    ${KARAF_HOME}/bin/stop
  57 ${NODE_KILL_COMMAND}    ps axf | grep org.apache.karaf | grep -v grep | awk '{print \"kill -9 \" $1}' | sh
  58 ${NODE_FREEZE_COMMAND}    ps axf | grep org.apache.karaf | grep -v grep | awk '{print \"kill -STOP \" $1}' | sh
  59 ${NODE_UNFREEZE_COMMAND}    ps axf | grep org.apache.karaf | grep -v grep | awk '{print \"kill -CONT \" $1}' | sh
  60
  61 *** Keywords ***
  62 ClusterManagement_Setup
  63     [Arguments]    ${http_timeout}=1    ${http_retries}=0
  64     [Documentation]    Detect repeated call, or detect number of members and initialize derived suite variables.
  65     ...    Http sessions are created with parameters to not waste time when ODL is no accepting connections properly.
  66     # Avoid multiple initialization by several downstream libraries.
  67     ${already_done} =    BuiltIn.Get_Variable_Value    \${ClusterManagement__has_setup_run}    False
  68     BuiltIn.Return_From_Keyword_If    ${already_done}
  69     BuiltIn.Set_Suite_Variable    \${ClusterManagement__has_setup_run}    True
  70     ${cluster_size} =    BuiltIn.Get_Variable_Value    \${NUM_ODL_SYSTEM}    1
  71     ${status}    ${possibly_int_of_members} =    BuiltIn.Run_Keyword_And_Ignore_Error    BuiltIn.Convert_To_Integer    ${cluster_size}
  72     ${int_of_members} =    BuiltIn.Set_Variable_If    '${status}' != 'PASS'    ${1}    ${possibly_int_of_members}
  73     ClusterManagement__Compute_Derived_Variables    int_of_members=${int_of_members}    http_timeout=${http_timeout}    http_retries=${http_retries}
  74
  75 Check_Cluster_Is_In_Sync
  76     [Arguments]    ${member_index_list}=${EMPTY}
  77     [Documentation]    Fail if no-sync is detected on a member from list (or any).
  78     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
  79     : FOR    ${index}    IN    @{index_list}    # usually: 1, 2, 3.
  80     \    ${status} =    Get_Sync_Status_Of_Member    member_index=${index}
  81     \    BuiltIn.Continue_For_Loop_If    'True' == '${status}'
  82     \    BuiltIn.Fail    Index ${index} has incorrect status: ${status}
  83
  84 Get_Sync_Status_Of_Member
  85     [Arguments]    ${member_index}
  86     [Documentation]    Obtain IP, two GETs from jolokia URIs, return combined sync status as string.
  87     ${session} =    Resolve_Http_Session_For_Member    member_index=${member_index}
  88     ${conf_text} =    TemplatedRequests.Get_As_Json_From_Uri    uri=${JOLOKIA_CONF_SHARD_MANAGER_URI}    session=${session}
  89     ${conf_status} =    ClusterManagement__Parse_Sync_Status    shard_manager_text=${conf_text}
  90     BuiltIn.Return_From_Keyword_If    'False' == ${conf_status}    False
  91     ${oper_text} =    TemplatedRequests.Get_As_Json_From_Uri    uri=${JOLOKIA_OPER_SHARD_MANAGER_URI}    session=${session}
  92     ${oper_status} =    ClusterManagement__Parse_Sync_Status    shard_manager_text=${oper_text}
  93     [Return]    ${oper_status}
  94
  95 Verify_Leader_Exists_For_Each_Shard
  96     [Arguments]    ${shard_name_list}    ${shard_type}=operational    ${member_index_list}=${EMPTY}    ${verify_restconf}=True
  97     [Documentation]    For each shard name, call Get_Leader_And_Followers_For_Shard.
  98     ...    Not much logic there, but single Keyword is useful when using BuiltIn.Wait_Until_Keyword_Succeeds.
  99     : FOR    ${shard_name}    IN    @{shard_name_list}
 100     \    Get_Leader_And_Followers_For_Shard    shard_name=${shard_name}    shard_type=${shard_type}    validate=True    member_index_list=${member_index_list}    verify_restconf=${verify_restconf}
 101
 102 Get_Leader_And_Followers_For_Shard
 103     [Arguments]    ${shard_name}=default    ${shard_type}=operational    ${validate}=True    ${member_index_list}=${EMPTY}    ${verify_restconf}=True    ${http_timeout}=5
 104     [Documentation]    Get role lists, validate there is one leader, return the leader and list of followers.
 105     ...    Optionally, issue GET to a simple restconf URL to make sure subsequent operations will not encounter 503.
 106     ${leader_list}    ${follower_list} =    Get_State_Info_For_Shard    shard_name=${shard_name}    shard_type=${shard_type}    validate=True    member_index_list=${member_index_list}
 107     ...    verify_restconf=${verify_restconf}    http_timeout=${http_timeout}
 108     ${leader_count} =    BuiltIn.Get_Length    ${leader_list}
 109     BuiltIn.Run_Keyword_If    ${leader_count} < 1    BuiltIn.Fail    No leader found.
 110     BuiltIn.Length_Should_Be    ${leader_list}    ${1}    Too many Leaders.
 111     ${leader} =    Collections.Get_From_List    ${leader_list}    0
 112     [Return]    ${leader}    ${follower_list}
 113
 114 Get_State_Info_For_Shard
 115     [Arguments]    ${shard_name}=default    ${shard_type}=operational    ${validate}=False    ${member_index_list}=${EMPTY}    ${verify_restconf}=False    ${http_timeout}=5
 116     [Documentation]    Return lists of Leader and Follower member indices from a given member index list
 117     ...    (or from the full list if empty). If \${shard_type} is not 'config', 'operational' is assumed.
 118     ...    If \${validate}, Fail if raft state is not Leader or Follower (for example on Candidate).
 119     ...    The biggest difference from Get_Leader_And_Followers_For_Shard
 120     ...    is that no check on number of Leaders is performed.
 121     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 122     Collections.Sort_List    ${index_list}    # to guarantee return values are also sorted lists
 123     # TODO: Support alternative capitalization of 'config'?
 124     ${ds_type} =    BuiltIn.Set_Variable_If    '${shard_type}' != 'config'    operational    config
 125     ${leader_list} =    BuiltIn.Create_List
 126     ${follower_list} =    BuiltIn.Create_List
 127     : FOR    ${index}    IN    @{index_list}    # usually: 1, 2, 3.
 128     \    ${raft_state} =    Get_Raft_State_Of_Shard_At_Member    shard_name=${shard_name}    shard_type=${ds_type}    member_index=${index}    verify_restconf=${verify_restconf}
 129     \    ...    http_timeout=${http_timeout}
 130     \    BuiltIn.Run_Keyword_If    'Follower' == '${raft_state}'    Collections.Append_To_List    ${follower_list}    ${index}
 131     \    ...    ELSE IF    'Leader' == '${raft_state}'    Collections.Append_To_List    ${leader_list}    ${index}
 132     \    ...    ELSE IF    ${validate}    BuiltIn.Fail    Unrecognized Raft state: ${raft_state}
 133     [Return]    ${leader_list}    ${follower_list}
 134
 135 Get_Raft_State_Of_Shard_At_Member
 136     [Arguments]    ${shard_name}    ${shard_type}    ${member_index}    ${verify_restconf}=False    ${http_timeout}=5
 137     [Documentation]    Send request to Jolokia on indexed member, return extracted Raft status.
 138     ...    Optionally, check restconf works.
 139     ${raft_state} =    Get_Raft_Property_From_Shard_Member    RaftState    ${shard_name}    ${shard_type}    ${member_index}    verify_restconf=${verify_restconf}
 140     ...    http_timeout=${http_timeout}
 141     [Return]    ${raft_state}
 142
 143 Get_Raft_Property_From_Shard_Member
 144     [Arguments]    ${property}    ${shard_name}    ${shard_type}    ${member_index}    ${verify_restconf}=False    ${http_timeout}=5
 145     [Documentation]    Send request to Jolokia on indexed member, return extracted Raft property.
 146     ...    Optionally, check restconf works.
 147     ${session} =    Resolve_Http_Session_For_Member    member_index=${member_index}
 148     # TODO: Does the used URI tend to generate large data which floods log.html?
 149     BuiltIn.Run_Keyword_If    ${verify_restconf}    TemplatedRequests.Get_As_Json_Templated    session=${session}    folder=${RESTCONF_MODULES_DIR}    verify=False    http_timeout=${http_timeout}
 150     ${type_class} =    Resolve_Shard_Type_Class    shard_type=${shard_type}
 151     ${uri} =    BuiltIn.Set_Variable    ${JOLOKIA_READ_URI}:Category=Shards,name=member-${member_index}-shard-${shard_name}-${shard_type},type=${type_class}
 152     ${data_text} =    TemplatedRequests.Get_As_Json_From_Uri    uri=${uri}    session=${session}    http_timeout=${http_timeout}
 153     ${data_object} =    RequestsLibrary.To_Json    ${data_text}
 154     ${value} =    Collections.Get_From_Dictionary    ${data_object}    value
 155     ${raft_property} =    Collections.Get_From_Dictionary    ${value}    ${property}
 156     [Return]    ${raft_property}
 157
 158 Verify_Shard_Leader_Elected
 159     [Arguments]    ${shard_name}    ${shard_type}    ${new_elected}    ${old_leader}    ${member_index_list}=${EMPTY}    ${verify_restconf}=True
 160     [Documentation]    Verify new leader was elected or remained the same. Bool paramter ${new_elected} indicates if
 161     ...    new leader is elected or should remained the same as ${old_leader}
 162     ${leader}    ${followers}=    Get_Leader_And_Followers_For_Shard    shard_name=${shard_name}    shard_type=${shard_type}    member_index_list=${member_index_list}    verify_restconf=${verify_restconf}
 163     BuiltIn.Run_Keyword_If    ${new_elected}    BuiltIn.Should_Not_Be_Equal_As_Numbers    ${old_leader}    ${leader}
 164     BuiltIn.Run_Keyword_Unless    ${new_elected}    BuiltIn.Should_Be_Equal_As_numbers    ${old_leader}    ${leader}
 165     BuiltIn.Return_From_Keyword    ${leader}    ${followers}
 166
 167 Verify_Owner_And_Successors_For_Device
 168     [Arguments]    ${device_name}    ${device_type}    ${member_index}    ${candidate_list}=${EMPTY}    ${after_stop}=False
 169     [Documentation]    Returns the owner and successors for the SB device ${device_name} of type ${device_type}. Request is sent to member ${member_index}.
 170     ...    For Boron and beyond, candidates are not removed on node down or isolation,
 171     ...    so this keyword expects candidates to be all members from Boron on.
 172     ...    Extra check is done to verify owner and successors are within the ${candidate_list}. This KW is useful when combined with WUKS.
 173     ...    ${candidate_list} minus owner is returned as ${successor list}.
 174     ...    Users can still use Get_Owner_And_Successors_For_Device if they are interested in downed candidates,
 175     ...    or for testing heterogeneous clusters.
 176     ${index_list} =    List_Indices_Or_All    given_list=${candidate_list}
 177     ${owner}    ${successor_list} =    Get_Owner_And_Successors_For_Device    device_name=${device_name}    device_type=${device_type}    member_index=${member_index}
 178     Collections.List_Should_Contain_Value    ${index_list}    ${owner}    Owner ${owner} is not in candidate list ${index_list}
 179     # In Beryllium or after stopping an instance, the removed instance does not show in the candidate list.
 180     ${expected_candidate_list_origin} =    BuiltIn.Set_Variable_If    ${after_stop}    ${index_list}    ${ClusterManagement__member_index_list}
 181     # We do not want to manipulate either origin list.
 182     ${expected_successor_list} =    BuiltIn.Create_List    @{expected_candidate_list_origin}
 183     Collections.Remove_Values_From_List    ${expected_successor_list}    ${owner}
 184     Collections.Lists_Should_Be_Equal    ${expected_successor_list}    ${successor_list}    Successor list ${successor_list} is not the came as expected ${expected_successor_list}
 185     # User expects the returned successor list to be the provided candidate list minus the owner.
 186     Collections.Remove_Values_From_List    ${index_list}    ${owner}
 187     [Return]    ${owner}    ${index_list}
 188
 189 Get_Owner_And_Successors_For_Device
 190     [Arguments]    ${device_name}    ${device_type}    ${member_index}    ${http_timeout}=${EMPTY}
 191     [Documentation]    Returns the owner and a list of successors for the SB device ${device_name} of type ${device_type}. Request is sent to member ${member_index}.
 192     ...    Successors are those device candidates not elected as owner. The list of successors = (list of candidates) - (owner).
 193     ...    The returned successor list is sorted numerically.
 194     ...    Note that "candidate list" definition currently differs between Beryllium and Boron.
 195     ...    Use Verify_Owner_And_Successors_For_Device if you want the older semantics (inaccessible nodes not present in the list).
 196     # TODO: somewhere to introduce ${DEFAULT_RESTCONF_DATASTORE_TIMEOUT}. Value may depend on protocol (ask vs tell) and perhaps stream.
 197     ${owner}    ${candidate_list} =    Get_Owner_And_Candidates_For_Device    device_name=${device_name}    device_type=${device_type}    member_index=${member_index}    http_timeout=${http_timeout}
 198     ${successor_list} =    BuiltIn.Create_List    @{candidate_list}    # Copy operation is not required, but new variable name requires a line anyway.
 199     Collections.Remove_Values_From_List    ${successor_list}    ${owner}
 200     [Return]    ${owner}    ${successor_list}
 201
 202 Get_Owner_And_Candidates_For_Device_Old
 203     [Arguments]    ${device_name}    ${device_type}    ${member_index}    ${http_timeout}=${EMPTY}
 204     [Documentation]    Returns the owner and a list of candidates for the SB device ${device_name} of type ${device_type}. Request is sent to member ${member_index}.
 205     ...    Candidates are all members that register to own a device, so the list of candiates includes the owner.
 206     ...    The returned candidate list is sorted numerically.
 207     ...    Note that "candidate list" definition currently differs between Beryllium and Boron.
 208     ...    It is recommended to use Get_Owner_And_Successors_For_Device instead of this keyword, see documentation there.
 209     BuiltIn.Comment    TODO: Can this implementation be changed to call Get_Owner_And_Candidates_For_Type_And_Id?
 210     ${session} =    Resolve_Http_Session_For_Member    member_index=${member_index}
 211     ${data} =    TemplatedRequests.Get_As_Json_From_Uri    uri=${ENTITY_OWNER_URI}    session=${session}    http_timeout=${http_timeout}
 212     ${candidate_list} =    BuiltIn.Create_List
 213     ${entity_type} =    BuiltIn.Set_Variable_If    '${device_type}' == 'netconf'    netconf-node/${device_name}    ${device_type}
 214     ${clear_data} =    BuiltIn.Run_Keyword_If    '${device_type}' == 'openflow' or '${device_type}' == 'netconf'    Extract_OpenFlow_Device_Data    ${data}
 215     ...    ELSE IF    '${device_type}' == 'ovsdb'    Extract_Ovsdb_Device_Data    ${data}
 216     ...    ELSE IF    '${device_type}' == 'org.opendaylight.mdsal.ServiceEntityType'    Extract_Service_Entity_Type    ${data}
 217     ...    ELSE    Fail    Not recognized device type: ${device_type}
 218     ${json} =    RequestsLibrary.To_Json    ${clear_data}
 219     ${entity_type_list} =    Collections.Get_From_Dictionary    &{json}[entity-owners]    entity-type
 220     ${entity_type_index} =    Utils.Get_Index_From_List_Of_Dictionaries    ${entity_type_list}    type    ${entity_type}
 221     BuiltIn.Should_Not_Be_Equal_As_Integers    ${entity_type_index}    -1    No Entity Owner found for ${device_type}
 222     ${entity_list} =    Collections.Get_From_Dictionary    @{entity_type_list}[${entity_type_index}]    entity
 223     ${entity_index} =    Utils.Get_Index_From_List_Of_Dictionaries    ${entity_list}    id    ${device_name}
 224     BuiltIn.Should_Not_Be_Equal_As_Integers    ${entity_index}    -1    Device ${device_name} not found in Entity Owner ${device_type}
 225     ${entity_owner} =    Collections.Get_From_Dictionary    @{entity_list}[${entity_index}]    owner
 226     BuiltIn.Should_Not_Be_Empty    ${entity_owner}    No owner found for ${device_name}
 227     ${owner} =    String.Replace_String    ${entity_owner}    member-    ${EMPTY}
 228     ${owner} =    BuiltIn.Convert_To_Integer    ${owner}
 229     ${entity_candidates_list} =    Collections.Get_From_Dictionary    @{entity_list}[${entity_index}]    candidate
 230     : FOR    ${entity_candidate}    IN    @{entity_candidates_list}
 231     \    ${candidate} =    String.Replace_String    &{entity_candidate}[name]    member-    ${EMPTY}
 232     \    ${candidate} =    BuiltIn.Convert_To_Integer    ${candidate}
 233     \    Collections.Append_To_List    ${candidate_list}    ${candidate}
 234     Collections.Sort_List    ${candidate_list}
 235     [Return]    ${owner}    ${candidate_list}
 236
 237 Get_Owner_And_Candidates_For_Device_Singleton
 238     [Arguments]    ${device_name}    ${device_type}    ${member_index}    ${http_timeout}=${EMPTY}
 239     [Documentation]    Returns the owner and a list of candidates for the SB device ${device_name} of type ${device_type}. Request is sent to member ${member_index}.
 240     ...    Parsing method is selected by device type
 241     ...    Separate kw for every supported device type must be defined
 242     BuiltIn.Keyword_Should_Exist    Get_Owner_And_Candidates_For_Device_Singleton_${device_type}
 243     BuiltIn.Run_Keyword_And_Return    Get_Owner_And_Candidates_For_Device_Singleton_${device_type}    ${device_name}    ${member_index}    http_timeout=${http_timeout}
 244
 245 Get_Owner_And_Candidates_For_Device_Singleton_Netconf
 246     [Arguments]    ${device_name}    ${member_index}    ${http_timeout}=${EMPTY}
 247     [Documentation]    Returns the owner and a list of candidates for the SB device ${device_name} of type netconf. Request is sent to member ${member_index}.
 248     ...    Parsing method is set as netconf (using netconf device id prefix and suffix)
 249     # Get election entity type results
 250     ${type} =    BuiltIn.Set_Variable    ${SINGLETON_ELECTION_ENTITY_TYPE}
 251     ${id} =    BuiltIn.Set_Variable    ${SINGLETON_NETCONF_DEVICE_ID_PREFIX}${device_name}${SINGLETON_NETCONF_DEVICE_ID_SUFFIX}
 252     ${owner_1}    ${candidate_list_1} =    Get_Owner_And_Candidates_For_Type_And_Id    ${type}    ${id}    ${member_index}    http_timeout=${http_timeout}
 253     # Get change ownership entity type results
 254     ${type} =    BuiltIn.Set_Variable    ${SINGLETON_CHANGE_OWNERSHIP_ENTITY_TYPE}
 255     ${id} =    BuiltIn.Set_Variable    ${SINGLETON_NETCONF_DEVICE_ID_PREFIX}${device_name}${SINGLETON_NETCONF_DEVICE_ID_SUFFIX}
 256     ${owner_2}    ${candidate_list_2} =    Get_Owner_And_Candidates_For_Type_And_Id    ${type}    ${id}    ${member_index}    http_timeout=${http_timeout}
 257     # Owners must be same, if not, there is still some election or change ownership in progress
 258     BuiltIn.Should_Be_Equal_As_Integers    ${owner_1}    ${owner_2}    Owners for device ${device_name} are not same
 259     [Return]    ${owner_1}    ${candidate_list_1}
 260
 261 Get_Owner_And_Candidates_For_Device
 262     [Arguments]    ${device_name}    ${device_type}    ${member_index}    ${http_timeout}=${EMPTY}
 263     [Documentation]    Returns the owner and a list of candidates for the SB device ${device_name} of type ${device_type}. Request is sent to member ${member_index}.
 264     ...    If parsing as singleton failed, kw try to parse data in old way (without singleton).
 265     ...    Candidates are all members that register to own a device, so the list of candiates includes the owner.
 266     ...    The returned candidate list is sorted numerically.
 267     ...    Note that "candidate list" definition currently differs between Beryllium and Boron.
 268     ...    It is recommended to use Get_Owner_And_Successors_For_Device instead of this keyword, see documentation there.
 269     # Try singleton
 270     ${status}    ${results} =    BuiltIn.Run_Keyword_And_Ignore_Error    Get_Owner_And_Candidates_For_Device_Singleton    device_name=${device_name}    device_type=${device_type}    member_index=${member_index}
 271     ...    http_timeout=${http_timeout}
 272     BuiltIn.Return_From_Keyword_If    "${status}"=="PASS"    ${results}
 273     # If singleton failed, try parsing in old way
 274     ${status}    ${results} =    BuiltIn.Run_Keyword_And_Ignore_Error    Get_Owner_And_Candidates_For_Device_Old    device_name=${device_name}    device_type=${device_type}    member_index=${member_index}
 275     ...    http_timeout=${http_timeout}
 276     # previous 3 lines (BuilIn.Return.., # If singleton..., ${status}....) could be deleted when old way will not be supported anymore
 277     BuiltIn.Run_Keyword_If    '${status}'=='FAIL'    BuiltIn.Fail    Could not parse owner and candidates for device ${device_name}
 278     [Return]    @{results}
 279
 280 Check_Old_Owner_Stays_Elected_For_Device
 281     [Arguments]    ${device_name}    ${device_type}    ${old_owner}    ${node_to_ask}    ${http_timeout}=${EMPTY}
 282     [Documentation]    Verify the owner remain the same as ${old_owner}
 283     ${owner}    ${candidates} =    Get_Owner_And_Candidates_For_Device    ${device_name}    ${device_type}    ${node_to_ask}    http_timeout=${http_timeout}
 284     BuiltIn.Should_Be_Equal_As_numbers    ${old_owner}    ${owner}
 285     BuiltIn.Return_From_Keyword    ${owner}    ${candidates}
 286
 287 Check_New_Owner_Got_Elected_For_Device
 288     [Arguments]    ${device_name}    ${device_type}    ${old_owner}    ${node_to_ask}    ${http_timeout}=${EMPTY}
 289     [Documentation]    Verify new owner was elected comparing to ${old_owner}
 290     ${owner}    ${candidates} =    Get_Owner_And_Candidates_For_Device    ${device_name}    ${device_type}    ${node_to_ask}    http_timeout=${http_timeout}
 291     BuiltIn.Should_Not_Be_Equal_As_Numbers    ${old_owner}    ${owner}
 292     BuiltIn.Return_From_Keyword    ${owner}    ${candidates}
 293
 294 Get_Owner_And_Candidates_For_Type_And_Id
 295     [Arguments]    ${type}    ${id}    ${member_index}    ${require_candidate_list}=${EMPTY}    ${http_timeout}=${EMPTY}
 296     [Documentation]    Returns the owner and a list of candidates for entity specified by ${type} and ${id}
 297     ...    Request is sent to member ${member_index}.
 298     ...    Candidates are all members that register to own a device, so the list of candiates includes the owner.
 299     ...    Bear in mind that for Boron and beyond, candidates are not removed on node down or isolation.
 300     ...    If ${require_candidate_list} is not \${EMPTY}, check whether the actual list of candidates matches.
 301     ...    Note that differs from "given list" semantics used in other keywords,
 302     ...    namely you cannot use \${EMPTY} to stand for "full list" in this keyword.
 303     BuiltIn.Comment    TODO: Find a way to unify and deduplicate code blocks in Get_Owner_And_Candidates_* keywords.
 304     ${session} =    Resolve_Http_Session_For_Member    member_index=${member_index}
 305     ${data} =    TemplatedRequests.Get_As_Json_From_Uri    uri=${ENTITY_OWNER_URI}    session=${session}    http_timeout=${http_timeout}
 306     ${candidate_list} =    BuiltIn.Create_List
 307     ${json} =    RequestsLibrary.To_Json    ${data}
 308     ${entity_type_list} =    Collections.Get_From_Dictionary    &{json}[entity-owners]    entity-type
 309     ${entity_type_index} =    Utils.Get_Index_From_List_Of_Dictionaries    ${entity_type_list}    type    ${type}
 310     BuiltIn.Should_Not_Be_Equal_As_Integers    ${entity_type_index}    -1    No Entity Owner found for ${type}
 311     ${entity_list} =    Collections.Get_From_Dictionary    @{entity_type_list}[${entity_type_index}]    entity
 312     ${entity_index} =    Utils.Get_Index_From_List_Of_Dictionaries    ${entity_list}    id    ${id}
 313     BuiltIn.Should Not_Be_Equal_As_Integers    ${entity_index}    -1    Id ${id} not found in Entity Owner ${type}
 314     ${entity_owner} =    Collections.Get_From_Dictionary    @{entity_list}[${entity_index}]    owner
 315     BuiltIn.Should_Not_Be_Empty    ${entity_owner}    No owner found for type=${type} id=${id}
 316     ${owner} =    String.Replace_String    ${entity_owner}    member-    ${EMPTY}
 317     ${owner} =    BuiltIn.Convert_To_Integer    ${owner}
 318     ${entity_candidates_list} =    Collections.Get_From_Dictionary    @{entity_list}[${entity_index}]    candidate
 319     : FOR    ${entity_candidate}    IN    @{entity_candidates_list}
 320     \    ${candidate} =    String.Replace_String    &{entity_candidate}[name]    member-    ${EMPTY}
 321     \    ${candidate} =    BuiltIn.Convert_To_Integer    ${candidate}
 322     \    Collections.Append_To_List    ${candidate_list}    ${candidate}
 323     Collections.Sort_List    ${candidate_list}
 324     BuiltIn.Comment    TODO: Separate check lines into Verify_Owner_And_Candidates_For_Type_And_Id
 325     BuiltIn.Run_Keyword_If    """${require_candidate_list}"""    BuiltIn.Should_Be_Equal    ${require_candidate_list}    ${candidate_list}    Candidate list does not match: ${candidate_list} is not ${require_candidate_list}
 326     [Return]    ${owner}    ${candidate_list}
 327
 328 Extract_Service_Entity_Type
 329     [Arguments]    ${data}
 330     [Documentation]    Remove superfluous device data from Entity Owner printout.
 331     ${clear_data} =    String.Replace_String    ${data}    /odl-general-entity:entity[odl-general-entity:name='    ${EMPTY}
 332     ${clear_data} =    String.Replace_String    ${clear_data}    -service-group']    ${EMPTY}
 333     Log    ${clear_data}
 334     [Return]    ${clear_data}
 335
 336 Extract_OpenFlow_Device_Data
 337     [Arguments]    ${data}
 338     [Documentation]    Remove superfluous OpenFlow device data from Entity Owner printout.
 339     ${clear_data} =    String.Replace_String    ${data}    org.opendaylight.mdsal.ServiceEntityType    openflow
 340     ${clear_data} =    String.Replace_String    ${clear_data}    /odl-general-entity:entity[odl-general-entity:name='    ${EMPTY}
 341     ${clear_data} =    String.Replace_String    ${clear_data}    /general-entity:entity[general-entity:name='    ${EMPTY}
 342     ${clear_data} =    String.Replace_String    ${clear_data}    ']    ${EMPTY}
 343     Log    ${clear_data}
 344     [Return]    ${clear_data}
 345
 346 Extract_Ovsdb_Device_Data
 347     [Arguments]    ${data}
 348     [Documentation]    Remove superfluous OVSDB device data from Entity Owner printout.
 349     ${clear_data} =    String.Replace_String    ${data}    /network-topology:network-topology/network-topology:topology[network-topology:topology-id='ovsdb:1']/network-topology:node[network-topology:node-id='    ${EMPTY}
 350     ${clear_data} =    String.Replace_String    ${clear_data}    ']    ${EMPTY}
 351     Log    ${clear_data}
 352     [Return]    ${clear_data}
 353
 354 Kill_Single_Member
 355     [Arguments]    ${member}    ${original_index_list}=${EMPTY}    ${confirm}=True
 356     [Documentation]    Convenience keyword that kills the specified member of the cluster.
 357     ...    The KW will return a list of available members: \${updated index_list}=\${original_index_list}-\${member}
 358     ${index_list} =    ClusterManagement__Build_List    ${member}
 359     ${member_ip} =    Return_Member_IP    ${member}
 360     KarafKeywords.Log_Message_To_Controller_Karaf    Killing ODL${member} ${member_ip}
 361     ${updated_index_list} =    Kill_Members_From_List_Or_All    ${index_list}    ${original_index_list}    ${confirm}
 362     [Return]    ${updated_index_list}
 363
 364 Kill_Members_From_List_Or_All
 365     [Arguments]    ${member_index_list}=${EMPTY}    ${original_index_list}=${EMPTY}    ${confirm}=True
 366     [Documentation]    If the list is empty, kill all ODL instances. Otherwise, kill members based on \${kill_index_list}
 367     ...    If \${confirm} is True, sleep 1 second and verify killed instances are not there anymore.
 368     ...    The KW will return a list of available members: \${updated index_list}=\${original_index_list}-\${member_index_list}
 369     ${kill_index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 370     ${index_list} =    List_Indices_Or_All    given_list=${original_index_list}
 371     Run_Bash_Command_On_List_Or_All    command=${NODE_KILL_COMMAND}    member_index_list=${member_index_list}
 372     ${updated_index_list} =    BuiltIn.Create_List    @{index_list}
 373     Collections.Remove_Values_From_List    ${updated_index_list}    @{kill_index_list}
 374     BuiltIn.Return_From_Keyword_If    not ${confirm}    ${updated_index_list}
 375     # TODO: Convert to WUKS with configurable timeout if it turns out 1 second is not enough.
 376     BuiltIn.Sleep    1s    Kill -9 closes open files, which may take longer than ssh overhead, but not long enough to warrant WUKS.
 377     : FOR    ${index}    IN    @{kill_index_list}
 378     \    Verify_Karaf_Is_Not_Running_On_Member    member_index=${index}
 379     Run_Bash_Command_On_List_Or_All    command=netstat -pnatu | grep 2550
 380     [Return]    ${updated_index_list}
 381
 382 Stop_Single_Member
 383     [Arguments]    ${member}    ${original_index_list}=${EMPTY}    ${confirm}=True
 384     [Documentation]    Convenience keyword that stops the specified member of the cluster.
 385     ...    The KW will return a list of available members: \${updated index_list}=\${original_index_list}-\${member}
 386     ${index_list} =    ClusterManagement__Build_List    ${member}
 387     ${updated_index_list} =    Stop_Members_From_List_Or_All    ${index_list}    ${original_index_list}    ${confirm}
 388     [Return]    ${updated_index_list}
 389
 390 Stop_Members_From_List_Or_All
 391     [Arguments]    ${member_index_list}=${EMPTY}    ${original_index_list}=${EMPTY}    ${confirm}=True    ${timeout}=120s
 392     [Documentation]    If the list is empty, stops all ODL instances. Otherwise stop members based on \${stop_index_list}
 393     ...    If \${confirm} is True, verify stopped instances are not there anymore.
 394     ...    The KW will return a list of available members: \${updated index_list}=\${original_index_list}-\${member_index_list}
 395     ${stop_index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 396     ${index_list} =    List_Indices_Or_All    given_list=${original_index_list}
 397     Run_Bash_Command_On_List_Or_All    command=${NODE_STOP_COMMAND}    member_index_list=${member_index_list}
 398     ${updated_index_list} =    BuiltIn.Create_List    @{index_list}
 399     Collections.Remove_Values_From_List    ${updated_index_list}    @{stop_index_list}
 400     BuiltIn.Return_From_Keyword_If    not ${confirm}    ${updated_index_list}
 401     : FOR    ${index}    IN    @{stop_index_list}
 402     \    BuiltIn.Wait Until Keyword Succeeds    ${timeout}    2s    Verify_Karaf_Is_Not_Running_On_Member    member_index=${index}
 403     Run_Bash_Command_On_List_Or_All    command=netstat -pnatu | grep 2550
 404     [Return]    ${updated_index_list}
 405
 406 Start_Single_Member
 407     [Arguments]    ${member}    ${wait_for_sync}=True    ${timeout}=300s
 408     [Documentation]    Convenience keyword that starts the specified member of the cluster.
 409     ${index_list} =    ClusterManagement__Build_List    ${member}
 410     Start_Members_From_List_Or_All    ${index_list}    ${wait_for_sync}    ${timeout}
 411
 412 Start_Members_From_List_Or_All
 413     [Arguments]    ${member_index_list}=${EMPTY}    ${wait_for_sync}=True    ${timeout}=300s    ${karaf_home}=${EMPTY}    ${export_java_home}=${EMPTY}    ${gc_log_dir}=${EMPTY}
 414     [Documentation]    If the list is empty, start all cluster members. Otherwise, start members based on present indices.
 415     ...    If ${wait_for_sync}, wait for cluster sync on listed members.
 416     ...    Optionally karaf_home can be overriden. Optionally specific JAVA_HOME is used for starting.
 417     ...    Garbage collection is unconditionally logged to files. TODO: Make that reasonable conditional?
 418     ${base_command} =    BuiltIn.Set_Variable_If    """${karaf_home}""" != ""    ${karaf_home}/bin/start    ${NODE_START_COMMAND}
 419     ${command} =    BuiltIn.Set_Variable_If    """${export_java_home}""" != ""    export JAVA_HOME="${export_java_home}"; ${base_command}    ${base_command}
 420     ${epoch} =    DateTime.Get_Current_Date    time_zone=UTC    result_format=epoch    exclude_millis=False
 421     ${gc_filepath} =    BuiltIn.Set_Variable_If    """${karaf_home}""" != ""    ${karaf_home}/data/log/gc_${epoch}.log    ${GC_LOG_PATH}/gc_${epoch}.log
 422     ${gc_options} =    BuiltIn.Set_Variable    -XX:+PrintGCDetails -XX:+PrintGCDateStamps -Xloggc:${gc_filepath}
 423     Run_Bash_Command_On_List_Or_All    command=${command} ${gc_options}    member_index_list=${member_index_list}
 424     BuiltIn.Return_From_Keyword_If    not ${wait_for_sync}
 425     BuiltIn.Wait_Until_Keyword_Succeeds    ${timeout}    10s    Check_Cluster_Is_In_Sync    member_index_list=${member_index_list}
 426     # TODO: Do we also want to check Shard Leaders here?
 427     [Teardown]    Run_Bash_Command_On_List_Or_All    command=netstat -pnatu | grep 2550
 428
 429 Freeze_Single_Member
 430     [Arguments]    ${member}
 431     [Documentation]    Convenience keyword that stops the specified member of the cluster by freezing the jvm.
 432     ${index_list} =    ClusterManagement__Build_List    ${member}
 433     Freeze_Or_Unfreeze_Members_From_List_Or_All    ${NODE_FREEZE_COMMAND}    ${index_list}
 434
 435 Unfreeze_Single_Member
 436     [Arguments]    ${member}    ${wait_for_sync}=True    ${timeout}=60s
 437     [Documentation]    Convenience keyword that "continues" the specified member of the cluster by unfreezing the jvm.
 438     ${index_list} =    ClusterManagement__Build_List    ${member}
 439     Freeze_Or_Unfreeze_Members_From_List_Or_All    ${NODE_UNFREEZE_COMMAND}    ${index_list}
 440     BuiltIn.Wait_Until_Keyword_Succeeds    ${timeout}    10s    Check_Cluster_Is_In_Sync
 441
 442 Freeze_Or_Unfreeze_Members_From_List_Or_All
 443     [Arguments]    ${command}    ${member_index_list}=${EMPTY}
 444     [Documentation]    If the list is empty, stops/runs all ODL instances. Otherwise stop/run members based on \${stop_index_list}
 445     ...    For command parameter only ${NODE_FREEZE_COMMAND} and ${NODE_UNFREEZE_COMMAND} should be used
 446     ${freeze_index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 447     Run_Bash_Command_On_List_Or_All    command=${command}    member_index_list=${member_index_list}
 448
 449 Clean_Journals_And_Snapshots_On_List_Or_All
 450     [Arguments]    ${member_index_list}=${EMPTY}    ${karaf_home}=${KARAF_HOME}
 451     [Documentation]    Delete journal and snapshots directories on every node listed (or all).
 452     ...    BEWARE: If only a subset of members is cleaned, this causes RetiredGenerationException in Carbon after the affected node re-start.
 453     ...    See https://bugs.opendaylight.org/show_bug.cgi?id=8138
 454     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 455     ${command} =    Set Variable    rm -rf "${karaf_home}/journal" "${karaf_home}/snapshots"
 456     : FOR    ${index}    IN    @{index_list}    # usually: 1, 2, 3.
 457     \    Run_Bash_Command_On_Member    command=${command}    member_index=${index}
 458
 459 Verify_Karaf_Is_Not_Running_On_Member
 460     [Arguments]    ${member_index}
 461     [Documentation]    Fail if non-zero karaf instances are counted on member of given index.
 462     ${count} =    Count_Running_Karafs_On_Member    member_index=${member_index}
 463     BuiltIn.Should_Be_Equal    0    ${count}    Found running Karaf count: ${count}
 464
 465 Verify_Single_Karaf_Is_Running_On_Member
 466     [Arguments]    ${member_index}
 467     [Documentation]    Fail if number of karaf instances on member of given index is not one.
 468     ${count} =    Count_Running_Karafs_On_Member    member_index=${member_index}
 469     BuiltIn.Should_Be_Equal    1    ${count}    Wrong number of Karafs running: ${count}
 470
 471 Count_Running_Karafs_On_Member
 472     [Arguments]    ${member_index}
 473     [Documentation]    Remotely execute grep for karaf process, return count as string.
 474     ${command} =    BuiltIn.Set_Variable    ps axf | grep org.apache.karaf | grep -v grep | wc -l
 475     ${count} =    Run_Bash_Command_On_Member    command=${command}    member_index=${member_index}
 476     [Return]    ${count}
 477
 478 Isolate_Member_From_List_Or_All
 479     [Arguments]    ${isolate_member_index}    ${member_index_list}=${EMPTY}
 480     [Documentation]    If the list is empty, isolate member from all ODL instances. Otherwise, isolate member based on present indices.
 481     ...    The KW will return a list of available members: \${updated index_list}=\${member_index_list}-\${isolate_member_index}
 482     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 483     ${source} =    Collections.Get_From_Dictionary    ${ClusterManagement__index_to_ip_mapping}    ${isolate_member_index}
 484     : FOR    ${index}    IN    @{index_list}
 485     \    ${destination} =    Collections.Get_From_Dictionary    ${ClusterManagement__index_to_ip_mapping}    ${index}
 486     \    ${command} =    BuiltIn.Set_Variable    sudo /sbin/iptables -I OUTPUT -p all --source ${source} --destination ${destination} -j DROP
 487     \    BuiltIn.Run_Keyword_If    "${index}" != "${isolate_member_index}"    Run_Bash_Command_On_Member    command=${command}    member_index=${isolate_member_index}
 488     ${command} =    BuiltIn.Set_Variable    sudo /sbin/iptables -L -n
 489     ${output} =    Run_Bash_Command_On_Member    command=${command}    member_index=${isolate_member_index}
 490     BuiltIn.Log    ${output}
 491     ${updated_index_list} =    BuiltIn.Create_List    @{index_list}
 492     Collections.Remove_Values_From_List    ${updated_index_list}    ${isolate_member_index}
 493     [Return]    ${updated_index_list}
 494
 495 Rejoin_Member_From_List_Or_All
 496     [Arguments]    ${rejoin_member_index}    ${member_index_list}=${EMPTY}
 497     [Documentation]    If the list is empty, rejoin member from all ODL instances. Otherwise, rejoin member based on present indices.
 498     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 499     ${source} =    Collections.Get_From_Dictionary    ${ClusterManagement__index_to_ip_mapping}    ${rejoin_member_index}
 500     : FOR    ${index}    IN    @{index_list}
 501     \    ${destination} =    Collections.Get_From_Dictionary    ${ClusterManagement__index_to_ip_mapping}    ${index}
 502     \    ${command} =    BuiltIn.Set_Variable    sudo /sbin/iptables -D OUTPUT -p all --source ${source} --destination ${destination} -j DROP
 503     \    BuiltIn.Run_Keyword_If    "${index}" != "${rejoin_member_index}"    Run_Bash_Command_On_Member    command=${command}    member_index=${rejoin_member_index}
 504     ${command} =    BuiltIn.Set_Variable    sudo /sbin/iptables -L -n
 505     ${output} =    Run_Bash_Command_On_Member    command=${command}    member_index=${rejoin_member_index}
 506     BuiltIn.Log    ${output}
 507
 508 Flush_Iptables_From_List_Or_All
 509     [Arguments]    ${member_index_list}=${EMPTY}
 510     [Documentation]    If the list is empty, flush IPTables in all ODL instances. Otherwise, flush member based on present indices.
 511     ${command} =    BuiltIn.Set_Variable    sudo iptables -v -F
 512     ${output} =    Run_Bash_Command_On_List_Or_All    command=${command}    member_index_list=${member_index_list}
 513
 514 Check_Bash_Command_On_List_Or_All
 515     [Arguments]    ${command}    ${member_index_list}=${EMPTY}    ${return_success_only}=False    ${log_on_success}=True    ${log_on_failure}=True    ${stderr_must_be_empty}=True
 516     [Documentation]    Cycle through indices (or all), run bash command on each, using temporary SSH session and restoring the previously active one.
 517     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 518     : FOR    ${index}    IN    @{index_list}
 519     \    Check_Bash_Command_On_Member    command=${command}    member_index=${index}    return_success_only=${return_success_only}    log_on_success=${log_on_success}    log_on_failure=${log_on_failure}
 520     \    ...    stderr_must_be_empty=${stderr_must_be_empty}
 521
 522 Check_Bash_Command_On_Member
 523     [Arguments]    ${command}    ${member_index}    ${return_success_only}=False    ${log_on_success}=True    ${log_on_failure}=True    ${stderr_must_be_empty}=True
 524     [Documentation]    Open SSH session, call SSHKeywords.Execute_Command_Passes, close session, restore previously active session and return output.
 525     BuiltIn.Run_Keyword_And_Return    SSHKeywords.Run_Keyword_Preserve_Connection    Check_Unsafely_Bash_Command_On_Member    ${command}    ${member_index}    return_success_only=${return_success_only}    log_on_success=${log_on_success}
 526     ...    log_on_failure=${log_on_failure}    stderr_must_be_empty=${stderr_must_be_empty}
 527
 528 Check_Unsafely_Bash_Command_On_Member
 529     [Arguments]    ${command}    ${member_index}    ${return_success_only}=False    ${log_on_success}=True    ${log_on_failure}=True    ${stderr_must_be_empty}=True
 530     [Documentation]    Obtain Ip address, open session, call SSHKeywords.Execute_Command_Passes, close session and return output. This affects which SSH session is active.
 531     ${member_ip} =    Resolve_Ip_Address_For_Member    ${member_index}
 532     BuiltIn.Run_Keyword_And_Return    SSHKeywords.Run_Unsafely_Keyword_Over_Temporary_Odl_Session    ${member_ip}    Execute_Command_Passes    ${command}    return_success_only=${return_success_only}    log_on_success=${log_on_success}
 533     ...    log_on_failure=${log_on_failure}    stderr_must_be_empty=${stderr_must_be_empty}
 534
 535 Run_Bash_Command_On_List_Or_All
 536     [Arguments]    ${command}    ${member_index_list}=${EMPTY}
 537     [Documentation]    Cycle through indices (or all), run command on each.
 538     # TODO: Migrate callers to Check_Bash_Command_*
 539     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 540     : FOR    ${index}    IN    @{index_list}
 541     \    Run_Bash_Command_On_Member    command=${command}    member_index=${index}
 542
 543 Run_Bash_Command_On_Member
 544     [Arguments]    ${command}    ${member_index}
 545     [Documentation]    Obtain IP, call Utils and return output. This keeps previous ssh session active.
 546     # TODO: Migrate callers to Check_Bash_Command_*
 547     ${member_ip} =    Collections.Get_From_Dictionary    dictionary=${ClusterManagement__index_to_ip_mapping}    key=${member_index}
 548     ${output} =    SSHKeywords.Run_Keyword_Preserve_Connection    Utils.Run_Command_On_Controller    ${member_ip}    ${command}
 549     Log    ${output}
 550     [Return]    ${output}
 551
 552 Run_Karaf_Command_On_List_Or_All
 553     [Arguments]    ${command}    ${member_index_list}=${EMPTY}    ${timeout}=10s
 554     [Documentation]    Cycle through indices (or all), run karaf command on each.
 555     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 556     : FOR    ${index}    IN    @{index_list}
 557     \    ${member_ip} =    Collections.Get_From_Dictionary    dictionary=${ClusterManagement__index_to_ip_mapping}    key=${index}
 558     \    KarafKeywords.Safe_Issue_Command_On_Karaf_Console    ${command}    ${member_ip}    timeout=${timeout}
 559
 560 Run_Karaf_Command_On_Member
 561     [Arguments]    ${command}    ${member_index}    ${timeout}=10s
 562     [Documentation]    Obtain IP address, call KarafKeywords and return output. This does not preserve active ssh session.
 563     ...    This keyword is not used by Run_Karaf_Command_On_List_Or_All, but returned output may be useful.
 564     ${member_ip} =    Collections.Get_From_Dictionary    dictionary=${ClusterManagement__index_to_ip_mapping}    key=${member_index}
 565     ${output} =    KarafKeywords.Safe_Issue_Command_On_Karaf_Console    ${command}    controller=${member_ip}    timeout=${timeout}
 566     [Return]    ${output}
 567
 568 Install_Feature_On_List_Or_All
 569     [Arguments]    ${feature_name}    ${member_index_list}=${EMPTY}    ${timeout}=60s
 570     [Documentation]    Attempt installation on each member from list (or all). Then look for failures.
 571     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 572     ${status_list} =    BuiltIn.Create_List
 573     : FOR    ${index}    IN    @{index_list}
 574     \    ${status}    ${text} =    BuiltIn.Run_Keyword_And_Ignore_Error    Install_Feature_On_Member    feature_name=${feature_name}    member_index=${index}
 575     \    ...    timeout=${timeout}
 576     \    BuiltIn.Log    ${text}
 577     \    Collections.Append_To_List    ${status_list}    ${status}
 578     : FOR    ${status}    IN    @{status_list}
 579     \    BuiltIn.Run_Keyword_If    "${status}" != "PASS"    BuiltIn.Fail    ${feature_name} installation failed, see log.
 580
 581 Install_Feature_On_Member
 582     [Arguments]    ${feature_name}    ${member_index}    ${timeout}=60s
 583     [Documentation]    Run feature:install karaf command, fail if installation was not successful. Return output.
 584     ${status}    ${output} =    BuiltIn.Run_Keyword_And_Ignore_Error    Run_Karaf_Command_On_Member    command=feature:install ${feature_name}    member_index=${member_index}    timeout=${timeout}
 585     BuiltIn.Run_Keyword_If    "${status}" != "PASS"    BuiltIn.Fail    Failed to install ${feature_name}: ${output}
 586     BuiltIn.Should_Not_Contain    ${output}    Can't install    Failed to install ${feature_name}: ${output}
 587     [Return]    ${output}
 588
 589 With_Ssh_To_List_Or_All_Run_Keyword
 590     [Arguments]    ${member_index_list}    ${keyword_name}    @{args}    &{kwargs}
 591     [Documentation]    For each index in given list (or all): activate SSH connection, run given Keyword, close active connection. Return None.
 592     ...    Beware that in order to avoid "got positional argument after named arguments", first two arguments in the call should not be named.
 593     BuiltIn.Comment    This keyword is experimental and there is high risk of being replaced by another approach.
 594     # TODO: For_Index_From_List_Or_All_Run_Keyword applied to With_Ssh_To_Member_Run_Keyword?
 595     # TODO: Imagine another keyword, using ScalarClosures and adding member index as first argument for each call. Worth it?
 596     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 597     : FOR    ${member_index}    IN    @{index_list}
 598     \    ${member_ip} =    Resolve_IP_Address_For_Member    ${member_index}
 599     \    SSHKeywords.Run_Unsafely_Keyword_Over_Temporary_Odl_Session    ${member_ip}    ${keyword_name}    @{args}    &{kwargs}
 600
 601 Safe_With_Ssh_To_List_Or_All_Run_Keyword
 602     [Arguments]    ${member_index_list}    ${keyword_name}    @{args}    &{kwargs}
 603     [Documentation]    Remember active ssh connection index, call With_Ssh_To_List_Or_All_Run_Keyword, return None. Restore the conection index on teardown.
 604     SSHKeywords.Run_Keyword_Preserve_Connection    With_Ssh_To_List_Or_All_Run_Keyword    ${member_index_list}    ${keyword_name}    @{args}    &{kwargs}
 605
 606 Clean_Directories_On_List_Or_All
 607     [Arguments]    ${member_index_list}=${EMPTY}    ${directory_list}=${EMPTY}    ${karaf_home}=${KARAF_HOME}    ${tmp_dir}=${EMPTY}
 608     [Documentation]    Clear @{directory_list} or @{ODL_DEFAULT_DATA_PATHS} for members in given list or all. Return None.
 609     ...    If \${tmp_dir} is nonempty, use that location to preserve data/log/.
 610     ...    This is intended to return Karaf (offline) to the state it was upon the first boot.
 611     ${path_list} =    Builtin.Set Variable If    "${directory_list}" == "${EMPTY}"    ${ODL_DEFAULT_DATA_PATHS}    ${directory_list}
 612     BuiltIn.Run_Keyword_If    """${tmp_dir}""" != ""    Check_Bash_Command_On_List_Or_All    mkdir -p '${tmp_dir}' && rm -vrf '${tmp_dir}/log' && mv -vf '${karaf_home}/data/log' '${tmp_dir}/'    ${member_index_list}
 613     Safe_With_Ssh_To_List_Or_All_Run_Keyword    ${member_index_list}    ClusterManagement__Clean_Directories    ${path_list}    ${karaf_home}
 614     BuiltIn.Run_Keyword_If    """${tmp_dir}""" != ""    Check_Bash_Command_On_List_Or_All    mkdir -p '${karaf_home}/data' && rm -vrf '${karaf_home}/log' && mv -vf '${tmp_dir}/log' '${karaf_home}/data/'    ${member_index_list}
 615
 616 Store_Karaf_Log_On_List_Or_All
 617     [Arguments]    ${member_index_list}=${EMPTY}    ${dst_dir}=/tmp    ${karaf_home}=${KARAF_HOME}
 618     [Documentation]    Saves karaf.log to the ${dst_dir} for members in given list or all. Return None.
 619     Safe_With_Ssh_To_List_Or_All_Run_Keyword    ${member_index_list}    SSHKeywords.Execute_Command_Should_Pass    cp ${karaf_home}/data/log/karaf.log ${dst_dir}
 620
 621 Restore_Karaf_Log_On_List_Or_All
 622     [Arguments]    ${member_index_list}=${EMPTY}    ${src_dir}=/tmp    ${karaf_home}=${KARAF_HOME}
 623     [Documentation]    Places stored karaf.log to the ${karaf_home}/data/log for members in given list or all. Return None.
 624     Safe_With_Ssh_To_List_Or_All_Run_Keyword    ${member_index_list}    SSHKeywords.Execute_Command_Should_Pass    cp ${src_dir}/karaf.log ${karaf_home}/data/log/
 625
 626 ClusterManagement__Clean_Directories
 627     [Arguments]    ${relative_path_list}    ${karaf_home}
 628     [Documentation]    For each relative path, remove files with respect to ${karaf_home}. Return None.
 629     : FOR    ${relative_path}    IN    @{relative_path_list}
 630     \    SSHLibrary.Execute_Command    rm -rf ${karaf_home}${/}${relative_path}
 631
 632 Put_As_Json_And_Check_Member_List_Or_All
 633     [Arguments]    ${uri}    ${data}    ${member_index}    ${member_index_list}=${EMPTY}
 634     [Documentation]    Send a PUT with the supplied uri ${uri} and body ${data} to member ${member_index}.
 635     ...    Then check data is replicated in all or some members defined in ${member_index_list}.
 636     ${response_text} =    Put_As_Json_To_Member    uri=${uri}    data=${data}    member_index=${member_index}
 637     Wait Until Keyword Succeeds    5s    1s    Check_Json_Member_List_Or_All    uri=${uri}    expected_data=${data}    member_index_list=${member_index_list}
 638     [Return]    ${response_text}
 639
 640 Put_As_Json_To_Member
 641     [Arguments]    ${uri}    ${data}    ${member_index}
 642     [Documentation]    Send a PUT with the supplied uri and data to member ${member_index}.
 643     ${session} =    Resolve_Http_Session_For_Member    member_index=${member_index}
 644     ${response_text} =    TemplatedRequests.Put_As_Json_To_Uri    uri=${uri}    data=${data}    session=${session}
 645     [Return]    ${response_text}
 646
 647 Post_As_Json_To_Member
 648     [Arguments]    ${uri}    ${data}    ${member_index}
 649     [Documentation]    Send a POST with the supplied uri and data to member ${member_index}.
 650     ${session} =    Resolve_Http_Session_For_Member    member_index=${member_index}
 651     ${response_text} =    TemplatedRequests.Post_As_Json_To_Uri    uri=${uri}    data=${data}    session=${session}
 652     [Return]    ${response_text}
 653
 654 Delete_And_Check_Member_List_Or_All
 655     [Arguments]    ${uri}    ${member_index}    ${member_index_list}=${EMPTY}
 656     [Documentation]    Send a DELETE with the supplied uri to the member ${member_index}.
 657     ...    Then check the data is removed from all members in ${member_index_list}.
 658     ${response_text} =    Delete_From_Member    ${uri}    ${member_index}
 659     BuiltIn.Wait_Until_Keyword_Succeeds    5s    1s    Check_No_Content_Member_List_Or_All    uri=${uri}    member_index_list=${member_index_list}
 660     [Return]    ${response_text}
 661
 662 Delete_From_Member
 663     [Arguments]    ${uri}    ${member_index}
 664     [Documentation]    Send a DELETE with the supplied uri to member ${member_index}.
 665     ${session} =    Resolve_Http_Session_For_Member    member_index=${member_index}
 666     ${response_text} =    TemplatedRequests.Delete_From_Uri    uri=${uri}    session=${session}
 667     [Return]    ${response_text}
 668
 669 Check_Json_Member_List_Or_All
 670     [Arguments]    ${uri}    ${expected_data}    ${member_index_list}=${EMPTY}
 671     [Documentation]    Send a GET with the supplied uri to all or some members defined in ${member_index_list}.
 672     ...    Then check received data is = ${expected data}.
 673     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 674     : FOR    ${index}    IN    @{index_list}
 675     \    ${data} =    Get_From_Member    uri=${uri}    member_index=${index}
 676     \    TemplatedRequests.Normalize_Jsons_And_Compare    ${expected_data}    ${data}
 677
 678 Check_Item_Occurrence_Member_List_Or_All
 679     [Arguments]    ${uri}    ${dictionary}    ${member_index_list}=${EMPTY}
 680     [Documentation]    Send a GET with the supplied uri to all or some members defined in ${member_index_list}.
 681     ...    Then check received for occurrences of items expressed in a dictionary ${dictionary}.
 682     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 683     : FOR    ${index}    IN    @{index_list}
 684     \    ${data} =    Get_From_Member    uri=${uri}    member_index=${index}
 685     \    Utils.Check Item Occurrence    ${data}    ${dictionary}
 686
 687 Check_No_Content_Member_List_Or_All
 688     [Arguments]    ${uri}    ${member_index_list}=${EMPTY}
 689     [Documentation]    Send a GET with the supplied uri to all or some members defined in ${member_index_list}.
 690     ...    Then check there is no content.
 691     ${index_list} =    List_Indices_Or_All    given_list=${member_index_list}
 692     : FOR    ${index}    IN    @{index_list}
 693     \    ${session} =    Resolve_Http_Session_For_Member    member_index=${index}
 694     \    Utils.No_Content_From_URI    ${session}    ${uri}
 695
 696 Get_From_Member
 697     [Arguments]    ${uri}    ${member_index}    ${access}=${ACCEPT_EMPTY}
 698     [Documentation]    Send a GET with the supplied uri to member ${member_index}.
 699     ${session} =    Resolve_Http_Session_For_Member    member_index=${member_index}
 700     ${response_text} =    TemplatedRequests.Get_From_Uri    uri=${uri}    accept=${access}    session=${session}
 701     [Return]    ${response_text}
 702
 703 Resolve_IP_Address_For_Member
 704     [Arguments]    ${member_index}
 705     [Documentation]    Return node IP address of given index.
 706     ${ip_address} =    Collections.Get From Dictionary    dictionary=${ClusterManagement__index_to_ip_mapping}    key=${member_index}
 707     [Return]    ${ip_address}
 708
 709 Resolve_IP_Address_For_Members
 710     [Arguments]    ${member_index_list}
 711     [Documentation]    Return a list of IP address of given indexes.
 712     ${member_ip_list} =    BuiltIn.Create_List
 713     : FOR    ${index}    IN    @{member_index_list}
 714     \    ${ip_address} =    Collections.Get From Dictionary    dictionary=${ClusterManagement__index_to_ip_mapping}    key=${index}
 715     \    Collections.Append_To_List    ${member_ip_list}    ${ip_address}
 716     [Return]    ${member_ip_list}
 717
 718 Resolve_Http_Session_For_Member
 719     [Arguments]    ${member_index}
 720     [Documentation]    Return RequestsLibrary session alias pointing to node of given index.
 721     ${session} =    BuiltIn.Set_Variable    ClusterManagement__session_${member_index}
 722     [Return]    ${session}
 723
 724 Resolve_Shard_Type_Class
 725     [Arguments]    ${shard_type}
 726     [Documentation]    Simple lookup for class name corresponding to desired type.
 727     BuiltIn.Run_Keyword_If    '${shard_type}' == 'config'    BuiltIn.Return_From_Keyword    DistributedConfigDatastore
 728     ...    ELSE IF    '${shard_type}' == 'operational'    BuiltIn.Return_From_Keyword    DistributedOperationalDatastore
 729     BuiltIn.Fail    Unrecognized shard type: ${shard_type}
 730
 731 ClusterManagement__Build_List
 732     [Arguments]    ${member}
 733     ${member_int} =    BuiltIn.Convert_To_Integer    ${member}
 734     ${index_list} =    BuiltIn.Create_List    ${member_int}
 735     [Return]    ${index_list}
 736
 737 ClusterManagement__Parse_Sync_Status
 738     [Arguments]    ${shard_manager_text}
 739     [Documentation]    Return sync status parsed out of given text. Called twice by Get_Sync_Status_Of_Member.
 740     BuiltIn.Log    ${shard_manager_text}
 741     ${manager_object} =    RequestsLibrary.To_Json    ${shard_manager_text}
 742     ${value_object} =    Collections.Get_From_Dictionary    dictionary=${manager_object}    key=value
 743     ${sync_status} =    Collections.Get_From_Dictionary    dictionary=${value_object}    key=SyncStatus
 744     [Return]    ${sync_status}
 745
 746 List_All_Indices
 747     [Documentation]    Create a new list of all indices.
 748     BuiltIn.Run_Keyword_And_Return    List_Indices_Or_All
 749
 750 List_Indices_Or_All
 751     [Arguments]    ${given_list}=${EMPTY}
 752     [Documentation]    Utility to allow \${EMPTY} as default argument value, as the internal list is computed at runtime.
 753     ...    This keyword always returns a (shallow) copy of given or default list,
 754     ...    so operations with the returned list should not affect other lists.
 755     ...    Also note that this keyword does not consider empty list to be \${EMPTY}.
 756     ${return_list_reference} =    BuiltIn.Set_Variable_If    """${given_list}""" != ""    ${given_list}    ${ClusterManagement__member_index_list}
 757     ${return_list_copy} =    BuiltIn.Create_List    @{return_list_reference}
 758     [Return]    ${return_list_copy}
 759
 760 List_Indices_Minus_Member
 761     [Arguments]    ${member_index}    ${member_index_list}=${EMPTY}
 762     [Documentation]    Create a new list which contains indices from ${member_index_list} (or all) without ${member_index}.
 763     ${index_list} =    List_Indices_Or_All    ${member_index_list}
 764     Collections.Remove Values From List    ${index_list}    ${member_index}
 765     [Return]    ${index_list}
 766
 767 ClusterManagement__Compute_Derived_Variables
 768     [Arguments]    ${int_of_members}    ${http_timeout}=1    ${http_retries}=0
 769     [Documentation]    Construct index list, session list and IP mapping, publish them as suite variables.
 770     @{member_index_list} =    BuiltIn.Create_List
 771     @{session_list} =    BuiltIn.Create_List
 772     &{index_to_ip_mapping} =    BuiltIn.Create_Dictionary
 773     : FOR    ${index}    IN RANGE    1    ${int_of_members+1}
 774     \    ClusterManagement__Include_Member_Index    ${index}    ${member_index_list}    ${session_list}    ${index_to_ip_mapping}    http_timeout=${http_timeout}
 775     \    ...    http_retries=${http_retries}
 776     BuiltIn.Set_Suite_Variable    \${ClusterManagement__member_index_list}    ${member_index_list}
 777     BuiltIn.Set_Suite_Variable    \${ClusterManagement__index_to_ip_mapping}    ${index_to_ip_mapping}
 778     BuiltIn.Set_Suite_Variable    \${ClusterManagement__session_list}    ${session_list}
 779
 780 ClusterManagement__Include_Member_Index
 781     [Arguments]    ${index}    ${member_index_list}    ${session_list}    ${index_to_ip_mapping}    ${http_timeout}=1    ${http_retries}=0
 782     [Documentation]    Add a corresponding item based on index into the last three arguments.
 783     ...    Create the Http session whose alias is added to list.
 784     Collections.Append_To_List    ${member_index_list}    ${index}
 785     ${member_ip} =    BuiltIn.Set_Variable    ${ODL_SYSTEM_${index}_IP}
 786     # ${index} is int (not string) so "key=value" syntax does not work in the following line.
 787     Collections.Set_To_Dictionary    ${index_to_ip_mapping}    ${index}    ${member_ip}
 788     # Http session, with ${AUTH}, without headers.
 789     ${session_alias} =    Resolve_Http_Session_For_Member    member_index=${index}
 790     RequestsLibrary.Create_Session    ${session_alias}    http://${member_ip}:${RESTCONFPORT}    auth=${AUTH}    timeout=${http_timeout}    max_retries=${http_retries}
 791     Collections.Append_To_List    ${session_list}    ${session_alias}
 792
 793 Sync_Status_Should_Be_False
 794     [Arguments]    ${controller_index}
 795     [Documentation]    Verify that cluster node is not in sync with others
 796     ${status}    Get_Sync_Status_Of_Member    ${controller_index}
 797     BuiltIn.Should_Not_Be_True    ${status}
 798
 799 Sync_Status_Should_Be_True
 800     [Arguments]    ${controller_index}
 801     [Documentation]    Verify that cluster node is in sync with others
 802     ${status}    Get_Sync_Status_Of_Member    ${controller_index}
 803     BuiltIn.Should_Be_True    ${status}
 804
 805 Return_Member_IP
 806     [Arguments]    ${member_index}
 807     [Documentation]    Return the IP address of the member given the member_index.
 808     ${member_int} =    BuiltIn.Convert_To_Integer    ${member_index}
 809     ${member_ip} =    Collections.Get_From_Dictionary    dictionary=${ClusterManagement__index_to_ip_mapping}    key=${member_int}
 810     [Return]    ${member_ip}