csit/libraries/NetconfKeywords.robot

   1 *** Settings ***
   2 Documentation     Perform complex operations on netconf.
   3 ...
   4 ...               Copyright (c) 2015 Cisco Systems, Inc. and others. All rights reserved.
   5 ...
   6 ...               This program and the accompanying materials are made available under the
   7 ...               terms of the Eclipse Public License v1.0 which accompanies this distribution,
   8 ...               and is available at http://www.eclipse.org/legal/epl-v10.html
   9 ...
  10 ...
  11 ...               This library encapsulates a bunch of somewhat complex and commonly used
  12 ...               netconf operations into reusable keywords to make writing netconf
  13 ...               test suites easier.
  14 Library           Collections
  15 Library           RequestsLibrary
  16 Resource          NetconfViaRestconf.robot
  17 Resource          SSHKeywords.robot
  18
  19 *** Variables ***
  20 ${DIRECTORY_WITH_DEVICE_TEMPLATES}    ${CURDIR}/../variables/netconf/device
  21 ${FIRST_TESTTOOL_PORT}    17830
  22 ${BASE_NETCONF_DEVICE_PORT}    17830
  23 ${DEVICE_NAME_BASE}    netconf-scaling-device
  24
  25 *** Keywords ***
  26 Setup_NetconfKeywords
  27     [Documentation]    Setup the environment for the other keywords of this Resource to work properly.
  28     ${tmp}=    BuiltIn.Create_Dictionary
  29     BuiltIn.Set_Suite_Variable    ${NetconfKeywords__mounted_device_types}    ${tmp}
  30     NetconfViaRestconf.Setup_Netconf_Via_Restconf
  31
  32 Configure_Device_In_Netconf
  33     [Arguments]    ${device_name}    ${device_type}=default    ${device_port}=${FIRST_TESTTOOL_PORT}
  34     [Documentation]    Tell Netconf about the specified device so it can add it into its configuration.
  35     ${template_as_string}=    BuiltIn.Set_Variable    {'DEVICE_IP': '${TOOLS_SYSTEM_IP}', 'DEVICE_NAME': '${device_name}', 'DEVICE_PORT': '${device_port}'}
  36     NetconfViaRestconf.Put_Xml_Template_Folder_Via_Restconf    ${DIRECTORY_WITH_DEVICE_TEMPLATES}${/}${device_type}    ${template_as_string}
  37     Collections.Set_To_Dictionary    ${NetconfKeywords__mounted_device_types}    ${device_name}    ${device_type}
  38
  39 Count_Netconf_Connectors_For_Device
  40     [Arguments]    ${device_name}
  41     [Documentation]    Count all Netconf connectors referring to the specified device (usually 0 or 1).
  42     ${mounts}=    Utils.Get_Data_From_URI    operational    network-topology:network-topology/topology/topology-netconf
  43     Builtin.Log    ${mounts}
  44     ${actual_count}=    Builtin.Evaluate    len('''${mounts}'''.split('"node-id":"${device_name}"'))-1
  45     Builtin.Return_From_Keyword    ${actual_count}
  46
  47 Check_Device_Has_No_Netconf_Connector
  48     [Arguments]    ${device_name}
  49     [Documentation]    Check that there are no Netconf connectors referring to the specified device.
  50     ${count}    Count_Netconf_Connectors_For_Device    ${device_name}
  51     Builtin.Should_Be_Equal_As_Strings    ${count}    0
  52
  53 Check_Device_Completely_Gone
  54     [Arguments]    ${device_name}
  55     [Documentation]    Check that the specified device has no Netconf connectors nor associated data.
  56     Check_Device_Has_No_Netconf_Connector    ${device_name}
  57     ${uri}=    Builtin.Set_Variable    network-topology:network-topology/topology/topology-netconf/node/${device_name}
  58     ${response}=    RequestsLibrary.Get Request    nvr_session    ${uri}    ${ACCEPT_XML}
  59     BuiltIn.Should_Be_Equal_As_Integers    ${response.status_code}    404
  60
  61 Check_Device_Connected
  62     [Arguments]    ${device_name}
  63     [Documentation]    Check that the specified device is accessible from Netconf.
  64     ${device_status}=    Utils.Get_Data_From_URI    operational    network-topology:network-topology/topology/topology-netconf/node/${device_name}
  65     Builtin.Should_Contain    ${device_status}    "netconf-node-topology:connection-status":"connected"
  66
  67 Wait_Device_Connected
  68     [Arguments]    ${device_name}    ${timeout}=10s    ${period}=1s
  69     [Documentation]    Wait for the device to become connected.
  70     ...    It is more readable to use this keyword in a test case than to put the whole WUKS below into it.
  71     BuiltIn.Wait_Until_Keyword_Succeeds    ${timeout}    ${period}    Check_Device_Connected    ${device_name}
  72
  73 Remove_Device_From_Netconf
  74     [Arguments]    ${device_name}
  75     [Documentation]    Tell Netconf to deconfigure the specified device
  76     ${device_type}=    Collections.Pop_From_Dictionary    ${NetconfKeywords__mounted_device_types}    ${device_name}
  77     ${template_as_string}=    BuiltIn.Set_Variable    {'DEVICE_NAME': '${device_name}'}
  78     NetconfViaRestconf.Delete_Xml_Template_Folder_Via_Restconf    ${DIRECTORY_WITH_DEVICE_TEMPLATES}${/}${device_type}    ${template_as_string}
  79
  80 Wait_Device_Fully_Removed
  81     [Arguments]    ${device_name}    ${timeout}=10s    ${period}=1s
  82     [Documentation]    Wait until all netconf connectors for the device with the given name disappear.
  83     ...    Call of Remove_Device_From_Netconf returns before netconf gets
  84     ...    around deleting the device's connector. To ensure the device is
  85     ...    really gone from netconf, use this keyword to make sure all
  86     ...    connectors disappear. If a call to Remove_Device_From_Netconf
  87     ...    is not made before using this keyword, the wait will fail.
  88     ...    Using this keyword is more readable than putting the WUKS below
  89     ...    into a test case.
  90     BuiltIn.Wait_Until_Keyword_Succeeds    ${timeout}    ${period}    Check_Device_Completely_Gone    ${device_name}
  91
  92 NetconfKeywords__Deploy_Additional_Schemas
  93     [Arguments]    ${schemas}
  94     [Documentation]    Internal keyword for Install_And_Start_TestTool
  95     ...    This deploys the additional schemas if any and returns a
  96     ...    command line argument to be added to the testtool commandline
  97     ...    to tell it to load them. While this code could be integrated
  98     ...    into its only user, I considered the resulting code to be too
  99     ...    unreadable as the actions are quite different in the two
 100     ...    possibilities (additional schemas present versus no additional
 101     ...    schemas present), therefore a separate keyword is used.
 102     # Make sure there is no schemas directory on the remote machine. A
 103     # previous test suite might have left some debris there and that might
 104     # lead to spurious failures, so it is better to make sure we start with a
 105     # clean slate. Additionally when the caller did not specify any
 106     # additional schemas for testtool, we want to make extra sure none are
 107     # used.
 108     ${response}=    SSHLibrary.Execute_Command    rm -rf schemas 2>&1
 109     BuiltIn.Log    ${response}
 110     # Drop out of the keyword, returning no command line argument when there
 111     # are no additional schemas to deploy.
 112     BuiltIn.Return_From_Keyword_If    '${schemas}' == 'none'    ${EMPTY}
 113     # Deploy the additional schemas into a standard directory on the remote
 114     # machine and construct a command line argument pointing to that
 115     # directory from the point of view of the process running on that
 116     # machine.
 117     SSHLibrary.Put_Directory    ${schemas}    destination=./schemas
 118     [Return]    --schemas-dir ./schemas
 119
 120 NetconfKeywords__Check_Device_Is_Up
 121     [Arguments]    ${last-port}
 122     ${count}=    SSHKeywords.Count_Port_Occurences    ${last-port}    LISTEN    java
 123     BuiltIn.Should_Be_Equal_As_Integers    ${count}    1
 124
 125 Install_And_Start_Testtool
 126     [Arguments]    ${device-count}=10    ${debug}=true    ${schemas}=none    ${options}=${EMPTY}
 127     [Documentation]    Install and run testtool. Also arrange to collect its output into a log file.
 128     ...    When the ${schemas} argument is set to 'none', it signifies that
 129     ...    there are no additional schemas to be deployed, so the directory
 130     ...    for the additional schemas is deleted on the remote machine and
 131     ...    the additional schemas argument is left out.
 132     # Install test tool on the machine.
 133     # TODO: The "urlbase" line is very similar to what pcep suites do. Reduce this code duplication.
 134     ${urlbase}=    BuiltIn.Set_Variable    ${NEXUSURL_PREFIX}/content/repositories/opendaylight.snapshot/org/opendaylight/netconf/netconf-testtool
 135     ${version}=    SSHLibrary.Execute_Command    curl ${urlbase}/maven-metadata.xml | grep '<version>' | cut -d '>' -f 2 | cut -d '<' -f 1
 136     BuiltIn.Log    ${version}
 137     ${namepart}=    SSHLibrary.Execute_Command    curl ${urlbase}/${version}/maven-metadata.xml | grep value | head -n 1 | cut -d '>' -f 2 | cut -d '<' -f 1
 138     BuiltIn.Log    ${namepart}
 139     BuiltIn.Set_Suite_Variable    ${filename}    netconf-testtool-${namepart}-executable.jar
 140     BuiltIn.Log    ${filename}
 141     ${response}=    SSHLibrary.Execute_Command    curl ${urlbase}/${version}/${filename} >${filename}
 142     BuiltIn.Log    ${response}
 143     ${schemas_option}=    NetconfKeywords__Deploy_Additional_Schemas    ${schemas}
 144     # Start the testtool
 145     ${command}    BuiltIn.Set_Variable    java -Xmx1G -XX:MaxPermSize=256M -jar ${filename} ${options} --device-count ${device-count} --debug ${debug} ${schemas_option}
 146     BuiltIn.Log    Running testtool: ${command}
 147     SSHLibrary.Write    ${command} >testtool.log 2>&1
 148     # Wait for the testtool to boot up.
 149     ${timeout}=    BuiltIn.Evaluate    (${device-count}/3)+5
 150     BuiltIn.Wait_Until_Keyword_Succeeds    ${timeout}s    1s    NetconfKeywords__Check_Device_Is_Up    ${FIRST_TESTTOOL_PORT}
 151
 152 Check_Device_Up_And_Running
 153     [Arguments]    ${device-number}
 154     [Documentation]    Query netstat on remote machine whether testtool device with the specified number has its port open and fail if not.
 155     ${device-port}=    BuiltIn.Evaluate    ${FIRST_TESTTOOL_PORT}+${device-number}-1
 156     NetconfKeywords__Check_Device_Is_Up    ${device-port}
 157
 158 Stop_Testtool
 159     [Documentation]    Stop testtool and download its log.
 160     Utils.Write_Bare_Ctrl_C
 161     SSHLibrary.Read_Until_Prompt
 162     # TODO: Unify with play.py and pcc-mock handling.
 163     # TODO: Maybe this keyword's content shall be moved into SSHUtils and named somewhat like
 164     # "Interrupt_Program_And_Download_Its_Log" which will get an argument stating the name of
 165     # the log file to get.
 166     SSHLibrary.Get_File    testtool.log
 167
 168 NetconfKeywords__Perform_Operation_With_Checking_On_Next_Device
 169     [Arguments]    ${operation}
 170     ${number}=    BuiltIn.Evaluate    ${current_port}-${BASE_NETCONF_DEVICE_PORT}+1
 171     BuiltIn.Wait_Until_Keyword_Succeeds    10s    1s    NetconfKeywords.Check_Device_Up_And_Running    ${number}
 172     BuiltIn.Run_Keyword    ${operation}    ${DEVICE_NAME_BASE}-${number}
 173     ${next}=    BuiltIn.Evaluate    ${current_port}+1
 174     BuiltIn.Set_Suite_Variable    ${current_port}    ${next}
 175
 176 Perform_Operation_On_Each_Device
 177     [Arguments]    ${operation}    ${count}=${DEVICE_COUNT}
 178     BuiltIn.Set_Suite_Variable    ${current_port}    ${BASE_NETCONF_DEVICE_PORT}
 179     BuiltIn.Repeat_Keyword    ${count} times    NetconfKeywords__Perform_Operation_With_Checking_On_Next_Device    ${operation}