csit/libraries/OpenStackOperations.robot

   1 *** Settings ***
   2 Documentation     Openstack library. This library is useful for tests to create network, subnet, router and vm instances
   3 Library           Collections
   4 Library           Process
   5 Library           OperatingSystem
   6 Library           RequestsLibrary
   7 Library           SSHLibrary
   8 Library           String
   9 Resource          DataModels.robot
  10 Resource          DevstackUtils.robot
  11 Resource          KarafKeywords.robot
  12 Resource          L2GatewayOperations.robot
  13 Resource          ODLTools.robot
  14 Resource          OVSDB.robot
  15 Resource          SetupUtils.robot
  16 Resource          SSHKeywords.robot
  17 Resource          Tcpdump.robot
  18 Resource          Utils.robot
  19 Resource          ../variables/Variables.robot
  20 Resource          ../variables/netvirt/Variables.robot
  21 Variables         ../variables/netvirt/Modules.py
  22
  23 *** Keywords ***
  24 Get Tenant ID From Security Group
  25     [Documentation]    Returns tenant ID by reading it from existing default security-group.
  26     ${output} =    OpenStack CLI    openstack security group show default | grep "| tenant_id" | awk '{print $4}'
  27     [Return]    ${output}
  28
  29 Get Tenant ID From Network
  30     [Arguments]    ${network_uuid}
  31     [Documentation]    Returns tenant ID by reading it from existing network.
  32     ${resp} =    TemplatedRequests.Get_From_Uri    uri=${CONFIG_API}/neutron:neutron/networks/network/${network_uuid}/    accept=${ACCEPT_EMPTY}    session=session
  33     ${tenant_id} =    Utils.Extract Value From Content    ${resp}    /network/0/tenant-id    strip
  34     [Return]    ${tenant_id}
  35
  36 Create Network
  37     [Arguments]    ${network_name}    ${additional_args}=${EMPTY}    ${verbose}=TRUE
  38     [Documentation]    Create Network with openstack request.
  39     ${output} =    OpenStack CLI    openstack network create ${network_name} ${additional_args}
  40     [Return]    ${output}
  41
  42 Update Network
  43     [Arguments]    ${network_name}    ${additional_args}=${EMPTY}
  44     [Documentation]    Update Network with neutron request.
  45     ${output} =    OpenStack CLI    openstack network set ${network_name} ${additional_args}
  46     [Return]    ${output}
  47
  48 Show Network
  49     [Arguments]    ${network_name}
  50     [Documentation]    Show Network with neutron request.
  51     ${output} =    OpenStack CLI    openstack network show ${network_name}
  52     [Return]    ${output}
  53
  54 List Networks
  55     [Documentation]    List networks and return output with neutron client.
  56     ${output} =    OpenStack CLI    openstack network list
  57     [Return]    ${output}
  58
  59 List Subnets
  60     [Documentation]    List subnets and return output with neutron client.
  61     ${output} =    OpenStack CLI    openstack subnet list
  62     [Return]    ${output}
  63
  64 Delete Network
  65     [Arguments]    ${network_name}
  66     [Documentation]    Delete Network with neutron request.
  67     ${output} =    OpenStack CLI    openstack network delete ${network_name}
  68
  69 Create SubNet
  70     [Arguments]    ${network_name}    ${subnet_name}    ${range_ip}    ${additional_args}=${EMPTY}
  71     [Documentation]    Create SubNet for the Network with neutron request.
  72     ${output} =    OpenStack CLI    openstack subnet create --network ${network_name} --subnet-range ${range_ip} ${subnet_name} ${additional_args}
  73
  74 Update SubNet
  75     [Arguments]    ${subnet_name}    ${additional_args}=${EMPTY}
  76     [Documentation]    Update subnet with openstack subnet set request.
  77     ${output} =    OpenStack CLI    openstack subnet set ${subnet_name} ${additional_args}
  78     [Return]    ${output}
  79
  80 Unset SubNet
  81     [Arguments]    ${subnet_name}    ${additional_args}=${EMPTY}
  82     [Documentation]    Update subnet with openstack subnet unset request
  83     ${output} =    OpenStack CLI    openstack subnet unset ${subnet_name} ${additional_args}
  84     [Return]    ${output}
  85
  86 Show SubNet
  87     [Arguments]    ${subnet_name}
  88     [Documentation]    Show subnet with neutron request.
  89     ${output} =    OpenStack CLI    openstack subnet show ${subnet_name}
  90     [Return]    ${output}
  91
  92 Create Port
  93     [Arguments]    ${network_name}    ${port_name}    ${sg}=default    ${additional_args}=${EMPTY}    ${allowed_address_pairs}=${EMPTY}
  94     [Documentation]    Create Port with neutron request.
  95     # if allowed_address_pairs is not empty we need to create the arguments to pass to the port create command. They are
  96     # in a different format with the neutron vs openstack cli.
  97     ${address_pair_length} =    BuiltIn.Get Length    ${allowed_address_pairs}
  98     ${allowed_pairs_argv} =    BuiltIn.Set Variable    ${EMPTY}
  99     ${allowed_pairs_argv} =    BuiltIn.Set Variable If    '${address_pair_length}'=='2'    --allowed-address ip-address=@{allowed_address_pairs}[0] --allowed-address ip-address=@{allowed_address_pairs}[1]    ${allowed_pairs_argv}
 100     ${output} =    OpenStack CLI    openstack port create --network ${network_name} ${port_name} --security-group ${sg} ${additional_args} ${allowed_pairs_argv}
 101
 102 Update Port
 103     [Arguments]    ${port_name}    ${additional_args}=${EMPTY}
 104     [Documentation]    Update port with neutron request.
 105     ${output} =    OpenStack CLI    openstack port set ${port_name} ${additional_args}
 106     [Return]    ${output}
 107
 108 Show Port
 109     [Arguments]    ${port_name}
 110     [Documentation]    Show port with neutron request.
 111     ${output} =    OpenStack CLI    openstack port show ${port_name}
 112     [Return]    ${output}
 113
 114 Delete Port
 115     [Arguments]    ${port_name}
 116     [Documentation]    Delete Port with neutron request.
 117     ${output} =    OpenStack CLI    openstack port delete ${port_name}
 118
 119 List Ports
 120     [Documentation]    List ports and return output with neutron client.
 121     ${output} =    OpenStack CLI    openstack port list
 122     [Return]    ${output}
 123
 124 List Nova VMs
 125     [Documentation]    List VMs and return output with nova client.
 126     ${output} =    OpenStack CLI    openstack server list --all-projects
 127     [Return]    ${output}
 128
 129 Create And Associate Floating IPs
 130     [Arguments]    ${external_net}    @{vm_list}
 131     [Documentation]    Create and associate floating IPs to VMs with nova request
 132     ${ip_list} =    BuiltIn.Create List    @{EMPTY}
 133     : FOR    ${vm}    IN    @{vm_list}
 134     \    ${output} =    OpenStack CLI    openstack floating ip create ${external_net}
 135     \    @{ip} =    String.Get Regexp Matches    ${output}    [0-9]{1,3}\\.[0-9]{1,3}\\.[0-9]{1,3}\\.[0-9]{1,3}
 136     \    ${ip_length} =    BuiltIn.Get Length    ${ip}
 137     \    BuiltIn.Run Keyword If    ${ip_length}>0    Collections.Append To List    ${ip_list}    @{ip}[0]
 138     \    ...    ELSE    Collections.Append To List    ${ip_list}    None
 139     \    ${output} =    OpenStack CLI    openstack server add floating ip ${vm} @{ip}[0]
 140     [Return]    ${ip_list}
 141
 142 Remove Floating Ip From Vm
 143     [Arguments]    ${vm_name}    ${fip}
 144     [Documentation]    Remove the Floating IP From VM Instance
 145     ${output} =    OpenStack CLI    openstack server remove floating ip ${vm_name} ${fip}
 146
 147 Delete Floating IP
 148     [Arguments]    ${fip}
 149     [Documentation]    Delete floating ip with neutron request.
 150     ${output} =    OpenStack CLI    openstack floating ip delete ${fip}
 151
 152 Delete SubNet
 153     [Arguments]    ${subnet}
 154     [Documentation]    Delete SubNet for the Network with neutron request.
 155     ${output} =    OpenStack CLI    openstack subnet delete ${subnet}
 156
 157 Delete Vm Instance
 158     [Arguments]    ${vm_name}
 159     [Documentation]    Delete Vm instances using instance names.
 160     ${output} =    OpenStack CLI    openstack server delete ${vm_name}
 161
 162 Get Net Id
 163     [Arguments]    ${network_name}
 164     [Documentation]    Retrieve the net id for the given network name to create specific vm instance
 165     ${output} =    OpenStack CLI    openstack network list | grep "${network_name}" | awk '{print $2}'
 166     ${splitted_output} =    String.Split String    ${output}    ${EMPTY}
 167     ${net_id} =    Collections.Get from List    ${splitted_output}    0
 168     [Return]    ${net_id}
 169
 170 Get Subnet Id
 171     [Arguments]    ${subnet_name}
 172     [Documentation]    Retrieve the subnet id for the given subnet name
 173     ${output} =    OpenStack CLI    openstack subnet show "${subnet_name}" | grep " id " | awk '{print $4}'
 174     ${splitted_output} =    String.Split String    ${output}    ${EMPTY}
 175     ${subnet_id} =    Collections.Get from List    ${splitted_output}    0
 176     [Return]    ${subnet_id}
 177
 178 Get Port Id
 179     [Arguments]    ${port_name}
 180     [Documentation]    Retrieve the port id for the given port name to attach specific vm instance to a particular port
 181     ${output} =    OpenStack CLI    openstack port list | grep "${port_name}" | awk '{print $2}'
 182     ${splitted_output} =    String.Split String    ${output}    ${EMPTY}
 183     ${port_id} =    Collections.Get from List    ${splitted_output}    0
 184     [Return]    ${port_id}
 185
 186 Get Sub Port Id
 187     [Arguments]    ${portname}
 188     [Documentation]    Retrieve the first 10 chars of the UUID for the given port name
 189     ${port_id} =    OpenStackOperations.Get Port Id    ${portname}
 190     ${output} =    String.Get Regexp Matches    ${port_id}    \\w{8}-\\w{2}
 191     ${subport_id} =    Collections.Get from List    ${output}    0
 192     [Return]    ${subport_id}
 193
 194 Get Router Id
 195     [Arguments]    ${router1}
 196     [Documentation]    Retrieve the router id for the given router name
 197     ${output} =    OpenStack CLI    openstack router show "${router1}" |awk '/ id / {print $4}'
 198     ${splitted_output} =    String.Split String    ${output}    ${EMPTY}
 199     ${router_id} =    Collections.Get from List    ${splitted_output}    0
 200     [Return]    ${router_id}
 201
 202 Create Vm Instances
 203     [Arguments]    ${net_name}    ${vm_instance_names}    ${image}=${EMPTY}    ${flavor}=m1.nano    ${sg}=default    ${min}=1
 204     ...    ${max}=1
 205     [Documentation]    Create X Vm Instance with the net id of the Netowrk.
 206     ${image}    BuiltIn.Set Variable If    "${image}"=="${EMPTY}"    ${CIRROS_${OPENSTACK_BRANCH}}    ${image}
 207     ${net_id} =    OpenStackOperations.Get Net Id    ${net_name}
 208     : FOR    ${vm}    IN    @{vm_instance_names}
 209     \    ${output} =    OpenStack CLI    openstack server create --image ${image} --flavor ${flavor} --nic net-id=${net_id} ${vm} --security-group ${sg} --min ${min} --max ${max}
 210
 211 Create Vm Instance On Compute Node
 212     [Arguments]    ${net_name}    ${vm_name}    ${node_hostname}    ${image}=${EMPTY}    ${flavor}=m1.nano    ${sg}=default
 213     [Documentation]    Create a VM instance on a specific compute node.
 214     ${image} =    BuiltIn.Set Variable If    "${image}"=="${EMPTY}"    ${CIRROS_${OPENSTACK_BRANCH}}    ${image}
 215     ${net_id} =    OpenStackOperations.Get Net Id    ${net_name}
 216     ${output} =    OpenStack CLI    openstack server create ${vm_name} --image ${image} --flavor ${flavor} --nic net-id=${net_id} --security-group ${sg} --availability-zone nova:${node_hostname}
 217
 218 Create Vm Instance With Port
 219     [Arguments]    ${port_name}    ${vm_instance_name}    ${image}=${EMPTY}    ${flavor}=m1.nano    ${sg}=default
 220     [Documentation]    Create One VM instance using given ${port_name} and for given ${compute_node}
 221     ${image} =    BuiltIn.Set Variable If    "${image}"=="${EMPTY}"    ${CIRROS_${OPENSTACK_BRANCH}}    ${image}
 222     ${port_id} =    OpenStackOperations.Get Port Id    ${port_name}
 223     ${output} =    OpenStack CLI    openstack server create --image ${image} --flavor ${flavor} --nic port-id=${port_id} ${vm_instance_name} --security-group ${sg}
 224
 225 Create Vm Instance With Ports
 226     [Arguments]    ${port_name}    ${port2_name}    ${vm_instance_name}    ${image}=${EMPTY}    ${flavor}=m1.nano    ${sg}=default
 227     [Documentation]    Create One VM instance using given ${port_name} and for given ${compute_node}
 228     ${image}    BuiltIn.Set Variable If    "${image}"=="${EMPTY}"    ${CIRROS_${OPENSTACK_BRANCH}}    ${image}
 229     ${port_id} =    OpenStackOperations.Get Port Id    ${port_name}
 230     ${port2_id} =    OpenStackOperations.Get Port Id    ${port2_name}
 231     ${output} =    OpenStack CLI    openstack server create --image ${image} --flavor ${flavor} --nic port-id=${port_id} --nic port-id=${port2_id} ${vm_instance_name} --security-group ${sg}
 232
 233 Create Vm Instance With Port On Compute Node
 234     [Arguments]    ${port_name}    ${vm_instance_name}    ${node_hostname}    ${image}=${EMPTY}    ${flavor}=m1.nano    ${sg}=default
 235     [Documentation]    Create One VM instance using given ${port_name} and for given ${compute_node}
 236     ${image} =    BuiltIn.Set Variable If    "${image}"=="${EMPTY}"    ${CIRROS_${OPENSTACK_BRANCH}}    ${image}
 237     ${port_id} =    OpenStackOperations.Get Port Id    ${port_name}
 238     ${output} =    OpenStack CLI    openstack server create --image ${image} --flavor ${flavor} --nic port-id=${port_id} --security-group ${sg} --availability-zone nova:${node_hostname} ${vm_instance_name}
 239
 240 Get Hypervisor Hostname From IP
 241     [Arguments]    ${hypervisor_ip}
 242     [Documentation]    Returns the hostname found for the given IP address if it's listed in hypervisor list. For debuggability
 243     ...    the full listing is logged first, then followed by a grep | cut to focus on the actual hostname to return
 244     ${output} =    OpenStack CLI    openstack hypervisor list
 245     ${hostname} =    OpenStack CLI    openstack hypervisor list -f value | grep "${hypervisor_ip} " | cut -d" " -f 2
 246     [Return]    ${hostname}
 247
 248 Create Nano Flavor
 249     [Documentation]    Create a nano flavor
 250     ${output} =    OpenStack CLI    openstack flavor create m1.nano --id auto --ram 64 --disk 0 --vcpus 1
 251
 252 Verify VM Is ACTIVE
 253     [Arguments]    ${vm_name}
 254     [Documentation]    Run these commands to check whether the created vm instance is active or not.
 255     ${output} =    OpenStack CLI    openstack server show ${vm_name} | grep OS-EXT-STS:vm_state
 256     BuiltIn.Should Contain    ${output}    active
 257
 258 Poll VM Is ACTIVE
 259     [Arguments]    ${vm_name}    ${retry}=600s    ${retry_interval}=30s
 260     [Documentation]    Run these commands to check whether the created vm instance is active or not.
 261     BuiltIn.Wait Until Keyword Succeeds    ${retry}    ${retry_interval}    OpenStackOperations.Verify VM Is ACTIVE    ${vm_name}
 262
 263 Get Match
 264     [Arguments]    ${text}    ${regexp}    ${index}=0
 265     [Documentation]    Wrapper around String.Get Regexp Matches to return None if not found or the first match if found.
 266     @{matches} =    String.Get Regexp Matches    ${text}    ${regexp}
 267     ${matches_length} =    BuiltIn.Get Length    ${matches}
 268     BuiltIn.Set Suite Variable    ${OS_MATCH}    None
 269     BuiltIn.Run Keyword If    ${matches_length} > ${index}    BuiltIn.Set Suite Variable    ${OS_MATCH}    @{matches}[${index}]
 270     [Return]    ${OS_MATCH}
 271
 272 Get VM IP
 273     [Arguments]    ${fail_on_none}    ${vm}
 274     [Documentation]    Get the vm ip address and nameserver by scraping the vm's console log.
 275     ...    Get VM IP returns three values: [0] the vm IP, [1] the DHCP IP and [2] the vm console log.
 276     ${vm_console_output} =    OpenStack CLI With No Log    openstack console log show ${vm}
 277     ${vm_ip} =    BuiltIn.Set Variable    None
 278     ${dhcp_ip} =    BuiltIn.Set Variable    None
 279     ${match} =    OpenStackOperations.Get Match    ${vm_console_output}    ${REGEX_OBTAINED}
 280     ${vm_ip} =    OpenStackOperations.Get Match    ${match}    ${REGEX_IPV4}    0
 281     ${match} =    OpenStackOperations.Get Match    ${vm_console_output}    ${REGEX_IPROUTE}
 282     ${dhcp_ip} =    OpenStackOperations.Get Match    ${match}    ${REGEX_IPV4}    1
 283     BuiltIn.Run Keyword If    '${fail_on_none}' == 'true'    BuiltIn.Should Not Contain    ${vm_ip}    None
 284     BuiltIn.Run Keyword If    '${fail_on_none}' == 'true'    BuiltIn.Should Not Contain    ${dhcp_ip}    None
 285     [Return]    ${vm_ip}    ${dhcp_ip}    ${vm_console_output}
 286
 287 Get VM IPs
 288     [Arguments]    @{vms}
 289     [Documentation]    Get the instance IP addresses and nameserver address for the list of given vms.
 290     ...    First poll for the vm instance to be in the active state, then poll for the vm ip address and nameserver.
 291     ...    Get VM IPs returns two things: [0] a list of the ips for the vms passed to this keyword (may contain values
 292     ...    of None) and [1] the dhcp ip address found in the last vm checked.
 293     ...    TODO: there is a potential issue for a caller that passes in VMs belonging to different networks that
 294     ...    may have different dhcp server addresses. Not sure what TODO about that, but noting it here for reference.
 295     @{vm_ips}    BuiltIn.Create List    @{EMPTY}
 296     : FOR    ${vm}    IN    @{vms}
 297     \    OpenStackOperations.Poll VM Is ACTIVE    ${vm}
 298     \    ${status}    ${ips_and_console_log}    BuiltIn.Run Keyword And Ignore Error    BuiltIn.Wait Until Keyword Succeeds    180s    15s
 299     \    ...    OpenStackOperations.Get VM IP    true    ${vm}
 300     \    # If there is trouble with Get VM IP, the status will be FAIL and the return value will be a string of what went
 301     \    # wrong. We need to handle both the PASS and FAIL cases. In the FAIL case we know we wont have access to the
 302     \    # console log, as it would not be returned; so we need to grab it again to log it. We also can append 'None' to
 303     \    # the vm ip list if status is FAIL.
 304     \    BuiltIn.Run Keyword If    "${status}" == "PASS"    BuiltIn.Log    ${ips_and_console_log[2]}
 305     \    BuiltIn.Run Keyword If    "${status}" == "PASS"    Collections.Append To List    ${vm_ips}    ${ips_and_console_log[0]}
 306     \    BuiltIn.Run Keyword If    "${status}" == "FAIL"    Collections.Append To List    ${vm_ips}    None
 307     \    ${vm_console_output} =    BuiltIn.Run Keyword If    "${status}" == "FAIL"    OpenStack CLI    openstack console log show ${vm}
 308     \    BuiltIn.Run Keyword If    "${status}" == "FAIL"    BuiltIn.Log    ${vm_console_output}
 309     OpenStackOperations.Copy DHCP Files From Control Node
 310     [Return]    @{vm_ips}    ${ips_and_console_log[1]}
 311
 312 Get Subnet Gateway Ip
 313     [Arguments]    ${subnet_name}
 314     [Documentation]    Show information of a subnet and grep for subnet gateway ip address
 315     ${output} =    OpenStackOperations.OpenStack CLI    openstack subnet show ${subnet_name} | grep gateway_ip | awk '{print $4}'
 316     ${splitted_output} =    String.Split String    ${output}    ${EMPTY}
 317     ${matches} =    Collections.Get Matches    ${splitted_output}    regexp=(\\d\.)+
 318     ${subnet_gateway_ip} =    String.Strip String    ${matches[0]}    characters=','
 319     [Return]    ${subnet_gateway_ip}
 320
 321 Collect VM IPv6 SLAAC Addresses
 322     [Arguments]    ${fail_on_none}    ${vm_list}    ${network}    ${subnet}
 323     [Documentation]    For each VM parse output of "openstack server show" to get its IPv6 address from Neutron DB.
 324     ...    Then try to connect to each VM by SSH and execute there "ip -6 a" command. This double-check allows to
 325     ...    obtain and compare IP info (Neutron DB vs dnsmasque/ODL DHCP) and to test L2 connectivity as well.
 326     ...    Returns an empty list if no IPv6 addresses found or if SSH connection fails.
 327     ...    Otherwise, returns a list of IPv6 addresses.
 328     ${ipv6_list} =    BuiltIn.Create List    @{EMPTY}
 329     : FOR    ${vm}    IN    @{vm_list}
 330     \    ${output} =    OpenStack CLI    openstack server show ${vm} -f shell
 331     \    ${pattern} =    String.Replace String    ${subnet}    ::/64    (:[a-f0-9]{,4}){,4}
 332     \    @{vm_ipv6} =    String.Get Regexp Matches    ${output}    ${pattern}
 333     \    ${vm_ip_length} =    BuiltIn.Get Length    ${vm_ipv6}[0]
 334     \    ${ipv6_data_from_vm} =    BuiltIn.Run Keyword If    ${vm_ip_length}>0    OpenStackOperations.Execute Command on VM Instance    ${network}    ${vm_ipv6[0]}
 335     \    ...    ip -6 a
 336     \    @{ipv6} =    String.Get Regexp Matches    ${ipv6_data_from_vm}    ${pattern}
 337     \    ${ipv6_addr_list_length}    BuiltIn.Get Length    @{ipv6}
 338     \    BuiltIn.Run Keyword If    ${ipv6_addr_list_length}>0    Collections.Append To List    ${ipv6_list}    ${ipv6[0]}
 339     \    ...    ELSE    Collections.Append To List    ${ipv6_list}    None
 340     [Return]    ${ipv6_list}
 341
 342 View Vm Console
 343     [Arguments]    ${vm_instance_names}
 344     [Documentation]    View Console log of the created vm instances using nova show.
 345     : FOR    ${vm}    IN    @{vm_instance_names}
 346     \    ${output} =    OpenStack CLI    openstack server show ${vm}
 347     \    ${output} =    OpenStack CLI    openstack console log show ${vm}
 348
 349 Ping Vm From DHCP Namespace
 350     [Arguments]    ${net_name}    ${vm_ip}
 351     [Documentation]    Reach all Vm Instance with the net id of the Netowrk.
 352     OpenStackOperations.Get ControlNode Connection
 353     ${net_id} =    OpenStackOperations.Get Net Id    ${net_name}
 354     ${output} =    DevstackUtils.Write Commands Until Prompt And Log    sudo ip netns exec qdhcp-${net_id} ping -c 3 ${vm_ip}    20s
 355     BuiltIn.Should Contain    ${output}    64 bytes
 356
 357 Ping From DHCP Should Not Succeed
 358     [Arguments]    ${net_name}    ${vm_ip}
 359     [Documentation]    Should Not Reach Vm Instance with the net id of the Netowrk.
 360     Return From Keyword If    "skip_if_${SECURITY_GROUP_MODE}" in @{TEST_TAGS}
 361     OpenStackOperations.Get ControlNode Connection
 362     ${net_id} =    OpenStackOperations.Get Net Id    ${net_name}
 363     ${output} =    DevstackUtils.Write Commands Until Prompt And Log    sudo ip netns exec qdhcp-${net_id} ping -c 3 ${vm_ip}    20s
 364     BuiltIn.Should Not Contain    ${output}    64 bytes
 365
 366 Ping Vm From Control Node
 367     [Arguments]    ${vm_floating_ip}    ${additional_args}=${EMPTY}
 368     [Documentation]    Ping VM floating IP from control node
 369     OpenStackOperations.Get ControlNode Connection
 370     ${output} =    DevstackUtils.Write Commands Until Prompt And Log    ping ${additional_args} -c 3 ${vm_floating_ip}    20s
 371     BuiltIn.Should Contain    ${output}    64 bytes
 372
 373 Curl Metadata Server
 374     [Documentation]    Ping to the expected destination ip.
 375     ${output} =    Utils.Write Commands Until Expected Prompt    curl -i http://169.254.169.254    ${OS_SYSTEM_PROMPT}
 376     DevstackUtils.Write Commands Until Prompt    exit
 377     BuiltIn.Should Contain    ${output}    200
 378
 379 Close Vm Instance
 380     [Documentation]    Exit the vm instance.
 381     ${output} =    DevstackUtils.Write Commands Until Prompt And Log    exit
 382
 383 Check If Console Is VmInstance
 384     [Arguments]    ${console}=cirros
 385     [Documentation]    Check if the session has been able to login to the VM instance
 386     ${output} =    Utils.Write Commands Until Expected Prompt    id    ${OS_SYSTEM_PROMPT}
 387     BuiltIn.Should Contain    ${output}    ${console}
 388
 389 Exit From Vm Console
 390     [Documentation]    Check if the session has been able to login to the VM instance and exit the instance
 391     ${rcode} =    BuiltIn.Run Keyword And Return Status    OpenStackOperations.Check If Console Is VmInstance    cirros
 392     BuiltIn.Run Keyword If    ${rcode}    DevstackUtils.Write Commands Until Prompt    exit
 393
 394 Check Ping
 395     [Arguments]    ${ip_address}    ${ttl}=64
 396     [Documentation]    Run Ping command on the IP available as argument
 397     ${ethertype} =    String.Get Regexp Matches    ${ip_address}    ${IP_REGEX}
 398     ${output} =    BuiltIn.Run Keyword If    ${ethertype}    Utils.Write Commands Until Expected Prompt    ping -t ${ttl} -c 3 ${ip_address}    ${OS_SYSTEM_PROMPT}
 399     ...    ELSE    Utils.Write Commands Until Expected Prompt    ping6 -t ${ttl} -c 3 ${ip_address}    ${OS_SYSTEM_PROMPT}
 400     BuiltIn.Should Contain    ${output}    64 bytes
 401
 402 Check No Ping
 403     [Arguments]    ${ip_address}    ${ttl}=64
 404     [Documentation]    Run Ping command to the IP given as argument, executing 3 times and expecting NOT to see "64 bytes"
 405     ${output} =    Utils.Write Commands Until Expected Prompt    ping -t ${ttl} -c 3 ${ip_address}    ${OS_SYSTEM_PROMPT}
 406     BuiltIn.Should Not Contain    ${output}    64 bytes
 407
 408 Check Metadata Access
 409     [Documentation]    Try curl on the Metadataurl and check if it is okay
 410     ${output} =    Utils.Write Commands Until Expected Prompt    curl -i http://169.254.169.254    ${OS_SYSTEM_PROMPT}
 411     BuiltIn.Should Contain    ${output}    200
 412
 413 Execute Command on VM Instance
 414     [Arguments]    ${net_name}    ${vm_ip}    ${cmd}    ${user}=cirros    ${password}=cubswin:)
 415     [Documentation]    Login to the vm instance using ssh in the network, executes a command inside the VM and returns the ouput.
 416     OpenStackOperations.Get ControlNode Connection
 417     ${net_id} =    OpenStackOperations.Get Net Id    ${net_name}
 418     ${output} =    Utils.Write Commands Until Expected Prompt    sudo ip netns exec qdhcp-${net_id} ssh ${user}@${vm_ip} -o ConnectTimeout=10 -o StrictHostKeyChecking=no -o UserKnownHostsFile=/dev/null    password:
 419     ${output} =    Utils.Write Commands Until Expected Prompt    ${password}    ${OS_SYSTEM_PROMPT}
 420     ${rcode} =    BuiltIn.Run Keyword And Return Status    OpenStackOperations.Check If Console Is VmInstance
 421     ${output} =    BuiltIn.Run Keyword If    ${rcode}    Utils.Write Commands Until Expected Prompt    ${cmd}    ${OS_SYSTEM_PROMPT}
 422     [Teardown]    Exit From Vm Console
 423     [Return]    ${output}
 424
 425 Test Operations From Vm Instance
 426     [Arguments]    ${net_name}    ${src_ip}    ${dest_ips}    ${user}=cirros    ${password}=cubswin:)    ${ttl}=64
 427     ...    ${ping_should_succeed}=True    ${check_metadata}=True
 428     [Documentation]    Login to the vm instance using ssh in the network.
 429     OpenStackOperations.Get ControlNode Connection
 430     ${net_id} =    OpenStackOperations.Get Net Id    ${net_name}
 431     ${output} =    Utils.Write Commands Until Expected Prompt    sudo ip netns exec qdhcp-${net_id} ssh -o ConnectTimeout=10 -o StrictHostKeyChecking=no ${user}@${src_ip} -o UserKnownHostsFile=/dev/null    password:
 432     ${output} =    Utils.Write Commands Until Expected Prompt    ${password}    ${OS_SYSTEM_PROMPT}
 433     ${rcode} =    BuiltIn.Run Keyword And Return Status    OpenStackOperations.Check If Console Is VmInstance
 434     BuiltIn.Run Keyword If    ${rcode}    Utils.Write Commands Until Expected Prompt    ifconfig    ${OS_SYSTEM_PROMPT}
 435     BuiltIn.Run Keyword If    ${rcode}    Utils.Write Commands Until Expected Prompt    route -n    ${OS_SYSTEM_PROMPT}
 436     BuiltIn.Run Keyword If    ${rcode}    Utils.Write Commands Until Expected Prompt    route -A inet6    ${OS_SYSTEM_PROMPT}
 437     BuiltIn.Run Keyword If    ${rcode}    Utils.Write Commands Until Expected Prompt    arp -an    ${OS_SYSTEM_PROMPT}
 438     BuiltIn.Run Keyword If    ${rcode}    Utils.Write Commands Until Expected Prompt    ip -f inet6 neigh show    ${OS_SYSTEM_PROMPT}
 439     : FOR    ${dest_ip}    IN    @{dest_ips}
 440     \    ${string_empty} =    BuiltIn.Run Keyword And Return Status    Should Be Empty    ${dest_ip}
 441     \    BuiltIn.Run Keyword If    ${string_empty}    Continue For Loop
 442     \    BuiltIn.Run Keyword If    ${rcode} and "${ping_should_succeed}" == "True"    OpenStackOperations.Check Ping    ${dest_ip}    ttl=${ttl}
 443     \    ...    ELSE    OpenStackOperations.Check No Ping    ${dest_ip}    ttl=${ttl}
 444     ${ethertype} =    String.Get Regexp Matches    ${src_ip}    ${IP_REGEX}
 445     BuiltIn.Run Keyword If    ${rcode} and "${check_metadata}" and ${ethertype} == "True"    OpenStackOperations.Check Metadata Access
 446     [Teardown]    Exit From Vm Console
 447
 448 Test Netcat Operations From Vm Instance
 449     [Arguments]    ${net_name}    ${vm_ip}    ${dest_ip}    ${additional_args}=${EMPTY}    ${port}=12345    ${user}=cirros
 450     ...    ${password}=cubswin:)
 451     [Documentation]    Use Netcat to test TCP/UDP connections to the controller
 452     ${client_data}    BuiltIn.Set Variable    Test Client Data
 453     ${server_data}    BuiltIn.Set Variable    Test Server Data
 454     OpenStackOperations.Get ControlNode Connection
 455     ${output} =    DevstackUtils.Write Commands Until Prompt And Log    ( ( echo "${server_data}" | sudo timeout 60 nc -l ${additional_args} ${port} ) & )
 456     ${output} =    DevstackUtils.Write Commands Until Prompt And Log    sudo netstat -nlap | grep ${port}
 457     ${nc_output} =    OpenStackOperations.Execute Command on VM Instance    ${net_name}    ${vm_ip}    sudo echo "${client_data}" | nc -v -w 5 ${additional_args} ${dest_ip} ${port}
 458     BuiltIn.Log    ${output}
 459     ${output} =    OpenStackOperations.Execute Command on VM Instance    ${net_name}    ${vm_ip}    sudo route -n
 460     BuiltIn.Log    ${output}
 461     ${output} =    OpenStackOperations.Execute Command on VM Instance    ${net_name}    ${vm_ip}    sudo arp -an
 462     BuiltIn.Log    ${output}
 463     BuiltIn.Should Match Regexp    ${nc_output}    ${server_data}
 464
 465 Ping Other Instances
 466     [Arguments]    ${list_of_external_dst_ips}
 467     [Documentation]    Check reachability with other network's instances.
 468     ${rcode} =    BuiltIn.Run Keyword And Return Status    OpenStackOperations.Check If Console Is VmInstance
 469     : FOR    ${dest_ip}    IN    @{list_of_external_dst_ips}
 470     \    OpenStackOperations.Check Ping    ${dest_ip}
 471
 472 Create Router
 473     [Arguments]    ${router_name}
 474     [Documentation]    Create Router and Add Interface to the subnets.
 475     ${output} =    OpenStack CLI    openstack router create ${router_name}
 476
 477 List Routers
 478     [Documentation]    List Routers and return output with neutron client.
 479     ${output} =    OpenStack CLI    openstack router list -f value
 480     [Return]    ${output}
 481
 482 Add Router Interface
 483     [Arguments]    ${router_name}    ${interface_name}
 484     ${output} =    OpenStack CLI    openstack router add subnet ${router_name} ${interface_name}
 485
 486 Show Router Interface
 487     [Arguments]    ${router_name}
 488     [Documentation]    List Routers interface associated with given Router and return output with neutron client.
 489     ${output} =    OpenStack CLI    openstack port list --router ${router_name} -f value
 490     [Return]    ${output}
 491
 492 Add Router Gateway
 493     [Arguments]    ${router_name}    ${external_network_name}    ${additional_args}=${EMPTY}
 494     ${output} =    OpenStack CLI    openstack router set ${router_name} --external-gateway ${external_network_name} ${additional_args}
 495
 496 Remove Interface
 497     [Arguments]    ${router_name}    ${interface_name}
 498     [Documentation]    Remove Interface to the subnets.
 499     ${output} =    OpenStack CLI    openstack router remove subnet ${router_name} ${interface_name}
 500
 501 Remove Gateway
 502     [Arguments]    ${router_name}
 503     [Documentation]    Remove external gateway from the router.
 504     BuiltIn.Log    openstack router unset ${router_name} --external-gateway
 505
 506 Update Router
 507     [Arguments]    ${router_name}    ${cmd}
 508     [Documentation]    Update the router with the command. Router name and command should be passed as argument.
 509     ${output} =    OpenStack CLI    openstack router set ${router_name} ${cmd}
 510
 511 Show Router
 512     [Arguments]    ${router_name}    ${options}
 513     [Documentation]    Show information of a given router. Router name and optional fields should be sent as arguments.
 514     ${output} =    OpenStack CLI    openstack router show ${router_name}
 515     [Return]    ${output}
 516
 517 Delete Router
 518     [Arguments]    ${router_name}
 519     [Documentation]    Delete Router and Interface to the subnets.
 520     ${output} =    OpenStack CLI    openstack router delete ${router_name}
 521
 522 Get DumpFlows And Ovsconfig
 523     [Arguments]    ${conn_id}
 524     [Documentation]    Get the OvsConfig and Flow entries from OVS from the Openstack Node
 525     SSHLibrary.Switch Connection    ${conn_id}
 526     Utils.Write Commands Until Expected Prompt    ip -o link    ${DEFAULT_LINUX_PROMPT_STRICT}
 527     Utils.Write Commands Until Expected Prompt    ip -o addr    ${DEFAULT_LINUX_PROMPT_STRICT}
 528     Utils.Write Commands Until Expected Prompt    ip route    ${DEFAULT_LINUX_PROMPT_STRICT}
 529     Utils.Write Commands Until Expected Prompt    arp -an    ${DEFAULT_LINUX_PROMPT_STRICT}
 530     ${nslist} =    Utils.Write Commands Until Expected Prompt    ip netns list | awk '{print $1}'    ${DEFAULT_LINUX_PROMPT_STRICT}
 531     @{lines}    Split To Lines    ${nslist}    end=-1
 532     : FOR    ${line}    IN    @{lines}
 533     \    Utils.Write Commands Until Expected Prompt    sudo ip netns exec ${line} ip -o link    ${DEFAULT_LINUX_PROMPT_STRICT}
 534     \    Utils.Write Commands Until Expected Prompt    sudo ip netns exec ${line} ip -o addr    ${DEFAULT_LINUX_PROMPT_STRICT}
 535     \    Utils.Write Commands Until Expected Prompt    sudo ip netns exec ${line} ip route    ${DEFAULT_LINUX_PROMPT_STRICT}
 536     Utils.Write Commands Until Expected Prompt    sudo ovs-vsctl show    ${DEFAULT_LINUX_PROMPT_STRICT}
 537     Utils.Write Commands Until Expected Prompt    sudo ovs-vsctl list Open_vSwitch    ${DEFAULT_LINUX_PROMPT_STRICT}
 538     Utils.Write Commands Until Expected Prompt    sudo ovs-ofctl show ${INTEGRATION_BRIDGE} -OOpenFlow13    ${DEFAULT_LINUX_PROMPT_STRICT}
 539     Utils.Write Commands Until Expected Prompt    sudo ovs-ofctl dump-flows ${INTEGRATION_BRIDGE} -OOpenFlow13    ${DEFAULT_LINUX_PROMPT_STRICT}
 540     Utils.Write Commands Until Expected Prompt    sudo ovs-ofctl dump-groups ${INTEGRATION_BRIDGE} -OOpenFlow13    ${DEFAULT_LINUX_PROMPT_STRICT}
 541     Utils.Write Commands Until Expected Prompt    sudo ovs-ofctl dump-group-stats ${INTEGRATION_BRIDGE} -OOpenFlow13    ${DEFAULT_LINUX_PROMPT_STRICT}
 542
 543 Get ControlNode Connection
 544     SSHLibrary.Switch Connection    ${OS_CNTL_CONN_ID}
 545     [Return]    ${OS_CNTL_CONN_ID}
 546
 547 Get OvsDebugInfo
 548     [Documentation]    Get the OvsConfig and Flow entries from all Openstack nodes
 549     : FOR    ${conn_id}    IN    @{OS_ALL_CONN_IDS}
 550     \    OpenStackOperations.Get DumpFlows And Ovsconfig    ${conn_id}
 551
 552 Get Test Teardown Debugs
 553     [Arguments]    ${test_name}=${SUITE_NAME}.${TEST_NAME}    ${fail}=${FAIL_ON_EXCEPTIONS}
 554     ODLTools.Get Cluster Info
 555     OpenStackOperations.Get OvsDebugInfo
 556     BuiltIn.Run Keyword And Ignore Error    DataModels.Get Model Dump    ${HA_PROXY_IP}    ${netvirt_data_models}
 557     BuiltIn.run Keyword And Ignore Error    ODLTools.Get EOS    ${HA_PROXY_IP}
 558     KarafKeywords.Fail If Exceptions Found During Test    ${test_name}    fail=${fail}
 559
 560 Get Suite Debugs
 561     Get Test Teardown Debugs    test_name=${SUITE_NAME}    fail=False
 562
 563 Get Test Teardown Debugs For SFC
 564     [Arguments]    ${test_name}=${TEST_NAME}
 565     BuiltIn.Run Keyword And Ignore Error    DataModels.Get Model Dump    ${HA_PROXY_IP}    ${netvirt_sfc_data_models}
 566
 567 Show Debugs
 568     [Arguments]    @{vm_indices}
 569     [Documentation]    Run these commands for debugging, it can list state of VM instances and ip information in control node
 570     OpenStackOperations.Get ControlNode Connection
 571     ${output} =    DevstackUtils.Write Commands Until Prompt And Log    sudo ip netns list
 572     : FOR    ${index}    IN    @{vm_indices}
 573     \    ${rc}    ${output} =    OperatingSystem.Run And Return Rc And Output    nova show ${index}
 574     \    BuiltIn.Log    ${output}
 575     OpenStackOperations.List Nova VMs
 576     OpenStackOperations.List Routers
 577     OpenStackOperations.List Networks
 578     OpenStackOperations.List Subnets
 579     OpenStackOperations.List Ports
 580     OpenStackOperations.List Security Groups
 581
 582 List Security Groups
 583     [Documentation]    Logging keyword to display all security groups using the openstack cli. Assumes openstack
 584     ...    credentials are already sourced
 585     ${output} =    OpenStack CLI    openstack security group list
 586     [Return]    ${output}
 587
 588 Neutron Security Group Show
 589     [Arguments]    ${SecurityGroupRuleName}
 590     [Documentation]    Displays the neutron security group configurations that belongs to a given neutron security group name
 591     ${output} =    OpenStack CLI    openstack security group show ${SecurityGroupRuleName}
 592     [Return]    ${output}
 593
 594 Neutron Port Show
 595     [Arguments]    ${PortName}
 596     [Documentation]    Display the port configuration that belong to a given neutron port
 597     ${output} =    OpenStack CLI    openstack port show ${PortName}
 598     [Return]    ${output}
 599
 600 Neutron Security Group Create
 601     [Arguments]    ${SecurityGroupName}    ${additional_args}=${EMPTY}
 602     [Documentation]    Create a security group with specified name ,description & protocol value according to security group template
 603     OpenStackOperations.Get ControlNode Connection
 604     ${output} =    OpenStack CLI    openstack security group create ${SecurityGroupName} ${additional_args}
 605     ${sgp_id} =    BuiltIn.Should Match Regexp    ${output}    ${REGEX_UUID}
 606     [Return]    ${output}    ${sgp_id}
 607
 608 Neutron Security Group Update
 609     [Arguments]    ${SecurityGroupName}    ${additional_args}=${EMPTY}
 610     [Documentation]    Updating security groups
 611     ${output} =    OpenStack CLI    openstack security group set ${SecurityGroupName} ${additional_args}
 612     [Return]    ${output}
 613
 614 Delete SecurityGroup
 615     [Arguments]    ${sg_name}
 616     [Documentation]    Delete Security group
 617     ${output} =    OpenStack CLI    openstack security group delete ${sg_name}
 618
 619 Neutron Security Group Rule Create
 620     [Arguments]    ${Security_group_name}    &{Kwargs}
 621     [Documentation]    Creates neutron security rule with Openstack CLI with or without optional params, here security group name is mandatory args, rule with optional params can be created by passing the optional args values ex: direction=${INGRESS_EGRESS}, Then these optional params are BuiltIn.Catenated with mandatory args, example of usage: "OpenStack Neutron Security Group Rule Create ${SGP_SSH} direction=${RULE_PARAMS[0]} ethertype=${RULE_PARAMS[1]} ..."
 622     BuiltIn.Run Keyword If    ${Kwargs}    BuiltIn.Log    ${Kwargs}
 623     ${description}    BuiltIn.Run Keyword If    ${Kwargs}    Collections.Pop From Dictionary    ${Kwargs}    description    default=${None}
 624     ${direction}    BuiltIn.Run Keyword If    ${Kwargs}    Collections.Pop From Dictionary    ${Kwargs}    direction    default=${None}
 625     ${ethertype}    BuiltIn.Run Keyword If    ${Kwargs}    Collections.Pop From Dictionary    ${Kwargs}    ethertype    default=${None}
 626     ${port_range_max}    BuiltIn.Run Keyword If    ${Kwargs}    Collections.Pop From Dictionary    ${Kwargs}    port_range_max    default=${None}
 627     ${port_range_min}    BuiltIn.Run Keyword If    ${Kwargs}    Collections.Pop From Dictionary    ${Kwargs}    port_range_min    default=${None}
 628     ${protocol}    BuiltIn.Run Keyword If    ${Kwargs}    Collections.Pop From Dictionary    ${Kwargs}    protocol    default=${None}
 629     ${remote_group_id}    BuiltIn.Run Keyword If    ${Kwargs}    Collections.Pop From Dictionary    ${Kwargs}    remote_group_id    default=${None}
 630     ${remote_ip_prefix}    BuiltIn.Run Keyword If    ${Kwargs}    Collections.Pop From Dictionary    ${Kwargs}    remote_ip_prefix    default=${None}
 631     ${cmd} =    BuiltIn.Set Variable    openstack security group rule create ${Security_group_name}
 632     ${cmd} =    BuiltIn.Run Keyword If    '${description}'!='None'    BuiltIn.Catenate    ${cmd}    --description ${description}
 633     ...    ELSE    BuiltIn.Catenate    ${cmd}
 634     ${cmd} =    BuiltIn.Run Keyword If    '${direction}'!='None'    BuiltIn.Catenate    ${cmd}    --${direction}
 635     ...    ELSE    BuiltIn.Catenate    ${cmd}
 636     ${cmd} =    BuiltIn.Run Keyword If    '${ethertype}'!='None'    BuiltIn.Catenate    ${cmd}    --ethertype ${ethertype}
 637     ...    ELSE    BuiltIn.Catenate    ${cmd}
 638     ${cmd} =    BuiltIn.Run Keyword If    '${port_range_min}'!='None' and '${port_range_max}'!='None'    BuiltIn.Catenate    ${cmd}    --dst-port ${port_range_min}:${port_range_max}
 639     ...    ELSE IF    '${port_range_max}'!='None'    BuiltIn.Catenate    ${cmd}    --dst-port ${port_range_max}
 640     ...    ELSE IF    '${port_range_min}'!='None'    BuiltIn.Catenate    ${cmd}    --dst-port ${port_range_min}
 641     ...    ELSE    BuiltIn.Catenate    ${cmd}
 642     ${cmd} =    BuiltIn.Run Keyword If    '${protocol}'!='None'    BuiltIn.Catenate    ${cmd}    --protocol ${protocol}
 643     ...    ELSE    BuiltIn.Catenate    ${cmd}
 644     ${cmd} =    BuiltIn.Run Keyword If    '${remote_group_id}'!='None'    BuiltIn.Catenate    ${cmd}    --remote-group ${remote_group_id}
 645     ...    ELSE    BuiltIn.Catenate    ${cmd}
 646     ${cmd} =    BuiltIn.Run Keyword If    '${remote_ip_prefix}'!='None'    BuiltIn.Catenate    ${cmd}    --src-ip ${remote_ip_prefix}
 647     ...    ELSE    BuiltIn.Catenate    ${cmd}
 648     ${output} =    OpenStack CLI    ${cmd}
 649     ${rule_id} =    BuiltIn.Should Match Regexp    ${output}    ${REGEX_UUID}
 650     [Return]    ${output}    ${rule_id}
 651
 652 Security Group Create Without Default Security Rules
 653     [Arguments]    ${sg_name}    ${additional_args}=${EMPTY}
 654     [Documentation]    Create Neutron Security Group with no default rules, using specified name and optional arguments.
 655     OpenStackOperations.Neutron Security Group Create    ${sg_name}    ${additional_args}
 656     Delete All Security Group Rules    ${sg_name}
 657
 658 Delete All Security Group Rules
 659     [Arguments]    ${sg_name}
 660     [Documentation]    Delete all security rules from a specified security group
 661     ${sg_rules_output} =    OpenStack CLI    openstack security group rule list ${sg_name} -cID -fvalue
 662     @{sg_rules} =    String.Split String    ${sg_rules_output}    \n
 663     : FOR    ${rule}    IN    @{sg_rules}
 664     \    ${output} =    OpenStack CLI    openstack security group rule delete ${rule}
 665
 666 Create Allow All SecurityGroup
 667     [Arguments]    ${sg_name}    ${ether_type}=IPv4
 668     [Documentation]    Allow all TCP/UDP/ICMP packets for this suite
 669     OpenStackOperations.Neutron Security Group Create    ${sg_name}
 670     OpenStackOperations.Neutron Security Group Rule Create    ${sg_name}    direction=ingress    ethertype=${ether_type}    port_range_max=65535    port_range_min=1    protocol=tcp
 671     OpenStackOperations.Neutron Security Group Rule Create    ${sg_name}    direction=egress    ethertype=${ether_type}    port_range_max=65535    port_range_min=1    protocol=tcp
 672     OpenStackOperations.Neutron Security Group Rule Create    ${sg_name}    direction=ingress    ethertype=${ether_type}    protocol=icmp
 673     OpenStackOperations.Neutron Security Group Rule Create    ${sg_name}    direction=egress    ethertype=${ether_type}    protocol=icmp
 674     OpenStackOperations.Neutron Security Group Rule Create    ${sg_name}    direction=ingress    ethertype=${ether_type}    port_range_max=65535    port_range_min=1    protocol=udp
 675     OpenStackOperations.Neutron Security Group Rule Create    ${sg_name}    direction=egress    ethertype=${ether_type}    port_range_max=65535    port_range_min=1    protocol=udp
 676
 677 Create Neutron Port With Additional Params
 678     [Arguments]    ${network_name}    ${port_name}    ${additional_args}=${EMPTY}
 679     [Documentation]    Create Port With given additional parameters
 680     ${rc}    ${output} =    OperatingSystem.Run And Return Rc And Output    neutron -v port-create ${network_name} --name ${port_name} ${additional_args}
 681     BuiltIn.Log    ${output}
 682     BuiltIn.Should Be True    '${rc}' == '0'
 683     ${port_id} =    BuiltIn.Should Match Regexp    ${OUTPUT}    ${REGEX_UUID}
 684     [Return]    ${OUTPUT}    ${port_id}
 685
 686 Get Ports MacAddr
 687     [Arguments]    ${ports}
 688     [Documentation]    Retrieve the port MacAddr for the given list of port name and return the MAC address list.
 689     ${macs}    BuiltIn.Create List
 690     : FOR    ${port}    IN    @{ports}
 691     \    ${mac} =    OpenStackOperations.Get Port Mac    ${port}
 692     \    Collections.Append To List    ${macs}    ${mac}
 693     [Return]    ${macs}
 694
 695 Get Port Ip
 696     [Arguments]    ${port_name}
 697     [Documentation]    Keyword would return the IP of the ${port_name} received.
 698     ${output} =    OpenStack CLI    openstack port list | grep "${port_name}" | awk -F\\' '{print $2}'
 699     ${splitted_output} =    String.Split String    ${output}    ${EMPTY}
 700     ${port_ip} =    Collections.Get from List    ${splitted_output}    0
 701     [Return]    ${port_ip}
 702
 703 Get Port Mac
 704     [Arguments]    ${port_name}
 705     [Documentation]    Keyword would return the MAC ID of the ${port_name} received.
 706     ${output} =    OpenStack CLI    openstack port show ${port_name} | grep mac_address | awk '{print $4}'
 707     ${splitted_output} =    String.Split String    ${output}    ${EMPTY}
 708     ${port_mac} =    Collections.Get from List    ${splitted_output}    0
 709     [Return]    ${port_mac}
 710
 711 Get Port Mac Address From Ip
 712     [Arguments]    ${ip}
 713     [Documentation]    Retrieve the mac address for a port that matches any given ip.
 714     ${output} =    OpenStack CLI    openstack port list | grep -w ${ip} | awk '{print $5}'
 715     ${splitted_output} =    String.Split String    ${output}    ${EMPTY}
 716     ${mac_addr} =    Collections.Get from List    ${splitted_output}    0
 717     [Return]    ${mac_addr}
 718
 719 Create L2Gateway
 720     [Arguments]    ${bridge_name}    ${intf_name}    ${gw_name}
 721     [Documentation]    Keyword to create an L2 Gateway ${gw_name} for bridge ${bridge_name} connected to interface ${intf_name} (Using Neutron CLI).
 722     ${rc}    ${l2gw_output} =    OperatingSystem.Run And Return Rc And Output    ${L2GW_CREATE} name=${bridge_name},interface_names=${intf_name} ${gw_name}
 723     BuiltIn.Log    ${l2gw_output}
 724     [Return]    ${l2gw_output}
 725
 726 Update L2Gateway
 727     [Arguments]    ${bridge_name}    ${gw_name}    ${intf_name_1}    ${intf_name_2}
 728     [Documentation]    Keyword to add {intf_name_list} to an existing L2 Gateway ${gw_name} (Using Neutron CLI).
 729     ${rc}    ${l2gw_output}=    Run And Return Rc And Output    ${L2GW_UPDATE} name=${bridge_name},interface_names="${intf_name_1};${intf_name_2}" ${gw_name}
 730     Log    ${l2gw_output}
 731     [Return]    ${l2gw_output}
 732
 733 Create L2Gateway Connection
 734     [Arguments]    ${gw_name}    ${net_name}
 735     [Documentation]    Keyword would create a new L2 Gateway Connection for ${gw_name} to ${net_name} (Using Neutron CLI).
 736     ${rc}    ${l2gw_output} =    OperatingSystem.Run And Return Rc And Output    ${L2GW_CONN_CREATE} ${gw_name} ${net_name}
 737     BuiltIn.Log    ${l2gw_output}
 738     BuiltIn.Should Be True    '${rc}' == '0'
 739     [Return]    ${l2gw_output}
 740
 741 Get All L2Gateway
 742     [Documentation]    Keyword to return all the L2 Gateways available (Using Neutron CLI).
 743     ${rc}    ${output} =    OperatingSystem.Run And Return Rc And Output    ${L2GW_GET_YAML}
 744     BuiltIn.Should Be True    '${rc}' == '0'
 745     [Return]    ${output}
 746
 747 Get All L2Gateway Connection
 748     [Documentation]    Keyword to return all the L2 Gateway connections available (Using Neutron CLI).
 749     ${rc}    ${output} =    OperatingSystem.Run And Return Rc And Output    ${L2GW_GET_CONN_YAML}
 750     BuiltIn.Should Be True    '${rc}' == '0'
 751     [Return]    ${output}
 752
 753 Get L2Gateway
 754     [Arguments]    ${gw_id}
 755     [Documentation]    Keyword to check if the ${gw_id} is available in the L2 Gateway list (Using Neutron CLI).
 756     ${rc}    ${output} =    OperatingSystem.Run And Return Rc And Output    ${L2GW_SHOW} ${gw_id}
 757     BuiltIn.Log    ${output}
 758     BuiltIn.Should Be True    '${rc}' == '0'
 759     [Return]    ${output}
 760
 761 Get L2gw Id
 762     [Arguments]    ${l2gw_name}
 763     [Documentation]    Keyword to retrieve the L2 Gateway ID for the ${l2gw_name} (Using Neutron CLI).
 764     ${rc}    ${output} =    OperatingSystem.Run And Return Rc And Output    ${L2GW_GET} | grep "${l2gw_name}" | awk '{print $2}'
 765     BuiltIn.Log    ${output}
 766     BuiltIn.Should Be True    '${rc}' == '0'
 767     ${splitted_output} =    String.Split String    ${output}    ${EMPTY}
 768     ${l2gw_id} =    Collections.Get from List    ${splitted_output}    0
 769     [Return]    ${l2gw_id}
 770
 771 Get L2gw Connection Id
 772     [Arguments]    ${l2gw_name}
 773     [Documentation]    Keyword to retrieve the L2 Gateway Connection ID for the ${l2gw_name} (Using Neutron CLI).
 774     ${l2gw_id} =    OpenStackOperations.Get L2gw Id    ${l2gw_name}
 775     ${rc}    ${output} =    OperatingSystem.Run And Return Rc And Output    ${L2GW_GET_CONN} | grep "${l2gw_id}" | awk '{print $2}'
 776     BuiltIn.Should Be True    '${rc}' == '0'
 777     ${splitted_output} =    String.Split String    ${output}    ${EMPTY}
 778     ${splitted_output} =    String.Split String    ${output}    ${EMPTY}
 779     ${l2gw_conn_id} =    Collections.Get from List    ${splitted_output}    0
 780     [Return]    ${l2gw_conn_id}
 781
 782 Neutron Port List Rest
 783     [Documentation]    Keyword to get all ports details in Neutron (Using REST).
 784     ${resp} =    RequestsLibrary.Get Request    session    ${PORT_URL}
 785     BuiltIn.Log    ${resp.content}
 786     BuiltIn.Should Be Equal As Strings    ${resp.status_code}    200
 787     [Return]    ${resp.content}
 788
 789 Get Neutron Port Rest
 790     [Arguments]    ${port_id}
 791     [Documentation]    Keyword to get the specific port details in Neutron (Using REST).
 792     ${resp} =    RequestsLibrary.Get Request    session    ${CONFIG_API}/${GET_PORT_URL}/${port_id}
 793     BuiltIn.Log    ${resp.content}
 794     BuiltIn.Should Be Equal As Strings    ${resp.status_code}    200
 795     [Return]    ${resp.content}
 796
 797 Update Port Rest
 798     [Arguments]    ${port_id}    ${json_data}
 799     [Documentation]    Keyword to update ${port_id} with json data received in ${json_data} (Using REST).
 800     BuiltIn.Log    ${json_data}
 801     ${resp} =    RequestsLibrary.Put Request    session    ${CONFIG_API}/${GET_PORT_URL}/${port_id}    ${json_data}
 802     BuiltIn.Log    ${resp.content}
 803     BuiltIn.Should Be Equal As Strings    ${resp.status_code}    200
 804     [Return]    ${resp.content}
 805
 806 Get Neutron Network Rest
 807     [Arguments]    ${net_id}
 808     [Documentation]    Keyword to get the specific network details in Neutron (Using REST).
 809     ${resp} =    RequestsLibrary.Get Request    session    ${NETWORK_URL}/network/${net_id}
 810     BuiltIn.Log    ${resp.content}
 811     BuiltIn.Should Be Equal As Strings    ${resp.status_code}    200
 812     [Return]    ${resp.content}
 813
 814 Create And Configure Security Group
 815     [Arguments]    ${sg-name}
 816     [Documentation]    Create Security Group with given name, and default allow rules for TCP/UDP/ICMP protocols.
 817     OpenStackOperations.Neutron Security Group Create    ${sg-name}
 818     OpenStackOperations.Neutron Security Group Rule Create    ${sg-name}    direction=ingress    port_range_max=65535    port_range_min=1    protocol=tcp    remote_ip_prefix=0.0.0.0/0
 819     OpenStackOperations.Neutron Security Group Rule Create    ${sg-name}    direction=egress    port_range_max=65535    port_range_min=1    protocol=tcp    remote_ip_prefix=0.0.0.0/0
 820     OpenStackOperations.Neutron Security Group Rule Create    ${sg-name}    direction=ingress    protocol=icmp    remote_ip_prefix=0.0.0.0/0
 821     OpenStackOperations.Neutron Security Group Rule Create    ${sg-name}    direction=egress    protocol=icmp    remote_ip_prefix=0.0.0.0/0
 822     OpenStackOperations.Neutron Security Group Rule Create    ${sg-name}    direction=ingress    port_range_max=65535    port_range_min=1    protocol=udp    remote_ip_prefix=0.0.0.0/0
 823     OpenStackOperations.Neutron Security Group Rule Create    ${sg-name}    direction=egress    port_range_max=65535    port_range_min=1    protocol=udp    remote_ip_prefix=0.0.0.0/0
 824
 825 Add Security Group To VM
 826     [Arguments]    ${vm}    ${sg}
 827     [Documentation]    Add the security group provided to the given VM.
 828     ${output} =    OpenStack CLI    openstack server add security group ${vm} ${sg}
 829
 830 Remove Security Group From VM
 831     [Arguments]    ${vm}    ${sg}
 832     [Documentation]    Remove the security group provided to the given VM.
 833     OpenStackOperations.Get ControlNode Connection
 834     ${output} =    OpenStack CLI    openstack server remove security group ${vm} ${sg}
 835
 836 Create SFC Flow Classifier
 837     [Arguments]    ${name}    ${src_ip}    ${dest_ip}    ${protocol}    ${dest_port}    ${neutron_src_port}
 838     [Documentation]    Create a flow classifier for SFC
 839     ${output} =    OpenStack CLI    openstack sfc flow classifier create --ethertype IPv4 --source-ip-prefix ${src_ip}/32 --destination-ip-prefix ${dest_ip}/32 --protocol ${protocol} --destination-port ${dest_port}:${dest_port} --logical-source-port ${neutron_src_port} ${name}
 840     BuiltIn.Should Contain    ${output}    ${name}
 841     [Return]    ${output}
 842
 843 Delete SFC Flow Classifier
 844     [Arguments]    ${name}
 845     [Documentation]    Delete a SFC flow classifier
 846     OpenStackOperations.Get ControlNode Connection
 847     ${output} =    OpenStack CLI    openstack sfc flow classifier delete ${name}
 848     [Return]    ${output}
 849
 850 Create SFC Port Pair
 851     [Arguments]    ${name}    ${port_in}    ${port_out}
 852     [Documentation]    Creates a neutron port pair for SFC
 853     OpenStackOperations.Get ControlNode Connection
 854     ${output} =    OpenStack CLI    openstack sfc port pair create --ingress=${port_in} --egress=${port_out} ${name}
 855     BuiltIn.Should Contain    ${output}    ${name}
 856     [Return]    ${output}
 857
 858 Delete SFC Port Pair
 859     [Arguments]    ${name}
 860     [Documentation]    Delete a SFC port pair
 861     ${output} =    OpenStack CLI    openstack sfc port pair delete ${name}
 862     [Return]    ${output}
 863
 864 Create SFC Port Pair Group
 865     [Arguments]    ${name}    ${port_pair}
 866     [Documentation]    Creates a port pair group with a single port pair for SFC
 867     ${output} =    OpenStack CLI    openstack sfc port pair group create --port-pair ${port_pair} ${name}
 868     BuiltIn.Should Contain    ${output}    ${name}
 869     [Return]    ${output}
 870
 871 Create SFC Port Pair Group With Two Pairs
 872     [Arguments]    ${name}    ${port_pair1}    ${port_pair2}
 873     [Documentation]    Creates a port pair group with two port pairs for SFC
 874     ${output} =    OpenStack CLI    openstack sfc port pair group create --port-pair ${port_pair1} --port-pair ${port_pair2} ${name}
 875     BuiltIn.Should Contain    ${output}    ${name}
 876     [Return]    ${output}
 877
 878 Delete SFC Port Pair Group
 879     [Arguments]    ${name}
 880     [Documentation]    Delete a SFC port pair group
 881     OpenStackOperations.Get ControlNode Connection
 882     ${output} =    OpenStack CLI    openstack sfc port pair group delete ${name}
 883     [Return]    ${output}
 884
 885 Create SFC Port Chain
 886     [Arguments]    ${name}    ${pg1}    ${pg2}    ${fc}
 887     [Documentation]    Creates a port pair chain with two port groups and a singel classifier.
 888     ${output} =    OpenStack CLI    openstack sfc port chain create --port-pair-group ${pg1} --port-pair-group ${pg2} --flow-classifier ${fc} ${name}
 889     BuiltIn.Should Contain    ${output}    ${name}
 890     [Return]    ${output}
 891
 892 Delete SFC Port Chain
 893     [Arguments]    ${name}
 894     [Documentation]    Delete a SFC port chain
 895     ${output} =    OpenStack CLI    openstack sfc port chain delete ${name}
 896     [Return]    ${output}
 897
 898 Reboot Nova VM
 899     [Arguments]    ${vm_name}
 900     [Documentation]    Reboot NOVA VM
 901     ${output} =    OpenStack CLI    openstack server reboot --wait ${vm_name}
 902     BuiltIn.Wait Until Keyword Succeeds    35s    10s    OpenStackOperations.Verify VM Is ACTIVE    ${vm_name}
 903
 904 Remove RSA Key From KnownHosts
 905     [Arguments]    ${vm_ip}
 906     [Documentation]    Remove RSA
 907     OpenStackOperations.Get ControlNode Connection
 908     ${output} =    DevstackUtils.Write Commands Until Prompt And Log    sudo cat /root/.ssh/known_hosts    30s
 909     ${output} =    DevstackUtils.Write Commands Until Prompt And Log    sudo ssh-keygen -f "/root/.ssh/known_hosts" -R ${vm_ip}    30s
 910     ${output} =    DevstackUtils.Write Commands Until Prompt    sudo cat "/root/.ssh/known_hosts"    30s
 911
 912 Wait For Routes To Propogate
 913     [Arguments]    ${networks}    ${subnets}
 914     [Documentation]    Check propagated routes
 915     OpenStackOperations.Get ControlNode Connection
 916     : FOR    ${INDEX}    IN RANGE    0    1
 917     \    ${net_id} =    OpenStackOperations.Get Net Id    @{networks}[${INDEX}]
 918     \    ${is_ipv6} =    String.Get Regexp Matches    @{subnets}[${INDEX}]    ${IP6_REGEX}
 919     \    ${length} =    BuiltIn.Get Length    ${is_ipv6}
 920     \    ${cmd} =    BuiltIn.Set Variable If    ${length} == 0    ip route    ip -6 route
 921     \    ${output} =    Utils.Write Commands Until Expected Prompt    sudo ip netns exec qdhcp-${net_id} ${cmd}    ${DEFAULT_LINUX_PROMPT_STRICT}
 922     \    BuiltIn.Should Contain    ${output}    @{subnets}[${INDEX}]
 923
 924 Neutron Cleanup
 925     [Arguments]    ${vms}=@{EMPTY}    ${networks}=@{EMPTY}    ${subnets}=@{EMPTY}    ${ports}=@{EMPTY}    ${sgs}=@{EMPTY}
 926     : FOR    ${vm}    IN    @{vms}
 927     \    BuiltIn.Run Keyword And Ignore Error    Delete Vm Instance    ${vm}
 928     : FOR    ${port}    IN    @{ports}
 929     \    BuiltIn.Run Keyword And Ignore Error    Delete Port    ${port}
 930     : FOR    ${subnet}    IN    @{subnets}
 931     \    BuiltIn.Run Keyword And Ignore Error    Delete SubNet    ${subnet}
 932     : FOR    ${network}    IN    @{networks}
 933     \    BuiltIn.Run Keyword And Ignore Error    Delete Network    ${network}
 934     : FOR    ${sg}    IN    @{sgs}
 935     \    BuiltIn.Run Keyword And Ignore Error    Delete SecurityGroup    ${sg}
 936
 937 OpenStack List All
 938     [Documentation]    Get a list of different OpenStack resources that might be in use.
 939     @{modules} =    BuiltIn.Create List    server    port    network    subnet    security group
 940     ...    security group rule    floating ip    router
 941     : FOR    ${module}    IN    @{modules}
 942     \    ${output} =    OpenStack CLI    openstack ${module} list
 943
 944 OpenStack CLI Get List
 945     [Arguments]    ${cmd}
 946     [Documentation]    Return a json list from the output of an OpenStack command.
 947     @{list} =    BuiltIn.Create List
 948     ${json} =    OpenStack CLI    ${cmd}
 949     @{list} =    RequestsLibrary.To Json    ${json}
 950     BuiltIn.Log    ${list}
 951     [Return]    @{list}
 952
 953 OpenStack CLI
 954     [Arguments]    ${cmd}
 955     [Documentation]    Run the given OpenStack ${cmd} and log the output.
 956     ${result} =    Process.Run Process    ${cmd}    shell=True
 957     BuiltIn.Log    ${result.stdout}
 958     BuiltIn.Log    ${result.stderr}
 959     BuiltIn.Should Be True    '${result.rc}' == '0'
 960     [Return]    ${result.stdout}
 961
 962 OpenStack CLI With No Log
 963     [Arguments]    ${cmd}
 964     [Documentation]    Run the given OpenStack ${cmd} and do not log the output.
 965     ${result} =    Process.Run Process    ${cmd}    shell=True
 966     BuiltIn.Should Be True    '${result.rc}' == '0'
 967     [Return]    ${result.stdout}
 968
 969 OpenStack Cleanup All
 970     [Documentation]    Cleanup all Openstack resources with best effort. The keyword will query for all resources
 971     ...    in use and then attempt to delete them. Errors are ignored to allow the cleanup to continue.
 972     @{fips} =    OpenStack CLI Get List    openstack floating ip list -f json
 973     : FOR    ${fip}    IN    @{fips}
 974     \    BuiltIn.Run Keyword And Ignore Error    Delete Floating IP    ${fip['ID']}
 975     @{vms} =    OpenStack CLI Get List    openstack server list -f json
 976     : FOR    ${vm}    IN    @{vms}
 977     \    BuiltIn.Run Keyword And Ignore Error    Delete Vm Instance    ${vm['ID']}
 978     @{routers} =    OpenStack CLI Get List    openstack router list -f json
 979     : FOR    ${router}    IN    @{routers}
 980     \    BuiltIn.Run Keyword And Ignore Error    Cleanup Router    ${router['ID']}
 981     @{ports} =    OpenStack CLI Get List    openstack port list -f json
 982     : FOR    ${port}    IN    @{ports}
 983     \    BuiltIn.Run Keyword And Ignore Error    Delete Port    ${port['ID']}
 984     @{networks} =    OpenStack CLI Get List    openstack network list -f json
 985     : FOR    ${network}    IN    @{networks}
 986     \    BuiltIn.Run Keyword And Ignore Error    Delete Subnet    ${network['Subnets']}
 987     \    BuiltIn.Run Keyword And Ignore Error    Delete Network    ${network['ID']}
 988     @{security_groups} =    OpenStack CLI Get List    openstack security group list -f json
 989     : FOR    ${security_group}    IN    @{security_groups}
 990     \    BuiltIn.Run Keyword If    "${security_group['Name']}" != "default"    BuiltIn.Run Keyword And Ignore Error    Delete SecurityGroup    ${security_group['ID']}
 991     OpenStack List All
 992
 993 Cleanup Router
 994     [Arguments]    ${id}
 995     [Documentation]    Delete a router, but first remove any interfaces or gateways so that the delete will be successful.
 996     @{ports} =    OpenStack CLI Get List    openstack port list --router ${id} -f json --long
 997     : FOR    ${port}    IN    @{ports}
 998     \    ${subnet_id} =    OpenStackOperations.Get Match    ${port['Fixed IP Addresses']}    ${REGEX_UUID}    0
 999     \    BuiltIn.Run Keyword If    "${port['Device Owner']}" == "network:router_gateway"    BuiltIn.Run Keyword And Ignore Error    Remove Gateway    ${id}
