csit/libraries/OpenStackOperations.robot

   1 *** Settings ***
   2 Documentation     Openstack library. This library is useful for tests to create network, subnet, router and vm instances
   3 Library           SSHLibrary
   4 Resource          Netvirt.robot
   5 Resource          Utils.robot
   6 Resource          ../variables/Variables.robot
   7
   8 *** Keywords ***
   9 Source Password
  10     [Arguments]    ${force}=no    ${source_pwd}=yes
  11     [Documentation]    Sourcing the Openstack PAsswords for neutron configurations
  12     Run Keyword If    '${source_pwd}' == 'yes' or '${force}' == 'yes'    Write Commands Until Prompt    cd ${DEVSTACK_DEPLOY_PATH}; source openrc admin admin
  13
  14 Get Tenant ID From Security Group
  15     [Documentation]    Returns tenant ID by reading it from existing default security-group.
  16     ${devstack_conn_id}=    Get ControlNode Connection
  17     Switch Connection    ${devstack_conn_id}
  18     ${output}=    Write Commands Until Prompt    neutron security-group-show default | grep "| tenant_id" | awk '{print $4}'
  19     Log    ${output}
  20     [Return]    ${output}
  21
  22 Get Tenant ID From Network
  23     [Arguments]    ${network_uuid}
  24     [Documentation]    Returns tenant ID by reading it from existing network.
  25     ${resp}=    Get_From_Uri    uri=${CONFIG_API}/neutron:neutron/networks/network/${network_uuid}/    accept=${ACCEPT_EMPTY}    session=session
  26     ${tenant_id}=    Utils.Extract Value From Content    ${resp}    /network/0/tenant-id    strip
  27     [Return]    ${tenant_id}
  28
  29 Create Network
  30     [Arguments]    ${network_name}    ${additional_args}=${EMPTY}    ${verbose}=TRUE
  31     [Documentation]    Create Network with neutron request.
  32     ${devstack_conn_id}=    Get ControlNode Connection
  33     Switch Connection    ${devstack_conn_id}
  34     ${command}    Set Variable If    "${verbose}" == "TRUE"    neutron -v net-create ${network_name} ${additional_args}    neutron net-create ${network_name} ${additional_args} | grep -w id | awk '{print $4}'
  35     ${output}=    Write Commands Until Prompt    ${command}    30s
  36     Log    ${output}
  37     [Return]    ${output}
  38
  39 List Networks
  40     [Documentation]    List networks and return output with neutron client.
  41     ${devstack_conn_id}=    Get ControlNode Connection
  42     Switch Connection    ${devstack_conn_id}
  43     ${output}=    Write Commands Until Prompt    neutron net-list    30s
  44     Close Connection
  45     Log    ${output}
  46     [Return]    ${output}
  47
  48 List Subnets
  49     [Documentation]    List subnets and return output with neutron client.
  50     ${devstack_conn_id}=    Get ControlNode Connection
  51     Switch Connection    ${devstack_conn_id}
  52     ${output}=    Write Commands Until Prompt    neutron subnet-list    30s
  53     Close Connection
  54     Log    ${output}
  55     [Return]    ${output}
  56
  57 Delete Network
  58     [Arguments]    ${network_name}
  59     [Documentation]    Delete Network with neutron request.
  60     ${devstack_conn_id}=    Get ControlNode Connection
  61     Switch Connection    ${devstack_conn_id}
  62     ${output}=    Write Commands Until Prompt    neutron -v net-delete ${network_name}    30s
  63     Close Connection
  64     Log    ${output}
  65     Should Match Regexp    ${output}    Deleted network: ${network_name}|Deleted network\\(s\\): ${network_name}
  66
  67 Create SubNet
  68     [Arguments]    ${network_name}    ${subnet}    ${range_ip}    ${additional_args}=${EMPTY}
  69     [Documentation]    Create SubNet for the Network with neutron request.
  70     ${devstack_conn_id}=    Get ControlNode Connection
  71     Switch Connection    ${devstack_conn_id}
  72     ${output}=    Write Commands Until Prompt    neutron -v subnet-create ${network_name} ${range_ip} --name ${subnet} ${additional_args}    30s
  73     Close Connection
  74     Log    ${output}
  75     Should Contain    ${output}    Created a new subnet
  76
  77 Create Port
  78     [Arguments]    ${network_name}    ${port_name}    ${sg}=default    ${additional_args}=${EMPTY}
  79     [Documentation]    Create Port with neutron request.
  80     ${devstack_conn_id}=    Get ControlNode Connection
  81     Switch Connection    ${devstack_conn_id}
  82     ${output}=    Write Commands Until Prompt    neutron -v port-create ${network_name} --name ${port_name} --security-group ${sg} ${additional_args}    30s
  83     Close Connection
  84     Log    ${output}
  85     Should Contain    ${output}    Created a new port
  86
  87 Delete Port
  88     [Arguments]    ${port_name}
  89     [Documentation]    Delete Port with neutron request.
  90     ${devstack_conn_id}=    Get ControlNode Connection
  91     Switch Connection    ${devstack_conn_id}
  92     ${output}=    Write Commands Until Prompt    neutron -v port-delete ${port_name}    30s
  93     Close Connection
  94     Log    ${output}
  95     Should Match Regexp    ${output}    Deleted port: ${port_name}|Deleted port\\(s\\): ${port_name}
  96
  97 List Ports
  98     [Documentation]    List ports and return output with neutron client.
  99     ${devstack_conn_id}=    Get ControlNode Connection
 100     Switch Connection    ${devstack_conn_id}
 101     ${output}=    Write Commands Until Prompt    neutron port-list    30s
 102     Close Connection
 103     Log    ${output}
 104     [Return]    ${output}
 105
 106 List Nova VMs
 107     [Documentation]    List VMs and return output with nova client.
 108     ${devstack_conn_id}=    Get ControlNode Connection
 109     Switch Connection    ${devstack_conn_id}
 110     ${output}=    Write Commands Until Prompt    nova list    30s
 111     Close Connection
 112     Log    ${output}
 113     [Return]    ${output}
 114
 115 Create And Associate Floating IPs
 116     [Arguments]    ${external_net}    @{vm_list}
 117     [Documentation]    Create and associate floating IPs to VMs with nova request
 118     ${devstack_conn_id}=    Get ControlNode Connection
 119     Switch Connection    ${devstack_conn_id}
 120     ${ip_list}=    Create List    @{EMPTY}
 121     : FOR    ${vm}    IN    @{vm_list}
 122     \    ${output}=    Write Commands Until Prompt    neutron floatingip-create ${external_net}    30s
 123     \    Log    ${output}
 124     \    @{ip}    Get Regexp Matches    ${output}    [0-9]{1,3}\\.[0-9]{1,3}\\.[0-9]{1,3}\\.[0-9]{1,3}
 125     \    ${ip_length}    Get Length    ${ip}
 126     \    Run Keyword If    ${ip_length}>0    Append To List    ${ip_list}    @{ip}[0]
 127     \    ...    ELSE    Append To List    ${ip_list}    None
 128     \    ${output}=    Write Commands Until Prompt    nova floating-ip-associate ${vm} @{ip}[0]    30s
 129     \    Log    ${output}
 130     [Return]    ${ip_list}
 131
 132 Verify Gateway Ips
 133     [Documentation]    Verifies the Gateway Ips with dump flow.
 134     ${output}=    Write Commands Until Prompt    sudo ovs-ofctl -O OpenFlow13 dump-flows br-int
 135     Log    ${output}
 136     : FOR    ${GatewayIpElement}    IN    @{GATEWAY_IPS}
 137     \    Should Contain    ${output}    ${GatewayIpElement}
 138
 139 Verify Dhcp Ips
 140     [Documentation]    Verifies the Dhcp Ips with dump flow.
 141     ${output}=    Write Commands Until Prompt    sudo ovs-ofctl -O OpenFlow13 dump-flows br-int
 142     Log    ${output}
 143     : FOR    ${DhcpIpElement}    IN    @{DHCP_IPS}
 144     \    Should Contain    ${output}    ${DhcpIpElement}
 145
 146 Verify No Dhcp Ips
 147     [Documentation]    Verifies the Dhcp Ips with dump flow.
 148     ${output}=    Write Commands Until Prompt    sudo ovs-ofctl -O OpenFlow13 dump-flows br-int
 149     Log    ${output}
 150     : FOR    ${DhcpIpElement}    IN    @{DHCP_IPS}
 151     \    Should Not Contain    ${output}    ${DhcpIpElement}
 152
 153 Delete SubNet
 154     [Arguments]    ${subnet}
 155     [Documentation]    Delete SubNet for the Network with neutron request.
 156     Log    ${subnet}
 157     ${devstack_conn_id}=    Get ControlNode Connection
 158     Switch Connection    ${devstack_conn_id}
 159     ${output}=    Write Commands Until Prompt    neutron -v subnet-delete ${subnet}
 160     Close Connection
 161     Log    ${output}
 162     Should Match Regexp    ${output}    Deleted subnet: ${subnet}|Deleted subnet\\(s\\): ${subnet}
 163
 164 Verify No Gateway Ips
 165     [Documentation]    Verifies the Gateway Ips removed with dump flow.
 166     ${output}=    Write Commands Until Prompt    sudo ovs-ofctl -O OpenFlow13 dump-flows br-int
 167     Log    ${output}
 168     : FOR    ${GatewayIpElement}    IN    @{GATEWAY_IPS}
 169     \    Should Not Contain    ${output}    ${GatewayIpElement}
 170
 171 Delete Vm Instance
 172     [Arguments]    ${vm_name}
 173     [Documentation]    Delete Vm instances using instance names.
 174     ${devstack_conn_id}=    Get ControlNode Connection
 175     Switch Connection    ${devstack_conn_id}
 176     ${output}=    Write Commands Until Prompt    nova force-delete ${vm_name}    40s
 177     Close Connection
 178
 179 Get Net Id
 180     [Arguments]    ${network_name}    ${devstack_conn_id}
 181     [Documentation]    Retrieve the net id for the given network name to create specific vm instance
 182     Switch Connection    ${devstack_conn_id}
 183     ${output}=    Write Commands Until Prompt    neutron net-list | grep "${network_name}" | awk '{print $2}'    30s
 184     Log    ${output}
 185     ${splitted_output}=    Split String    ${output}    ${EMPTY}
 186     ${net_id}=    Get from List    ${splitted_output}    0
 187     Log    ${net_id}
 188     [Return]    ${net_id}
 189
 190 Get Subnet Id
 191     [Arguments]    ${subnet_name}    ${devstack_conn_id}
 192     [Documentation]    Retrieve the subnet id for the given subnet name
 193     Switch Connection    ${devstack_conn_id}
 194     ${output}=    Write Commands Until Prompt    neutron subnet-list | grep "${subnet_name}" | awk '{print $2}'    30s
 195     Log    ${output}
 196     ${splitted_output}=    Split String    ${output}    ${EMPTY}
 197     ${subnet_id}=    Get from List    ${splitted_output}    0
 198     Log    ${subnet_id}
 199     [Return]    ${subnet_id}
 200
 201 Get Port Id
 202     [Arguments]    ${port_name}    ${devstack_conn_id}
 203     [Documentation]    Retrieve the port id for the given port name to attach specific vm instance to a particular port
 204     Switch Connection    ${devstack_conn_id}
 205     ${output}=    Write Commands Until Prompt    neutron port-list | grep "${port_name}" | awk '{print $2}'    30s
 206     Log    ${output}
 207     ${splitted_output}=    Split String    ${output}    ${EMPTY}
 208     ${port_id}=    Get from List    ${splitted_output}    0
 209     Log    ${port_id}
 210     [Return]    ${port_id}
 211
 212 Get Router Id
 213     [Arguments]    ${router1}    ${devstack_conn_id}
 214     [Documentation]    Retrieve the router id for the given router name
 215     Switch Connection    ${devstack_conn_id}
 216     ${output}=    Write Commands Until Prompt    neutron router-list | grep "${router1}" | awk '{print $2}'    30s
 217     Log    ${output}
 218     ${splitted_output}=    Split String    ${output}    ${EMPTY}
 219     ${router_id}=    Get from List    ${splitted_output}    0
 220     Log    ${router_id}
 221     [Return]    ${router_id}
 222
 223 Create Vm Instances
 224     [Arguments]    ${net_name}    ${vm_instance_names}    ${image}=cirros-0.3.4-x86_64-uec    ${flavor}=m1.nano    ${sg}=default
 225     [Documentation]    Create X Vm Instance with the net id of the Netowrk.
 226     ${devstack_conn_id}=    Get ControlNode Connection
 227     Switch Connection    ${devstack_conn_id}
 228     ${net_id}=    Get Net Id    ${net_name}    ${devstack_conn_id}
 229     : FOR    ${VmElement}    IN    @{vm_instance_names}
 230     \    ${output}=    Write Commands Until Prompt    nova boot --image ${image} --flavor ${flavor} --nic net-id=${net_id} ${VmElement} --security-groups ${sg}    30s
 231     \    Log    ${output}
 232
 233 Create Vm Instance With Port On Compute Node
 234     [Arguments]    ${port_name}    ${vm_instance_name}    ${compute_node}    ${image}=cirros-0.3.4-x86_64-uec    ${flavor}=m1.nano    ${sg}=default
 235     [Documentation]    Create One VM instance using given ${port_name} and for given ${compute_node}
 236     ${devstack_conn_id}=    Get ControlNode Connection
 237     Switch Connection    ${devstack_conn_id}
 238     ${port_id}=    Get Port Id    ${port_name}    ${devstack_conn_id}
 239     ${hostname_compute_node}=    Run Command On Remote System    ${compute_node}    hostname
 240     ${output}=    Write Commands Until Prompt    nova boot --image ${image} --flavor ${flavor} --nic port-id=${port_id} ${vm_instance_name} --security-groups ${sg} --availability-zone nova:${hostname_compute_node}    30s
 241     Log    ${output}
 242
 243 Verify VM Is ACTIVE
 244     [Arguments]    ${vm_name}
 245     [Documentation]    Run these commands to check whether the created vm instance is active or not.
 246     ${devstack_conn_id}=    Get ControlNode Connection
 247     Switch Connection    ${devstack_conn_id}
 248     ${output}=    Write Commands Until Prompt    nova show ${vm_name} | grep OS-EXT-STS:vm_state    30s
 249     Log    ${output}
 250     Should Contain    ${output}    active
 251
 252 Verify VMs Received DHCP Lease
 253     [Arguments]    @{vm_list}
 254     [Documentation]    Using nova console-log on the provided ${vm_list} to search for the string "obtained" which
 255     ...    correlates to the instance receiving it's IP address via DHCP. Also retrieved is the ip of the nameserver
 256     ...    if available in the console-log output. The keyword will also return a list of the learned ips as it
 257     ...    finds them in the console log output, and will have "None" for Vms that no ip was found.
 258     ${devstack_conn_id}=    Get ControlNode Connection
 259     Switch Connection    ${devstack_conn_id}
 260     ${ip_list}    Create List    @{EMPTY}
 261     ${dhcp_ip}    Create List    @{EMPTY}
 262     : FOR    ${vm}    IN    @{vm_list}
 263     \    ${vm_ip_line}=    Write Commands Until Prompt    nova console-log ${vm} | grep -i "obtained"    30s
 264     \    Log    ${vm_ip_line}
 265     \    @{vm_ip}    Get Regexp Matches    ${vm_ip_line}    [0-9]{1,3}\\.[0-9]{1,3}\\.[0-9]{1,3}\\.[0-9]{1,3}
 266     \    ${vm_ip_length}    Get Length    ${vm_ip}
 267     \    Run Keyword If    ${vm_ip_length}>0    Append To List    ${ip_list}    @{vm_ip}[0]
 268     \    ...    ELSE    Append To List    ${ip_list}    None
 269     \    ${dhcp_ip_line}=    Write Commands Until Prompt    nova console-log ${vm} | grep "^nameserver"    30s
 270     \    Log    ${dhcp_ip_line}
 271     \    @{dhcp_ip}    Get Regexp Matches    ${dhcp_ip_line}    [0-9]{1,3}\\.[0-9]{1,3}\\.[0-9]{1,3}\\.[0-9]{1,3}
 272     \    Log    ${dhcp_ip}
 273     ${dhcp_length}    Get Length    ${dhcp_ip}
 274     Return From Keyword If    ${dhcp_length}==0    ${ip_list}    ${EMPTY}
 275     [Return]    ${ip_list}    @{dhcp_ip}[0]
 276
 277 View Vm Console
 278     [Arguments]    ${vm_instance_names}
 279     [Documentation]    View Console log of the created vm instances using nova show.
 280     : FOR    ${VmElement}    IN    @{vm_instance_names}
 281     \    ${output}=    Write Commands Until Prompt    nova show ${VmElement}
 282     \    Log    ${output}
 283     \    ${output}=    Write Commands Until Prompt    nova console-log ${VmElement}
 284     \    Log    ${output}
 285
 286 Ping Vm From DHCP Namespace
 287     [Arguments]    ${net_name}    ${vm_ip}
 288     [Documentation]    Reach all Vm Instance with the net id of the Netowrk.
 289     Log    ${vm_ip}
 290     ${devstack_conn_id}=    Get ControlNode Connection
 291     Switch Connection    ${devstack_conn_id}
 292     ${net_id}=    Get Net Id    ${net_name}    ${devstack_conn_id}
 293     Log    ${net_id}
 294     ${output}=    Write Commands Until Prompt    sudo ip netns exec qdhcp-${net_id} ping -c 3 ${vm_ip}    20s
 295     Log    ${output}
 296     Close Connection
 297     Should Contain    ${output}    64 bytes
 298
 299 Ping From DHCP Should Not Succeed
 300     [Arguments]    ${net_name}    ${vm_ip}
 301     [Documentation]    Should Not Reach Vm Instance with the net id of the Netowrk.
 302     Log    ${vm_ip}
 303     ${devstack_conn_id}=    Get ControlNode Connection
 304     Switch Connection    ${devstack_conn_id}
 305     ${net_id}=    Get Net Id    ${net_name}    ${devstack_conn_id}
 306     Log    ${net_id}
 307     ${output}=    Write Commands Until Prompt    sudo ip netns exec qdhcp-${net_id} ping -c 3 ${vm_ip}    20s
 308     Close Connection
 309     Log    ${output}
 310     Should Not Contain    ${output}    64 bytes
 311
 312 Ping Vm From Control Node
 313     [Arguments]    ${vm_floating_ip}
 314     [Documentation]    Ping VM floating IP from control node
 315     Log    ${vm_floating_ip}
 316     ${devstack_conn_id}=    Get ControlNode Connection
 317     Switch Connection    ${devstack_conn_id}
 318     ${output}=    Write Commands Until Prompt    ping -c 3 ${vm_floating_ip}    20s
 319     Log    ${output}
 320     Close Connection
 321     Should Contain    ${output}    64 bytes
 322
 323 Ping From Instance
 324     [Arguments]    ${dest_vm_ip}
 325     [Documentation]    Ping to the expected destination ip.
 326     ${output}=    Write Commands Until Expected Prompt    ping -c 3 ${dest_vm_ip}    ${OS_SYSTEM_PROMPT}
 327     Log    ${output}
 328     [Return]    ${output}
 329
 330 Curl Metadata Server
 331     [Documentation]    Ping to the expected destination ip.
 332     ${output}=    Write Commands Until Expected Prompt    curl -i http://169.254.169.254    ${OS_SYSTEM_PROMPT}
 333     Write Commands Until Prompt    exit
 334     Should Contain    ${output}    200
 335
 336 Close Vm Instance
 337     [Documentation]    Exit the vm instance.
 338     ${output}=    Write Commands Until Prompt    exit
 339     Log    ${output}
 340
 341 Check If Console Is VmInstance
 342     [Arguments]    ${console}=cirros
 343     [Documentation]    Check if the session has been able to login to the VM instance
 344     ${output}=    Write Commands Until Expected Prompt    id    ${OS_SYSTEM_PROMPT}
 345     Should Contain    ${output}    ${console}
 346
 347 Exit From Vm Console
 348     [Documentation]    Check if the session has been able to login to the VM instance and exit the instance
 349     ${rcode}=    Run Keyword And Return Status    Check If Console Is VmInstance    cirros
 350     Run Keyword If    ${rcode}    Write Commands Until Prompt    exit
 351
 352 Check Ping
 353     [Arguments]    ${ip_address}
 354     [Documentation]    Run Ping command on the IP available as argument
 355     ${output}=    Write Commands Until Expected Prompt    ping -c 3 ${ip_address}    ${OS_SYSTEM_PROMPT}
 356     Should Contain    ${output}    64 bytes
 357
 358 Check Metadata Access
 359     [Documentation]    Try curl on the Metadataurl and check if it is okay
 360     ${output}=    Write Commands Until Expected Prompt    curl -i http://169.254.169.254    ${OS_SYSTEM_PROMPT}
 361     Should Contain    ${output}    200
 362
 363 Execute Command on VM Instance
 364     [Arguments]    ${net_name}    ${vm_ip}    ${cmd}    ${user}=cirros    ${password}=cubswin:)
 365     [Documentation]    Login to the vm instance using ssh in the network, executes a command inside the VM and returns the ouput.
 366     ${devstack_conn_id} =    Get ControlNode Connection
 367     Switch Connection    ${devstack_conn_id}
 368     ${net_id} =    Get Net Id    ${net_name}    ${devstack_conn_id}
 369     Log    ${vm_ip}
 370     ${output} =    Write Commands Until Expected Prompt    sudo ip netns exec qdhcp-${net_id} ssh ${user}@${vm_ip} -o ConnectTimeout=10 -o StrictHostKeyChecking=no -o UserKnownHostsFile=/dev/null    d:
 371     Log    ${output}
 372     ${output} =    Write Commands Until Expected Prompt    ${password}    ${OS_SYSTEM_PROMPT}
 373     Log    ${output}
 374     ${rcode} =    Run Keyword And Return Status    Check If Console Is VmInstance
 375     ${output} =    Run Keyword If    ${rcode}    Write Commands Until Expected Prompt    ${cmd}    ${OS_SYSTEM_PROMPT}
 376     [Teardown]    Exit From Vm Console
 377     [Return]    ${output}
 378
 379 Test Operations From Vm Instance
 380     [Arguments]    ${net_name}    ${src_ip}    ${dest_ips}    ${user}=cirros    ${password}=cubswin:)
 381     [Documentation]    Login to the vm instance using ssh in the network.
 382     ${devstack_conn_id}=    Get ControlNode Connection
 383     Switch Connection    ${devstack_conn_id}
 384     Log    ${src_ip}
 385     ${net_id}=    Get Net Id    ${net_name}    ${devstack_conn_id}
 386     ${output}=    Write Commands Until Expected Prompt    sudo ip netns exec qdhcp-${net_id} ssh -o ConnectTimeout=10 -o StrictHostKeyChecking=no ${user}@${src_ip} -o UserKnownHostsFile=/dev/null    d:
 387     Log    ${output}
 388     ${output}=    Write Commands Until Expected Prompt    ${password}    ${OS_SYSTEM_PROMPT}
 389     Log    ${output}
 390     ${rcode}=    Run Keyword And Return Status    Check If Console Is VmInstance
 391     Run Keyword If    ${rcode}    Write Commands Until Expected Prompt    ifconfig    ${OS_SYSTEM_PROMPT}
 392     Run Keyword If    ${rcode}    Write Commands Until Expected Prompt    route    ${OS_SYSTEM_PROMPT}
 393     Run Keyword If    ${rcode}    Write Commands Until Expected Prompt    arp -an    ${OS_SYSTEM_PROMPT}
 394     : FOR    ${dest_ip}    IN    @{dest_ips}
 395     \    Log    ${dest_ip}
 396     \    ${string_empty}=    Run Keyword And Return Status    Should Be Empty    ${dest_ip}
 397     \    Run Keyword If    ${string_empty}    Continue For Loop
 398     \    Run Keyword If    ${rcode}    Check Ping    ${dest_ip}
 399     Run Keyword If    ${rcode}    Check Metadata Access
 400     [Teardown]    Exit From Vm Console
 401
 402 Install Netcat On Controller
 403     [Documentation]    Installs Netcat on the controller - this probably shouldn't be here
 404     ${devstack_conn_id}=    Get ControlNode Connection
 405     Switch Connection    ${devstack_conn_id}
 406     ${output}=    Write Commands Until Prompt    sudo yum install -y nc
 407     Log    ${output}
 408     Close Connection
 409
 410 Test Netcat Operations From Vm Instance
 411     [Arguments]    ${net_name}    ${vm_ip}    ${dest_ip}    ${additional_args}=${EMPTY}    ${port}=12345    ${user}=cirros
 412     ...    ${password}=cubswin:)
 413     [Documentation]    Use Netcat to test TCP/UDP connections to the controller
 414     ${client_data}    Set Variable    Test Client Data
 415     ${server_data}    Set Variable    Test Server Data
 416     ${devstack_conn_id}=    Get ControlNode Connection
 417     Switch Connection    ${devstack_conn_id}
 418     Log    ${vm_ip}
 419     ${output}=    Write Commands Until Prompt    ( ( echo "${server_data}" | sudo timeout 60 nc -l ${additional_args} ${port} ) & )
 420     Log    ${output}
 421     ${output}=    Write Commands Until Prompt    sudo netstat -nlap | grep ${port}
 422     Log    ${output}
 423     ${nc_output}=    Execute Command on VM Instance    ${net_name}    ${vm_ip}    sudo echo "${client_data}" | nc -v -w 5 ${additional_args} ${dest_ip} ${port}
 424     Log    ${nc_output}
 425     ${output}=    Execute Command on VM Instance    ${net_name}    ${vm_ip}    sudo route -n
 426     Log    ${output}
 427     ${output}=    Execute Command on VM Instance    ${net_name}    ${vm_ip}    sudo arp -an
 428     Log    ${output}
 429     Should Match Regexp    ${nc_output}    ${server_data}
 430
 431 Ping Other Instances
 432     [Arguments]    ${list_of_external_dst_ips}
 433     [Documentation]    Check reachability with other network's instances.
 434     ${rcode}=    Run Keyword And Return Status    Check If Console Is VmInstance
 435     : FOR    ${dest_ip}    IN    @{list_of_external_dst_ips}
 436     \    Log    ${dest_ip}
 437     \    Check Ping    ${dest_ip}
 438
 439 Create Router
 440     [Arguments]    ${router_name}
 441     [Documentation]    Create Router and Add Interface to the subnets.
 442     ${devstack_conn_id}=    Get ControlNode Connection
 443     Switch Connection    ${devstack_conn_id}
 444     ${output}=    Write Commands Until Prompt    neutron -v router-create ${router_name}    30s
 445     Close Connection
 446     Should Contain    ${output}    Created a new router
 447
 448 List Router
 449     [Documentation]    List Router and return output with neutron client.
 450     ${devstack_conn_id}=    Get ControlNode Connection
 451     Switch Connection    ${devstack_conn_id}
 452     ${output}=    Write Commands Until Prompt    neutron router-list    30s
 453     Close Connection
 454     Log    ${output}
 455     [Return]    ${output}
 456
 457 Add Router Interface
 458     [Arguments]    ${router_name}    ${interface_name}
 459     ${devstack_conn_id}=    Get ControlNode Connection
 460     Switch Connection    ${devstack_conn_id}
 461     ${output}=    Write Commands Until Prompt    neutron -v router-interface-add ${router_name} ${interface_name}
 462     Close Connection
 463     Should Contain    ${output}    Added interface
 464
 465 Show Router Interface
 466     [Arguments]    ${router_name}
 467     [Documentation]    List Router interface associated with given Router and return output with neutron client.
 468     ${devstack_conn_id}=    Get ControlNode Connection
 469     Switch Connection    ${devstack_conn_id}
 470     ${output}=    Write Commands Until Prompt    neutron router-port-list ${router_name} -f csv    30s
 471     Close Connection
 472     Log    ${output}
 473     [Return]    ${output}
 474
 475 Add Router Gateway
 476     [Arguments]    ${router_name}    ${network_name}
 477     ${devstack_conn_id}=    Get ControlNode Connection
 478     Switch Connection    ${devstack_conn_id}
 479     ${output}=    Write Commands Until Prompt    neutron -v router-gateway-set ${router_name} ${network_name}
 480     Close Connection
 481     Should Contain    ${output}    Set gateway
 482
 483 Remove Interface
 484     [Arguments]    ${router_name}    ${interface_name}
 485     [Documentation]    Remove Interface to the subnets.
 486     ${devstack_conn_id}=    Get ControlNode Connection
 487     Switch Connection    ${devstack_conn_id}
 488     ${output}=    Write Commands Until Prompt    neutron -v router-interface-delete ${router_name} ${interface_name}
 489     Close Connection
 490     Should Contain    ${output}    Removed interface from router
 491
 492 Update Router
 493     [Arguments]    ${router_name}    ${cmd}
 494     [Documentation]    Update the router with the command. Router name and command should be passed as argument.
 495     ${devstack_conn_id} =    Get ControlNode Connection
 496     Switch Connection    ${devstack_conn_id}
 497     ${output} =    Write Commands Until Prompt    neutron router-update ${router_name} ${cmd}    30s
 498     Close Connection
 499     Should Contain    ${output}    Updated
 500
 501 Show Router
 502     [Arguments]    ${router_name}    ${options}
 503     [Documentation]    Show information of a given router. Router name and optional fields should be sent as arguments.
 504     ${devstack_conn_id} =    Get ControlNode Connection
 505     Switch Connection    ${devstack_conn_id}
 506     ${output} =    Write Commands Until Prompt    neutron router-show ${router_name} ${options}    30s
 507     Log    ${output}
 508     Close Connection
 509
 510 Delete Router
 511     [Arguments]    ${router_name}
 512     [Documentation]    Delete Router and Interface to the subnets.
 513     ${devstack_conn_id}=    Get ControlNode Connection
 514     Switch Connection    ${devstack_conn_id}
 515     ${output}=    Write Commands Until Prompt    neutron -v router-delete ${router_name}    60s
 516     Close Connection
 517     Should Match Regexp    ${output}    Deleted router: ${router_name}|Deleted router\\(s\\): ${router_name}
 518
 519 Get DumpFlows And Ovsconfig
 520     [Arguments]    ${openstack_node_ip}
 521     [Documentation]    Get the OvsConfig and Flow entries from OVS from the Openstack Node
 522     Log    ${openstack_node_ip}
 523     SSHLibrary.Open Connection    ${openstack_node_ip}    prompt=${DEFAULT_LINUX_PROMPT}
 524     Utils.Flexible SSH Login    ${OS_USER}    ${DEVSTACK_SYSTEM_PASSWORD}
 525     SSHLibrary.Set Client Configuration    timeout=${default_devstack_prompt_timeout}
 526     Write Commands Until Expected Prompt    ip -o link    ]>
 527     Write Commands Until Expected Prompt    ip -o addr    ]>
 528     Write Commands Until Expected Prompt    ip route    ]>
 529     Write Commands Until Expected Prompt    arp -an    ]>
 530     ${nslist}=    Write Commands Until Expected Prompt    ip netns list | awk '{print $1}'    ]>
 531     @{lines}    Split To Lines    ${nslist}
 532     : FOR    ${line}    IN    @{lines}
 533     \    Write Commands Until Expected Prompt    sudo ip netns exec ${line} ip -o link    ]>
 534     \    Write Commands Until Expected Prompt    sudo ip netns exec ${line} ip -o addr    ]>
 535     \    Write Commands Until Expected Prompt    sudo ip netns exec ${line} ip route    ]>
 536     Write Commands Until Expected Prompt    sudo ovs-vsctl show    ]>
 537     Write Commands Until Expected Prompt    sudo ovs-vsctl list Open_vSwitch    ]>
 538     Write Commands Until Expected Prompt    sudo ovs-ofctl show br-int -OOpenFlow13    ]>
 539     Write Commands Until Expected Prompt    sudo ovs-ofctl dump-ports-desc br-int -OOpenFlow13    ]>
 540     Write Commands Until Expected Prompt    sudo ovs-ofctl dump-flows br-int -OOpenFlow13    ]>
 541     Write Commands Until Expected Prompt    sudo ovs-ofctl dump-groups br-int -OOpenFlow13    ]>
 542     Write Commands Until Expected Prompt    sudo ovs-ofctl dump-group-stats br-int -OOpenFlow13    ]>
 543
 544 Get Karaf Log Type From Test Start
 545     [Arguments]    ${ip}    ${test_name}    ${type}    ${user}=${ODL_SYSTEM_USER}    ${password}=${ODL_SYSTEM_PASSWORD}    ${prompt}=${ODL_SYSTEM_PROMPT}
 546     ...    ${log_file}=${WORKSPACE}/${BUNDLEFOLDER}/data/log/karaf.log
 547     ${cmd}    Set Variable    sed '1,/ROBOT MESSAGE: Starting test ${test_name}/d' ${log_file} | grep '${type}'
 548     ${output}    Run Command On Controller    ${ip}    ${cmd}    ${user}    ${password}    ${prompt}
 549     Log    ${output}
 550
 551 Get Karaf Log Types From Test Start
 552     [Arguments]    ${ip}    ${test_name}    ${types}    ${user}=${ODL_SYSTEM_USER}    ${password}=${ODL_SYSTEM_PASSWORD}    ${prompt}=${ODL_SYSTEM_PROMPT}
 553     ...    ${log_file}=${WORKSPACE}/${BUNDLEFOLDER}/data/log/karaf.log
 554     : FOR    ${type}    IN    @{types}
 555     \    Get Karaf Log Type From Test Start    ${ip}    ${test_name}    ${type}    ${user}    ${password}
 556     \    ...    ${prompt}    ${log_file}
 557
 558 Get Karaf Log Events From Test Start
 559     [Arguments]    ${test_name}    ${user}=${ODL_SYSTEM_USER}    ${password}=${ODL_SYSTEM_PASSWORD}    ${prompt}=${ODL_SYSTEM_PROMPT}
 560     ${log_types} =    Create List    ERROR    WARN    Exception
 561     Run Keyword If    0 < ${NUM_ODL_SYSTEM}    Get Karaf Log Types From Test Start    ${ODL_SYSTEM_IP}    ${test_name}    ${log_types}
 562     Run Keyword If    1 < ${NUM_ODL_SYSTEM}    Get Karaf Log Types From Test Start    ${ODL_SYSTEM_2_IP}    ${test_name}    ${log_types}
 563     Run Keyword If    2 < ${NUM_ODL_SYSTEM}    Get Karaf Log Types From Test Start    ${ODL_SYSTEM_3_IP}    ${test_name}    ${log_types}
 564
 565 Get ControlNode Connection
 566     ${control_conn_id}=    SSHLibrary.Open Connection    ${OS_CONTROL_NODE_IP}    prompt=${DEFAULT_LINUX_PROMPT_STRICT}
 567     Utils.Flexible SSH Login    ${OS_USER}    ${DEVSTACK_SYSTEM_PASSWORD}
 568     SSHLibrary.Set Client Configuration    timeout=30s
 569     Source Password    force=yes
 570     [Return]    ${control_conn_id}
 571
 572 Get OvsDebugInfo
 573     [Documentation]    Get the OvsConfig and Flow entries from all Openstack nodes
 574     Run Keyword If    0 < ${NUM_OS_SYSTEM}    Get DumpFlows And Ovsconfig    ${OS_CONTROL_NODE_IP}
 575     Run Keyword If    1 < ${NUM_OS_SYSTEM}    Get DumpFlows And Ovsconfig    ${OS_COMPUTE_1_IP}
 576     Run Keyword If    2 < ${NUM_OS_SYSTEM}    Get DumpFlows And Ovsconfig    ${OS_COMPUTE_2_IP}
 577
 578 Get Test Teardown Debugs
 579     [Arguments]    ${test_name}=${TEST_NAME}
 580     Get OvsDebugInfo
 581     Get Model Dump    ${HA_PROXY_IP}
 582     Get Karaf Log Events From Test Start    ${test_name}
 583
 584 Get Suite Teardown Debugs
 585     Get OvsDebugInfo
 586     Get Model Dump    ${HA_PROXY_IP}
 587
 588 Show Debugs
 589     [Arguments]    @{vm_indices}
 590     [Documentation]    Run these commands for debugging, it can list state of VM instances and ip information in control node
 591     ${devstack_conn_id}=    Get ControlNode Connection
 592     Switch Connection    ${devstack_conn_id}
 593     ${output}=    Write Commands Until Prompt    sudo ip netns list
 594     Log    ${output}
 595     : FOR    ${index}    IN    @{vm_indices}
 596     \    ${output}=    Write Commands Until Prompt    nova show ${index}    30s
 597     \    Log    ${output}
 598     Close Connection
 599     List Nova VMs
 600     List Networks
 601     List Subnets
 602     List Ports
 603
 604 Create Security Group
 605     [Arguments]    ${sg_name}    ${desc}
 606     ${devstack_conn_id}=    Get ControlNode Connection
 607     Switch Connection    ${devstack_conn_id}
 608     ${output}=    Write Commands Until Prompt    nova secgroup-create ${sg_name} ${desc}    40s
 609     Close Connection
 610
 611 Create Security Rule
 612     [Arguments]    ${direction}    ${protocol}    ${min_port}    ${max_port}    ${remote_ip}    ${sg_name}
 613     ${devstack_conn_id}=    Get ControlNode Connection
 614     Switch Connection    ${devstack_conn_id}
 615     ${output}=    Write Commands Until Prompt    neutron security-group-rule-create --direction ${direction} --protocol ${protocol} --port-range-min ${min_port} --port-range-max ${max_port} --remote-ip-prefix ${remote_ip} ${sg_name}
 616     Close Connection
 617
 618 Neutron Security Group Show
 619     [Arguments]    ${SecurityGroupRuleName}    ${additional_args}=${EMPTY}
 620     [Documentation]    Displays the neutron security group configurations that belongs to a given neutron security group name
 621     ${devstack_conn_id}=    Get ControlNode Connection
 622     Switch Connection    ${devstack_conn_id}
 623     ${cmd}=    Set Variable    neutron security-group-show ${SecurityGroupRuleName} ${additional_args}
 624     Log    ${cmd}
 625     ${output}=    Write Commands Until Prompt    ${cmd}    30s
 626     Log    ${output}
 627     Close Connection
 628     [Return]    ${output}
 629
 630 Neutron Port Show
 631     [Arguments]    ${PortName}    ${additional_args}=${EMPTY}
 632     [Documentation]    Display the port configuration that belong to a given neutron port
 633     ${devstack_conn_id}=    Get ControlNode Connection
 634     Switch Connection    ${devstack_conn_id}
 635     ${cmd}=    Set Variable    neutron port-show ${PortName} ${additional_args}
 636     Log    ${cmd}
 637     ${output}=    Write Commands Until Prompt    ${cmd}    30s
 638     Log    ${output}
 639     Close Connection
 640     [Return]    ${output}
 641
 642 Neutron Security Group Create
 643     [Arguments]    ${SecurityGroupName}    ${additional_args}=${EMPTY}
 644     [Documentation]    Create a security group with specified name ,description & protocol value according to security group template
 645     ${devstack_conn_id}=    Get ControlNode Connection
 646     Switch Connection    ${devstack_conn_id}
 647     ${cmd}=    Set Variable    neutron security-group-create ${SecurityGroupName} ${additional_args}
 648     Log    ${cmd}
 649     ${output}=    Write Commands Until Prompt    ${cmd}    30s
 650     Log    ${output}
 651     Should Contain    ${output}    Created a new security_group
 652     ${sgp_id}=    Should Match Regexp    ${output}    [0-9a-f]{8}-[0-9a-f]{4}-[0-9a-f]{4}-[0-9a-f]{4}-[0-9a-f]{12}
 653     Log    ${sgp_id}
 654     Close Connection
 655     [Return]    ${output}    ${sgp_id}
 656
 657 Neutron Security Group Update
 658     [Arguments]    ${SecurityGroupName}    ${additional_args}=${EMPTY}
 659     [Documentation]    Updating security groups
 660     ${devstack_conn_id}=    Get ControlNode Connection
 661     Switch Connection    ${devstack_conn_id}
 662     ${cmd}=    Set Variable    neutron security-group-update ${SecurityGroupName} ${additional_args}
 663     Log    ${cmd}
 664     ${output}=    Write Commands Until Prompt    ${cmd}    30s
 665     Log    ${output}
 666     Close Connection
 667     [Return]    ${output}
 668
 669 Delete SecurityGroup
 670     [Arguments]    ${sg_name}
 671     [Documentation]    Delete Security group
 672     ${devstack_conn_id}=    Get ControlNode Connection
 673     Switch Connection    ${devstack_conn_id}
 674     ${output}=    Write Commands Until Prompt    neutron security-group-delete ${sg_name}    40s
 675     Log    ${output}
 676     Should Match Regexp    ${output}    Deleted security_group: ${sg_name}|Deleted security_group\\(s\\): ${sg_name}
 677     Close Connection
 678
 679 Neutron Security Group Rule Create
 680     [Arguments]    ${Security_group_name}    &{Kwargs}
 681     [Documentation]    Creates neutron security rule with neutron request with or without optional params, here security group name is mandatory args, rule with optional params can be created by passing the optional args values ex: direction=${INGRESS_EGRESS}, Then these optional params are catenated with mandatory args, example of usage: "Neutron Security Group Rule Create ${SGP_SSH} direction=${RULE_PARAMS[0]} ethertype=${RULE_PARAMS[1]} ..."
 682     ${devstack_conn_id}=    Get ControlNode Connection
 683     Switch Connection    ${devstack_conn_id}
 684     Run Keyword If    ${Kwargs}    Log    ${Kwargs}
 685     ${description}    Run Keyword If    ${Kwargs}    Pop From Dictionary    ${Kwargs}    description    default=${None}
 686     ${direction}    Run Keyword If    ${Kwargs}    Pop From Dictionary    ${Kwargs}    direction    default=${None}
 687     ${ethertype}    Run Keyword If    ${Kwargs}    Pop From Dictionary    ${Kwargs}    ethertype    default=${None}
 688     ${port_range_max}    Run Keyword If    ${Kwargs}    Pop From Dictionary    ${Kwargs}    port_range_max    default=${None}
 689     ${port_range_min}    Run Keyword If    ${Kwargs}    Pop From Dictionary    ${Kwargs}    port_range_min    default=${None}
 690     ${protocol}    Run Keyword If    ${Kwargs}    Pop From Dictionary    ${Kwargs}    protocol    default=${None}
 691     ${remote_group_id}    Run Keyword If    ${Kwargs}    Pop From Dictionary    ${Kwargs}    remote_group_id    default=${None}
 692     ${remote_ip_prefix}    Run Keyword If    ${Kwargs}    Pop From Dictionary    ${Kwargs}    remote_ip_prefix    default=${None}
 693     ${cmd}=    Set Variable    neutron security-group-rule-create ${Security_group_name}
 694     ${cmd}=    Run Keyword If    '${description}'!='None'    Catenate    ${cmd}    --description ${description}
 695     ...    ELSE    Catenate    ${cmd}
 696     ${cmd}=    Run Keyword If    '${direction}'!='None'    Catenate    ${cmd}    --direction ${direction}
 697     ...    ELSE    Catenate    ${cmd}
 698     ${cmd}=    Run Keyword If    '${ethertype}'!='None'    Catenate    ${cmd}    --ethertype ${ethertype}
 699     ...    ELSE    Catenate    ${cmd}
 700     ${cmd}=    Run Keyword If    '${port_range_max}'!='None'    Catenate    ${cmd}    --port_range_max ${port_range_max}
 701     ...    ELSE    Catenate    ${cmd}
 702     ${cmd}=    Run Keyword If    '${port_range_min}'!='None'    Catenate    ${cmd}    --port_range_min ${port_range_min}
 703     ...    ELSE    Catenate    ${cmd}
 704     ${cmd}=    Run Keyword If    '${protocol}'!='None'    Catenate    ${cmd}    --protocol ${protocol}
 705     ...    ELSE    Catenate    ${cmd}
 706     ${cmd}=    Run Keyword If    '${remote_group_id}'!='None'    Catenate    ${cmd}    --remote_group_id ${remote_group_id}
 707     ...    ELSE    Catenate    ${cmd}
 708     ${cmd}=    Run Keyword If    '${remote_ip_prefix}'!='None'    Catenate    ${cmd}    --remote_ip_prefix ${remote_ip_prefix}
 709     ...    ELSE    Catenate    ${cmd}
 710     ${output}=    Write Commands Until Prompt    ${cmd}    30s
 711     ${rule_id}=    Should Match Regexp    ${output}    [0-9a-f]{8}-[0-9a-f]{4}-[0-9a-f]{4}-[0-9a-f]{4}-[0-9a-f]{12}
 712     Log    ${rule_id}
 713     Should Contain    ${output}    Created a new security_group_rule
 714     Close Connection
 715     [Return]    ${output}    ${rule_id}
 716
 717 Create Neutron Port With Additional Params
 718     [Arguments]    ${network_name}    ${port_name}    ${additional_args}=${EMPTY}
 719     [Documentation]    Create Port With given additional parameters
 720     ${devstack_conn_id}=    Get ControlNode Connection
 721     Switch Connection    ${devstack_conn_id}
 722     ${cmd}=    Set Variable    neutron -v port-create ${network_name} --name ${port_name} ${additional_args}
 723     Log    ${cmd}
 724     ${OUTPUT}=    Write Commands Until Prompt    ${cmd}    30s
 725     Log    ${OUTPUT}
 726     Should Contain    ${output}    Created a new port
 727     ${port_id}=    Should Match Regexp    ${OUTPUT}    [0-9a-f]{8}-[0-9a-f]{4}-[0-9a-f]{4}-[0-9a-f]{4}-[0-9a-f]{12}
 728     Log    ${port_id}
 729     Close Connection
 730     [Return]    ${OUTPUT}    ${port_id}
 731
 732 Get Ports MacAddr
 733     [Arguments]    ${portName_list}
 734     [Documentation]    Retrieve the port MacAddr for the given list of port name and return the MAC address list.
 735     ${devstack_conn_id}=    Get ControlNode Connection
 736     Switch Connection    ${devstack_conn_id}
 737     ${MacAddr-list}    Create List
 738     : FOR    ${portName}    IN    @{portName_list}
 739     \    ${output} =    Write Commands Until Prompt    neutron port-list | grep "${portName}" | awk '{print $6}'    30s
 740     \    Log    ${output}
 741     \    ${splitted_output}=    Split String    ${output}    ${EMPTY}
 742     \    ${macAddr}=    Get from List    ${splitted_output}    0
 743     \    Log    ${macAddr}
 744     \    Append To List    ${MacAddr-list}    ${macAddr}
 745     [Return]    ${MacAddr-list}