csit/libraries/OcpAgentKeywords.robot

   1 *** Settings ***
   2 Documentation     OCP agent library. This library is useful for tests using ocp agent tool to simulate RRH devices.
   3 Library           SSHLibrary
   4 Resource          SSHKeywords.robot
   5 Resource          OVSDB.robot
   6 Variables         ../variables/Variables.py
   7
   8 *** Keywords ***
   9 Install Agent
  10     [Arguments]    ${mininet}=${TOOLS_SYSTEM_IP}    ${controller}=${ODL_SYSTEM_IP}
  11     [Documentation]    Start Agent with custom topology and connect to controller.
  12     Log    Clear any existing Agent
  13     ${conn_id}=    SSHLibrary.Open Connection    ${mininet}    prompt=${TOOLS_SYSTEM_PROMPT}    timeout=${DEFAULT_TIMEOUT}
  14     Set Suite Variable    ${conn_id}
  15     SSHKeywords.Flexible Mininet Login
  16     SSHLibrary.Write    rm -rf /tmp/agent
  17     SSHLibrary.Write    pkill -f OcpAgent
  18     SSHLibrary.Write    git clone https://git.opendaylight.org/gerrit/ocpplugin.git /tmp/agent
  19     SSHLibrary.Read Until    Checking connectivity... done
  20     SSHLibrary.Write    cd /tmp/agent/simple-agent
  21     SSHLibrary.Write    javac -verbose src/main/java/org/opendaylight/ocpplugin/OcpAgent.java
  22     SSHLibrary.Read Until    OcpAgent.class
  23     Log    Agent installed
  24     Close Connection
  25
  26 Start Emulator Single
  27     [Arguments]    ${mininet}=${TOOLS_SYSTEM_IP}    ${controller}=${ODL_SYSTEM_IP}    ${vendorID}=TST    ${serialNumber}=100
  28     [Documentation]    Start Agent with custom topology and connect to controller.
  29     ${mininet_conn_id}=    SSHLibrary.Open Connection    ${mininet}    prompt=${TOOLS_SYSTEM_PROMPT}    timeout=${DEFAULT_TIMEOUT}
  30     Set Suite Variable    ${mininet_conn_id}
  31     SSHKeywords.Flexible Mininet Login
  32     SSHLibrary.Write    java -cp /tmp/agent/simple-agent/src/main/java/ org.opendaylight.ocpplugin.OcpAgent ${controller} 1033 ${vendorID} ${serialNumber}
  33     SSHLibrary.Read Until    getParamResp
  34     [Return]    ${mininet_conn_id}
  35
  36 Start Emulator Multiple
  37     [Arguments]    ${mininet}=${TOOLS_SYSTEM_IP}    ${controller}=${ODL_SYSTEM_IP}    ${vendorID}=TST    ${number}=100
  38     [Documentation]    Start Agent with custom topology and connect to controller.
  39     ${mininet_conn_id}=    SSHLibrary.Open Connection    ${mininet}    prompt=${TOOLS_SYSTEM_PROMPT}    timeout=${DEFAULT_TIMEOUT}
  40     Set Suite Variable    ${mininet_conn_id}
  41     SSHKeywords.Flexible Mininet Login
  42     FOR    ${NODE_NUM}    IN RANGE    1    ${number}
  43         SSHLibrary.Write    java -cp /tmp/agent/simple-agent/src/main/java/ org.opendaylight.ocpplugin.OcpAgent ${controller} 1033 ${vendorID} ${NODE_NUM} &
  44         SSHLibrary.Read Until    getParamResp
  45     END
  46     [Return]    ${mininet_conn_id}
  47
  48 Stop Emulator And Exit
  49     [Arguments]    ${mininet_conn_id}
  50     [Documentation]    Stops Agent and exits session ${mininet_conn_id}
  51     SSHLibrary.Switch Connection    ${mininet_conn_id}
  52     SSHLibrary.Write    pkill -f OcpAgent
  53     Close Connection