csit/libraries/NetconfKeywords.robot

   1 *** Settings ***
   2 Documentation     Perform complex operations on netconf.
   3 ...
   4 ...               Copyright (c) 2015,2017 Cisco Systems, Inc. and others. All rights reserved.
   5 ...
   6 ...               This program and the accompanying materials are made available under the
   7 ...               terms of the Eclipse Public License v1.0 which accompanies this distribution,
   8 ...               and is available at http://www.eclipse.org/legal/epl-v10.html
   9 ...
  10 ...
  11 ...               This library encapsulates a bunch of somewhat complex and commonly used
  12 ...               netconf operations into reusable keywords to make writing netconf
  13 ...               test suites easier.
  14 ...
  15 ...               TODO: RemoteBash.robot contains logic which could be reused here.
  16 Library           Collections
  17 Library           DateTime
  18 Library           RequestsLibrary
  19 Library           SSHLibrary
  20 Resource          NexusKeywords.robot
  21 Resource          SSHKeywords.robot
  22 Resource          TemplatedRequests.robot
  23 Resource          Utils.robot
  24 Resource          RemoteBash.robot
  25
  26 *** Variables ***
  27 ${TESTTOOL_DEFAULT_JAVA_OPTIONS}    -Xmx1G -XX:MaxPermSize=256M
  28 ${DIRECTORY_WITH_DEVICE_TEMPLATES}    ${CURDIR}/../variables/netconf/device
  29 ${FIRST_TESTTOOL_PORT}    17830
  30 ${BASE_NETCONF_DEVICE_PORT}    17830
  31 ${DEVICE_NAME_BASE}    netconf-scaling-device
  32 ${TESTTOOL_BOOT_TIMEOUT}    60s
  33 ${ENABLE_NETCONF_TEST_TIMEOUT}    ${ENABLE_GLOBAL_TEST_DEADLINES}
  34
  35 *** Keywords ***
  36 Setup_NetconfKeywords
  37     [Arguments]    ${create_session_for_templated_requests}=True
  38     [Documentation]    Setup the environment for the other keywords of this Resource to work properly.
  39     ${tmp}=    BuiltIn.Create_Dictionary
  40     BuiltIn.Set_Suite_Variable    ${NetconfKeywords__mounted_device_types}    ${tmp}
  41     BuiltIn.Run_Keyword_If    ${create_session_for_templated_requests}    TemplatedRequests.Create_Default_Session    timeout=2
  42     NexusKeywords.Initialize_Artifact_Deployment_And_Usage
  43
  44 Configure_Device_In_Netconf
  45     [Arguments]    ${device_name}    ${device_type}=default    ${device_port}=${FIRST_TESTTOOL_PORT}    ${device_address}=${TOOLS_SYSTEM_IP}    ${device_user}=admin    ${device_password}=topsecret
  46     ...    ${device_key}=device-key    ${session}=default    ${schema_directory}=/tmp/schema    ${http_timeout}=${EMPTY}    ${http_method}=put
  47     [Documentation]    Tell Netconf about the specified device so it can add it into its configuration.
  48     ${mapping}=    BuiltIn.Create_dictionary    DEVICE_IP=${device_address}    DEVICE_NAME=${device_name}    DEVICE_PORT=${device_port}    DEVICE_USER=${device_user}    DEVICE_PASSWORD=${device_password}
  49     ...    DEVICE_KEY=${device_key}    SCHEMA_DIRECTORY=${schema_directory}
  50     # TODO: Is it possible to use &{kwargs} as a mapping directly?
  51     Run Keyword if    '${http_method}'=='post'    TemplatedRequests.Post_As_Xml_Templated    folder=${DIRECTORY_WITH_DEVICE_TEMPLATES}${/}${device_type}    mapping=${mapping}    session=${session}    http_timeout=${http_timeout}
  52     ...    ELSE    TemplatedRequests.Put_As_Xml_Templated    folder=${DIRECTORY_WITH_DEVICE_TEMPLATES}${/}${device_type}    mapping=${mapping}    session=${session}    http_timeout=${http_timeout}
  53     Collections.Set_To_Dictionary    ${NetconfKeywords__mounted_device_types}    ${device_name}    ${device_type}
  54
  55 Count_Netconf_Connectors_For_Device
  56     [Arguments]    ${device_name}    ${session}=default
  57     [Documentation]    Count all instances of the specified device in the Netconf topology (usually 0 or 1).
  58     # FIXME: This no longer counts netconf connectors, it counts "device instances in Netconf topology".
  59     # This keyword should be renamed but without an automatic keyword naming standards checker this is
  60     # potentially destabilizing change so right now it is as FIXME. Proposed new name:
  61     # Count_Device_Instances_In_Netconf_Topology
  62     ${mounts}=    TemplatedRequests.Get_As_Json_From_Uri    ${OPERATIONAL_API}/network-topology:network-topology/topology/topology-netconf    session=${session}
  63     Builtin.Log    ${mounts}
  64     ${actual_count}=    Builtin.Evaluate    len('''${mounts}'''.split('"node-id": "${device_name}"'))-1
  65     Builtin.Return_From_Keyword    ${actual_count}
  66
  67 Check_Device_Has_No_Netconf_Connector
  68     [Arguments]    ${device_name}    ${session}=default
  69     [Documentation]    Check that there are no instances of the specified device in the Netconf topology.
  70     # FIXME: Similarlt to "Count_Netconf_Connectors_For_Device", this does not check whether the device has
  71     # no netconf connector but whether the device is present in the netconf topology or not. Rename, proposed
  72     # new name: Check_Device_Not_Present_In_Netconf_Topology
  73     ${count}    Count_Netconf_Connectors_For_Device    ${device_name}    session=${session}
  74     Builtin.Should_Be_Equal_As_Strings    ${count}    0
  75
  76 Check_Device_Completely_Gone
  77     [Arguments]    ${device_name}    ${session}=default
  78     [Documentation]    Check that the specified device has no Netconf connectors nor associated data.
  79     Check_Device_Has_No_Netconf_Connector    ${device_name}    session=${session}
  80     ${uri}=    Builtin.Set_Variable    ${CONFIG_API}/network-topology:network-topology/topology/topology-netconf/node/${device_name}
  81     ${status}    ${response}=    BuiltIn.Run_Keyword_And_Ignore_Error    TemplatedRequests.Get_As_Xml_From_Uri    ${uri}    session=${session}
  82     BuiltIn.Should_Be_Equal_As_Strings    ${status}    FAIL
  83     BuiltIn.Should_Contain    ${response}    404
  84
  85 Check_Device_Connected
  86     [Arguments]    ${device_name}    ${session}=default
  87     [Documentation]    Check that the specified device is accessible from Netconf.
  88     ${device_status}=    TemplatedRequests.Get_As_Json_From_Uri    ${OPERATIONAL_API}/network-topology:network-topology/topology/topology-netconf/node/${device_name}    session=${session}
  89     Builtin.Should_Contain    ${device_status}    "netconf-node-topology:connection-status": "connected"
  90
  91 Wait_Device_Connected
  92     [Arguments]    ${device_name}    ${timeout}=20s    ${period}=1s    ${session}=default
  93     [Documentation]    Wait for the device to become connected.
  94     ...    It is more readable to use this keyword in a test case than to put the whole WUKS below into it.
  95     BuiltIn.Wait_Until_Keyword_Succeeds    ${timeout}    ${period}    Check_Device_Connected    ${device_name}    session=${session}
  96
  97 Remove_Device_From_Netconf
  98     [Arguments]    ${device_name}    ${session}=default    ${location}=location
  99     [Documentation]    Tell Netconf to deconfigure the specified device
 100     ${device_type}=    Collections.Pop_From_Dictionary    ${NetconfKeywords__mounted_device_types}    ${device_name}
 101     ${template_as_string}=    BuiltIn.Set_Variable    {'DEVICE_NAME': '${device_name}'}
 102     TemplatedRequests.Delete_Templated    ${DIRECTORY_WITH_DEVICE_TEMPLATES}${/}${device_type}    ${template_as_string}    session=${session}    location=${location}
 103
 104 Wait_Device_Fully_Removed
 105     [Arguments]    ${device_name}    ${timeout}=10s    ${period}=1s    ${session}=default
 106     [Documentation]    Wait until all netconf connectors for the device with the given name disappear.
 107     ...    Call of Remove_Device_From_Netconf returns before netconf gets
 108     ...    around deleting the device's connector. To ensure the device is
 109     ...    really gone from netconf, use this keyword to make sure all
 110     ...    connectors disappear. If a call to Remove_Device_From_Netconf
 111     ...    is not made before using this keyword, the wait will fail.
 112     ...    Using this keyword is more readable than putting the WUKS below
 113     ...    into a test case.
 114     BuiltIn.Wait_Until_Keyword_Succeeds    ${timeout}    ${period}    Check_Device_Completely_Gone    ${device_name}    session=${session}
 115
 116 NetconfKeywords__Deploy_Additional_Schemas
 117     [Arguments]    ${schemas}
 118     [Documentation]    Internal keyword for Install_And_Start_TestTool
 119     ...    This deploys the additional schemas if any and returns a
 120     ...    command line argument to be added to the testtool commandline
 121     ...    to tell it to load them. While this code could be integrated
 122     ...    into its only user, I considered the resulting code to be too
 123     ...    unreadable as the actions are quite different in the two
 124     ...    possibilities (additional schemas present versus no additional
 125     ...    schemas present), therefore a separate keyword is used.
 126     # Make sure there is no schemas directory on the remote machine. A
 127     # previous test suite might have left some debris there and that might
 128     # lead to spurious failures, so it is better to make sure we start with a
 129     # clean slate. Additionally when the caller did not specify any
 130     # additional schemas for testtool, we want to make extra sure none are
 131     # used.
 132     ${response}=    SSHLibrary.Execute_Command    rm -rf schemas 2>&1
 133     BuiltIn.Log    ${response}
 134     # Drop out of the keyword, returning no command line argument when there
 135     # are no additional schemas to deploy.
 136     BuiltIn.Return_From_Keyword_If    '${schemas}' == 'none'    ${EMPTY}
 137     # Deploy the additional schemas into a standard directory on the remote
 138     # machine and construct a command line argument pointing to that
 139     # directory from the point of view of the process running on that
 140     # machine.
 141     SSHLibrary.Put_Directory    ${schemas}    destination=./schemas
 142     [Return]    --schemas-dir ./schemas
 143
 144 NetconfKeywords__Check_Device_Is_Up
 145     [Arguments]    ${last-port}
 146     ${count}=    SSHKeywords.Count_Port_Occurences    ${last-port}    LISTEN    java
 147     BuiltIn.Should_Be_Equal_As_Integers    ${count}    1
 148
 149 NetconfKeywords__Wait_Device_Is_Up_And_Running
 150     [Arguments]    ${device_name}
 151     ${number}=    BuiltIn.Evaluate    '${device_name}'.split('-').pop()
 152     BuiltIn.Wait_Until_Keyword_Succeeds    ${TESTTOOL_BOOT_TIMEOUT}    1s    Check_Device_Up_And_Running    ${number}
 153
 154 Install_And_Start_Testtool
 155     [Arguments]    ${device-count}=10    ${debug}=true    ${schemas}=none    ${tool_options}=${EMPTY}    ${java_options}=${TESTTOOL_DEFAULT_JAVA_OPTIONS}    ${mdsal}=true
 156     [Documentation]    Install and run testtool.
 157     ${filename}=    NexusKeywords.Deploy_Test_Tool    netconf    netconf-testtool
 158     Start_Testtool    ${filename}    ${device-count}    ${debug}    ${schemas}    ${tool_options}    ${java_options}
 159     ...    ${mdsal}
 160
 161 Start_Testtool
 162     [Arguments]    ${filename}    ${device-count}=10    ${debug}=true    ${schemas}=none    ${tool_options}=${EMPTY}    ${java_options}=${TESTTOOL_DEFAULT_JAVA_OPTIONS}
 163     ...    ${mdsal}=true
 164     [Documentation]    Arrange to collect tool's output into a log file.
 165     ...    Will use specific ${schemas} unless argument resolves to 'none',
 166     ...    which signifies that there are no additional schemas to be deployed.
 167     ...    If so the directory for the additional schemas is deleted on the
 168     ...    remote machine and the additional schemas argument is left out.
 169     ${schemas_option}=    NetconfKeywords__Deploy_Additional_Schemas    ${schemas}
 170     ${command}=    NexusKeywords.Compose_Full_Java_Command    ${java_options} -jar ${filename} ${tool_options} --device-count ${device-count} --debug ${debug} ${schemas_option} --md-sal ${mdsal}
 171     BuiltIn.Log    Running testtool: ${command}
 172     ${logfile}=    Utils.Get_Log_File_Name    testtool
 173     BuiltIn.Set_Suite_Variable    ${testtool_log}    ${logfile}
 174     SSHLibrary.Write    ${command} >${logfile} 2>&1
 175     # Store information needed by other keywords.
 176     BuiltIn.Set_Suite_Variable    ${NetconfKeywords__testtool_device_count}    ${device-count}
 177     # Wait for the testtool to boot up.
 178     Perform_Operation_On_Each_Device    NetconfKeywords__Wait_Device_Is_Up_And_Running
 179
 180 Check_Device_Up_And_Running
 181     [Arguments]    ${device-number}
 182     [Documentation]    Query netstat on remote machine whether testtool device with the specified number has its port open and fail if not.
 183     ${device-port}=    BuiltIn.Evaluate    ${FIRST_TESTTOOL_PORT}+${device-number}-1
 184     NetconfKeywords__Check_Device_Is_Up    ${device-port}
 185
 186 Stop_Testtool
 187     [Documentation]    Stop testtool and download its log.
 188     RemoteBash.Write_Bare_Ctrl_C
 189     SSHLibrary.Read_Until_Prompt
 190     # TODO: Unify with play.py and pcc-mock handling.
 191     # TODO: Maybe this keyword's content shall be moved into SSHUtils and named somewhat like
 192     # "Interrupt_Program_And_Download_Its_Log" which will get an argument stating the name of
 193     # the log file to get.
 194     SSHLibrary.Get_File    ${testtool_log}
 195
 196 NetconfKeywords__Check_Netconf_Test_Timeout_Not_Expired
 197     [Arguments]    ${deadline_Date}
 198     BuiltIn.Return_From_Keyword_If    not ${ENABLE_NETCONF_TEST_TIMEOUT}
 199     ${current_Date}=    DateTime.Get_Current_Date
 200     ${ellapsed_seconds}=    DateTime.Subtract_Date_From_Date    ${deadline_Date}    ${current_Date}
 201     BuiltIn.Run_Keyword_If    ${ellapsed_seconds}<0    Fail    The global time out period expired
 202
 203 NetconfKeywords__Perform_Operation_With_Checking_On_Next_Device
 204     [Arguments]    ${operation}    ${deadline_Date}
 205     NetconfKeywords__Check_Netconf_Test_Timeout_Not_Expired    ${deadline_Date}
 206     ${number}=    BuiltIn.Evaluate    ${current_port}-${BASE_NETCONF_DEVICE_PORT}+1
 207     BuiltIn.Run_Keyword    ${operation}    ${DEVICE_NAME_BASE}-${number}
 208     ${next}=    BuiltIn.Evaluate    ${current_port}+1
 209     BuiltIn.Set_Suite_Variable    ${current_port}    ${next}
 210
 211 Perform_Operation_On_Each_Device
 212     [Arguments]    ${operation}    ${count}=${NetconfKeywords__testtool_device_count}    ${timeout}=30m
 213     ${current_Date}=    DateTime.Get_Current_Date
 214     ${deadline_Date}=    DateTime.Add_Time_To_Date    ${current_Date}    ${timeout}
 215     BuiltIn.Set_Suite_Variable    ${current_port}    ${BASE_NETCONF_DEVICE_PORT}
 216     BuiltIn.Repeat_Keyword    ${count} times    NetconfKeywords__Perform_Operation_With_Checking_On_Next_Device    ${operation}    ${deadline_Date}