csit/libraries/Utils.robot

   1 *** Settings ***
   2 Documentation     General Utils library. This library has broad scope, it can be used by any robot system tests.
   3 Library           SSHLibrary
   4 Library           String
   5 Library           DateTime
   6 Library           Process
   7 Library           Collections
   8 Library           RequestsLibrary
   9 Library           ./UtilLibrary.py
  10 Resource          KarafKeywords.robot
  11 Variables         ../variables/Variables.py
  12
  13 *** Variables ***
  14 # TODO: Introduce ${tree_size} and use instead of 1 in the next line.
  15 ${start}          sudo mn --controller=remote,ip=${ODL_SYSTEM_IP} --topo tree,1 --switch ovsk,protocols=OpenFlow13
  16
  17 *** Keywords ***
  18 Start Suite
  19     [Arguments]    ${system}=${TOOLS_SYSTEM_IP}    ${user}=${TOOLS_SYSTEM_USER}    ${password}=${TOOLS_SYSTEM_PASSWORD}    ${prompt}=${DEFAULT_LINUX_PROMPT}    ${timeout}=30s
  20     [Documentation]    Basic setup/cleanup work that can be done safely before any system
  21     ...    is run.
  22     Log    Start the test on the base edition
  23     Clean Mininet System
  24     ${mininet_conn_id}=    Open Connection    ${system}    prompt=${prompt}    timeout=${timeout}
  25     Set Suite Variable    ${mininet_conn_id}
  26     Flexible Mininet Login    user=${user}    password=${password}
  27     Execute Command    sudo ovs-vsctl set-manager ptcp:6644
  28     Write    ${start}
  29     Read Until    mininet>
  30
  31 Start Mininet
  32     [Arguments]    ${system}=${TOOLS_SYSTEM_IP}    ${cmd}=${start}    ${custom}=    ${user}=${TOOLS_SYSTEM_USER}    ${password}=${TOOLS_SYSTEM_PASSWORD}    ${prompt}=${DEFAULT_LINUX_PROMPT}
  33     ...    ${prompt_timeout}=30s
  34     [Documentation]    Basic setup to start mininet with custom topology
  35     Log    Start the test on the base edition
  36     Clean Mininet System
  37     ${mininet_conn_id}=    Open Connection    ${system}    prompt=${prompt}    timeout=${prompt_timeout}
  38     Set Suite Variable    ${mininet_conn_id}
  39     Flexible Mininet Login    user=${user}    password=${password}
  40     Put File    ${custom}
  41     Write    ${cmd}
  42     Read Until    mininet>
  43     [Return]    ${mininet_conn_id}
  44
  45 Stop Mininet
  46     [Arguments]    ${mininet_conn_id}    ${prompt}=${DEFAULT_LINUX_PROMPT}
  47     [Documentation]    Basic setup to stop/clean mininet
  48     Switch Connection    ${mininet_conn_id}
  49     SSHLibrary.Write    exit
  50     Read Until    ${prompt}
  51     Close Connection
  52
  53 Stop Suite
  54     [Arguments]    ${prompt}=${DEFAULT_LINUX_PROMPT}
  55     [Documentation]    Cleanup/Shutdown work that should be done at the completion of all
  56     ...    tests
  57     Log    Stop the test on the base edition
  58     Switch Connection    ${mininet_conn_id}
  59     Read
  60     Write    exit
  61     Read Until    ${prompt}
  62     Close Connection
  63
  64 Report_Failure_Due_To_Bug
  65     [Arguments]    ${number}
  66     [Documentation]    Report that a test failed due to a known Bugzilla bug whose
  67     ...    number is provided as an argument.
  68     ...    Not FAILED (incl. SKIPPED) test are not reported.
  69     ...    This keyword must be used in the [Teardown] setting of the affected test
  70     ...    or as the first line of the test if FastFail module is not being
  71     ...    used. It reports the URL of the bug on console and also puts it
  72     ...    into the Robot log file.
  73     ${test_skipped}=    BuiltIn.Evaluate    len(re.findall('SKIPPED', '''${TEST_MESSAGE}''')) > 0    modules=re
  74     BuiltIn.Return From Keyword If    ('${TEST_STATUS}' != 'FAIL') or ${test_skipped}
  75     ${newline}=    BuiltIn.Evaluate    chr(10)
  76     ${msg}=    BuiltIn.Set_Variable    This test fails due to https://bugs.opendaylight.org/show_bug.cgi?id=${number}
  77     BuiltIn.Set Test Message    ${msg}${newline}${newline}${TEST_MESSAGE}
  78     BuiltIn.Log    ${msg}
  79
  80 Report_Failure_And_Point_To_Linked_Bugs
  81     [Documentation]    Report that a test failed and point to linked Bugzilla bug(s).
  82     ...    Linked bugs must contain the ${reference} inside comments (workaround
  83     ...    becasue of currently missing suitable field for external references and
  84     ...    not correctly working the CONTENT MATCHES filter).
  85     ...    Not FAILED (incl. SKIPPED) test are not reported.
  86     ...    This keyword must be used in the [Teardown] setting of the affected test
  87     ...    or as the first line of the test if FastFail module is not being
  88     ...    used. It reports the URL of the bug on console and also puts it
  89     ...    into the Robot log file.
  90     ${test_skipped}=    BuiltIn.Evaluate    len(re.findall('SKIPPED', '''${TEST_MESSAGE}''')) > 0    modules=re
  91     BuiltIn.Return From Keyword If    ('${TEST_STATUS}' != 'FAIL') or ${test_skipped}
  92     ${newline}=    BuiltIn.Evaluate    chr(10)
  93     ${reference}=    String.Replace_String_Using_Regexp    ${SUITE_NAME}_${TEST_NAME}    [ /\.-]    _
  94     ${reference}=    String.Convert_To_Lowercase    ${reference}
  95     ${msg}=    BuiltIn.Set_Variable    ... click for list of related bugs or create a new one if needed (with the${newline}"${reference}"${newline}reference somewhere inside)
  96     ${bugs}=    BuiltIn.Set_Variable    "https://bugs.opendaylight.org/buglist.cgi?f1=longdesc&o1=substring&v1=${reference}&order=bug_status"
  97     BuiltIn.Set Test Message    ${msg}${newline}${bugs}${newline}${newline}${TEST_MESSAGE}
  98     BuiltIn.Log    ${msg}${newline}${bugs}
  99
 100 Ensure All Nodes Are In Response
 101     [Arguments]    ${URI}    ${node_list}
 102     [Documentation]    A GET is made to the supplied ${URI} and every item in the ${node_list}
 103     ...    is verified to exist in the repsonse. This keyword currently implies that it's node
 104     ...    specific but any list of strings can be given in ${node_list}. Refactoring of this
 105     ...    to make it more generic should be done. (see keyword "Check For Elements At URI")
 106     : FOR    ${node}    IN    @{node_list}
 107     \    ${resp}    RequestsLibrary.Get Request    session    ${URI}
 108     \    Should Be Equal As Strings    ${resp.status_code}    200
 109     \    Should Contain    ${resp.content}    ${node}
 110
 111 Check Nodes Stats
 112     [Arguments]    ${node}
 113     [Documentation]    A GET on the /node/${node} API is made and specific flow stat
 114     ...    strings are checked for existence.
 115     ${resp}    RequestsLibrary.Get Request    session    ${OPERATIONAL_NODES_API}/node/${node}
 116     Should Be Equal As Strings    ${resp.status_code}    200
 117     Should Contain    ${resp.content}    flow-capable-node-connector-statistics
 118     Should Contain    ${resp.content}    flow-table-statistics
 119
 120 Check That Port Count Is Ok
 121     [Arguments]    ${node}    ${count}
 122     [Documentation]    A GET on the /port API is made and the specified port ${count} is
 123     ...    verified. A more generic Keyword "Check For Specific Number Of Elements At URI"
 124     ...    also does this work and further consolidation should be done.
 125     ${resp}    RequestsLibrary.Get Request    session    ${REST_CONTEXT}/${CONTAINER}/port
 126     Log    ${resp.content}
 127     Should Be Equal As Strings    ${resp.status_code}    200
 128     Should Contain X Times    ${resp.content}    ${node}    ${count}
 129
 130 Check For Specific Number Of Elements At URI
 131     [Arguments]    ${uri}    ${element}    ${expected_count}
 132     [Documentation]    A GET is made to the specified ${URI} and the specific count of a
 133     ...    given element is done (as supplied by ${element} and ${expected_count})
 134     ${resp}    RequestsLibrary.Get Request    session    ${uri}
 135     Log    ${resp.content}
 136     Should Be Equal As Strings    ${resp.status_code}    200
 137     Should Contain X Times    ${resp.content}    ${element}    ${expected_count}
 138
 139 Check For Elements At URI
 140     [Arguments]    ${uri}    ${elements}
 141     [Documentation]    A GET is made at the supplied ${URI} and every item in the list of
 142     ...    ${elements} is verified to exist in the response
 143     ${resp}    RequestsLibrary.Get Request    session    ${uri}
 144     Log    ${resp.content}
 145     Should Be Equal As Strings    ${resp.status_code}    200
 146     : FOR    ${i}    IN    @{elements}
 147     \    Should Contain    ${resp.content}    ${i}
 148
 149 Check For Elements Not At URI
 150     [Arguments]    ${uri}    ${elements}
 151     [Documentation]    A GET is made at the supplied ${URI} and every item in the list of
 152     ...    ${elements} is verified to NOT exist in the response
 153     ${resp}    RequestsLibrary.Get Request    session    ${uri}
 154     Log    ${resp.content}
 155     Should Be Equal As Strings    ${resp.status_code}    200
 156     : FOR    ${i}    IN    @{elements}
 157     \    Should Not Contain    ${resp.content}    ${i}
 158
 159 Clean Mininet System
 160     [Arguments]    ${system}=${TOOLS_SYSTEM_IP}
 161     Run Command On Mininet    ${system}    sudo mn -c
 162     Run Command On Mininet    ${system}    sudo ps -elf | egrep 'usr/local/bin/mn' | egrep python | awk '{print "sudo kill -9",$4}' | sh
 163
 164 Clean Up Ovs
 165     [Arguments]    ${system}=${TOOLS_SYSTEM_IP}
 166     [Documentation]    Cleans up the OVS instance and remove any existing common known bridges.
 167     ${output}=    Run Command On Mininet    ${system}    sudo ovs-vsctl list-br
 168     Log    ${output}
 169     : FOR    ${i}    IN    ${output}
 170     \    Run Command On Mininet    ${system}    sudo ovs-vsctl --if-exists del-br ${i}
 171     Run Command On Mininet    ${system}    sudo ovs-vsctl del-manager
 172
 173 Extract Value From Content
 174     [Arguments]    ${content}    ${index}    ${strip}=nostrip
 175     [Documentation]    Will take the given response content and return the value at the given index as a string
 176     ${value}=    Get Json Value    ${content}    ${index}
 177     ${value}=    Convert To String    ${value}
 178     ${value}=    Run Keyword If    '${strip}' == 'strip'    Strip Quotes    ${value}
 179     [Return]    ${value}
 180
 181 Get Process ID Based On Regex On Remote System
 182     [Arguments]    ${system}    ${regex_string_to_match_on}    ${user}=${TOOLS_SYSTEM_USER}    ${password}=${EMPTY}    ${prompt}=${DEFAULT_LINUX_PROMPT}    ${prompt_timeout}=30s
 183     [Documentation]    Uses ps to find a process that matches the supplied regex. Returns the PID of that process
 184     ...    The ${regex_string_to_match_on} should produce a unique process otherwise the PID returned may not be
 185     ...    the expected PID
 186     # doing the extra -v grep in this command to exclude the grep process itself from the output
 187     ${cmd}=    Set Variable    ps -elf | grep -v grep | grep ${regex_string_to_match_on} | awk '{print $4}'
 188     ${output}=    Run Command On Remote System    ${system}    ${cmd}    user=${user}    password=${password}    prompt=${prompt}
 189     ...    prompt_timeout=${prompt_timeout}
 190     # ${output} contains the system prompt and all we want is the value of the number
 191     ${pid}=    Fetch From Left    ${output}    \r
 192     # TODO: Get Process * keywords have perhaps non-standard default credentials.
 193     # ...    Should there be * On Mininet and * On Controller specializations?
 194     [Return]    ${pid}
 195
 196 Get Process Thread Count On Remote System
 197     [Arguments]    ${system}    ${pid}    ${user}=${TOOLS_SYSTEM_USER}    ${password}=${EMPTY}    ${prompt}=${DEFAULT_LINUX_PROMPT}    ${prompt_timeout}=30s
 198     [Documentation]    Executes the ps command to retrieve the lightweight process (aka thread) count.
 199     ${cmd}=    Set Variable    ps --no-headers -o nlwp ${pid}
 200     ${output}=    Run Command On Remote System    ${system}    ${cmd}    user=${user}    password=${password}    prompt=${prompt}
 201     ...    prompt_timeout=${prompt_timeout}
 202     # ${output} contains the system prompt and all we want is the value of the number
 203     ${thread_count}=    Fetch From Left    ${output}    \r
 204     [Return]    ${thread_count}
 205
 206 Strip Quotes
 207     [Arguments]    ${string_to_strip}
 208     [Documentation]    Will strip ALL quotes from given string and return the new string
 209     ${string_to_return}=    Replace String    ${string_to_strip}    "    \    count=-1
 210     [Return]    ${string_to_return}
 211
 212 Flexible SSH Login
 213     [Arguments]    ${user}    ${password}=${EMPTY}    ${delay}=0.5s
 214     [Documentation]    On active SSH session: if given non-empty password, do Login, else do Login With Public Key.
 215     ${pwd_length} =    BuiltIn.Get Length    ${password}
 216     # ${pwd_length} is guaranteed to be an integer, so we are safe to evaluate it as Python expression.
 217     BuiltIn.Run Keyword And Return If    ${pwd_length} > 0    SSHLibrary.Login    ${user}    ${password}    delay=${delay}
 218     BuiltIn.Run Keyword And Return    SSHLibrary.Login With Public Key    ${user}    ${USER_HOME}/.ssh/${SSH_KEY}    ${KEYFILE_PASS}    delay=${delay}
 219
 220 Flexible Mininet Login
 221     [Arguments]    ${user}=${TOOLS_SYSTEM_USER}    ${password}=${TOOLS_SYSTEM_PASSWORD}    ${delay}=0.5s
 222     [Documentation]    Call Flexible SSH Login, but with default values suitable for Mininet machine.
 223     BuiltIn.Run Keyword And Return    Flexible SSH Login    user=${user}    password=${password}    delay=${delay}
 224
 225 Flexible Controller Login
 226     [Arguments]    ${user}=${ODL_SYSTEM_USER}    ${password}=${ODL_SYSTEM_PASSWORD}    ${delay}=0.5s
 227     [Documentation]    Call Flexible SSH Login, but with default values suitable for Controller machine.
 228     BuiltIn.Run Keyword And Return    Flexible SSH Login    user=${user}    password=${password}    delay=${delay}
 229
 230 Run Command On Remote System
 231     [Arguments]    ${system}    ${cmd}    ${user}=${DEFAULT_USER}    ${password}=${EMPTY}    ${prompt}=${DEFAULT_LINUX_PROMPT}    ${prompt_timeout}=${DEFAULT_TIMEOUT}
 232     [Documentation]    Reduces the common work of running a command on a remote system to a single higher level
 233     ...    robot keyword, taking care to log in with a public key and. The command given is written
 234     ...    and the output returned. No test conditions are checked.
 235     Log    Attempting to execute ${cmd} on ${system} by ${user} with ${keyfile_pass} and ${prompt}
 236     ${conn_id}=    SSHLibrary.Open Connection    ${system}    prompt=${prompt}    timeout=${prompt_timeout}
 237     Flexible SSH Login    ${user}    ${password}
 238     ${stdout}    ${stderr}    SSHLibrary.Execute Command    ${cmd}    return_stderr=True
 239     SSHLibrary.Close Connection
 240     Log    ${stderr}
 241     [Return]    ${stdout}
 242
 243 Write_Bare_Ctrl_C
 244     [Documentation]    Construct ctrl+c character and SSH-write it (without endline) to the current SSH connection.
 245     ...    Do not read anything yet.
 246     ${ctrl_c}=    BuiltIn.Evaluate    chr(int(3))
 247     SSHLibrary.Write_Bare    ${ctrl_c}
 248
 249 Write Bare Ctrl D
 250     [Documentation]    Construct ctrl+d character and SSH-write it (without endline) to the current SSH connection.
 251     ...    Do not read anything yet.
 252     ${ctrl_d}=    BuiltIn.Evaluate    chr(int(4))
 253     SSHLibrary.Write Bare    ${ctrl_d}
 254
 255 Run Command On Mininet
 256     [Arguments]    ${system}=${TOOLS_SYSTEM_IP}    ${cmd}=echo    ${user}=${TOOLS_SYSTEM_USER}    ${password}=${TOOLS_SYSTEM_PASSWORD}    ${prompt}=${TOOLS_SYSTEM_PROMPT}
 257     [Documentation]    Call Run Comand On Remote System, but with default values suitable for Mininet machine.
 258     BuiltIn.Run Keyword And Return    Run Command On Remote System    ${system}    ${cmd}    ${user}    ${password}    prompt=${prompt}
 259
 260 Run Command On Controller
 261     [Arguments]    ${system}=${ODL_SYSTEM_IP}    ${cmd}=echo    ${user}=${ODL_SYSTEM_USER}    ${password}=${ODL_SYSTEM_PASSWORD}    ${prompt}=${ODL_SYSTEM_PROMPT}
 262     [Documentation]    Call Run Comand On Remote System, but with default values suitable for Controller machine.
 263     BuiltIn.Run Keyword And Return    Run Command On Remote System    ${system}    ${cmd}    ${user}    ${password}    prompt=${prompt}
 264
 265 Verify File Exists On Remote System
 266     [Arguments]    ${system}    ${file}    ${user}=${TOOLS_SYSTEM_USER}    ${password}=${TOOLS_SYSTEM_PASSWORD}    ${prompt}=${DEFAULT_LINUX_PROMPT}    ${prompt_timeout}=5s
 267     [Documentation]    Will create connection with public key and will PASS if the given ${file} exists,
 268     ...    otherwise will FAIL
 269     ${conn_id}=    Open Connection    ${system}    prompt=${prompt}    timeout=${prompt_timeout}
 270     Flexible SSH Login    ${user}    ${password}
 271     SSHLibrary.File Should Exist    ${file}
 272     Close Connection
 273
 274 Verify Controller Is Not Dead
 275     [Arguments]    ${controller_ip}=${ODL_SYSTEM_IP}
 276     [Documentation]    Will execute any tests to verify the controller is not dead. Some checks are
 277     ...    Out Of Memory Execptions.
 278     Check Karaf Log File Does Not Have Messages    ${controller_ip}    java.lang.OutOfMemoryError
 279     # TODO: Should Verify Controller * keywords also accept user, password, prompt and karaf_log arguments?
 280
 281 Verify Controller Has No Null Pointer Exceptions
 282     [Arguments]    ${controller_ip}=${ODL_SYSTEM_IP}
 283     [Documentation]    Will execute any tests to verify the controller is not having any null pointer eceptions.
 284     Check Karaf Log File Does Not Have Messages    ${controller_ip}    java.lang.NullPointerException
 285
 286 Get Epoch Time
 287     [Arguments]    ${time}
 288     [Documentation]    Get the Epoc time from MM/DD/YYYY HH:MM:SS
 289     ${epoch_time}=    Convert Date    ${time}    epoch    exclude_milles=True    date_format=%m/%d/%Y %H:%M:%S
 290     ${epoch_time}=    Convert To Integer    ${epoch_time}
 291     [Return]    ${epoch_time}
 292
 293 Remove Space on String
 294     [Arguments]    ${str}    ${count}=-1
 295     [Documentation]    Remove the empty space from given string.count is optional,if its given
 296     ...    that many occurence of space will be removed from left
 297     ${x}=    Convert To String    ${str}
 298     ${x}=    Replace String    ${str}    ${SPACE}    ${EMPTY}    count=${count}
 299     [Return]    ${x}
 300
 301 Split Value from String
 302     [Arguments]    ${str}    ${splitter}
 303     [Documentation]    Split the String based on given splitter and return as list
 304     @{x}=    Split String    ${str}    ${splitter}
 305     [Return]    @{x}
 306
 307 Concatenate the String
 308     [Arguments]    ${str1}    ${str2}
 309     [Documentation]    Catenate the two non-string objects and return as String
 310     ${str1}=    Convert to String    ${str1}
 311     ${str2}=    Convert to String    ${str2}
 312     ${output}=    Catenate    ${str1}    ${str2}
 313     [Return]    ${output}
 314
 315 Post Elements To URI
 316     [Arguments]    ${rest_uri}    ${data}    ${headers}=${headers}
 317     [Documentation]    Perform a POST rest operation, using the URL and data provided
 318     ${resp} =    RequestsLibrary.Post Request    session    ${rest_uri}    data=${data}    headers=${headers}
 319     Should Be Equal As Strings    ${resp.status_code}    200
 320
 321 Remove All Elements At URI
 322     [Arguments]    ${uri}
 323     ${resp}    RequestsLibrary.Delete Request    session    ${uri}
 324     Should Be Equal As Strings    ${resp.status_code}    200
 325
 326 Remove All Elements At URI And Verify
 327     [Arguments]    ${uri}
 328     ${resp}    RequestsLibrary.Delete Request    session    ${uri}
 329     Should Be Equal As Strings    ${resp.status_code}    200
 330     ${resp}    RequestsLibrary.Get Request    session    ${uri}
 331     Should Be Equal As Strings    ${resp.status_code}    404
 332
 333 Add Elements To URI From File
 334     [Arguments]    ${dest_uri}    ${data_file}    ${headers}=${headers}
 335     ${body}    OperatingSystem.Get File    ${data_file}
 336     ${resp}    RequestsLibrary.Put Request    session    ${dest_uri}    data=${body}    headers=${headers}
 337     Should Be Equal As Strings    ${resp.status_code}    200
 338
 339 Post Elements To URI From File
 340     [Arguments]    ${dest_uri}    ${data_file}    ${headers}=${headers}
 341     ${body}    OperatingSystem.Get File    ${data_file}
 342     ${resp}    RequestsLibrary.Post Request    session    ${dest_uri}    data=${body}    headers=${headers}
 343     Should Be Equal As Strings    ${resp.status_code}    200
 344
 345 Run Process With Logging And Status Check
 346     [Arguments]    @{proc_args}
 347     [Documentation]    Execute an OS command, log STDOUT and STDERR output and check exit code to be 0
 348     ${result}=    Run Process    @{proc_args}
 349     Log    ${result.stdout}
 350     Log    ${result.stderr}
 351     Should Be Equal As Integers    ${result.rc}    0
 352     [Return]    ${result}
 353
 354 Get Data From URI
 355     [Arguments]    ${session}    ${uri}    ${headers}=${NONE}
 356     [Documentation]    Issue a GET request and return the data obtained or on error log the error and fail.
 357     ...    Issues a GET request for ${uri} in ${session} using headers from
 358     ...    ${headers}. If the request returns a HTTP error, fails. Otherwise
 359     ...    returns the data obtained by the request.
 360     ${response}=    RequestsLibrary.Get Request    ${session}    ${uri}    ${headers}
 361     Builtin.Return_From_Keyword_If    ${response.status_code} == 200    ${response.text}
 362     Builtin.Log    ${response.text}
 363     Builtin.Fail    The request failed with code ${response.status_code}
 364
 365 No Content From URI
 366     [Arguments]    ${session}    ${uri}    ${headers}=${NONE}
 367     [Documentation]    Issue a GET request and return on error 404 (No content) or will fail and log the content.
 368     ...    Issues a GET request for ${uri} in ${session} using headers from
 369     ...    ${headers}. If the request returns a HTTP error, fails. Otherwise
 370     ...    returns the data obtained by the request.
 371     ${response}=    RequestsLibrary.Get Request    ${session}    ${uri}    ${headers}
 372     Builtin.Return_From_Keyword_If    ${response.status_code} == 404
 373     Builtin.Log    ${response.text}
 374     Builtin.Fail    The request failed with code ${response.status_code}
 375
 376 Get Index From List Of Dictionaries
 377     [Arguments]    ${dictionary_list}    ${key}    ${value}
 378     [Documentation]    Extract index for the dictionary in a list that contains a key-value pair. Returns -1 if key-value is not found.
 379     ${length}=    Get Length    ${dictionary_list}
 380     ${index}=    Set Variable    -1
 381     : FOR    ${i}    IN RANGE    ${length}
 382     \    ${dictionary}=    Get From List    ${dictionary_list}    ${i}
 383     \    Run Keyword If    '&{dictionary}[${key}]' == '${value}'    Set Test Variable    ${index}    ${i}
 384     [Return]    ${index}
 385
 386 Check Item Occurrence
 387     [Arguments]    ${string}    ${dictionary_item_occurrence}
 388     [Documentation]    Check string for occurrences of items expressed in a list of dictionaries {item=occurrences}. 0 occurences means item is not present.
 389     : FOR    ${item}    IN    @{dictionary_item_occurrence}
 390     \    Should Contain X Times    ${string}    ${item}    &{dictionary_item_occurrence}[${item}]
 391
 392 Post Log Check
 393     [Arguments]    ${uri}    ${body}    ${status_code}=200
 394     [Documentation]    Post body to ${uri}, log response content, and check status
 395     ${resp}=    RequestsLibrary.Post Request    session    ${uri}    ${body}
 396     Log    ${resp.content}
 397     Should Be Equal As Strings    ${resp.status_code}    ${status_code}
 398     [Return]    ${resp}