1000     \    BuiltIn.Run Keyword If    "${port['Device Owner']}" == "network:router_interface"    BuiltIn.Run Keyword And Ignore Error    Remove Interface    ${id}    ${subnet_id}
1001     BuiltIn.Run Keyword And Ignore Error    Delete Router    ${id}
1002
1003 OpenStack Suite Setup
1004     [Documentation]    Wrapper teardown keyword that can be used in any suite running in an openstack environement
1005     SetupUtils.Setup_Utils_For_Setup_And_Teardown
1006     @{loggers} =    BuiltIn.Create List    org.apache.karaf.shell.support.ShellUtil    org.apache.sshd.server.session.ServerSessionImpl
1007     Setuputils.Setup_Logging_For_Debug_Purposes_On_List_Or_All    OFF    ${loggers}
1008     DevstackUtils.Devstack Suite Setup
1009     @{tcpdump_port_6653_conn_ids} =    OpenStackOperations.Start Packet Capture On Nodes    tcpdump_port_6653    port 6653    @{OS_ALL_IPS}
1010     BuiltIn.Set Suite Variable    @{tcpdump_port_6653_conn_ids}
1011     BuiltIn.Run Keyword If    "${PRE_CLEAN_OPENSTACK_ALL}"=="True"    OpenStack Cleanup All
1012     OpenStackOperations.Add OVS Logging On All OpenStack Nodes
1013     Run_Keyword_If_At_Least_Oxygen    Wait Until Keyword Succeeds    60    2    ClusterManagement.Check Status Of Services Is OPERATIONAL    @{NETVIRT_DIAG_SERVICES}
1014     Verify Expected Default Tables On Nodes
1015
1016 OpenStack Suite Teardown
1017     [Documentation]    Wrapper teardown keyword that can be used in any suite running in an openstack environement
1018     ...    to clean up all openstack resources. For example, all instances, networks, ports, etc will be listed and
1019     ...    and deleted. As other global cleanup tasks are needed, they can be added here and the suites will all
1020     ...    benefit automatically.
1021     # TODO: followup patch will add the list of vms to pass to Show Debugs
1022     # OpenStackOperations.Show Debugs    @{NET_1_VMS}    @{NET_2_VMS}
1023     OpenStackOperations.Get Suite Debugs
1024     OpenStack Cleanup All
1025     OpenStackOperations.Stop Packet Capture On Nodes    ${tcpdump_port_6653_conn_ids}
1026     SSHLibrary.Close All Connections
1027     : FOR    ${i}    IN RANGE    ${NUM_ODL_SYSTEM}
1028     \    KarafKeywords.Issue Command On Karaf Console    threads --list | wc -l    ${ODL_SYSTEM_${i+1}_IP}
1029
1030 Copy DHCP Files From Control Node
1031     [Documentation]    Copy the current DHCP files to the robot vm. The keyword must be called
1032     ...    after the subnet(s) are created and before the subnet(s) are deleted.
1033     ${suite_} =    BuiltIn.Evaluate    """${SUITE_NAME}""".replace(" ","_").replace("/","_").replace(".","_")
1034     ${dstdir} =    BuiltIn.Set Variable    /tmp/qdhcp/${suite_}
1035     OperatingSystem.Create Directory    ${dstdir}
1036     OpenStackOperations.Get ControlNode Connection
1037     BuiltIn.Run Keyword And Ignore Error    SSHLibrary.Get Directory    /opt/stack/data/neutron/dhcp    ${dstdir}    recursive=True
1038
1039 Is Feature Installed
1040     [Arguments]    ${features}=none
1041     : FOR    ${feature}    IN    @{features}
1042     \    ${status}    ${output}    BuiltIn.Run Keyword And Ignore Error    BuiltIn.Should Contain    ${CONTROLLERFEATURES}    ${feature}
1043     \    Return From Keyword If    "${status}" == "PASS"    True
1044     [Return]    False
1045
1046 Add OVS Logging On All OpenStack Nodes
1047     [Documentation]    Add higher levels of OVS logging to all the OpenStack nodes
1048     : FOR    ${conn_id}    IN    @{OS_ALL_CONN_IDS}
1049     \    OVSDB.Add OVS Logging    ${conn_id}
1050
1051 Reset OVS Logging On All OpenStack Nodes
1052     [Documentation]    Reset the OVS logging to all the OpenStack nodes
1053     : FOR    ${conn_id}    IN    @{OS_ALL_CONN_IDS}
1054     \    OVSDB.Reset OVS Logging    ${conn_id}
1055
1056 Start Packet Capture On Nodes
1057     [Arguments]    ${tag}    ${filter}    @{ips}
1058     [Documentation]    Wrapper keyword around the TcpDump packet capture that is catered to the Openstack setup.
1059     ...    The caller must pass the three arguments with a variable number of ips at the end,
1060     ...    but ${EMPTY} can be used for the tag and filter.
1061     ${suite_} =    BuiltIn.Evaluate    """${SUITE_NAME}""".replace(" ","_").replace("/","_").replace(".","_")
1062     ${tag_} =    BuiltIn.Catenate    SEPARATOR=__    ${tag}    ${suite_}
1063     @{conn_ids} =    Tcpdump.Start Packet Capture on Nodes    tag=${tag_}    filter=${filter}    ips=${ips}
1064     [Return]    @{conn_ids}
1065
1066 Stop Packet Capture On Nodes
1067     [Arguments]    ${conn_ids}=@{EMPTY}
1068     Tcpdump.Stop Packet Capture on Nodes    ${conn_ids}
1069
1070 Server Live Migrate
1071     [Arguments]    ${vm_instance_name}
1072     [Documentation]    Keyword for live migration of VM instance
1073     ...    additional_agrs is to select particular migration(live/shared-migration/block-migration)
1074     ...    if the additional_agrs is not given default migration(shared-migration) will happen
1075     ${output} =    OpenStackOperations.OpenStack CLI    nova live-migration ${vm_instance_name}
1076
1077 Get Hypervisor Host Of Vm
1078     [Arguments]    ${vm_name}
1079     [Documentation]    Show server with neutron request.
1080     ${output} =    OpenStackOperations.OpenStack CLI    openstack server show -f value -c OS-EXT-SRV-ATTR:host ${vm_name}
1081     [Return]    ${output}
1082
1083 Check If Migration Is Complete
1084     [Arguments]    ${vm_name}
1085     [Documentation]    Show server and verify if task_state is not migrating
1086     ${output} =    OpenStackOperations.OpenStack CLI    openstack server show ${vm_name} | grep "OS-EXT-STS:task_state"
1087     BuiltIn.Should Not Contain    ${output}    migrating
1088
1089 Modify OpenStack Configuration File
1090     [Arguments]    ${conn_id}    ${file_name}    ${section}    ${key}    ${value}
1091     [Documentation]    Use crudini to modify any parameter in any Openstack configuration File
1092     SSHLibrary.Switch Connection    ${conn_id}
1093     ${output}    ${rc} =    SSHLibrary.Execute Command    sudo crudini --verbose --set --inplace ${file_name} ${section} ${key} ${value}    return_rc=True    return_stdout=True
1094     BuiltIn.Log    ${output}
1095     BuiltIn.Should Be True    '${rc}' == '0'
1096
1097 Restart DevStack Service
1098     [Arguments]    ${conn_id}    ${service_name}
1099     [Documentation]    Restart the Openstack Service
1100     SSHLibrary.Switch Connection    ${conn_id}
1101     ${output}    ${rc} =    SSHLibrary.Execute Command    sudo systemctl restart devstack@${service_name}.service    return_rc=True    return_stdout=True
1102     BuiltIn.Log    ${output}
1103     BuiltIn.Should Be True    '${rc}' == '0'
1104
1105 Get Network Segmentation Id
1106     [Arguments]    ${network_name}
1107     [Documentation]    Returns network segmentation id for the given network name.
1108     ${output} =    OpenStack CLI    openstack network show ${network_name} | grep segmentation_id | awk '{print $4}'
1109     @{list} =    String.Split String    ${output}
1110     [Return]    @{list}[0]
1111
1112 Verify Expected Default Tables On Nodes
1113     [Arguments]    ${node_ips}=@{OS_ALL_IPS}
1114     [Documentation]    Verify if Default Table Entries are programmed on all Nodes
1115     ${resp} =    RequestsLibrary.Get Request    session    ${CONFIG_NODES_API}
1116     Utils.Log Content    ${resp.content}
1117     ${failed_node_list} =    BuiltIn.Create List
1118     : FOR    ${node_ip}    IN    @{node_ips}
1119     \    ${failed_table_list} =    Verify Expected Default Tables    ${node_ip}
1120     \    ${failed_table_list_size} =    BuiltIn.Get Length    ${failed_table_list}
1121     \    BuiltIn.Run Keyword If    ${failed_table_list_size} > 0    Collections.Append To List    ${failed_node_list}    ${node_ip}
1122     Builtin.Should Be Empty    ${failed_node_list}
1123
1124 Verify Expected Default Tables
1125     [Arguments]    ${ovs_ip}
1126     [Documentation]    Verify if Default Table Entries are programmed on specific Node
1127     ${flow_dump} =    Utils.Run Command On Remote System    ${ovs_ip}    sudo ovs-ofctl dump-flows ${INTEGRATION_BRIDGE} -OOpenFlow13
1128     BuiltIn.Log    ${flow_dump}
1129     ${failed_table_list} =    BuiltIn.Create List
1130     : FOR    ${table}    IN    @{DEFAULT_FLOW_TABLES}
1131     \    ${rc} =    Builtin.Run Keyword And Return Status    Builtin.Should Not Match Regexp    ${flow_dump}    .*table=${table}.*priority=0
1132     \    BuiltIn.Run Keyword If    ${rc}    Collections.Append To List    ${failed_table_list}    ${table}
1133     [Return]    ${failed_table_list}
1134
1135 Get Project Id
1136     [Arguments]    ${project_name}
1137     [Documentation]    Returns project ID for the given project name.
1138     ${project_id} =    OpenStack CLI    openstack project show ${project_name} -f value -c id
1139     [Return]    ${project_id}
1140
1141 Set Instance Quota For Project
1142     [Arguments]    ${num_instances}    ${project_id}
1143     [Documentation]    Set quota for the created instances using the specific project id.
1144     ${output} =    OpenStack CLI    openstack quota set --instances ${num_instances} ${project_id}
1145     [Return]    ${output}