csit/libraries/OpenStackOperations.robot

   1 *** Settings ***
   2 Documentation     Openstack library. This library is useful for tests to create network, subnet, router and vm instances
   3 Library           Collections
   4 Library           Process
   5 Library           OperatingSystem
   6 Library           RequestsLibrary
   7 Library           SSHLibrary
   8 Library           String
   9 Resource          DataModels.robot
  10 Resource          DevstackUtils.robot
  11 Resource          KarafKeywords.robot
  12 Resource          L2GatewayOperations.robot
  13 Resource          ODLTools.robot
  14 Resource          OVSDB.robot
  15 Resource          SetupUtils.robot
  16 Resource          SSHKeywords.robot
  17 Resource          Tcpdump.robot
  18 Resource          Utils.robot
  19 Resource          ../variables/Variables.robot
  20 Resource          ../variables/netvirt/Variables.robot
  21 Variables         ../variables/netvirt/Modules.py
  22
  23 *** Variables ***
  24 @{VALIDATION_KEYWORDS}    Verify Services    Verify Expected Default Tunnels    Verify Expected Default Tables On Nodes
  25 ${VALIDATION_FILE}    /tmp/validations.txt
  26
  27 *** Keywords ***
  28 Get Tenant ID From Security Group
  29     [Documentation]    Returns tenant ID by reading it from existing default security-group.
  30     ${output} =    OpenStack CLI    openstack security group show default | grep "| tenant_id" | awk '{print $4}'
  31     [Return]    ${output}
  32
  33 Get Tenant ID From Network
  34     [Arguments]    ${network_uuid}
  35     [Documentation]    Returns tenant ID by reading it from existing network.
  36     ${resp} =    TemplatedRequests.Get_From_Uri    uri=${CONFIG_API}/neutron:neutron/networks/network/${network_uuid}/    accept=${ACCEPT_EMPTY}    session=session
  37     ${temp_vars} =    BuiltIn.Set Variable    ['network'][0]['tenant-id']
  38     ${tenant_id} =    Utils.Extract Value From Content    ${resp}    ${temp_vars}
  39     [Return]    ${tenant_id}
  40
  41 Create Network
  42     [Arguments]    ${network_name}    ${additional_args}=${EMPTY}    ${verbose}=TRUE
  43     [Documentation]    Create Network with openstack request.
  44     ${output} =    OpenStack CLI    openstack network create ${network_name} ${additional_args}
  45     [Return]    ${output}
  46
  47 Create Multiple Networks
  48     [Arguments]    @{name_of_networks}
  49     [Documentation]    Create required number of networks and return a list of the resulting network ids
  50     ${net_list_ids} =    BuiltIn.Create List    @{EMPTY}
  51     FOR    ${net}    IN    @{name_of_networks}
  52         ${output} =    OpenStackOperations.Create Network    ${net}
  53         ${net_id} =    Get Regexp Matches    ${output}    ${REGEX_UUID}
  54         Collections.Append To List    ${net_list_ids}    ${net_id}
  55     END
  56     [Return]    @{net_list_ids}
  57
  58 Update Network
  59     [Arguments]    ${network_name}    ${additional_args}=${EMPTY}
  60     [Documentation]    Update Network with neutron request.
  61     ${output} =    OpenStack CLI    openstack network set ${network_name} ${additional_args}
  62     [Return]    ${output}
  63
  64 Show Network
  65     [Arguments]    ${network_name}
  66     [Documentation]    Show Network with neutron request.
  67     ${output} =    OpenStack CLI    openstack network show ${network_name}
  68     [Return]    ${output}
  69
  70 List Networks
  71     [Documentation]    List networks and return output with neutron client.
  72     ${output} =    OpenStack CLI    openstack network list
  73     [Return]    ${output}
  74
  75 List Subnets
  76     [Documentation]    List subnets and return output with neutron client.
  77     ${output} =    OpenStack CLI    openstack subnet list
  78     [Return]    ${output}
  79
  80 Delete Network
  81     [Arguments]    ${network_name}
  82     [Documentation]    Delete Network with neutron request.
  83     ${output} =    OpenStack CLI    openstack network delete ${network_name}
  84
  85 Create SubNet
  86     [Arguments]    ${network_name}    ${subnet_name}    ${range_ip}    ${additional_args}=${EMPTY}
  87     [Documentation]    Create SubNet for the Network with neutron request.
  88     ${output} =    OpenStack CLI    openstack subnet create --network ${network_name} --subnet-range ${range_ip} ${subnet_name} ${additional_args}
  89
  90 Create Multiple Subnets
  91     [Arguments]    ${network_names}    ${subnet_names}    ${subnet_cidr}
  92     [Documentation]    Create required number of subnets for previously created networks and return subnet id
  93     ${number_of_networks} =    BuiltIn.Get Length    ${network_names}
  94     @{subnet_id_list} =    BuiltIn.Create List    @{EMPTY}
  95     FOR    ${index}    IN RANGE    ${number_of_networks}
  96         OpenStackOperations.Create SubNet    ${network_names[${index}]}    ${subnet_names[${index}]}    ${subnet_cidr[${index}]}
  97     END
  98     ${sub_list} =    OpenStackOperations.List Subnets
  99     FOR    ${index}    IN RANGE    ${number_of_networks}
 100         BuiltIn.Should Contain    ${sub_list}    ${subnet_names[${index}]}
 101         ${subnet_id} =    OpenStackOperations.Get Subnet Id    ${subnet_names[${index}]}
 102         Collections.Append To List    ${subnet_id_list}    ${subnet_id}
 103     END
 104     [Return]    @{subnet_id_list}
 105
 106 Update SubNet
 107     [Arguments]    ${subnet_name}    ${additional_args}=${EMPTY}
 108     [Documentation]    Update subnet with openstack subnet set request.
 109     ${output} =    OpenStack CLI    openstack subnet set ${subnet_name} ${additional_args}
 110     [Return]    ${output}
 111
 112 Unset SubNet
 113     [Arguments]    ${subnet_name}    ${additional_args}=${EMPTY}
 114     [Documentation]    Update subnet with openstack subnet unset request
 115     ${output} =    OpenStack CLI    openstack subnet unset ${subnet_name} ${additional_args}
 116     [Return]    ${output}
 117
 118 Show SubNet
 119     [Arguments]    ${subnet_name}
 120     [Documentation]    Show subnet with neutron request.
 121     ${output} =    OpenStack CLI    openstack subnet show ${subnet_name}
 122     [Return]    ${output}
 123
 124 Create Port
 125     [Arguments]    ${network_name}    ${port_name}    ${sg}=default    ${additional_args}=${EMPTY}    ${allowed_address_pairs}=${EMPTY}
 126     [Documentation]    Create Port with neutron request.
 127     # if allowed_address_pairs is not empty we need to create the arguments to pass to the port create command. They are
 128     # in a different format with the neutron vs openstack cli.
 129     ${address_pair_length} =    BuiltIn.Get Length    ${allowed_address_pairs}
 130     ${allowed_pairs_argv} =    BuiltIn.Set Variable    ${EMPTY}
 131     ${allowed_pairs_argv} =    BuiltIn.Set Variable If    '${address_pair_length}'=='2'    --allowed-address ip-address=${allowed_address_pairs}[0] --allowed-address ip-address=${allowed_address_pairs}[1]    ${allowed_pairs_argv}
 132     ${output} =    OpenStack CLI    openstack port create --network ${network_name} ${port_name} --security-group ${sg} ${additional_args} ${allowed_pairs_argv}
 133
 134 Update Port
 135     [Arguments]    ${port_name}    ${additional_args}=${EMPTY}
 136     [Documentation]    Update port with neutron request.
 137     ${output} =    OpenStack CLI    openstack port set ${port_name} ${additional_args}
 138     [Return]    ${output}
 139
 140 Show Port
 141     [Arguments]    ${port_name}
 142     [Documentation]    Show port with neutron request.
 143     ${output} =    OpenStack CLI    openstack port show ${port_name}
 144     [Return]    ${output}
 145
 146 Delete Port
 147     [Arguments]    ${port_name}
 148     [Documentation]    Delete Port with neutron request.
 149     ${output} =    OpenStack CLI    openstack port delete ${port_name}
 150
 151 List Ports
 152     [Documentation]    List ports and return output with neutron client.
 153     ${output} =    OpenStack CLI    openstack port list
 154     [Return]    ${output}
 155
 156 List Nova VMs
 157     [Documentation]    List VMs and return output with nova client.
 158     ${output} =    OpenStack CLI    openstack server list --all-projects
 159     [Return]    ${output}
 160
 161 Create And Associate Floating IPs
 162     [Arguments]    ${external_net}    @{vm_list}
 163     [Documentation]    Create and associate floating IPs to VMs with nova request
 164     ${ip_list} =    BuiltIn.Create List    @{EMPTY}
 165     FOR    ${vm}    IN    @{vm_list}
 166         ${output} =    OpenStack CLI    openstack floating ip create ${external_net}
 167         @{ip} =    String.Get Regexp Matches    ${output}    [0-9]{1,3}\\.[0-9]{1,3}\\.[0-9]{1,3}\\.[0-9]{1,3}
 168         ${ip_length} =    BuiltIn.Get Length    ${ip}
 169         BuiltIn.Run Keyword If    ${ip_length}>0    Collections.Append To List    ${ip_list}    ${ip}[0]
 170         ...    ELSE    Collections.Append To List    ${ip_list}    None
 171         ${vm_ip} =    OpenStack CLI    openstack server show ${vm} | grep "addresses" | awk '{print $4}' | cut -d"=" -f 2
 172         ${port_id} =    OpenStack CLI    openstack port list | grep "ip_address='${vm_ip}'" | awk '{print $2}' | cut -d"=" -f 2
 173         ${output} =    BuiltIn.Run Keyword If    '${OPENSTACK_BRANCH}' == 'stable/rocky'    OpenStack CLI    openstack floating ip set --port ${port_id} ${ip}[0]
 174         ...    ELSE    OpenStack CLI    openstack server add floating ip ${vm} ${ip}[0]
 175     END
 176     [Return]    ${ip_list}
 177
 178 Remove Floating Ip From Vm
 179     [Arguments]    ${vm_name}    ${fip}
 180     [Documentation]    Remove the Floating IP From VM Instance
 181     ${vm_ip} =    OpenStack CLI    openstack server show ${vm_name} | grep "addresses" | awk '{print $4}' | cut -d"=" -f 2
 182     ${port_id} =    OpenStack CLI    openstack port list | grep "ip_address='${vm_ip}'" | awk '{print $2}' | cut -d"=" -f 2
 183     ${output} =    BuiltIn.Run Keyword If    '${OPENSTACK_BRANCH}' == 'stable/rocky'    OpenStack CLI    openstack floating ip unset --port ${port_id} ${fip}
 184     ...    ELSE    OpenStack CLI    openstack server remove floating ip ${vm_name} ${fip}
 185
 186 Delete Floating IP
 187     [Arguments]    ${fip}
 188     [Documentation]    Delete floating ip with neutron request.
 189     ${output} =    OpenStack CLI    openstack floating ip delete ${fip}
 190
 191 Delete SubNet
 192     [Arguments]    ${subnet}
 193     [Documentation]    Delete SubNet for the Network with neutron request.
 194     ${output} =    OpenStack CLI    openstack subnet delete ${subnet}
 195
 196 Delete Vm Instance
 197     [Arguments]    ${vm_name}
 198     [Documentation]    Delete Vm instances using instance names.
 199     ${output} =    OpenStack CLI    openstack server delete ${vm_name}
 200
 201 Get Net Id
 202     [Arguments]    ${network_name}
 203     [Documentation]    Retrieve the net id for the given network name to create specific vm instance
 204     ${output} =    OpenStack CLI    openstack network list | grep "${network_name}" | awk '{print $2}'
 205     ${splitted_output} =    String.Split String    ${output}    ${EMPTY}
 206     ${net_id} =    Collections.Get from List    ${splitted_output}    0
 207     [Return]    ${net_id}
 208
 209 Get Subnet Id
 210     [Arguments]    ${subnet_name}
 211     [Documentation]    Retrieve the subnet id for the given subnet name
 212     ${output} =    OpenStack CLI    openstack subnet show "${subnet_name}" | grep " id " | awk '{print $4}'
 213     ${splitted_output} =    String.Split String    ${output}    ${EMPTY}
 214     ${subnet_id} =    Collections.Get from List    ${splitted_output}    0
 215     [Return]    ${subnet_id}
 216
 217 Get Port Id
 218     [Arguments]    ${port_name}
 219     [Documentation]    Retrieve the port id for the given port name to attach specific vm instance to a particular port
 220     ${output} =    OpenStack CLI    openstack port list | grep "${port_name}" | awk '{print $2}'
 221     ${splitted_output} =    String.Split String    ${output}    ${EMPTY}
 222     ${port_id} =    Collections.Get from List    ${splitted_output}    0
 223     [Return]    ${port_id}
 224
 225 Get Sub Port Id
 226     [Arguments]    ${portname}
 227     [Documentation]    Retrieve the first 10 chars of the UUID for the given port name
 228     ${port_id} =    OpenStackOperations.Get Port Id    ${portname}
 229     ${output} =    String.Get Regexp Matches    ${port_id}    \\w{8}-\\w{2}
 230     ${subport_id} =    Collections.Get from List    ${output}    0
 231     [Return]    ${subport_id}
 232
 233 Get Router Id
 234     [Arguments]    ${router1}
 235     [Documentation]    Retrieve the router id for the given router name
 236     ${output} =    OpenStack CLI    openstack router show "${router1}" |awk '/ id / {print $4}'
 237     ${splitted_output} =    String.Split String    ${output}    ${EMPTY}
 238     ${router_id} =    Collections.Get from List    ${splitted_output}    0
 239     [Return]    ${router_id}
 240
 241 Get VMs OVS Port Number
 242     [Arguments]    ${ip_address}    ${portname}
 243     [Documentation]    Get the port number for given portname
 244     ${subportid} =    OpenStackOperations.Get Sub Port Id    ${portname}
 245     ${vm_port_number} =    OVSDB.Get Port Number    ${subportid}    ${ip_address}
 246     [Return]    ${vm_port_number}
 247
 248 Add New Image From Url
 249     [Arguments]    ${image_url}    ${image_name}
 250     [Documentation]    To add new qcow2 images for testing.
 251     ${rc}    ${output} =    OperatingSystem.Run And Return Rc And Output    wget ${image_url} -O /tmp/new_image.qcow2
 252     BuiltIn.Log    ${output}
 253     BuiltIn.Should Be True    '${rc}' == '0'
 254     ${output} =    OpenStack CLI    openstack image create ${image_name} --file /tmp/new_image.qcow2 --disk-format qcow2 --container-format bare --public
 255
 256 Create Flavor
 257     [Arguments]    ${flavor_name}    ${ram_in_mb}    ${disk_in_gb}    ${ncpu}=1
 258     [Documentation]    To create new flavors for instance deployment and testing
 259     ${output} =    OpenStack CLI    openstack flavor create ${flavor_name} --ram ${ram_in_mb} --disk ${disk_in_gb} --vcpus ${ncpu}
 260
 261 Create Keypair
 262     [Arguments]    ${keyname}    ${public_key_file}
 263     [Documentation]    To add keypairs to Openstack that can be used when ssh to instances using publickey authentication
 264     ${output} =    OpenStack CLI    openstack keypair create ${keyname} --public-key ${public_key_file}
 265
 266 Generate And Add Keypair
 267     [Arguments]    ${keyname}    ${keyfilename}
 268     [Documentation]    To generate keypair using ssh-keygen and add them to Openstack
 269     ${result} =    Process.Run Process    ssh-keygen -b 2048 -t rsa -f ${JENKINS_WORKSPACE}/${keyfilename} -q -N ""    shell=True
 270     BuiltIn.Log    ${result.stdout}
 271     BuiltIn.Log    ${result.stderr}
 272     BuiltIn.Should Be True    '${result.rc}' == '0'
 273     OpenStackOperations.Create Keypair    ${keyname}    ${JENKINS_WORKSPACE}/${keyfilename}.pub
 274     OpenStackOperations.Get ControlNode Connection
 275     SSHLibrary.Put_File    ${JENKINS_WORKSPACE}/${keyfilename}    /tmp
 276
 277 Create Vm Instances
 278     [Arguments]    ${net_name}    ${vm_instance_names}    ${image}=${EMPTY}    ${flavor}=m1.nano    ${sg}=default    ${min}=1
 279     [Documentation]    Create X Vm Instance with the net id of the Netowrk.
 280     ..    ${max}=1
 281     ${image}    BuiltIn.Set Variable If    "${image}"=="${EMPTY}"    ${CIRROS_${OPENSTACK_BRANCH}}    ${image}
 282     ${net_id} =    OpenStackOperations.Get Net Id    ${net_name}
 283     FOR    ${vm}    IN    @{vm_instance_names}
 284         ${output} =    OpenStack CLI    openstack server create --image ${image} --flavor ${flavor} --nic net-id=${net_id} ${vm} --security-group ${sg} --min ${min} --max ${max}
 285     END
 286
 287 Create Vm Instance On Compute Node
 288     [Arguments]    ${net_name}    ${vm_name}    ${node_hostname}    ${image}=${EMPTY}    ${flavor}=m1.nano    ${sg}=default
 289     [Documentation]    Create a VM instance on a specific compute node.
 290     ${image} =    BuiltIn.Set Variable If    "${image}"=="${EMPTY}"    ${CIRROS_${OPENSTACK_BRANCH}}    ${image}
 291     ${net_id} =    OpenStackOperations.Get Net Id    ${net_name}
 292     ${output} =    OpenStack CLI    openstack server create ${vm_name} --image ${image} --flavor ${flavor} --nic net-id=${net_id} --security-group ${sg} --availability-zone nova:${node_hostname}
 293
 294 Create Vm Instance With Port
 295     [Arguments]    ${port_name}    ${vm_instance_name}    ${image}=${EMPTY}    ${flavor}=m1.nano    ${sg}=default
 296     [Documentation]    Create One VM instance using given ${port_name} and for given ${compute_node}
 297     ${image} =    BuiltIn.Set Variable If    "${image}"=="${EMPTY}"    ${CIRROS_${OPENSTACK_BRANCH}}    ${image}
 298     ${output} =    OpenStack CLI    openstack server create --image ${image} --flavor ${flavor} --port ${port_name} --security-group ${sg} ${vm_instance_name}
 299
 300 Create Vm Instance With Ports And Key On Compute Node
 301     [Arguments]    ${port1_name}    ${port2_name}    ${vm_instance_name}    ${node_hostname}    ${image}=${EMPTY}    ${flavor}=m1.nano
 302     ...    ${sg}=default    ${keyname}=${EMPTY}
 303     [Documentation]    Create One VM instance using given ${port1_name} and ${port2_name} with keyname for ssh and also on a specific compute node
 304     ${image}    BuiltIn.Set Variable If    "${image}"=="${EMPTY}"    ${CIRROS_${OPENSTACK_BRANCH}}    ${image}
 305     ${output} =    OpenStack CLI    openstack server create --image ${image} --flavor ${flavor} --port ${port1_name} --port ${port2_name} ${vm_instance_name} --security-group ${sg} --availability-zone nova:${node_hostname} --key-name ${keyname}
 306
 307 Create Vm Instance With Port On Compute Node
 308     [Arguments]    ${port_name}    ${vm_instance_name}    ${node_hostname}    ${image}=${EMPTY}    ${flavor}=m1.nano    ${sg}=default
 309     [Documentation]    Create One VM instance using given ${port_name} and for given ${node_hostname}
 310     ${image} =    BuiltIn.Set Variable If    "${image}"=="${EMPTY}"    ${CIRROS_${OPENSTACK_BRANCH}}    ${image}
 311     ${output} =    OpenStack CLI    openstack server create --image ${image} --flavor ${flavor} --port ${port_name} --security-group ${sg} --availability-zone nova:${node_hostname} ${vm_instance_name}
 312
 313 Remove Security Group From Vm Instance
 314     [Arguments]    ${vm_instance_name}    ${security_group}
 315     [Documentation]    Delete the Security Group from the VM Instance.
 316     ${output} =    OpenStack CLI    openstack server remove security group ${vm_instance_name} ${security_group}
 317
 318 Create Vm Instance With Ports On Compute Node
 319     [Arguments]    ${port1_name}    ${port2_name}    ${vm_instance_name}    ${node_hostname}    ${image}=${EMPTY}    ${flavor}=m1.nano
 320     ...    ${sg}=default
 321     [Documentation]    Create One VM instance using given ${port1_name}, ${port2_name} and for given ${node_hostname} with no keys (cirros like)
 322     ${image} =    BuiltIn.Set Variable If    "${image}"=="${EMPTY}"    ${CIRROS_${OPENSTACK_BRANCH}}    ${image}
 323     ${port1_id} =    OpenStackOperations.Get Port Id    ${port1_name}
 324     ${port2_id} =    OpenStackOperations.Get Port Id    ${port2_name}
 325     ${output} =    OpenStack CLI    openstack server create --image ${image} --flavor ${flavor} --nic port-id=${port1_id} --nic port-id=${port2_id} --security-group ${sg} --availability-zone nova:${node_hostname} ${vm_instance_name}
 326
 327 Get Hypervisor Hostname From IP
 328     [Arguments]    ${hypervisor_ip}
 329     [Documentation]    Returns the hostname found for the given IP address if it's listed in hypervisor list. For debuggability
 330     ...    the full listing is logged first, then followed by a grep | cut to focus on the actual hostname to return
 331     ${output} =    OpenStack CLI    openstack hypervisor list
 332     ${hostname} =    OpenStack CLI    openstack hypervisor list -f value | grep "${hypervisor_ip} " | cut -d" " -f 2
 333     [Return]    ${hostname}
 334
 335 Create Nano Flavor
 336     [Documentation]    Create a nano flavor
 337     ${output} =    OpenStack CLI    openstack flavor create m1.nano --id auto --ram 64 --disk 0 --vcpus 1
 338
 339 Verify VM Is ACTIVE
 340     [Arguments]    ${vm_name}
 341     [Documentation]    Run these commands to check whether the created vm instance is active or not.
 342     OpenStack CLI    openstack server show ${vm_name}
 343     ${output} =    OpenStack CLI    openstack server show ${vm_name} | grep OS-EXT-STS:vm_state
 344     BuiltIn.Should Contain    ${output}    active
 345
 346 Poll VM Is ACTIVE
 347     [Arguments]    ${vm_name}    ${retry}=600s    ${retry_interval}=30s
 348     [Documentation]    Run these commands to check whether the created vm instance is active or not.
 349     BuiltIn.Wait Until Keyword Succeeds    ${retry}    ${retry_interval}    OpenStackOperations.Verify VM Is ACTIVE    ${vm_name}
 350
 351 Get Match
 352     [Arguments]    ${text}    ${regexp}    ${index}=0
 353     [Documentation]    Wrapper around String.Get Regexp Matches to return None if not found or the first match if found.
 354     @{matches} =    String.Get Regexp Matches    ${text}    ${regexp}
 355     ${matches_length} =    BuiltIn.Get Length    ${matches}
 356     BuiltIn.Set Suite Variable    ${OS_MATCH}    None
 357     BuiltIn.Run Keyword If    ${matches_length} > ${index}    BuiltIn.Set Suite Variable    ${OS_MATCH}    ${matches}[${index}]
 358     [Return]    ${OS_MATCH}
 359
 360 Get VM IP
 361     [Arguments]    ${fail_on_none}    ${vm}
 362     [Documentation]    Get the vm ip address and nameserver by scraping the vm's console log.
 363     ...    Get VM IP returns three values: [0] the vm IP, [1] the DHCP IP and [2] the vm console log.
 364     ${vm_console_output} =    OpenStack CLI With No Log    openstack console log show ${vm}
 365     ${vm_ip} =    BuiltIn.Set Variable    None
 366     ${dhcp_ip} =    BuiltIn.Set Variable    None
 367     ${match} =    OpenStackOperations.Get Match    ${vm_console_output}    ${REGEX_OBTAINED}
 368     ${vm_ip} =    OpenStackOperations.Get Match    ${match}    ${REGEX_IPV4}    0
 369     ${match} =    OpenStackOperations.Get Match    ${vm_console_output}    ${REGEX_IPROUTE}
 370     ${dhcp_ip} =    OpenStackOperations.Get Match    ${match}    ${REGEX_IPV4}    1
 371     BuiltIn.Run Keyword If    '${fail_on_none}' == 'true'    BuiltIn.Should Not Contain    ${vm_ip}    None
 372     BuiltIn.Run Keyword If    '${fail_on_none}' == 'true'    BuiltIn.Should Not Contain    ${dhcp_ip}    None
 373     [Return]    ${vm_ip}    ${dhcp_ip}    ${vm_console_output}
 374
 375 Verify If Instance Is Arpingable From DHCP Namespace
 376     [Arguments]    ${net_name}    ${mac}    ${ip}
 377     [Documentation]    Get the Port IP and check the arp -a from DHCP NS to ensure that the VM's have been assigned IP's
 378     OpenStackOperations.Get ControlNode Connection
 379     ${net_id} =    OpenStackOperations.Get Net Id    ${net_name}
 380     ${output} =    Utils.Write Commands Until Expected Prompt    sudo ip netns exec qdhcp-${net_id} arping ${ip} -c3    ${DEFAULT_LINUX_PROMPT_STRICT}    timeout=60s
 381     ${mac_uppercase} =    String.Convert To Upper Case    ${mac}
 382     BuiltIn.Should Contain    ${output}    [${mac_uppercase}]
 383
 384 Check If Instance Is Ready For Ssh Login Using PublicKey
 385     [Arguments]    ${net_name}    ${vm_ip}    ${user}=centos    ${idfile}=/tmp/odlkey    ${console}=cirros
 386     [Documentation]    Ensure the VM is reachable from ssh as tests would require. This keyword will use publickey authentication
 387     ${output} =    Execute Command on VM Instance with PublicKey Auth    ${net_name}    ${vm_ip}    ifconfig    user=${user}    idfile=${idfile}
 388     ...    console=${console}
 389     BuiltIn.Should Contain    ${output}    ${vm_ip}
 390
 391 Check If Instance Is Ready For Ssh Login Using Password
 392     [Arguments]    ${net_name}    ${vm_ip}    ${user}=cirros    ${password}=${EMPTY}    ${console}=cirros
 393     [Documentation]    Ensure the VM is reachable from ssh as tests would require. This keyword will use password authentication
 394     ${password}    BuiltIn.Set Variable If    "${password}"=="${EMPTY}"    ${PASSWORD_CIRROS_${OPENSTACK_BRANCH}}
 395     ${output} =    Execute Command on VM Instance    ${net_name}    ${vm_ip}    ifconfig    ${user}    ${password}
 396     ...    console=${console}
 397     BuiltIn.Should Contain    ${output}    ${vm_ip}
 398
 399 Get VM IPs
 400     [Arguments]    @{vms}
 401     [Documentation]    Get the instance IP addresses and nameserver address for the list of given vms.
 402     ...    First poll for the vm instance to be in the active state, then poll for the vm ip address and nameserver.
 403     ...    Get VM IPs returns two things: [0] a list of the ips for the vms passed to this keyword (may contain values
 404     ...    of None) and [1] the dhcp ip address found in the last vm checked.
 405     ...    TODO: there is a potential issue for a caller that passes in VMs belonging to different networks that
 406     ...    may have different dhcp server addresses. Not sure what TODO about that, but noting it here for reference.
 407     @{vm_ips}    BuiltIn.Create List    @{EMPTY}
 408     FOR    ${vm}    IN    @{vms}
 409         OpenStackOperations.Poll VM Is ACTIVE    ${vm}
 410         ${status}    ${ips_and_console_log}    BuiltIn.Run Keyword And Ignore Error    BuiltIn.Wait Until Keyword Succeeds    180s    15s
 411         ...    OpenStackOperations.Get VM IP    true    ${vm}
 412         # If there is trouble with Get VM IP, the status will be FAIL and the return value will be a string of what went
 413         # wrong. We need to handle both the PASS and FAIL cases. In the FAIL case we know we wont have access to the
 414         # console log, as it would not be returned; so we need to grab it again to log it. We also can append 'None' to
 415         # the vm ip list if status is FAIL.
 416         BuiltIn.Run Keyword If    "${status}" == "PASS"    BuiltIn.Log    ${ips_and_console_log[2]}
 417         BuiltIn.Run Keyword If    "${status}" == "PASS"    Collections.Append To List    ${vm_ips}    ${ips_and_console_log[0]}
 418         BuiltIn.Run Keyword If    "${status}" == "FAIL"    Collections.Append To List    ${vm_ips}    None
 419         ${vm_console_output} =    BuiltIn.Run Keyword If    "${status}" == "FAIL"    OpenStack CLI    openstack console log show ${vm}
 420         BuiltIn.Run Keyword If    "${status}" == "FAIL"    BuiltIn.Log    ${vm_console_output}
 421     END
 422     OpenStackOperations.Copy DHCP Files From Control Node
 423     [Return]    @{vm_ips}    ${ips_and_console_log[1]}
 424
 425 Get All VM IP Addresses
 426     [Arguments]    ${conn_id}    ${vm_name}
 427     [Documentation]    Show information of a given two port VM and grep for two ip address. VM name should be sent as arguments.
 428     SSHLibrary.Switch Connection    ${conn_id}
 429     ${cmd} =    BuiltIn.Set Variable    openstack server show ${vm_name}
 430     ${output} =    OpenStackOperations.OpenStack CLI    ${cmd}
 431     BuiltIn.Log    ${output}
 432     ${address_output} =    OpenStackOperations.OpenStack CLI    ${cmd} | grep "addresses" | awk '{print $4$5}'
 433     @{vm_ips} =    String.Get Regexp Matches    ${address_output}    ${REGEX_IPV4}
 434     [Return]    @{vm_ips}
 435
 436 Get Subnet Gateway Ip
 437     [Arguments]    ${subnet_name}
 438     [Documentation]    Show information of a subnet and grep for subnet gateway ip address
 439     ${output} =    OpenStackOperations.OpenStack CLI    openstack subnet show ${subnet_name} | grep gateway_ip | awk '{print $4}'
 440     ${splitted_output} =    String.Split String    ${output}    ${EMPTY}
 441     ${matches} =    Collections.Get Matches    ${splitted_output}    regexp=(\\d\.)+
 442     ${subnet_gateway_ip} =    String.Strip String    ${matches[0]}    characters=','
 443     [Return]    ${subnet_gateway_ip}
 444
 445 Collect VM IPv6 SLAAC Addresses
 446     [Arguments]    ${fail_on_none}    ${vm_list}    ${network}    ${subnet}
 447     [Documentation]    For each VM parse output of "openstack server show" to get its IPv6 address from Neutron DB.
 448     ...    Then try to connect to each VM by SSH and execute there "ip -6 a" command. This double-check allows to
 449     ...    obtain and compare IP info (Neutron DB vs dnsmasque/ODL DHCP) and to test L2 connectivity as well.
 450     ...    Returns an empty list if no IPv6 addresses found or if SSH connection fails.
 451     ...    Otherwise, returns a list of IPv6 addresses.
 452     ${ipv6_list} =    BuiltIn.Create List    @{EMPTY}
 453     FOR    ${vm}    IN    @{vm_list}
 454         ${output} =    OpenStack CLI    openstack server show ${vm} -f shell
 455         ${pattern} =    String.Replace String    ${subnet}    ::/64    (:[a-f0-9]{,4}){,4}
 456         @{vm_ipv6} =    String.Get Regexp Matches    ${output}    ${pattern}
 457         ${vm_ip_length} =    BuiltIn.Get Length    ${vm_ipv6}[0]
 458         ${ipv6_data_from_vm} =    BuiltIn.Run Keyword If    ${vm_ip_length}>0    OpenStackOperations.Execute Command on VM Instance    ${network}    ${vm_ipv6[0]}
 459         ...    ip -6 a
 460         @{ipv6} =    String.Get Regexp Matches    ${ipv6_data_from_vm}    ${pattern}
 461         ${ipv6_addr_list_length}    BuiltIn.Get Length    @{ipv6}
 462         BuiltIn.Run Keyword If    ${ipv6_addr_list_length}>0    Collections.Append To List    ${ipv6_list}    ${ipv6[0]}
 463         ...    ELSE    Collections.Append To List    ${ipv6_list}    None
 464     END
 465     [Return]    ${ipv6_list}
 466
 467 View Vm Console
 468     [Arguments]    ${vm_instance_names}
 469     [Documentation]    View Console log of the created vm instances using nova show.
 470     FOR    ${vm}    IN    @{vm_instance_names}
 471         ${output} =    OpenStack CLI    openstack server show ${vm}
 472         ${output} =    OpenStack CLI    openstack console log show ${vm}
 473     END
 474
 475 Ping Vm From DHCP Namespace
 476     [Arguments]    ${net_name}    ${vm_ip}
 477     [Documentation]    Reach all Vm Instance with the net id of the Netowrk.
 478     OpenStackOperations.Get ControlNode Connection
 479     ${net_id} =    OpenStackOperations.Get Net Id    ${net_name}
 480     ${output} =    DevstackUtils.Write Commands Until Prompt And Log    sudo ip netns exec qdhcp-${net_id} ping -c 3 ${vm_ip}    20s
 481     BuiltIn.Should Contain    ${output}    64 bytes
 482
 483 Ping From DHCP Should Not Succeed
 484     [Arguments]    ${net_name}    ${vm_ip}
 485     [Documentation]    Should Not Reach Vm Instance with the net id of the Netowrk.
 486     Return From Keyword If    "skip_if_${SECURITY_GROUP_MODE}" in @{TEST_TAGS}
 487     OpenStackOperations.Get ControlNode Connection
 488     ${net_id} =    OpenStackOperations.Get Net Id    ${net_name}
 489     ${output} =    DevstackUtils.Write Commands Until Prompt And Log    sudo ip netns exec qdhcp-${net_id} ping -c 3 ${vm_ip}    20s
 490     BuiltIn.Should Not Contain    ${output}    64 bytes
 491
 492 Ping Vm From Control Node
 493     [Arguments]    ${vm_floating_ip}    ${additional_args}=${EMPTY}
 494     [Documentation]    Ping VM floating IP from control node
 495     OpenStackOperations.Get ControlNode Connection
 496     ${output} =    DevstackUtils.Write Commands Until Prompt And Log    ping ${additional_args} -c 3 ${vm_floating_ip}    20s
 497     BuiltIn.Should Contain    ${output}    64 bytes
 498
 499 Curl Metadata Server
 500     [Documentation]    Ping to the expected destination ip.
 501     ${output} =    Utils.Write Commands Until Expected Prompt    curl -i http://169.254.169.254    ${OS_SYSTEM_PROMPT}
 502     DevstackUtils.Write Commands Until Prompt    exit
 503     BuiltIn.Should Contain    ${output}    200
 504
 505 Close Vm Instance
 506     [Documentation]    Exit the vm instance.
 507     ${output} =    DevstackUtils.Write Commands Until Prompt And Log    exit
 508
 509 Check If Console Is VmInstance
 510     [Arguments]    ${console}=cirros
 511     [Documentation]    Check if the session has been able to login to the VM instance
 512     ${output} =    Utils.Write Commands Until Expected Prompt    id    ${OS_SYSTEM_PROMPT}
 513     BuiltIn.Should Contain    ${output}    ${console}
 514
 515 Exit From Vm Console
 516     [Arguments]    ${console}=cirros
 517     [Documentation]    Check if the session has been able to login to the VM instance and exit the instance
 518     ${rcode} =    BuiltIn.Run Keyword And Return Status    OpenStackOperations.Check If Console Is VmInstance    ${console}
 519     BuiltIn.Run Keyword If    ${rcode}    DevstackUtils.Write Commands Until Prompt    exit
 520
 521 Check Ping
 522     [Arguments]    ${ip_address}    ${ttl}=64    ${ping_tries}=3
 523     [Documentation]    Run Ping command on the IP available as argument
 524     ${ethertype} =    String.Get Regexp Matches    ${ip_address}    ${IP_REGEX}
 525     ${ping} =    BuiltIn.Set Variable If    ${ethertype}    ping    ping6
 526     ${cmd} =    BuiltIn.Set Variable    rc=0; for count in `seq 1 ${ping_tries}`; do ${ping} -W1 -t${ttl} -c5 ${ip_address}; rc=$?; if [ $rc -eq 0 ]; then break; fi; done; echo ping_rc=$rc
 527     ${output} =    Utils.Write Commands Until Expected Regexp    ${cmd}    ping_rc=\\d+    120
 528     BuiltIn.Log    output: ${output}
 529     BuiltIn.Should Contain    ${output}    64 bytes
 530
 531 Check No Ping
 532     [Arguments]    ${ip_address}    ${ttl}=64
 533     [Documentation]    Run Ping command to the IP given as argument, executing 3 times and expecting NOT to see "64 bytes"
 534     ${output} =    Utils.Write Commands Until Expected Prompt    ping -t ${ttl} -c 3 ${ip_address}    ${OS_SYSTEM_PROMPT}
 535     BuiltIn.Should Not Contain    ${output}    64 bytes
 536
 537 Check Metadata Access
 538     [Documentation]    Try curl on the Metadataurl and check if it is okay
 539     ${output} =    Utils.Write Commands Until Expected Prompt    curl -i http://169.254.169.254    ${OS_SYSTEM_PROMPT}
 540     BuiltIn.Should Contain    ${output}    200
 541
 542 Execute Command on VM Instance
 543     [Arguments]    ${net_name}    ${vm_ip}    ${cmd}    ${user}=cirros    ${password}=${EMPTY}    ${cmd_timeout}=30s
 544     ...    ${console}=cirros
 545     [Documentation]    Login to the vm instance using ssh in the network, executes a command inside the VM and returns the ouput.
 546     ${password}    BuiltIn.Set Variable If    "${password}"=="${EMPTY}"    ${PASSWORD_CIRROS_${OPENSTACK_BRANCH}}
 547     OpenStackOperations.Get ControlNode Connection
 548     ${net_id} =    OpenStackOperations.Get Net Id    ${net_name}
 549     ${output} =    Utils.Write Commands Until Expected Prompt    sudo ip netns exec qdhcp-${net_id} ssh ${user}@${vm_ip} -o MACs=hmac-sha1 -o ConnectTimeout=5 -o StrictHostKeyChecking=no -o UserKnownHostsFile=/dev/null -o PreferredAuthentications=password    password:
 550     ${output} =    Utils.Write Commands Until Expected Prompt    ${password}    ${OS_SYSTEM_PROMPT}
 551     ${rcode} =    BuiltIn.Run Keyword And Return Status    OpenStackOperations.Check If Console Is VmInstance    ${console}
 552     ${output} =    BuiltIn.Run Keyword If    ${rcode}    Utils.Write Commands Until Expected Prompt    ${cmd}    ${OS_SYSTEM_PROMPT}    timeout=${cmd_timeout}
 553     [Teardown]    Exit From Vm Console    ${console}
 554     [Return]    ${output}
 555
 556 Execute Command on VM Instance With PublicKey Auth
 557     [Arguments]    ${net_name}    ${vm_ip}    ${cmd}    ${user}=centos    ${idfile}=/tmp/odlkey    ${console}=cirros
 558     [Documentation]    Login to the vm instance using ssh publickey in the network, executes a command inside the VM and returns the ouput.
 559     OpenStackOperations.Get ControlNode Connection
 560     ${net_id} =    OpenStackOperations.Get Net Id    ${net_name}
 561     ${output} =    Utils.Write Commands Until Expected Prompt    sudo ip netns exec qdhcp-${net_id} ssh -i ${idfile} ${user}@${vm_ip} -o MACs=hmac-sha1 -o ConnectTimeout=5 -o StrictHostKeyChecking=no -o UserKnownHostsFile=/dev/null -o PreferredAuthentications=publickey    prompt=${OS_SYSTEM_PROMPT}    timeout=60s
 562     ${rcode} =    BuiltIn.Run Keyword And Return Status    OpenStackOperations.Check If Console Is VmInstance    ${console}
 563     ${output} =    BuiltIn.Run Keyword If    ${rcode}    Utils.Write Commands Until Expected Prompt    ${cmd}    ${OS_SYSTEM_PROMPT}
 564     [Teardown]    Exit From Vm Console    ${console}
 565     [Return]    ${output}
 566
 567 Copy File To VM Instance With PublicKey Auth
 568     [Arguments]    ${net_name}    ${vm_ip}    ${file_to_copy}    ${user}=centos    ${idfile}=/tmp/odlkey
 569     [Documentation]    Login to the vm instance using ssh publickey in the network, executes a command inside the VM and returns the ouput.
 570     OpenStackOperations.Get ControlNode Connection
 571     ${net_id} =    OpenStackOperations.Get Net Id    ${net_name}
 572     ${rc} =    SSHLibrary.Execute Command    sudo ip netns exec qdhcp-${net_id} scp -i ${idfile} -o MACs=hmac-sha1 -o ConnectTimeout=5 -o StrictHostKeyChecking=no -o UserKnownHostsFile=/dev/null -o PreferredAuthentications=publickey ${file_to_copy} ${user}@${vm_ip}:/tmp/    return_stdout=False    return_rc=True
 573     BuiltIn.Should Be True    '${rc}' == '0'
 574
 575 Test Operations From Vm Instance
 576     [Arguments]    ${net_name}    ${src_ip}    ${dest_ips}    ${user}=cirros    ${password}=${EMPTY}    ${ttl}=64
 577     ...    ${ping_should_succeed}=True    ${check_metadata}=True    ${console}=cirros    ${ping_tries}=3
 578     [Documentation]    Login to the vm instance using ssh in the network.
 579     ${password}    BuiltIn.Set Variable If    "${password}"=="${EMPTY}"    ${PASSWORD_CIRROS_${OPENSTACK_BRANCH}}
 580     OpenStackOperations.Get ControlNode Connection
 581     ${net_id} =    OpenStackOperations.Get Net Id    ${net_name}
 582     ${output} =    Utils.Write Commands Until Expected Prompt    sudo ip netns exec qdhcp-${net_id} ssh -o MACs=hmac-sha1 -o ConnectTimeout=5 -o StrictHostKeyChecking=no ${user}@${src_ip} -o UserKnownHostsFile=/dev/null    password:    10s
 583     ${output} =    Utils.Write Commands Until Expected Prompt    ${password}    ${OS_SYSTEM_PROMPT}
 584     ${rcode} =    BuiltIn.Run Keyword And Return Status    OpenStackOperations.Check If Console Is VmInstance    ${console}
 585     BuiltIn.Run Keyword If    ${rcode}    Utils.Write Commands Until Expected Prompt    ifconfig    ${OS_SYSTEM_PROMPT}
 586     BuiltIn.Run Keyword If    ${rcode}    Utils.Write Commands Until Expected Prompt    route -n    ${OS_SYSTEM_PROMPT}
 587     BuiltIn.Run Keyword If    ${rcode}    Utils.Write Commands Until Expected Prompt    route -A inet6    ${OS_SYSTEM_PROMPT}
 588     BuiltIn.Run Keyword If    ${rcode}    Utils.Write Commands Until Expected Prompt    arp -an    ${OS_SYSTEM_PROMPT}
 589     BuiltIn.Run Keyword If    ${rcode}    Utils.Write Commands Until Expected Prompt    ip -f inet6 neigh show    ${OS_SYSTEM_PROMPT}
 590     FOR    ${dest_ip}    IN    @{dest_ips}
 591         ${string_empty} =    BuiltIn.Run Keyword And Return Status    Should Be Empty    ${dest_ip}
 592         BuiltIn.Run Keyword If    ${string_empty}    Continue For Loop
 593         BuiltIn.Run Keyword If    ${rcode} and "${ping_should_succeed}" == "True"    OpenStackOperations.Check Ping    ${dest_ip}    ttl=${ttl}    ping_tries=${ping_tries}
 594         ...    ELSE    OpenStackOperations.Check No Ping    ${dest_ip}    ttl=${ttl}
 595     END
 596     ${ethertype} =    String.Get Regexp Matches    ${src_ip}    ${IP_REGEX}
 597     BuiltIn.Run Keyword If    ${rcode} and "${check_metadata}" and ${ethertype} == "True"    OpenStackOperations.Check Metadata Access
 598     [Teardown]    Exit From Vm Console    ${console}
 599
 600 Test Netcat Operations From Vm Instance
 601     [Arguments]    ${net_name}    ${vm_ip}    ${dest_ip}    ${additional_args}=${EMPTY}    ${port}=12345    ${user}=cirros
 602     ...    ${password}=${EMPTY}
 603     [Documentation]    Use Netcat to test TCP/UDP connections to the controller
 604     ${password}    BuiltIn.Set Variable If    "${password}"=="${EMPTY}"    ${PASSWORD_CIRROS_${OPENSTACK_BRANCH}}
 605     ${client_data}    BuiltIn.Set Variable    Test Client Data
 606     ${server_data}    BuiltIn.Set Variable    Test Server Data
 607     OpenStackOperations.Get ControlNode Connection
 608     ${output} =    DevstackUtils.Write Commands Until Prompt And Log    ( ( echo "${server_data}" | sudo timeout 60 nc -l ${additional_args} ${port} ) & )
 609     ${output} =    DevstackUtils.Write Commands Until Prompt And Log    sudo netstat -nlap | grep ${port}
 610     ${nc_output} =    OpenStackOperations.Execute Command on VM Instance    ${net_name}    ${vm_ip}    sudo echo "${client_data}" | nc -v -w 5 ${additional_args} ${dest_ip} ${port}
 611     BuiltIn.Log    ${output}
 612     ${output} =    OpenStackOperations.Execute Command on VM Instance    ${net_name}    ${vm_ip}    sudo route -n
 613     BuiltIn.Log    ${output}
 614     ${output} =    OpenStackOperations.Execute Command on VM Instance    ${net_name}    ${vm_ip}    sudo arp -an
 615     BuiltIn.Log    ${output}
 616     BuiltIn.Should Match Regexp    ${nc_output}    ${server_data}
 617
 618 Ping Other Instances
 619     [Arguments]    ${list_of_external_dst_ips}    ${console}=cirros
 620     [Documentation]    Check reachability with other network's instances.
 621     ${rcode} =    BuiltIn.Run Keyword And Return Status    OpenStackOperations.Check If Console Is VmInstance    ${console}
 622     FOR    ${dest_ip}    IN    @{list_of_external_dst_ips}
 623         OpenStackOperations.Check Ping    ${dest_ip}
 624     END
 625
 626 Create Router
 627     [Arguments]    ${router_name}
 628     [Documentation]    Create Router and Add Interface to the subnets.
 629     ${output} =    OpenStack CLI    openstack router create ${router_name}
 630
 631 List Routers
 632     [Documentation]    List Routers and return output with neutron client.
 633     ${output} =    OpenStack CLI    openstack router list -f value
 634     [Return]    ${output}
 635
 636 Add Router Interface
 637     [Arguments]    ${router_name}    ${interface_name}
 638     ${output} =    OpenStack CLI    openstack router add subnet ${router_name} ${interface_name}
 639
 640 Show Router Interface
 641     [Arguments]    ${router_name}
 642     [Documentation]    List Routers interface associated with given Router and return output with neutron client.
 643     ${output} =    OpenStack CLI    openstack port list --router ${router_name} -f value
 644     [Return]    ${output}
 645
 646 Add Router Gateway
 647     [Arguments]    ${router_name}    ${external_network_name}    ${additional_args}=${EMPTY}
 648     ${output} =    OpenStack CLI    openstack router set ${router_name} --external-gateway ${external_network_name} ${additional_args}
 649
 650 Remove Interface
 651     [Arguments]    ${router_name}    ${interface_name}
 652     [Documentation]    Remove Interface to the subnets.
 653     ${output} =    OpenStack CLI    openstack router remove subnet ${router_name} ${interface_name}
 654
 655 Remove Gateway
 656     [Arguments]    ${router_name}
 657     [Documentation]    Remove external gateway from the router.
 658     ${output} =    OpenStack CLI    openstack router unset ${router_name} --external-gateway
 659
 660 Update Router
 661     [Arguments]    ${router_name}    ${cmd}
 662     [Documentation]    Update the router with the command. Router name and command should be passed as argument.
 663     ${output} =    OpenStack CLI    openstack router set ${router_name} ${cmd}
 664
 665 Show Router
 666     [Arguments]    ${router_name}    ${additional_args}=${EMPTY}
 667     [Documentation]    Show information of a given router. Router name and optional fields should be sent as arguments.
 668     ${output} =    OpenStack CLI    openstack router show ${router_name} ${additional_args}
 669     [Return]    ${output}
 670
 671 Delete Router
 672     [Arguments]    ${router_name}
 673     [Documentation]    Delete Router and Interface to the subnets.
 674     ${output} =    OpenStack CLI    openstack router delete ${router_name}
 675
 676 Get DumpFlows And Ovsconfig
 677     [Arguments]    ${conn_id}
 678     [Documentation]    Get the OvsConfig and Flow entries from OVS from the Openstack Node
 679     SSHLibrary.Switch Connection    ${conn_id}
 680     Utils.Write Commands Until Expected Prompt    ip -o link    ${DEFAULT_LINUX_PROMPT_STRICT}
 681     Utils.Write Commands Until Expected Prompt    ip -o addr    ${DEFAULT_LINUX_PROMPT_STRICT}
 682     Utils.Write Commands Until Expected Prompt    ip route    ${DEFAULT_LINUX_PROMPT_STRICT}
 683     Utils.Write Commands Until Expected Prompt    arp -an    ${DEFAULT_LINUX_PROMPT_STRICT}
 684     ${nslist} =    Utils.Write Commands Until Expected Prompt    ip netns list | awk '{print $1}'    ${DEFAULT_LINUX_PROMPT_STRICT}
 685     @{lines}    Split To Lines    ${nslist}    end=-1
 686     FOR    ${line}    IN    @{lines}
 687         Utils.Write Commands Until Expected Prompt    sudo ip netns exec ${line} ip -o link    ${DEFAULT_LINUX_PROMPT_STRICT}
 688         Utils.Write Commands Until Expected Prompt    sudo ip netns exec ${line} ip -o addr    ${DEFAULT_LINUX_PROMPT_STRICT}
 689         Utils.Write Commands Until Expected Prompt    sudo ip netns exec ${line} ip route    ${DEFAULT_LINUX_PROMPT_STRICT}
 690     END
 691     Utils.Write Commands Until Expected Prompt    sudo ovs-vsctl show    ${DEFAULT_LINUX_PROMPT_STRICT}
 692     Utils.Write Commands Until Expected Prompt    sudo ovs-vsctl list Open_vSwitch    ${DEFAULT_LINUX_PROMPT_STRICT}
 693     Utils.Write Commands Until Expected Prompt    sudo ovs-ofctl show ${INTEGRATION_BRIDGE} -OOpenFlow13    ${DEFAULT_LINUX_PROMPT_STRICT}
 694     Utils.Write Commands Until Expected Prompt    sudo ovs-ofctl dump-flows ${INTEGRATION_BRIDGE} -OOpenFlow13    ${DEFAULT_LINUX_PROMPT_STRICT}
 695     Utils.Write Commands Until Expected Prompt    sudo ovs-ofctl dump-groups ${INTEGRATION_BRIDGE} -OOpenFlow13    ${DEFAULT_LINUX_PROMPT_STRICT}
 696     Utils.Write Commands Until Expected Prompt    sudo ovs-ofctl dump-group-stats ${INTEGRATION_BRIDGE} -OOpenFlow13    ${DEFAULT_LINUX_PROMPT_STRICT}
 697
 698 Get ControlNode Connection
 699     SSHLibrary.Switch Connection    ${OS_CNTL_CONN_ID}
 700     [Return]    ${OS_CNTL_CONN_ID}
 701
 702 Get OvsDebugInfo
 703     [Documentation]    Get the OvsConfig and Flow entries from all Openstack nodes
 704     FOR    ${conn_id}    IN    @{OS_ALL_CONN_IDS}
 705         OpenStackOperations.Get DumpFlows And Ovsconfig    ${conn_id}
 706     END
 707
 708 Get Test Teardown Debugs
 709     [Arguments]    ${test_name}=${SUITE_NAME}.${TEST_NAME}    ${fail}=${FAIL_ON_EXCEPTIONS}
 710     ODLTools.Get All    node_ip=${HA_PROXY_IP}    test_name=${test_name}
 711     OpenStackOperations.Get OvsDebugInfo
 712     BuiltIn.Run Keyword And Ignore Error    DataModels.Get Model Dump    ${HA_PROXY_IP}    ${netvirt_data_models}
 713     KarafKeywords.Fail If Exceptions Found During Test    ${test_name}    fail=${fail}
 714     FOR    ${i}    IN RANGE    ${NUM_ODL_SYSTEM}
 715         BuiltIn.Run Keyword And Ignore Error    Issue_Command_On_Karaf_Console    trace:transactions    ${ODL_SYSTEM_${i+1}_IP}
 716     END
 717
 718 Get Suite Debugs
 719     Get Test Teardown Debugs    test_name=${SUITE_NAME}    fail=False
 720
 721 Get Test Teardown Debugs For SFC
 722     [Arguments]    ${test_name}=${TEST_NAME}
 723     BuiltIn.Run Keyword And Ignore Error    DataModels.Get Model Dump    ${HA_PROXY_IP}    ${netvirt_sfc_data_models}
 724
 725 Show Debugs
 726     [Arguments]    @{vm_indices}
 727     [Documentation]    Run these commands for debugging, it can list state of VM instances and ip information in control node
 728     OpenStackOperations.Get ControlNode Connection
 729     ${output} =    DevstackUtils.Write Commands Until Prompt And Log    sudo ip netns list
 730     FOR    ${index}    IN    @{vm_indices}
 731         ${rc}    ${output} =    OperatingSystem.Run And Return Rc And Output    nova show ${index}
 732         BuiltIn.Log    ${output}
 733     END
 734     OpenStackOperations.List Nova VMs
 735     OpenStackOperations.List Routers
 736     OpenStackOperations.List Networks
 737     OpenStackOperations.List Subnets
 738     OpenStackOperations.List Ports
 739     OpenStackOperations.List Security Groups
 740
 741 List Security Groups
 742     [Documentation]    Logging keyword to display all security groups using the openstack cli. Assumes openstack
 743     ...    credentials are already sourced
 744     ${output} =    OpenStack CLI    openstack security group list
 745     [Return]    ${output}
 746
 747 Neutron Security Group Show
 748     [Arguments]    ${SecurityGroupRuleName}
 749     [Documentation]    Displays the neutron security group configurations that belongs to a given neutron security group name
 750     ${output} =    OpenStack CLI    openstack security group show ${SecurityGroupRuleName}
 751     [Return]    ${output}
 752
 753 Neutron Port Show
 754     [Arguments]    ${PortName}
 755     [Documentation]    Display the port configuration that belong to a given neutron port
 756     ${output} =    OpenStack CLI    openstack port show ${PortName}
 757     [Return]    ${output}
 758
 759 Neutron Security Group Create
 760     [Arguments]    ${SecurityGroupName}    ${additional_args}=${EMPTY}
 761     [Documentation]    Create a security group with specified name ,description & protocol value according to security group template
 762     OpenStackOperations.Get ControlNode Connection
 763     ${output} =    OpenStack CLI    openstack security group create ${SecurityGroupName} ${additional_args}
 764     ${sgp_id} =    BuiltIn.Should Match Regexp    ${output}    ${REGEX_UUID}
 765     [Return]    ${output}    ${sgp_id}
 766
 767 Neutron Security Group Update
 768     [Arguments]    ${SecurityGroupName}    ${additional_args}=${EMPTY}
 769     [Documentation]    Updating security groups
 770     ${output} =    OpenStack CLI    openstack security group set ${SecurityGroupName} ${additional_args}
 771     [Return]    ${output}
 772
 773 Delete SecurityGroup
 774     [Arguments]    ${sg_name}
 775     [Documentation]    Delete Security group
 776     ${output} =    OpenStack CLI    openstack security group delete ${sg_name}
 777
 778 Neutron Security Group Rule Create
 779     [Arguments]    ${Security_group_name}    &{Kwargs}
 780     [Documentation]    Creates neutron security rule with Openstack CLI with or without optional params, here security group name is mandatory args, rule with optional params can be created by passing the optional args values ex: direction=${INGRESS_EGRESS}, Then these optional params are BuiltIn.Catenated with mandatory args, example of usage: "OpenStack Neutron Security Group Rule Create ${SGP_SSH} direction=${RULE_PARAMS[0]} ethertype=${RULE_PARAMS[1]} ..."
 781     BuiltIn.Run Keyword If    ${Kwargs}    BuiltIn.Log    ${Kwargs}
 782     ${description}    BuiltIn.Run Keyword If    ${Kwargs}    Collections.Pop From Dictionary    ${Kwargs}    description    default=${None}
 783     ${direction}    BuiltIn.Run Keyword If    ${Kwargs}    Collections.Pop From Dictionary    ${Kwargs}    direction    default=${None}
 784     ${ethertype}    BuiltIn.Run Keyword If    ${Kwargs}    Collections.Pop From Dictionary    ${Kwargs}    ethertype    default=${None}
 785     ${port_range_max}    BuiltIn.Run Keyword If    ${Kwargs}    Collections.Pop From Dictionary    ${Kwargs}    port_range_max    default=${None}
 786     ${port_range_min}    BuiltIn.Run Keyword If    ${Kwargs}    Collections.Pop From Dictionary    ${Kwargs}    port_range_min    default=${None}
 787     ${protocol}    BuiltIn.Run Keyword If    ${Kwargs}    Collections.Pop From Dictionary    ${Kwargs}    protocol    default=${None}
 788     ${remote_group_id}    BuiltIn.Run Keyword If    ${Kwargs}    Collections.Pop From Dictionary    ${Kwargs}    remote_group_id    default=${None}
 789     ${remote_ip_prefix}    BuiltIn.Run Keyword If    ${Kwargs}    Collections.Pop From Dictionary    ${Kwargs}    remote_ip_prefix    default=${None}
 790     ${remote_ip}    BuiltIn.Run Keyword If    ${Kwargs}    Collections.Pop From Dictionary    ${Kwargs}    remote_ip    default=${None}
 791     ${cmd} =    BuiltIn.Set Variable    openstack security group rule create ${Security_group_name}
 792     ${cmd} =    BuiltIn.Run Keyword If    '${description}'!='None'    BuiltIn.Catenate    ${cmd}    --description ${description}
 793     ...    ELSE    BuiltIn.Catenate    ${cmd}
 794     ${cmd} =    BuiltIn.Run Keyword If    '${direction}'!='None'    BuiltIn.Catenate    ${cmd}    --${direction}
 795     ...    ELSE    BuiltIn.Catenate    ${cmd}
 796     ${cmd} =    BuiltIn.Run Keyword If    '${ethertype}'!='None'    BuiltIn.Catenate    ${cmd}    --ethertype ${ethertype}
 797     ...    ELSE    BuiltIn.Catenate    ${cmd}
 798     ${cmd} =    BuiltIn.Run Keyword If    '${port_range_min}'!='None' and '${port_range_max}'!='None'    BuiltIn.Catenate    ${cmd}    --dst-port ${port_range_min}:${port_range_max}
 799     ...    ELSE IF    '${port_range_max}'!='None'    BuiltIn.Catenate    ${cmd}    --dst-port ${port_range_max}
 800     ...    ELSE IF    '${port_range_min}'!='None'    BuiltIn.Catenate    ${cmd}    --dst-port ${port_range_min}
 801     ...    ELSE    BuiltIn.Catenate    ${cmd}
 802     ${cmd} =    BuiltIn.Run Keyword If    '${protocol}'!='None'    BuiltIn.Catenate    ${cmd}    --protocol ${protocol}
 803     ...    ELSE    BuiltIn.Catenate    ${cmd}
 804     ${cmd} =    BuiltIn.Run Keyword If    '${remote_group_id}'!='None'    BuiltIn.Catenate    ${cmd}    --remote-group ${remote_group_id}
 805     ...    ELSE    BuiltIn.Catenate    ${cmd}
 806     ${cmd} =    BuiltIn.Run Keyword If    '${remote_ip_prefix}'!='None'    BuiltIn.Catenate    ${cmd}    --src-ip ${remote_ip_prefix}
 807     ...    ELSE    BuiltIn.Catenate    ${cmd}
 808     ${cmd} =    BuiltIn.Run Keyword If    '${remote_ip}'!='None'    BuiltIn.Catenate    ${cmd}    --remote-ip ${remote_ip}
 809     ...    ELSE    BuiltIn.Catenate    ${cmd}
 810     ${output} =    OpenStack CLI    ${cmd}
 811     ${rule_id} =    BuiltIn.Should Match Regexp    ${output}    ${REGEX_UUID}
 812     [Return]    ${output}    ${rule_id}
 813
 814 Security Group Create Without Default Security Rules
 815     [Arguments]    ${sg_name}    ${additional_args}=${EMPTY}
 816     [Documentation]    Create Neutron Security Group with no default rules, using specified name and optional arguments.
 817     OpenStackOperations.Neutron Security Group Create    ${sg_name}    ${additional_args}
 818     Delete All Security Group Rules    ${sg_name}
 819
 820 Delete All Security Group Rules
 821     [Arguments]    ${sg_name}
 822     [Documentation]    Delete all security rules from a specified security group
 823     ${sg_rules_output} =    OpenStack CLI    openstack security group rule list ${sg_name} -cID -fvalue
 824     @{sg_rules} =    String.Split String    ${sg_rules_output}    \n
 825     FOR    ${rule}    IN    @{sg_rules}
 826         ${output} =    OpenStack CLI    openstack security group rule delete ${rule}
 827     END
 828
 829 Create Allow All SecurityGroup
 830     [Arguments]    ${sg_name}    ${ether_type}=IPv4    ${dual}=False
 831     [Documentation]    Allow all TCP/UDP/ICMP packets for this suite
 832     OpenStackOperations.Neutron Security Group Create    ${sg_name}
 833     OpenStackOperations.Neutron Security Group Rule Create    ${sg_name}    direction=ingress    ethertype=${ether_type}    port_range_max=65535    port_range_min=1    protocol=tcp
 834     OpenStackOperations.Neutron Security Group Rule Create    ${sg_name}    direction=egress    ethertype=${ether_type}    port_range_max=65535    port_range_min=1    protocol=tcp
 835     OpenStackOperations.Neutron Security Group Rule Create    ${sg_name}    direction=ingress    ethertype=${ether_type}    protocol=icmp
 836     OpenStackOperations.Neutron Security Group Rule Create    ${sg_name}    direction=egress    ethertype=${ether_type}    protocol=icmp
 837     OpenStackOperations.Neutron Security Group Rule Create    ${sg_name}    direction=ingress    ethertype=${ether_type}    port_range_max=65535    port_range_min=1    protocol=udp
 838     OpenStackOperations.Neutron Security Group Rule Create    ${sg_name}    direction=egress    ethertype=${ether_type}    port_range_max=65535    port_range_min=1    protocol=udp
 839     BuiltIn.Run Keyword If    "${dual}"=="True"    Run Keywords    OpenStackOperations.Neutron Security Group Rule Create    ${sg_name}    direction=ingress    ethertype=IPv6
 840     ...    port_range_max=65535    port_range_min=1    protocol=tcp
 841     ...    AND    OpenStackOperations.Neutron Security Group Rule Create    ${sg_name}    direction=egress    ethertype=IPv6    port_range_max=65535
 842     ...    port_range_min=1    protocol=tcp
 843     ...    AND    OpenStackOperations.Neutron Security Group Rule Create    ${sg_name}    direction=ingress    ethertype=IPv6    protocol=icmp
 844     ...    AND    OpenStackOperations.Neutron Security Group Rule Create    ${sg_name}    direction=egress    ethertype=IPv6    protocol=icmp
 845     ...    AND    OpenStackOperations.Neutron Security Group Rule Create    ${sg_name}    direction=ingress    ethertype=IPv6    port_range_max=65535
 846     ...    port_range_min=1    protocol=udp
 847     ...    AND    OpenStackOperations.Neutron Security Group Rule Create    ${sg_name}    direction=egress    ethertype=IPv6    port_range_max=65535
 848     ...    port_range_min=1    protocol=udp
 849
 850 Create Neutron Port With Additional Params
 851     [Arguments]    ${network_name}    ${port_name}    ${additional_args}=${EMPTY}
 852     [Documentation]    Create Port With given additional parameters
 853     ${rc}    ${output} =    OperatingSystem.Run And Return Rc And Output    neutron -v port-create ${network_name} --name ${port_name} ${additional_args}
 854     BuiltIn.Log    ${output}
 855     BuiltIn.Should Be True    '${rc}' == '0'
 856     ${port_id} =    BuiltIn.Should Match Regexp    ${OUTPUT}    ${REGEX_UUID}
 857     [Return]    ${OUTPUT}    ${port_id}
 858
 859 Get Ports MacAddr
 860     [Arguments]    ${ports}
 861     [Documentation]    Retrieve the port MacAddr for the given list of port name and return the MAC address list.
 862     ${macs}    BuiltIn.Create List
 863     FOR    ${port}    IN    @{ports}
 864         ${mac} =    OpenStackOperations.Get Port Mac    ${port}
 865         Collections.Append To List    ${macs}    ${mac}
 866     END
 867     [Return]    ${macs}
 868
 869 Get Port Ip
 870     [Arguments]    ${port_name}
 871     [Documentation]    Keyword would return the IP of the ${port_name} received.
 872     ${output} =    OpenStack CLI    openstack port list | grep "${port_name}" | awk -F\\' '{print $2}'
 873     ${splitted_output} =    String.Split String    ${output}    ${EMPTY}
 874     ${port_ip} =    Collections.Get from List    ${splitted_output}    0
 875     [Return]    ${port_ip}
 876
 877 Get Port Mac
 878     [Arguments]    ${port_name}
 879     [Documentation]    Keyword would return the MAC ID of the ${port_name} received.
 880     ${output} =    OpenStack CLI    openstack port show ${port_name} | grep mac_address | awk '{print $4}'
 881     ${splitted_output} =    String.Split String    ${output}    ${EMPTY}
 882     ${port_mac} =    Collections.Get from List    ${splitted_output}    0
 883     [Return]    ${port_mac}
 884
 885 Get Port Mac Address From Ip
 886     [Arguments]    ${ip}
 887     [Documentation]    Retrieve the mac address for a port that matches any given ip.
 888     ${output} =    OpenStack CLI    openstack port list | grep -w ${ip} | awk '{print $5}'
 889     ${splitted_output} =    String.Split String    ${output}    ${EMPTY}
 890     ${mac_addr} =    Collections.Get from List    ${splitted_output}    0
 891     [Return]    ${mac_addr}
 892
 893 Create L2Gateway
 894     [Arguments]    ${bridge_name}    ${intf_name}    ${gw_name}
 895     [Documentation]    Keyword to create an L2 Gateway ${gw_name} for bridge ${bridge_name} connected to interface ${intf_name} (Using Neutron CLI).
 896     ${rc}    ${l2gw_output} =    OperatingSystem.Run And Return Rc And Output    ${L2GW_CREATE} name=${bridge_name},interface_names=${intf_name} ${gw_name}
 897     BuiltIn.Log    ${l2gw_output}
 898     [Return]    ${l2gw_output}
 899
 900 Update L2Gateway
 901     [Arguments]    ${bridge_name}    ${gw_name}    ${intf_name_1}    ${intf_name_2}
 902     [Documentation]    Keyword to add {intf_name_list} to an existing L2 Gateway ${gw_name} (Using Neutron CLI).
 903     ${rc}    ${l2gw_output}=    Run And Return Rc And Output    ${L2GW_UPDATE} name=${bridge_name},interface_names="${intf_name_1};${intf_name_2}" ${gw_name}
 904     Log    ${l2gw_output}
 905     [Return]    ${l2gw_output}
 906
 907 Create L2Gateway Connection
 908     [Arguments]    ${gw_name}    ${net_name}
 909     [Documentation]    Keyword would create a new L2 Gateway Connection for ${gw_name} to ${net_name} (Using Neutron CLI).
 910     ${rc}    ${l2gw_output} =    OperatingSystem.Run And Return Rc And Output    ${L2GW_CONN_CREATE} ${gw_name} ${net_name}
 911     BuiltIn.Log    ${l2gw_output}
 912     BuiltIn.Should Be True    '${rc}' == '0'
 913     [Return]    ${l2gw_output}
 914
 915 Get All L2Gateway
 916     [Documentation]    Keyword to return all the L2 Gateways available (Using Neutron CLI).
 917     ${rc}    ${output} =    OperatingSystem.Run And Return Rc And Output    ${L2GW_GET_YAML}
 918     BuiltIn.Should Be True    '${rc}' == '0'
 919     [Return]    ${output}
 920
 921 Get All L2Gateway Connection
 922     [Documentation]    Keyword to return all the L2 Gateway connections available (Using Neutron CLI).
 923     ${rc}    ${output} =    OperatingSystem.Run And Return Rc And Output    ${L2GW_GET_CONN_YAML}
 924     BuiltIn.Should Be True    '${rc}' == '0'
 925     [Return]    ${output}
 926
 927 Get L2Gateway
 928     [Arguments]    ${gw_id}
 929     [Documentation]    Keyword to check if the ${gw_id} is available in the L2 Gateway list (Using Neutron CLI).
 930     ${rc}    ${output} =    OperatingSystem.Run And Return Rc And Output    ${L2GW_SHOW} ${gw_id}
 931     BuiltIn.Log    ${output}
 932     BuiltIn.Should Be True    '${rc}' == '0'
 933     [Return]    ${output}
 934
 935 Get L2gw Id
 936     [Arguments]    ${l2gw_name}
 937     [Documentation]    Keyword to retrieve the L2 Gateway ID for the ${l2gw_name} (Using Neutron CLI).
 938     ${rc}    ${output} =    OperatingSystem.Run And Return Rc And Output    ${L2GW_GET} | grep "${l2gw_name}" | awk '{print $2}'
 939     BuiltIn.Log    ${output}
 940     BuiltIn.Should Be True    '${rc}' == '0'
 941     ${splitted_output} =    String.Split String    ${output}    ${EMPTY}
 942     ${l2gw_id} =    Collections.Get from List    ${splitted_output}    0
 943     [Return]    ${l2gw_id}
 944
 945 Get L2gw Connection Id
 946     [Arguments]    ${l2gw_name}
 947     [Documentation]    Keyword to retrieve the L2 Gateway Connection ID for the ${l2gw_name} (Using Neutron CLI).
 948     ${l2gw_id} =    OpenStackOperations.Get L2gw Id    ${l2gw_name}
 949     ${rc}    ${output} =    OperatingSystem.Run And Return Rc And Output    ${L2GW_GET_CONN} | grep "${l2gw_id}" | awk '{print $2}'
 950     BuiltIn.Should Be True    '${rc}' == '0'
 951     ${splitted_output} =    String.Split String    ${output}    ${EMPTY}
 952     ${splitted_output} =    String.Split String    ${output}    ${EMPTY}
 953     ${l2gw_conn_id} =    Collections.Get from List    ${splitted_output}    0
 954     [Return]    ${l2gw_conn_id}
 955
 956 Neutron Port List Rest
 957     [Documentation]    Keyword to get all ports details in Neutron (Using REST).
 958     ${resp} =    RequestsLibrary.Get Request    session    ${PORT_URL}
 959     BuiltIn.Log    ${resp.text}
 960     BuiltIn.Should Be Equal As Strings    ${resp.status_code}    200
 961     [Return]    ${resp.text}
 962
 963 Get Neutron Port Rest
 964     [Arguments]    ${port_id}
 965     [Documentation]    Keyword to get the specific port details in Neutron (Using REST).
 966     ${resp} =    RequestsLibrary.Get Request    session    ${CONFIG_API}/${GET_PORT_URL}/${port_id}
 967     BuiltIn.Log    ${resp.text}
 968     BuiltIn.Should Be Equal As Strings    ${resp.status_code}    200
 969     [Return]    ${resp.text}
 970
 971 Update Port Rest
 972     [Arguments]    ${port_id}    ${json_data}
 973     [Documentation]    Keyword to update ${port_id} with json data received in ${json_data} (Using REST).
 974     BuiltIn.Log    ${json_data}
 975     ${resp} =    RequestsLibrary.Put Request    session    ${CONFIG_API}/${GET_PORT_URL}/${port_id}    ${json_data}
 976     BuiltIn.Log    ${resp.text}
 977     BuiltIn.Should Be Equal As Strings    ${resp.status_code}    200
 978     [Return]    ${resp.text}
 979
 980 Get Neutron Network Rest
 981     [Arguments]    ${net_id}
 982     [Documentation]    Keyword to get the specific network details in Neutron (Using REST).
 983     ${resp} =    RequestsLibrary.Get Request    session    ${NETWORK_URL}/network/${net_id}
 984     BuiltIn.Log    ${resp.text}
 985     BuiltIn.Should Be Equal As Strings    ${resp.status_code}    200
 986     [Return]    ${resp.text}
 987
 988 Create And Configure Security Group
 989     [Arguments]    ${sg-name}
 990     [Documentation]    Create Security Group with given name, and default allow rules for TCP/UDP/ICMP protocols.
 991     OpenStackOperations.Neutron Security Group Create    ${sg-name}
 992     OpenStackOperations.Neutron Security Group Rule Create    ${sg-name}    direction=ingress    port_range_max=65535    port_range_min=1    protocol=tcp    remote_ip_prefix=0.0.0.0/0
 993     OpenStackOperations.Neutron Security Group Rule Create    ${sg-name}    direction=egress    port_range_max=65535    port_range_min=1    protocol=tcp    remote_ip_prefix=0.0.0.0/0
 994     OpenStackOperations.Neutron Security Group Rule Create    ${sg-name}    direction=ingress    protocol=icmp    remote_ip_prefix=0.0.0.0/0
 995     OpenStackOperations.Neutron Security Group Rule Create    ${sg-name}    direction=egress    protocol=icmp    remote_ip_prefix=0.0.0.0/0
 996     OpenStackOperations.Neutron Security Group Rule Create    ${sg-name}    direction=ingress    port_range_max=65535    port_range_min=1    protocol=udp    remote_ip_prefix=0.0.0.0/0
 997     OpenStackOperations.Neutron Security Group Rule Create    ${sg-name}    direction=egress    port_range_max=65535    port_range_min=1    protocol=udp    remote_ip_prefix=0.0.0.0/0
 998
 999 Add Security Group To VM
