csit/libraries/NetconfKeywords.robot

   1 *** Settings ***
   2 Documentation     Perform complex operations on netconf.
   3 ...
   4 ...               Copyright (c) 2015 Cisco Systems, Inc. and others. All rights reserved.
   5 ...
   6 ...               This program and the accompanying materials are made available under the
   7 ...               terms of the Eclipse Public License v1.0 which accompanies this distribution,
   8 ...               and is available at http://www.eclipse.org/legal/epl-v10.html
   9 ...
  10 ...
  11 ...               This library encapsulates a bunch of somewhat complex and commonly used
  12 ...               netconf operations into reusable keywords to make writing netconf
  13 ...               test suites easier.
  14 Library           Collections
  15 Library           DateTime
  16 Library           RequestsLibrary
  17 Resource          NetconfViaRestconf.robot
  18 Resource          NexusKeywords.robot
  19 Resource          SSHKeywords.robot
  20
  21 *** Variables ***
  22 ${TESTTOOL_DEFAULT_JAVA_OPTIONS}    -Xmx1G -XX:MaxPermSize=256M -Dorg.apache.sshd.registerBouncyCastle=false
  23 ${DIRECTORY_WITH_DEVICE_TEMPLATES}    ${CURDIR}/../variables/netconf/device
  24 ${FIRST_TESTTOOL_PORT}    17830
  25 ${BASE_NETCONF_DEVICE_PORT}    17830
  26 ${DEVICE_NAME_BASE}    netconf-scaling-device
  27 ${TESTTOOL_DEVICE_TIMEOUT}    60s
  28 ${ENABLE_NETCONF_TEST_TIMEOUT}    ${ENABLE_GLOBAL_TEST_DEADLINES}
  29
  30 *** Keywords ***
  31 Setup_NetconfKeywords
  32     [Documentation]    Setup the environment for the other keywords of this Resource to work properly.
  33     ${tmp}=    BuiltIn.Create_Dictionary
  34     BuiltIn.Set_Suite_Variable    ${NetconfKeywords__mounted_device_types}    ${tmp}
  35     NetconfViaRestconf.Setup_Netconf_Via_Restconf
  36
  37 Configure_Device_In_Netconf
  38     [Arguments]    ${device_name}    ${device_type}=default    ${device_port}=${FIRST_TESTTOOL_PORT}
  39     [Documentation]    Tell Netconf about the specified device so it can add it into its configuration.
  40     ${template_as_string}=    BuiltIn.Set_Variable    {'DEVICE_IP': '${TOOLS_SYSTEM_IP}', 'DEVICE_NAME': '${device_name}', 'DEVICE_PORT': '${device_port}'}
  41     NetconfViaRestconf.Put_Xml_Template_Folder_Via_Restconf    ${DIRECTORY_WITH_DEVICE_TEMPLATES}${/}${device_type}    ${template_as_string}
  42     Collections.Set_To_Dictionary    ${NetconfKeywords__mounted_device_types}    ${device_name}    ${device_type}
  43
  44 Count_Netconf_Connectors_For_Device
  45     [Arguments]    ${device_name}
  46     [Documentation]    Count all instances of the specified device in the Netconf topology (usually 0 or 1).
  47     # FIXME: This no longer counts netconf connectors, it counts "device instances in Netconf topology".
  48     # This keyword should be renamed but without an automatic keyword naming standards checker this is
  49     # potentially destabilizing change so right now it is as FIXME. Proposed new name:
  50     # Count_Device_Instances_In_Netconf_Topology
  51     ${mounts}=    NetconfViaRestconf.Get_Operational_Data_From_URI    network-topology:network-topology/topology/topology-netconf
  52     Builtin.Log    ${mounts}
  53     ${actual_count}=    Builtin.Evaluate    len('''${mounts}'''.split('"node-id":"${device_name}"'))-1
  54     Builtin.Return_From_Keyword    ${actual_count}
  55
  56 Check_Device_Has_No_Netconf_Connector
  57     [Arguments]    ${device_name}
  58     [Documentation]    Check that there are no instances of the specified device in the Netconf topology.
  59     # FIXME: Similarlt to "Count_Netconf_Connectors_For_Device", this does not check whether the device has
  60     # no netconf connector but whether the device is present in the netconf topology or not. Rename, proposed
  61     # new name: Check_Device_Not_Present_In_Netconf_Topology
  62     ${count}    Count_Netconf_Connectors_For_Device    ${device_name}
  63     Builtin.Should_Be_Equal_As_Strings    ${count}    0
  64
  65 Check_Device_Completely_Gone
  66     [Arguments]    ${device_name}
  67     [Documentation]    Check that the specified device has no Netconf connectors nor associated data.
  68     Check_Device_Has_No_Netconf_Connector    ${device_name}
  69     ${uri}=    Builtin.Set_Variable    network-topology:network-topology/topology/topology-netconf/node/${device_name}
  70     ${response}=    RequestsLibrary.Get Request    nvr_session    ${uri}    ${ACCEPT_XML}
  71     BuiltIn.Should_Be_Equal_As_Integers    ${response.status_code}    404
  72
  73 Check_Device_Connected
  74     [Arguments]    ${device_name}
  75     [Documentation]    Check that the specified device is accessible from Netconf.
  76     ${device_status}=    NetconfViaRestconf.Get_Operational_Data_From_URI    network-topology:network-topology/topology/topology-netconf/node/${device_name}
  77     Builtin.Should_Contain    ${device_status}    "netconf-node-topology:connection-status":"connected"
  78
  79 Wait_Device_Connected
  80     [Arguments]    ${device_name}    ${timeout}=10s    ${period}=1s
  81     [Documentation]    Wait for the device to become connected.
  82     ...    It is more readable to use this keyword in a test case than to put the whole WUKS below into it.
  83     BuiltIn.Wait_Until_Keyword_Succeeds    ${timeout}    ${period}    Check_Device_Connected    ${device_name}
  84
  85 Remove_Device_From_Netconf
  86     [Arguments]    ${device_name}
  87     [Documentation]    Tell Netconf to deconfigure the specified device
  88     ${device_type}=    Collections.Pop_From_Dictionary    ${NetconfKeywords__mounted_device_types}    ${device_name}
  89     ${template_as_string}=    BuiltIn.Set_Variable    {'DEVICE_NAME': '${device_name}'}
  90     NetconfViaRestconf.Delete_Xml_Template_Folder_Via_Restconf    ${DIRECTORY_WITH_DEVICE_TEMPLATES}${/}${device_type}    ${template_as_string}
  91
  92 Wait_Device_Fully_Removed
  93     [Arguments]    ${device_name}    ${timeout}=10s    ${period}=1s
  94     [Documentation]    Wait until all netconf connectors for the device with the given name disappear.
  95     ...    Call of Remove_Device_From_Netconf returns before netconf gets
  96     ...    around deleting the device's connector. To ensure the device is
  97     ...    really gone from netconf, use this keyword to make sure all
  98     ...    connectors disappear. If a call to Remove_Device_From_Netconf
  99     ...    is not made before using this keyword, the wait will fail.
 100     ...    Using this keyword is more readable than putting the WUKS below
 101     ...    into a test case.
 102     BuiltIn.Wait_Until_Keyword_Succeeds    ${timeout}    ${period}    Check_Device_Completely_Gone    ${device_name}
 103
 104 NetconfKeywords__Deploy_Additional_Schemas
 105     [Arguments]    ${schemas}
 106     [Documentation]    Internal keyword for Install_And_Start_TestTool
 107     ...    This deploys the additional schemas if any and returns a
 108     ...    command line argument to be added to the testtool commandline
 109     ...    to tell it to load them. While this code could be integrated
 110     ...    into its only user, I considered the resulting code to be too
 111     ...    unreadable as the actions are quite different in the two
 112     ...    possibilities (additional schemas present versus no additional
 113     ...    schemas present), therefore a separate keyword is used.
 114     # Make sure there is no schemas directory on the remote machine. A
 115     # previous test suite might have left some debris there and that might
 116     # lead to spurious failures, so it is better to make sure we start with a
 117     # clean slate. Additionally when the caller did not specify any
 118     # additional schemas for testtool, we want to make extra sure none are
 119     # used.
 120     ${response}=    SSHLibrary.Execute_Command    rm -rf schemas 2>&1
 121     BuiltIn.Log    ${response}
 122     # Drop out of the keyword, returning no command line argument when there
 123     # are no additional schemas to deploy.
 124     BuiltIn.Return_From_Keyword_If    '${schemas}' == 'none'    ${EMPTY}
 125     # Deploy the additional schemas into a standard directory on the remote
 126     # machine and construct a command line argument pointing to that
 127     # directory from the point of view of the process running on that
 128     # machine.
 129     SSHLibrary.Put_Directory    ${schemas}    destination=./schemas
 130     [Return]    --schemas-dir ./schemas
 131
 132 NetconfKeywords__Check_Device_Is_Up
 133     [Arguments]    ${last-port}
 134     ${count}=    SSHKeywords.Count_Port_Occurences    ${last-port}    LISTEN    java
 135     BuiltIn.Should_Be_Equal_As_Integers    ${count}    1
 136
 137 NetconfKeywords__Wait_Device_Is_Up_And_Running
 138     [Arguments]    ${device_name}
 139     ${number}=    BuiltIn.Evaluate    '${device_name}'.split('-').pop()
 140     BuiltIn.Wait_Until_Keyword_Succeeds    ${TESTTOOL_DEVICE_TIMEOUT}    1s    Check_Device_Up_And_Running    ${number}
 141
 142 Install_And_Start_Testtool
 143     [Arguments]    ${device-count}=10    ${debug}=true    ${schemas}=none    ${tool_options}=${EMPTY}    ${java_options}=${TESTTOOL_DEFAULT_JAVA_OPTIONS}    ${mdsal}=true
 144     [Documentation]    Install and run testtool. Also arrange to collect its output into a log file.
 145     ...    When the ${schemas} argument is set to 'none', it signifies that
 146     ...    there are no additional schemas to be deployed, so the directory
 147     ...    for the additional schemas is deleted on the remote machine and
 148     ...    the additional schemas argument is left out.
 149     # Install test tool on the machine.
 150     ${filename}=    NexusKeywords.Deploy_Test_Tool    netconf/netconf-testtool
 151     ${schemas_option}=    NetconfKeywords__Deploy_Additional_Schemas    ${schemas}
 152     # Start the testtool
 153     ${command}    BuiltIn.Set_Variable    java ${java_options} -jar ${filename} ${tool_options} --device-count ${device-count} --debug ${debug} ${schemas_option} --md-sal ${mdsal}
 154     BuiltIn.Log    Running testtool: ${command}
 155     SSHLibrary.Write    ${command} >testtool.log 2>&1
 156     # Store information needed by other keywords.
 157     BuiltIn.Set_Suite_Variable    ${NetconfKeywords__testtool_device_count}    ${device-count}
 158     # Wait for the testtool to boot up.
 159     Perform_Operation_On_Each_Device    NetconfKeywords__Wait_Device_Is_Up_And_Running
 160
 161 Check_Device_Up_And_Running
 162     [Arguments]    ${device-number}
 163     [Documentation]    Query netstat on remote machine whether testtool device with the specified number has its port open and fail if not.
 164     ${device-port}=    BuiltIn.Evaluate    ${FIRST_TESTTOOL_PORT}+${device-number}-1
 165     NetconfKeywords__Check_Device_Is_Up    ${device-port}
 166
 167 Stop_Testtool
 168     [Documentation]    Stop testtool and download its log.
 169     Utils.Write_Bare_Ctrl_C
 170     SSHLibrary.Read_Until_Prompt
 171     # TODO: Unify with play.py and pcc-mock handling.
 172     # TODO: Maybe this keyword's content shall be moved into SSHUtils and named somewhat like
 173     # "Interrupt_Program_And_Download_Its_Log" which will get an argument stating the name of
 174     # the log file to get.
 175     SSHLibrary.Get_File    testtool.log
 176
 177 NetconfKeywords__Check_Netconf_Test_Timeout_Not_Expired
 178     [Arguments]    ${deadline_Date}
 179     BuiltIn.Return_From_Keyword_If    not ${ENABLE_NETCONF_TEST_TIMEOUT}
 180     ${current_Date}=    DateTime.Get_Current_Date
 181     ${ellapsed_seconds}=    DateTime.Subtract_Date_From_Date    ${deadline_Date}    ${current_Date}
 182     BuiltIn.Run_Keyword_If    ${ellapsed_seconds}<0    Fail    The global time out period expired
 183
 184 NetconfKeywords__Perform_Operation_With_Checking_On_Next_Device
 185     [Arguments]    ${operation}    ${deadline_Date}
 186     NetconfKeywords__Check_Netconf_Test_Timeout_Not_Expired    ${deadline_Date}
 187     ${number}=    BuiltIn.Evaluate    ${current_port}-${BASE_NETCONF_DEVICE_PORT}+1
 188     BuiltIn.Run_Keyword    ${operation}    ${DEVICE_NAME_BASE}-${number}
 189     ${next}=    BuiltIn.Evaluate    ${current_port}+1
 190     BuiltIn.Set_Suite_Variable    ${current_port}    ${next}
 191
 192 Perform_Operation_On_Each_Device
 193     [Arguments]    ${operation}    ${count}=${NetconfKeywords__testtool_device_count}    ${timeout}=30m
 194     ${current_Date}=    DateTime.Get_Current_Date
 195     ${deadline_Date}=    DateTime.Add_Time_To_Date    ${current_Date}    ${timeout}
 196     BuiltIn.Set_Suite_Variable    ${current_port}    ${BASE_NETCONF_DEVICE_PORT}
 197     BuiltIn.Repeat_Keyword    ${count} times    NetconfKeywords__Perform_Operation_With_Checking_On_Next_Device    ${operation}    ${deadline_Date}