csit/libraries/NettyReplication.robot

   1 *** Settings ***
   2 Documentation       Netty replication library. This library can be used to setup and teardown netty replication connections.
   3
   4 Resource            KarafKeywords.robot
   5 Resource            ClusterManagement.robot
   6
   7
   8 *** Variables ***
   9 ${DEFAULT_NETTY_SOURCE_NODE_INDEX}      ${1}
  10 @{DEFAULT_NETTY_SINK_NODE_INDEXES}      ${2}
  11
  12
  13 *** Keywords ***
  14 Setup_Netty_Replication
  15     [Documentation]    Set up netty replication connections betwean source and sinks.
  16     [Arguments]    ${source_member_index}=${DEFAULT_NETTY_SOURCE_NODE_INDEX}    ${sink_members_indexes}=${DEFAULT_NETTY_SINK_NODE_INDEXES}
  17     Open_Source_Connection    ${source_member_index}
  18     FOR    ${sink_member_index}    IN    @{sink_members_indexes}
  19         Open_Sink_Connection    ${sink_member_index}    source_member_index=${source_member_index}
  20     END
  21
  22 Teardown_Netty_Replication
  23     [Documentation]    Tear down netty replication connections betwean source and sinks.
  24     [Arguments]    ${source_member_index}=${DEFAULT_NETTY_SOURCE_NODE_INDEX}    ${sink_members_indexes}=${DEFAULT_NETTY_SINK_NODE_INDEXES}
  25     Close_Source_Connection    ${source_member_index}
  26     FOR    ${sink_member_index}    IN    @{sink_members_indexes}
  27         Close_Sink_Connection    ${sink_member_index}
  28     END
  29
  30 Open_Source_Connection
  31     [Documentation]    Open source part of netty replicate connection on specific node.
  32     [Arguments]    ${source_member_index}=${DEFAULT_NETTY_SOURCE_NODE_INDEX}
  33     KarafKeywords.Execute_Controller_Karaf_Command_On_Background
  34     ...    config:edit org.opendaylight.mdsal.replicate.netty.source
  35     ...    member_index=${source_member_index}
  36     KarafKeywords.Execute_Controller_Karaf_Command_On_Background
  37     ...    config:property-set enabled true
  38     ...    member_index=${source_member_index}
  39     KarafKeywords.Execute_Controller_Karaf_Command_On_Background
  40     ...    config:update
  41     ...    member_index=${source_member_index}
  42
  43 Close_Source_Connection
  44     [Documentation]    Close source part of netty replicate connection on specific node.
  45     [Arguments]    ${source_member_index}=${DEFAULT_NETTY_SOURCE_NODE_INDEX}
  46     KarafKeywords.Execute_Controller_Karaf_Command_On_Background
  47     ...    config:edit org.opendaylight.mdsal.replicate.netty.source
  48     ...    member_index=${source_member_index}
  49     KarafKeywords.Execute_Controller_Karaf_Command_On_Background
  50     ...    config:property-set enabled false
  51     ...    member_index=${source_member_index}
  52     KarafKeywords.Execute_Controller_Karaf_Command_On_Background
  53     ...    config:update
  54     ...    member_index=${source_member_index}
  55
  56 Open_Sink_Connection
  57     [Documentation]    Open sink part of netty replicate connection on specific node.
  58     [Arguments]    ${sink_member_index}=@{DEFAULT_NETTY_SINK_NODE_INDEXES}[0]    ${source_member_index}=${DEFAULT_NETTY_SOURCE_NODE_INDEX}
  59     ${replicate_source_ip}=    ClusterManagement.Resolve_Ip_Address_For_Member    ${source_member_index}
  60     KarafKeywords.Execute_Controller_Karaf_Command_On_Background
  61     ...    config:edit org.opendaylight.mdsal.replicate.netty.sink
  62     ...    member_index=${sink_member_index}
  63     KarafKeywords.Execute_Controller_Karaf_Command_On_Background
  64     ...    config:property-set enabled true
  65     ...    member_index=${sink_member_index}
  66     KarafKeywords.Execute_Controller_Karaf_Command_On_Background
  67     ...    config:property-set source-host ${replicate_source_ip}
  68     ...    member_index=${sink_member_index}
  69     KarafKeywords.Execute_Controller_Karaf_Command_On_Background    config:update    member_index=${sink_member_index}
  70
  71 Close_Sink_Connection
  72     [Documentation]    Close sink part of netty replicate connection on specific node.
  73     [Arguments]    ${sink_member_index}=@{DEFAULT_NETTY_SINK_NODE_INDEXES}[0]
  74     KarafKeywords.Execute_Controller_Karaf_Command_On_Background
  75     ...    config:edit org.opendaylight.mdsal.replicate.netty.sink
  76     ...    member_index=${sink_member_index}
  77     KarafKeywords.Execute_Controller_Karaf_Command_On_Background
  78     ...    config:property-set enabled false
  79     ...    member_index=${sink_member_index}
  80     KarafKeywords.Execute_Controller_Karaf_Command_On_Background    config:update    member_index=${sink_member_index}