1000     [Arguments]    ${vm}    ${sg}
1001     [Documentation]    Add the security group provided to the given VM.
1002     ${output} =    OpenStack CLI    openstack server add security group ${vm} ${sg}
1003
1004 Remove Security Group From VM
1005     [Arguments]    ${vm}    ${sg}
1006     [Documentation]    Remove the security group provided to the given VM.
1007     OpenStackOperations.Get ControlNode Connection
1008     ${output} =    OpenStack CLI    openstack server remove security group ${vm} ${sg}
1009
1010 Create SFC Flow Classifier
1011     [Arguments]    ${name}    ${src_ip}    ${dest_ip}    ${protocol}    ${neutron_src_port}    ${args}=${EMPTY}
1012     [Documentation]    Create a flow classifier for SFC
1013     ${output} =    OpenStack CLI    openstack sfc flow classifier create --ethertype IPv4 --source-ip-prefix ${src_ip}/32 --destination-ip-prefix ${dest_ip}/32 --protocol ${protocol} --logical-source-port ${neutron_src_port} ${args} ${name}
1014     BuiltIn.Should Contain    ${output}    ${name}
1015     [Return]    ${output}
1016
1017 Delete SFC Flow Classifier
1018     [Arguments]    ${name}
1019     [Documentation]    Delete a SFC flow classifier
1020     ${output} =    OpenStack CLI    openstack sfc flow classifier delete ${name}
1021     [Return]    ${output}
1022
1023 Create SFC Port Pair
1024     [Arguments]    ${name}    ${port_in}    ${port_out}
1025     [Documentation]    Creates a neutron port pair for SFC
1026     ${output} =    OpenStack CLI    openstack sfc port pair create --ingress=${port_in} --egress=${port_out} ${name}
1027     BuiltIn.Should Contain    ${output}    ${name}
1028     [Return]    ${output}
1029
1030 Delete SFC Port Pair
1031     [Arguments]    ${name}
1032     [Documentation]    Delete a SFC port pair
1033     ${output} =    OpenStack CLI    openstack sfc port pair delete ${name}
1034     [Return]    ${output}
1035
1036 Create SFC Port Pair Group
1037     [Arguments]    ${name}    ${port_pair}
1038     [Documentation]    Creates a port pair group with a single port pair for SFC
1039     ${output} =    OpenStack CLI    openstack sfc port pair group create --port-pair ${port_pair} ${name}
1040     BuiltIn.Should Contain    ${output}    ${name}
1041     [Return]    ${output}
1042
1043 Create SFC Port Pair Group With Two Pairs
1044     [Arguments]    ${name}    ${port_pair1}    ${port_pair2}
1045     [Documentation]    Creates a port pair group with two port pairs for SFC
1046     ${output} =    OpenStack CLI    openstack sfc port pair group create --port-pair ${port_pair1} --port-pair ${port_pair2} ${name}
1047     BuiltIn.Should Contain    ${output}    ${name}
1048     [Return]    ${output}
1049
1050 Delete SFC Port Pair Group
1051     [Arguments]    ${name}
1052     [Documentation]    Delete a SFC port pair group
1053     OpenStackOperations.Get ControlNode Connection
1054     ${output} =    OpenStack CLI    openstack sfc port pair group delete ${name}
1055     [Return]    ${output}
1056
1057 Create SFC Port Chain
1058     [Arguments]    ${name}    ${args}=${EMPTY}
1059     [Documentation]    Creates a port pair chain with two port groups and a singel classifier.
1060     ${output} =    OpenStack CLI    openstack sfc port chain create ${name} ${args}
1061     BuiltIn.Should Contain    ${output}    ${name}
1062     [Return]    ${output}
1063
1064 Update SFC Port Chain With A New Flow Classifier
1065     [Arguments]    ${name}    ${fc}
1066     [Documentation]    Adds a Flow Classifier to a Port Chain
1067     ${output} =    OpenStack CLI    openstack sfc port chain set ${name} --flow-classifier ${fc}
1068     [Return]    ${output}
1069
1070 Update SFC Port Chain Removing A Flow Classifier
1071     [Arguments]    ${name}    ${fc}
1072     [Documentation]    Adds a Flow Classifier to a Port Chain
1073     ${output} =    OpenStack CLI    openstack sfc port chain unset ${name} --flow-classifier ${fc}
1074     [Return]    ${output}
1075
1076 Delete SFC Port Chain
1077     [Arguments]    ${name}
1078     [Documentation]    Delete a SFC port chain
1079     ${output} =    OpenStack CLI    openstack sfc port chain delete ${name}
1080     [Return]    ${output}
1081
1082 Reboot Nova VM
1083     [Arguments]    ${vm_name}
1084     [Documentation]    Reboot NOVA VM
1085     ${output} =    OpenStack CLI    openstack server reboot --wait ${vm_name}
1086     BuiltIn.Wait Until Keyword Succeeds    35s    10s    OpenStackOperations.Verify VM Is ACTIVE    ${vm_name}
1087
1088 Remove RSA Key From KnownHosts
1089     [Arguments]    ${vm_ip}
1090     [Documentation]    Remove RSA
1091     OpenStackOperations.Get ControlNode Connection
1092     ${output} =    DevstackUtils.Write Commands Until Prompt And Log    sudo cat /root/.ssh/known_hosts    30s
1093     ${output} =    DevstackUtils.Write Commands Until Prompt And Log    sudo ssh-keygen -f "/root/.ssh/known_hosts" -R ${vm_ip}    30s
1094     ${output} =    DevstackUtils.Write Commands Until Prompt    sudo cat "/root/.ssh/known_hosts"    30s
1095
1096 Wait For Routes To Propogate
1097     [Arguments]    ${networks}    ${subnets}
1098     [Documentation]    Check propagated routes
1099     OpenStackOperations.Get ControlNode Connection
1100     FOR    ${INDEX}    IN RANGE    0    1
1101         ${net_id} =    OpenStackOperations.Get Net Id    ${networks}[${INDEX}]
1102         ${is_ipv6} =    String.Get Regexp Matches    ${subnets}[${INDEX}]    ${IP6_REGEX}
1103         ${length} =    BuiltIn.Get Length    ${is_ipv6}
1104         ${cmd} =    BuiltIn.Set Variable If    ${length} == 0    ip route    ip -6 route
1105         ${output} =    Utils.Write Commands Until Expected Prompt    sudo ip netns exec qdhcp-${net_id} ${cmd}    ${DEFAULT_LINUX_PROMPT_STRICT}
1106         BuiltIn.Should Contain    ${output}    ${subnets}[${INDEX}]
1107     END
1108
1109 Neutron Cleanup
1110     [Arguments]    ${vms}=@{EMPTY}    ${networks}=@{EMPTY}    ${subnets}=@{EMPTY}    ${ports}=@{EMPTY}    ${sgs}=@{EMPTY}
1111     FOR    ${vm}    IN    @{vms}
1112         BuiltIn.Run Keyword And Ignore Error    Delete Vm Instance    ${vm}
1113     END
1114     FOR    ${port}    IN    @{ports}
1115         BuiltIn.Run Keyword And Ignore Error    Delete Port    ${port}
1116     END
1117     FOR    ${subnet}    IN    @{subnets}
1118         BuiltIn.Run Keyword And Ignore Error    Delete SubNet    ${subnet}
1119     END
1120     FOR    ${network}    IN    @{networks}
1121         BuiltIn.Run Keyword And Ignore Error    Delete Network    ${network}
1122     END
1123     FOR    ${sg}    IN    @{sgs}
1124         BuiltIn.Run Keyword And Ignore Error    Delete SecurityGroup    ${sg}
1125     END
1126
1127 OpenStack List All
1128     [Documentation]    Get a list of different OpenStack resources that might be in use.
1129     @{modules} =    BuiltIn.Create List    server    port    network    subnet    security group
1130     ...    security group rule    floating ip    router
1131     FOR    ${module}    IN    @{modules}
1132         ${output} =    OpenStack CLI    openstack ${module} list
1133     END
1134
1135 OpenStack CLI Get List
1136     [Arguments]    ${cmd}
1137     [Documentation]    Return a json list from the output of an OpenStack command.
1138     @{list} =    BuiltIn.Create List
1139     ${json} =    OpenStack CLI    ${cmd}
1140     @{list} =    RequestsLibrary.To Json    ${json}
1141     BuiltIn.Log    ${list}
1142     [Return]    @{list}
1143
1144 OpenStack CLI
1145     [Arguments]    ${cmd}
1146     [Documentation]    Run the given OpenStack ${cmd} and log the output.
1147     ${result} =    Process.Run Process    ${cmd}    shell=True
1148     BuiltIn.Log    ${result.stdout}
1149     BuiltIn.Log    ${result.stderr}
1150     BuiltIn.Should Be True    '${result.rc}' == '0'
1151     [Return]    ${result.stdout}
1152
1153 OpenStack CLI With No Log
1154     [Arguments]    ${cmd}
1155     [Documentation]    Run the given OpenStack ${cmd} and do not log the output.
1156     ${result} =    Process.Run Process    ${cmd}    shell=True
1157     BuiltIn.Should Be True    '${result.rc}' == '0'
1158     [Return]    ${result.stdout}
1159
1160 OpenStack Cleanup All
1161     [Documentation]    Cleanup all Openstack resources with best effort. The keyword will query for all resources
1162     ...    in use and then attempt to delete them. Errors are ignored to allow the cleanup to continue.
1163     @{fips} =    OpenStack CLI Get List    openstack floating ip list -f json
1164     FOR    ${fip}    IN    @{fips}
1165         BuiltIn.Run Keyword And Ignore Error    Delete Floating IP    ${fip['ID']}
1166     END
1167     @{vms} =    OpenStack CLI Get List    openstack server list -f json
1168     FOR    ${vm}    IN    @{vms}
1169         OpenStack CLI    openstack server show ${vm['ID']}
1170         BuiltIn.Run Keyword And Ignore Error    Delete Vm Instance    ${vm['ID']}
1171     END
1172     @{routers} =    OpenStack CLI Get List    openstack router list -f json
1173     FOR    ${router}    IN    @{routers}
1174         BuiltIn.Run Keyword And Ignore Error    Cleanup Router    ${router['ID']}
1175     END
1176     @{ports} =    OpenStack CLI Get List    openstack port list -f json
1177     FOR    ${port}    IN    @{ports}
1178         BuiltIn.Run Keyword And Ignore Error    Delete Port    ${port['ID']}
1179     END
1180     @{networks} =    OpenStack CLI Get List    openstack network list -f json
1181     FOR    ${network}    IN    @{networks}
1182         BuiltIn.Run Keyword And Ignore Error    Delete Subnet    ${network['Subnets']}
1183         BuiltIn.Run Keyword And Ignore Error    Delete Network    ${network['ID']}
1184     END
1185     @{security_groups} =    OpenStack CLI Get List    openstack security group list -f json
1186     FOR    ${security_group}    IN    @{security_groups}
1187         BuiltIn.Run Keyword If    "${security_group['Name']}" != "default"    BuiltIn.Run Keyword And Ignore Error    Delete SecurityGroup    ${security_group['ID']}
1188     END
1189     OpenStack List All
1190
1191 Cleanup Router
1192     [Arguments]    ${id}
1193     [Documentation]    Delete a router, but first remove any interfaces or gateways so that the delete will be successful.
1194     @{ports} =    OpenStack CLI Get List    openstack port list --router ${id} -f json --long
1195     FOR    ${port}    IN    @{ports}
1196         ${subnet_id} =    OpenStackOperations.Get Match    ${port['Fixed IP Addresses']}    ${REGEX_UUID}    0
1197         BuiltIn.Run Keyword If    "${port['Device Owner']}" == "network:router_gateway"    BuiltIn.Run Keyword And Ignore Error    Remove Gateway    ${id}
1198         BuiltIn.Run Keyword If    "${port['Device Owner']}" == "network:router_interface"    BuiltIn.Run Keyword And Ignore Error    Remove Interface    ${id}    ${subnet_id}
1199     END
1200     BuiltIn.Run Keyword And Ignore Error    Delete Router    ${id}
1201
1202 OpenStack Suite Setup
1203     [Documentation]    Wrapper teardown keyword that can be used in any suite running in an openstack environement
1204     SetupUtils.Setup_Utils_For_Setup_And_Teardown
1205     @{loggers} =    BuiltIn.Create List    org.apache.karaf.shell.support.ShellUtil    org.apache.sshd.server.session.ServerSessionImpl
1206     Setuputils.Setup_Logging_For_Debug_Purposes_On_List_Or_All    OFF    ${loggers}
1207     DevstackUtils.Devstack Suite Setup
1208     @{tcpdump_port_6653_conn_ids} =    OpenStackOperations.Start Packet Capture On Nodes    tcpdump_port_6653    port 6653    @{OS_ALL_IPS}
1209     BuiltIn.Set Suite Variable    @{tcpdump_port_6653_conn_ids}
1210     BuiltIn.Run Keyword If    "${PRE_CLEAN_OPENSTACK_ALL}"=="True"    OpenStack Cleanup All
1211     OpenStackOperations.Add OVS Logging On All OpenStack Nodes
1212     Validate Deployment
1213
1214 OpenStack Suite Teardown
1215     [Documentation]    Wrapper teardown keyword that can be used in any suite running in an openstack environement
1216     ...    to clean up all openstack resources. For example, all instances, networks, ports, etc will be listed and
1217     ...    and deleted. As other global cleanup tasks are needed, they can be added here and the suites will all
1218     ...    benefit automatically.
1219     # TODO: followup patch will add the list of vms to pass to Show Debugs
1220     # OpenStackOperations.Show Debugs    @{NET_1_VMS}    @{NET_2_VMS}
1221     OpenStackOperations.Get Suite Debugs
1222     OpenStack Cleanup All
1223     OpenStackOperations.Stop Packet Capture On Nodes    ${tcpdump_port_6653_conn_ids}
1224     SSHLibrary.Close All Connections
1225     FOR    ${i}    IN RANGE    ${NUM_ODL_SYSTEM}
1226         KarafKeywords.Issue Command On Karaf Console    threads --list | wc -l    ${ODL_SYSTEM_${i+1}_IP}
1227     END
1228
1229 Validate Deployment
1230     [Documentation]    Validate the deployment. Examples to validate are verifying default table
1231     ...    flows are installed and that the tunnel mesh has been built correctly.
1232     Write To Validate File    ----------------------------------------\n${SUITE_NAME}\n
1233     FOR    ${keyword}    IN    @{VALIDATION_KEYWORDS}
1234         ${status} =    Builtin.Run Keyword And Return Status    ${keyword}
1235         BuiltIn.Run Keyword If    "${status}" == "FAIL" or "${status}" == "False"    BuiltIn.Run Keywords    Write To Validate File    Failed: ${keyword}
1236         ...    AND    BuiltIn.Fail
1237         ...    ELSE    Write To Validate File    Passed: ${keyword}
1238     END
1239
1240 Write To Validate File
1241     [Arguments]    ${msg}
1242     [Documentation]    Write the given ${msg} to ${VALIDATION_FILE}. Create the file if not present.
1243     ${status} =    BuiltIn.Run Keyword And Return Status    OperatingSystem.File Should Exist    ${VALIDATION_FILE}
1244     BuiltIn.Run Keyword If    "${status}" == "False"    OperatingSystem.Create File    ${VALIDATION_FILE}
1245     OperatingSystem.Append To File    ${VALIDATION_FILE}    ${msg}\n
1246
1247 Copy DHCP Files From Control Node
1248     [Documentation]    Copy the current DHCP files to the robot vm. The keyword must be called
1249     ...    after the subnet(s) are created and before the subnet(s) are deleted.
1250     ${suite_} =    BuiltIn.Evaluate    """${SUITE_NAME}""".replace(" ","_").replace("/","_").replace(".","_")
1251     ${dstdir} =    BuiltIn.Set Variable    /tmp/qdhcp/${suite_}
1252     OperatingSystem.Create Directory    ${dstdir}
1253     OpenStackOperations.Get ControlNode Connection
1254     BuiltIn.Run Keyword And Ignore Error    SSHLibrary.Get Directory    /opt/stack/data/neutron/dhcp    ${dstdir}    recursive=True
1255
1256 Is Feature Installed
1257     [Arguments]    ${features}=none
1258     FOR    ${feature}    IN    @{features}
1259         ${status}    ${output}    BuiltIn.Run Keyword And Ignore Error    BuiltIn.Should Contain    ${CONTROLLERFEATURES}    ${feature}
1260         Return From Keyword If    "${status}" == "PASS"    True
1261     END
1262     [Return]    False
1263
1264 Add OVS Logging On All OpenStack Nodes
1265     [Documentation]    Add higher levels of OVS logging to all the OpenStack nodes
1266     FOR    ${conn_id}    IN    @{OS_ALL_CONN_IDS}
1267         OVSDB.Add OVS Logging    ${conn_id}
1268     END
1269
1270 Reset OVS Logging On All OpenStack Nodes
1271     [Documentation]    Reset the OVS logging to all the OpenStack nodes
1272     FOR    ${conn_id}    IN    @{OS_ALL_CONN_IDS}
1273         OVSDB.Reset OVS Logging    ${conn_id}
1274     END
1275
1276 Start Packet Capture On Nodes
1277     [Arguments]    ${tag}    ${filter}    @{ips}
1278     [Documentation]    Wrapper keyword around the TcpDump packet capture that is catered to the Openstack setup.
1279     ...    The caller must pass the three arguments with a variable number of ips at the end,
1280     ...    but ${EMPTY} can be used for the tag and filter.
1281     ${suite_} =    BuiltIn.Evaluate    """${SUITE_NAME}""".replace(" ","_").replace("/","_").replace(".","_")
1282     ${tag_} =    BuiltIn.Catenate    SEPARATOR=__    ${tag}    ${suite_}
1283     @{conn_ids} =    Tcpdump.Start Packet Capture on Nodes    tag=${tag_}    filter=${filter}    ips=${ips}
1284     [Return]    @{conn_ids}
1285
1286 Stop Packet Capture On Nodes
1287     [Arguments]    ${conn_ids}=@{EMPTY}
1288     Tcpdump.Stop Packet Capture on Nodes    ${conn_ids}
1289
1290 Server Live Migrate
1291     [Arguments]    ${vm_instance_name}
1292     [Documentation]    Keyword for live migration of VM instance
1293     ...    additional_agrs is to select particular migration(live/shared-migration/block-migration)
1294     ...    if the additional_agrs is not given default migration(shared-migration) will happen
1295     ${output} =    OpenStackOperations.OpenStack CLI    nova live-migration ${vm_instance_name}
1296
1297 Get Hypervisor Host Of Vm
1298     [Arguments]    ${vm_name}
1299     [Documentation]    Show server with neutron request.
1300     ${output} =    OpenStackOperations.OpenStack CLI    openstack server show -f value -c OS-EXT-SRV-ATTR:host ${vm_name}
1301     [Return]    ${output}
1302
1303 Check If Migration Is Complete
1304     [Arguments]    ${vm_name}
1305     [Documentation]    Show server and verify if task_state is not migrating
1306     ${output} =    OpenStackOperations.OpenStack CLI    openstack server show ${vm_name} | grep "OS-EXT-STS:task_state"
1307     BuiltIn.Should Not Contain    ${output}    migrating
1308
1309 Modify OpenStack Configuration File
1310     [Arguments]    ${conn_id}    ${file_name}    ${section}    ${key}    ${value}
1311     [Documentation]    Use crudini to modify any parameter in any Openstack configuration File
1312     SSHLibrary.Switch Connection    ${conn_id}
1313     ${output}    ${rc} =    SSHLibrary.Execute Command    sudo crudini --verbose --set --inplace ${file_name} ${section} ${key} ${value}    return_rc=True    return_stdout=True
1314     BuiltIn.Log    ${output}
1315     BuiltIn.Should Be True    '${rc}' == '0'
1316
1317 Restart DevStack Service
1318     [Arguments]    ${conn_id}    ${service_name}
1319     [Documentation]    Restart the Openstack Service
1320     SSHLibrary.Switch Connection    ${conn_id}
1321     ${output}    ${rc} =    SSHLibrary.Execute Command    sudo systemctl restart devstack@${service_name}.service    return_rc=True    return_stdout=True
1322     BuiltIn.Log    ${output}
1323     BuiltIn.Should Be True    '${rc}' == '0'
1324
1325 Get Network Segmentation Id
1326     [Arguments]    ${network_name}
1327     [Documentation]    Returns network segmentation id for the given network name.
1328     ${output} =    OpenStack CLI    openstack network show ${network_name} | grep segmentation_id | awk '{print $4}'
1329     @{list} =    String.Split String    ${output}
1330     [Return]    ${list}[0]
1331
1332 Verify Services
1333     [Documentation]    Verify if the services are operational
1334     Wait Until Keyword Succeeds    60    2    ClusterManagement.Check Status Of Services Is OPERATIONAL    @{NETVIRT_DIAG_SERVICES}
1335
1336 Verify Expected Default Tunnels
1337     [Documentation]    Verify if the default tunnels are created.
1338     ...    SFC jobs currently fail this validation because it uses of-tunnels.
1339     ...    This validation will be blocked for NEtvirt SFC jobs until support for of-tunnels
1340     ...    added to odltools.
1341     ${check_feature_list} =    BuiltIn.Create List    odl-netvirt-sfc
1342     ${is_sfc_enabled} =    OpenStackOperations.Is Feature Installed    features=${check_feature_list}
1343     BuiltIn.Return From Keyword If    ${is_sfc_enabled} == ${True}    ${True}
1344     BuiltIn.Return From Keyword If    ${OS_NODE_CNT} == ${1}    ${True}
1345     ${output} =    ODLTools.Analyze Tunnels    test_name=${SUITE_NAME}.Suite Setup
1346     BuiltIn.Should Contain    ${output}    All tunnels are up
1347
1348 Verify Expected Default Tables On Nodes
1349     [Arguments]    ${node_ips}=@{OS_ALL_IPS}
1350     [Documentation]    Verify if Default Table Entries are programmed on all Nodes
1351     ${resp} =    RequestsLibrary.Get Request    session    ${CONFIG_NODES_API}
1352     Utils.Log Content    ${resp.text}
1353     ${failed_node_list} =    BuiltIn.Create List
1354     FOR    ${node_ip}    IN    @{node_ips}
1355         ${failed_table_list} =    Verify Expected Default Tables    ${node_ip}
1356         ${failed_table_list_size} =    BuiltIn.Get Length    ${failed_table_list}
1357         BuiltIn.Run Keyword If    ${failed_table_list_size} > 0    Collections.Append To List    ${failed_node_list}    ${node_ip}
1358     END
1359     Builtin.Should Be Empty    ${failed_node_list}
1360
1361 Verify Expected Default Tables
1362     [Arguments]    ${ovs_ip}
1363     [Documentation]    Verify if Default Table Entries are programmed on specific Node
1364     ${flow_dump} =    Utils.Run Command On Remote System    ${ovs_ip}    sudo ovs-ofctl dump-flows ${INTEGRATION_BRIDGE} -OOpenFlow13
1365     BuiltIn.Log    ${flow_dump}
1366     ${failed_table_list} =    BuiltIn.Create List
1367     FOR    ${table}    IN    @{DEFAULT_FLOW_TABLES}
1368         ${rc} =    Builtin.Run Keyword And Return Status    Builtin.Should Not Match Regexp    ${flow_dump}    .*table=${table}.*priority=0
1369         BuiltIn.Run Keyword If    ${rc}    Collections.Append To List    ${failed_table_list}    ${table}
1370     END
1371     [Return]    ${failed_table_list}
1372
1373 Get Project Id
1374     [Arguments]    ${project_name}
1375     [Documentation]    Returns project ID for the given project name.
1376     ${project_id} =    OpenStack CLI    openstack project show ${project_name} -f value -c id
1377     [Return]    ${project_id}
1378
1379 Set Instance Quota For Project
1380     [Arguments]    ${num_instances}    ${project_id}
1381     [Documentation]    Set quota for the created instances using the specific project id.
1382     ${output} =    OpenStack CLI    openstack quota set --instances ${num_instances} ${project_id}
1383     [Return]    ${output}
1384
1385 Create Bgpvpn
1386     [Arguments]    ${vpnname}    ${additional_args}=${EMPTY}
1387     [Documentation]    Create Bgpvpn with neutron request.
1388     ${output} =    OpenStack CLI    openstack bgpvpn create --name ${vpnname} ${additional_args}
1389
1390 Get BgpVpn Id
1391     [Arguments]    ${vpnName}
1392     [Documentation]    Retrieve the bgpvpn id for the given bgpvpn name
1393     ${output} =    OpenStack CLI    openstack bgpvpn show ${vpnName} | grep " ID" | awk '{print $4}'
1394     ${splitted_output} =    String.Split String    ${output}    ${EMPTY}
1395     ${vpn_id} =    Collections.Get from List    ${splitted_output}    0
1396     [Return]    ${vpn_id}
1397
1398 Configure_IP_On_Sub_Interface
1399     [Arguments]    ${network_name}    ${ip}    ${vm_ip}    ${mask}    ${sub_interface_state}=${EMPTY}    ${interface}=eth0
1400     ...    ${sub_interface_number}=1
1401     [Documentation]    Keyword for configuring specified IP on specified interface and the corresponding specified sub interface
1402     OpenStackOperations.Execute Command on VM Instance    ${network_name}    ${vm_ip}    sudo ifconfig ${interface}:${sub_interface_number} ${ip} netmask ${mask} ${sub_interface_state}
1403
1404 Verify_IP_Configured_On_Sub_Interface
1405     [Arguments]    ${network_name}    ${ip}    ${vm_ip}    ${interface}=eth0    ${sub_interface_number}=1
1406     [Documentation]    Keyword for verifying specified IP on specified interface and the corresponding specified sub interface
1407     ${resp} =    OpenStackOperations.Execute Command on VM Instance    ${network_name}    ${vm_ip}    sudo ifconfig ${interface}:${sub_interface_number}
1408     BuiltIn.Should Contain    ${resp}    ${ip}