csit/libraries/NetconfKeywords.robot

   1 *** Settings ***
   2 Documentation     Perform complex operations on netconf.
   3 ...
   4 ...               Copyright (c) 2015 Cisco Systems, Inc. and others. All rights reserved.
   5 ...
   6 ...               This program and the accompanying materials are made available under the
   7 ...               terms of the Eclipse Public License v1.0 which accompanies this distribution,
   8 ...               and is available at http://www.eclipse.org/legal/epl-v10.html
   9 ...
  10 ...
  11 ...               This library encapsulates a bunch of somewhat complex and commonly used
  12 ...               netconf operations into reusable keywords to make writing netconf
  13 ...               test suites easier.
  14 Library           Collections
  15 Library           DateTime
  16 Library           RequestsLibrary
  17 Resource          NetconfViaRestconf.robot
  18 Resource          NexusKeywords.robot
  19 Resource          SSHKeywords.robot
  20
  21 *** Variables ***
  22 ${TESTTOOL_DEFAULT_JAVA_OPTIONS}    -Xmx1G -XX:MaxPermSize=256M -Dorg.apache.sshd.registerBouncyCastle=false
  23 ${DIRECTORY_WITH_DEVICE_TEMPLATES}    ${CURDIR}/../variables/netconf/device
  24 ${FIRST_TESTTOOL_PORT}    17830
  25 ${BASE_NETCONF_DEVICE_PORT}    17830
  26 ${DEVICE_NAME_BASE}    netconf-scaling-device
  27
  28 *** Keywords ***
  29 Setup_NetconfKeywords
  30     [Documentation]    Setup the environment for the other keywords of this Resource to work properly.
  31     ${tmp}=    BuiltIn.Create_Dictionary
  32     BuiltIn.Set_Suite_Variable    ${NetconfKeywords__mounted_device_types}    ${tmp}
  33     NetconfViaRestconf.Setup_Netconf_Via_Restconf
  34
  35 Configure_Device_In_Netconf
  36     [Arguments]    ${device_name}    ${device_type}=default    ${device_port}=${FIRST_TESTTOOL_PORT}
  37     [Documentation]    Tell Netconf about the specified device so it can add it into its configuration.
  38     ${template_as_string}=    BuiltIn.Set_Variable    {'DEVICE_IP': '${TOOLS_SYSTEM_IP}', 'DEVICE_NAME': '${device_name}', 'DEVICE_PORT': '${device_port}'}
  39     NetconfViaRestconf.Put_Xml_Template_Folder_Via_Restconf    ${DIRECTORY_WITH_DEVICE_TEMPLATES}${/}${device_type}    ${template_as_string}
  40     Collections.Set_To_Dictionary    ${NetconfKeywords__mounted_device_types}    ${device_name}    ${device_type}
  41
  42 Count_Netconf_Connectors_For_Device
  43     [Arguments]    ${device_name}
  44     [Documentation]    Count all Netconf connectors referring to the specified device (usually 0 or 1).
  45     ${mounts}=    Utils.Get_Data_From_URI    operational    network-topology:network-topology/topology/topology-netconf
  46     Builtin.Log    ${mounts}
  47     ${actual_count}=    Builtin.Evaluate    len('''${mounts}'''.split('"node-id":"${device_name}"'))-1
  48     Builtin.Return_From_Keyword    ${actual_count}
  49
  50 Check_Device_Has_No_Netconf_Connector
  51     [Arguments]    ${device_name}
  52     [Documentation]    Check that there are no Netconf connectors referring to the specified device.
  53     ${count}    Count_Netconf_Connectors_For_Device    ${device_name}
  54     Builtin.Should_Be_Equal_As_Strings    ${count}    0
  55
  56 Check_Device_Completely_Gone
  57     [Arguments]    ${device_name}
  58     [Documentation]    Check that the specified device has no Netconf connectors nor associated data.
  59     Check_Device_Has_No_Netconf_Connector    ${device_name}
  60     ${uri}=    Builtin.Set_Variable    network-topology:network-topology/topology/topology-netconf/node/${device_name}
  61     ${response}=    RequestsLibrary.Get Request    nvr_session    ${uri}    ${ACCEPT_XML}
  62     BuiltIn.Should_Be_Equal_As_Integers    ${response.status_code}    404
  63
  64 Check_Device_Connected
  65     [Arguments]    ${device_name}
  66     [Documentation]    Check that the specified device is accessible from Netconf.
  67     ${device_status}=    Utils.Get_Data_From_URI    operational    network-topology:network-topology/topology/topology-netconf/node/${device_name}
  68     Builtin.Should_Contain    ${device_status}    "netconf-node-topology:connection-status":"connected"
  69
  70 Wait_Device_Connected
  71     [Arguments]    ${device_name}    ${timeout}=10s    ${period}=1s
  72     [Documentation]    Wait for the device to become connected.
  73     ...    It is more readable to use this keyword in a test case than to put the whole WUKS below into it.
  74     BuiltIn.Wait_Until_Keyword_Succeeds    ${timeout}    ${period}    Check_Device_Connected    ${device_name}
  75
  76 Remove_Device_From_Netconf
  77     [Arguments]    ${device_name}
  78     [Documentation]    Tell Netconf to deconfigure the specified device
  79     ${device_type}=    Collections.Pop_From_Dictionary    ${NetconfKeywords__mounted_device_types}    ${device_name}
  80     ${template_as_string}=    BuiltIn.Set_Variable    {'DEVICE_NAME': '${device_name}'}
  81     NetconfViaRestconf.Delete_Xml_Template_Folder_Via_Restconf    ${DIRECTORY_WITH_DEVICE_TEMPLATES}${/}${device_type}    ${template_as_string}
  82
  83 Wait_Device_Fully_Removed
  84     [Arguments]    ${device_name}    ${timeout}=10s    ${period}=1s
  85     [Documentation]    Wait until all netconf connectors for the device with the given name disappear.
  86     ...    Call of Remove_Device_From_Netconf returns before netconf gets
  87     ...    around deleting the device's connector. To ensure the device is
  88     ...    really gone from netconf, use this keyword to make sure all
  89     ...    connectors disappear. If a call to Remove_Device_From_Netconf
  90     ...    is not made before using this keyword, the wait will fail.
  91     ...    Using this keyword is more readable than putting the WUKS below
  92     ...    into a test case.
  93     BuiltIn.Wait_Until_Keyword_Succeeds    ${timeout}    ${period}    Check_Device_Completely_Gone    ${device_name}
  94
  95 NetconfKeywords__Deploy_Additional_Schemas
  96     [Arguments]    ${schemas}
  97     [Documentation]    Internal keyword for Install_And_Start_TestTool
  98     ...    This deploys the additional schemas if any and returns a
  99     ...    command line argument to be added to the testtool commandline
 100     ...    to tell it to load them. While this code could be integrated
 101     ...    into its only user, I considered the resulting code to be too
 102     ...    unreadable as the actions are quite different in the two
 103     ...    possibilities (additional schemas present versus no additional
 104     ...    schemas present), therefore a separate keyword is used.
 105     # Make sure there is no schemas directory on the remote machine. A
 106     # previous test suite might have left some debris there and that might
 107     # lead to spurious failures, so it is better to make sure we start with a
 108     # clean slate. Additionally when the caller did not specify any
 109     # additional schemas for testtool, we want to make extra sure none are
 110     # used.
 111     ${response}=    SSHLibrary.Execute_Command    rm -rf schemas 2>&1
 112     BuiltIn.Log    ${response}
 113     # Drop out of the keyword, returning no command line argument when there
 114     # are no additional schemas to deploy.
 115     BuiltIn.Return_From_Keyword_If    '${schemas}' == 'none'    ${EMPTY}
 116     # Deploy the additional schemas into a standard directory on the remote
 117     # machine and construct a command line argument pointing to that
 118     # directory from the point of view of the process running on that
 119     # machine.
 120     SSHLibrary.Put_Directory    ${schemas}    destination=./schemas
 121     [Return]    --schemas-dir ./schemas
 122
 123 NetconfKeywords__Check_Device_Is_Up
 124     [Arguments]    ${last-port}
 125     ${count}=    SSHKeywords.Count_Port_Occurences    ${last-port}    LISTEN    java
 126     BuiltIn.Should_Be_Equal_As_Integers    ${count}    1
 127
 128 Install_And_Start_Testtool
 129     [Arguments]    ${device-count}=10    ${debug}=true    ${schemas}=none    ${tool_options}=${EMPTY}    ${java_options}=${TESTTOOL_DEFAULT_JAVA_OPTIONS}
 130     [Documentation]    Install and run testtool. Also arrange to collect its output into a log file.
 131     ...    When the ${schemas} argument is set to 'none', it signifies that
 132     ...    there are no additional schemas to be deployed, so the directory
 133     ...    for the additional schemas is deleted on the remote machine and
 134     ...    the additional schemas argument is left out.
 135     # Install test tool on the machine.
 136     ${filename}=    NexusKeywords.Deploy_Test_Tool    netconf/netconf-testtool
 137     ${schemas_option}=    NetconfKeywords__Deploy_Additional_Schemas    ${schemas}
 138     # Start the testtool
 139     ${command}    BuiltIn.Set_Variable    java ${java_options} -jar ${filename} ${tool_options} --device-count ${device-count} --debug ${debug} ${schemas_option}
 140     BuiltIn.Log    Running testtool: ${command}
 141     SSHLibrary.Write    ${command} >testtool.log 2>&1
 142     # Wait for the testtool to boot up.
 143     ${timeout}=    BuiltIn.Evaluate    (${device-count}/3)+5
 144     BuiltIn.Wait_Until_Keyword_Succeeds    ${timeout}s    1s    NetconfKeywords__Check_Device_Is_Up    ${FIRST_TESTTOOL_PORT}
 145     # Store information needed by other keywords.
 146     BuiltIn.Set_Suite_Variable    ${NetconfKeywords__testtool_device_count}    ${device-count}
 147
 148 Check_Device_Up_And_Running
 149     [Arguments]    ${device-number}
 150     [Documentation]    Query netstat on remote machine whether testtool device with the specified number has its port open and fail if not.
 151     ${device-port}=    BuiltIn.Evaluate    ${FIRST_TESTTOOL_PORT}+${device-number}-1
 152     NetconfKeywords__Check_Device_Is_Up    ${device-port}
 153
 154 Stop_Testtool
 155     [Documentation]    Stop testtool and download its log.
 156     Utils.Write_Bare_Ctrl_C
 157     SSHLibrary.Read_Until_Prompt
 158     # TODO: Unify with play.py and pcc-mock handling.
 159     # TODO: Maybe this keyword's content shall be moved into SSHUtils and named somewhat like
 160     # "Interrupt_Program_And_Download_Its_Log" which will get an argument stating the name of
 161     # the log file to get.
 162     SSHLibrary.Get_File    testtool.log
 163
 164 NetconfKeywords__Perform_Operation_With_Checking_On_Next_Device
 165     [Arguments]    ${operation}    ${deadline_Date}
 166     ${current_Date}=    DateTime.Get_Current_Date
 167     ${ellapsed_seconds}=    DateTime.Subtract_Date_From_Date    ${deadline_Date}    ${current_Date}
 168     BuiltIn.Run_Keyword_If    ${ellapsed_seconds}<0    Fail    The global time out period expired
 169     ${number}=    BuiltIn.Evaluate    ${current_port}-${BASE_NETCONF_DEVICE_PORT}+1
 170     BuiltIn.Wait_Until_Keyword_Succeeds    10s    1s    NetconfKeywords.Check_Device_Up_And_Running    ${number}
 171     BuiltIn.Run_Keyword    ${operation}    ${DEVICE_NAME_BASE}-${number}
 172     ${next}=    BuiltIn.Evaluate    ${current_port}+1
 173     BuiltIn.Set_Suite_Variable    ${current_port}    ${next}
 174
 175 Perform_Operation_On_Each_Device
 176     [Arguments]    ${operation}    ${count}=${NetconfKeywords__testtool_device_count}    ${timeout}=30m
 177     ${current_Date}=    DateTime.Get_Current_Date
 178     ${deadline_Date}=    DateTime.Add_Time_To_Date    ${current_Date}    ${timeout}
 179     BuiltIn.Set_Suite_Variable    ${current_port}    ${BASE_NETCONF_DEVICE_PORT}
 180     BuiltIn.Repeat_Keyword    ${count} times    NetconfKeywords__Perform_Operation_With_Checking_On_Next_Device    ${operation}    ${deadline_Date}