csit/libraries/NetconfKeywords.robot

   1 *** Settings ***
   2 Documentation     Perform complex operations on netconf.
   3 ...
   4 ...               Copyright (c) 2015 Cisco Systems, Inc. and others. All rights reserved.
   5 ...
   6 ...               This program and the accompanying materials are made available under the
   7 ...               terms of the Eclipse Public License v1.0 which accompanies this distribution,
   8 ...               and is available at http://www.eclipse.org/legal/epl-v10.html
   9 ...
  10 ...
  11 ...               This library encapsulates a bunch of somewhat complex and commonly used
  12 ...               netconf operations into reusable keywords to make writing netconf
  13 ...               test suites easier.
  14 Library           Collections
  15 Library           DateTime
  16 Library           RequestsLibrary
  17 Resource          NetconfViaRestconf.robot
  18 Resource          NexusKeywords.robot
  19 Resource          SSHKeywords.robot
  20
  21 *** Variables ***
  22 ${TESTTOOL_DEFAULT_JAVA_OPTIONS}    -Xmx1G -XX:MaxPermSize=256M -Dorg.apache.sshd.registerBouncyCastle=false
  23 ${DIRECTORY_WITH_DEVICE_TEMPLATES}    ${CURDIR}/../variables/netconf/device
  24 ${FIRST_TESTTOOL_PORT}    17830
  25 ${BASE_NETCONF_DEVICE_PORT}    17830
  26 ${DEVICE_NAME_BASE}    netconf-scaling-device
  27 ${TESTTOOL_DEVICE_TIMEOUT}    60s
  28
  29 *** Keywords ***
  30 Setup_NetconfKeywords
  31     [Documentation]    Setup the environment for the other keywords of this Resource to work properly.
  32     ${tmp}=    BuiltIn.Create_Dictionary
  33     BuiltIn.Set_Suite_Variable    ${NetconfKeywords__mounted_device_types}    ${tmp}
  34     NetconfViaRestconf.Setup_Netconf_Via_Restconf
  35
  36 Configure_Device_In_Netconf
  37     [Arguments]    ${device_name}    ${device_type}=default    ${device_port}=${FIRST_TESTTOOL_PORT}
  38     [Documentation]    Tell Netconf about the specified device so it can add it into its configuration.
  39     ${template_as_string}=    BuiltIn.Set_Variable    {'DEVICE_IP': '${TOOLS_SYSTEM_IP}', 'DEVICE_NAME': '${device_name}', 'DEVICE_PORT': '${device_port}'}
  40     NetconfViaRestconf.Put_Xml_Template_Folder_Via_Restconf    ${DIRECTORY_WITH_DEVICE_TEMPLATES}${/}${device_type}    ${template_as_string}
  41     Collections.Set_To_Dictionary    ${NetconfKeywords__mounted_device_types}    ${device_name}    ${device_type}
  42
  43 Count_Netconf_Connectors_For_Device
  44     [Arguments]    ${device_name}
  45     [Documentation]    Count all Netconf connectors referring to the specified device (usually 0 or 1).
  46     ${mounts}=    Utils.Get_Data_From_URI    operational    network-topology:network-topology/topology/topology-netconf
  47     Builtin.Log    ${mounts}
  48     ${actual_count}=    Builtin.Evaluate    len('''${mounts}'''.split('"node-id":"${device_name}"'))-1
  49     Builtin.Return_From_Keyword    ${actual_count}
  50
  51 Check_Device_Has_No_Netconf_Connector
  52     [Arguments]    ${device_name}
  53     [Documentation]    Check that there are no Netconf connectors referring to the specified device.
  54     ${count}    Count_Netconf_Connectors_For_Device    ${device_name}
  55     Builtin.Should_Be_Equal_As_Strings    ${count}    0
  56
  57 Check_Device_Completely_Gone
  58     [Arguments]    ${device_name}
  59     [Documentation]    Check that the specified device has no Netconf connectors nor associated data.
  60     Check_Device_Has_No_Netconf_Connector    ${device_name}
  61     ${uri}=    Builtin.Set_Variable    network-topology:network-topology/topology/topology-netconf/node/${device_name}
  62     ${response}=    RequestsLibrary.Get Request    nvr_session    ${uri}    ${ACCEPT_XML}
  63     BuiltIn.Should_Be_Equal_As_Integers    ${response.status_code}    404
  64
  65 Check_Device_Connected
  66     [Arguments]    ${device_name}
  67     [Documentation]    Check that the specified device is accessible from Netconf.
  68     ${device_status}=    Utils.Get_Data_From_URI    operational    network-topology:network-topology/topology/topology-netconf/node/${device_name}
  69     Builtin.Should_Contain    ${device_status}    "netconf-node-topology:connection-status":"connected"
  70
  71 Wait_Device_Connected
  72     [Arguments]    ${device_name}    ${timeout}=10s    ${period}=1s
  73     [Documentation]    Wait for the device to become connected.
  74     ...    It is more readable to use this keyword in a test case than to put the whole WUKS below into it.
  75     BuiltIn.Wait_Until_Keyword_Succeeds    ${timeout}    ${period}    Check_Device_Connected    ${device_name}
  76
  77 Remove_Device_From_Netconf
  78     [Arguments]    ${device_name}
  79     [Documentation]    Tell Netconf to deconfigure the specified device
  80     ${device_type}=    Collections.Pop_From_Dictionary    ${NetconfKeywords__mounted_device_types}    ${device_name}
  81     ${template_as_string}=    BuiltIn.Set_Variable    {'DEVICE_NAME': '${device_name}'}
  82     NetconfViaRestconf.Delete_Xml_Template_Folder_Via_Restconf    ${DIRECTORY_WITH_DEVICE_TEMPLATES}${/}${device_type}    ${template_as_string}
  83
  84 Wait_Device_Fully_Removed
  85     [Arguments]    ${device_name}    ${timeout}=10s    ${period}=1s
  86     [Documentation]    Wait until all netconf connectors for the device with the given name disappear.
  87     ...    Call of Remove_Device_From_Netconf returns before netconf gets
  88     ...    around deleting the device's connector. To ensure the device is
  89     ...    really gone from netconf, use this keyword to make sure all
  90     ...    connectors disappear. If a call to Remove_Device_From_Netconf
  91     ...    is not made before using this keyword, the wait will fail.
  92     ...    Using this keyword is more readable than putting the WUKS below
  93     ...    into a test case.
  94     BuiltIn.Wait_Until_Keyword_Succeeds    ${timeout}    ${period}    Check_Device_Completely_Gone    ${device_name}
  95
  96 NetconfKeywords__Deploy_Additional_Schemas
  97     [Arguments]    ${schemas}
  98     [Documentation]    Internal keyword for Install_And_Start_TestTool
  99     ...    This deploys the additional schemas if any and returns a
 100     ...    command line argument to be added to the testtool commandline
 101     ...    to tell it to load them. While this code could be integrated
 102     ...    into its only user, I considered the resulting code to be too
 103     ...    unreadable as the actions are quite different in the two
 104     ...    possibilities (additional schemas present versus no additional
 105     ...    schemas present), therefore a separate keyword is used.
 106     # Make sure there is no schemas directory on the remote machine. A
 107     # previous test suite might have left some debris there and that might
 108     # lead to spurious failures, so it is better to make sure we start with a
 109     # clean slate. Additionally when the caller did not specify any
 110     # additional schemas for testtool, we want to make extra sure none are
 111     # used.
 112     ${response}=    SSHLibrary.Execute_Command    rm -rf schemas 2>&1
 113     BuiltIn.Log    ${response}
 114     # Drop out of the keyword, returning no command line argument when there
 115     # are no additional schemas to deploy.
 116     BuiltIn.Return_From_Keyword_If    '${schemas}' == 'none'    ${EMPTY}
 117     # Deploy the additional schemas into a standard directory on the remote
 118     # machine and construct a command line argument pointing to that
 119     # directory from the point of view of the process running on that
 120     # machine.
 121     SSHLibrary.Put_Directory    ${schemas}    destination=./schemas
 122     [Return]    --schemas-dir ./schemas
 123
 124 NetconfKeywords__Check_Device_Is_Up
 125     [Arguments]    ${last-port}
 126     ${count}=    SSHKeywords.Count_Port_Occurences    ${last-port}    LISTEN    java
 127     BuiltIn.Should_Be_Equal_As_Integers    ${count}    1
 128
 129 NetconfKeywords__Wait_Device_Is_Up_And_Running
 130     [Arguments]    ${device_name}
 131     ${number}=    BuiltIn.Evaluate    '${device_name}'.split('-').pop()
 132     BuiltIn.Wait_Until_Keyword_Succeeds    ${TESTTOOL_DEVICE_TIMEOUT}    1s    Check_Device_Up_And_Running    ${number}
 133
 134 Install_And_Start_Testtool
 135     [Arguments]    ${device-count}=10    ${debug}=true    ${schemas}=none    ${tool_options}=${EMPTY}    ${java_options}=${TESTTOOL_DEFAULT_JAVA_OPTIONS}    ${mdsal}=true
 136     [Documentation]    Install and run testtool. Also arrange to collect its output into a log file.
 137     ...    When the ${schemas} argument is set to 'none', it signifies that
 138     ...    there are no additional schemas to be deployed, so the directory
 139     ...    for the additional schemas is deleted on the remote machine and
 140     ...    the additional schemas argument is left out.
 141     # Install test tool on the machine.
 142     ${filename}=    NexusKeywords.Deploy_Test_Tool    netconf/netconf-testtool
 143     ${schemas_option}=    NetconfKeywords__Deploy_Additional_Schemas    ${schemas}
 144     # Start the testtool
 145     ${command}    BuiltIn.Set_Variable    java ${java_options} -jar ${filename} ${tool_options} --device-count ${device-count} --debug ${debug} ${schemas_option} --md-sal ${mdsal}
 146     BuiltIn.Log    Running testtool: ${command}
 147     SSHLibrary.Write    ${command} >testtool.log 2>&1
 148     # Store information needed by other keywords.
 149     BuiltIn.Set_Suite_Variable    ${NetconfKeywords__testtool_device_count}    ${device-count}
 150     # Wait for the testtool to boot up.
 151     Perform_Operation_On_Each_Device    NetconfKeywords__Wait_Device_Is_Up_And_Running
 152
 153 Check_Device_Up_And_Running
 154     [Arguments]    ${device-number}
 155     [Documentation]    Query netstat on remote machine whether testtool device with the specified number has its port open and fail if not.
 156     ${device-port}=    BuiltIn.Evaluate    ${FIRST_TESTTOOL_PORT}+${device-number}-1
 157     NetconfKeywords__Check_Device_Is_Up    ${device-port}
 158
 159 Stop_Testtool
 160     [Documentation]    Stop testtool and download its log.
 161     Utils.Write_Bare_Ctrl_C
 162     SSHLibrary.Read_Until_Prompt
 163     # TODO: Unify with play.py and pcc-mock handling.
 164     # TODO: Maybe this keyword's content shall be moved into SSHUtils and named somewhat like
 165     # "Interrupt_Program_And_Download_Its_Log" which will get an argument stating the name of
 166     # the log file to get.
 167     SSHLibrary.Get_File    testtool.log
 168
 169 NetconfKeywords__Perform_Operation_With_Checking_On_Next_Device
 170     [Arguments]    ${operation}    ${deadline_Date}
 171     ${current_Date}=    DateTime.Get_Current_Date
 172     ${ellapsed_seconds}=    DateTime.Subtract_Date_From_Date    ${deadline_Date}    ${current_Date}
 173     BuiltIn.Run_Keyword_If    ${ellapsed_seconds}<0    Fail    The global time out period expired
 174     ${number}=    BuiltIn.Evaluate    ${current_port}-${BASE_NETCONF_DEVICE_PORT}+1
 175     BuiltIn.Run_Keyword    ${operation}    ${DEVICE_NAME_BASE}-${number}
 176     ${next}=    BuiltIn.Evaluate    ${current_port}+1
 177     BuiltIn.Set_Suite_Variable    ${current_port}    ${next}
 178
 179 Perform_Operation_On_Each_Device
 180     [Arguments]    ${operation}    ${count}=${NetconfKeywords__testtool_device_count}    ${timeout}=30m
 181     ${current_Date}=    DateTime.Get_Current_Date
 182     ${deadline_Date}=    DateTime.Add_Time_To_Date    ${current_Date}    ${timeout}
 183     BuiltIn.Set_Suite_Variable    ${current_port}    ${BASE_NETCONF_DEVICE_PORT}
 184     BuiltIn.Repeat_Keyword    ${count} times    NetconfKeywords__Perform_Operation_With_Checking_On_Next_Device    ${operation}    ${deadline_Date}