csit/libraries/VtnMaKeywordsLi.robot

   1 *** Settings ***
   2 Library           SSHLibrary
   3 Library           String
   4 Library           DateTime
   5 Library           Collections
   6 Library           json
   7 Library           RequestsLibrary
   8 Variables         ../variables/Variables.py
   9 Resource          ./Utils.robot
  10
  11 *** Variables ***
  12 ${vlan_topo_10}    sudo mn --controller=remote,ip=${ODL_SYSTEM_IP} --custom vlan_vtn_test.py --topo vlantopo
  13 ${vlan_topo_13}    sudo mn --controller=remote,ip=${ODL_SYSTEM_IP} --custom vlan_vtn_test.py --topo vlantopo --switch ovsk,protocols=OpenFlow13
  14 ${REST_CONTEXT_VTNS}    controller/nb/v2/vtn/default/vtns
  15 ${REST_CONTEXT}    controller/nb/v2/vtn/default
  16 ${VERSION_VTN}    controller/nb/v2/vtn/version
  17 ${VTN_INVENTORY}    restconf/operational/vtn-inventory:vtn-nodes
  18 ${DUMPFLOWS_OF10}    dpctl dump-flows -O OpenFlow10
  19 ${DUMPFLOWS_OF13}    dpctl dump-flows -O OpenFlow13
  20 ${index}          7
  21 @{FLOWELMENTS}    nw_src=10.0.0.1    nw_dst=10.0.0.3    actions=drop
  22 @{BRIDGE1_DATAFLOW}    "reason":"PORTMAPPED"    "path":{"tenant":"Tenant1","bridge":"vBridge1","interface":"if2"}
  23 @{BRIDGE2_DATAFLOW}    "reason":"PORTMAPPED"    "path":{"tenant":"Tenant1","bridge":"vBridge2","interface":"if3"}
  24 ${vlanmap_bridge1}    {"vlan": "200"}
  25 ${vlanmap_bridge2}    {"vlan": "300"}
  26 @{VLANMAP_BRIDGE1_DATAFLOW}    "reason":"VLANMAPPED"    "path":{"tenant":"Tenant1","bridge":"vBridge1_vlan"}
  27 @{VLANMAP_BRIDGE2_DATAFLOW}    "reason":"VLANMAPPED"    "path":{"tenant":"Tenant1","bridge":"vBridge2_vlan"}
  28 ${pathpolicy_topo_13}    sudo mn --controller=remote,ip=${ODL_SYSTEM_IP} --custom topo-3sw-2host_multipath.py --topo pathpolicytopo --switch ovsk,protocols=OpenFlow13
  29 ${pathpolicy_topo_10}    sudo mn --controller=remote,ip=${ODL_SYSTEM_IP} --custom topo-3sw-2host_multipath.py --topo pathpolicytopo --switch ovsk,protocols=OpenFlow10
  30 @{PATHMAP_ATTR}    "index":"1"    "condition":"flowcond_path"    "policy":"1"
  31 ${policy_id}      1
  32 @{PATHPOLICY_ATTR}    "id":"1"    "type":"OF"    "name":"s4-eth2"
  33 ${custom}         ${CURDIR}/${CREATE_PATHPOLICY_TOPOLOGY_FILE_PATH}
  34 ${in_port}        1
  35 ${out_before_pathpolicy}    output:2
  36 ${out_after_pathpolicy}    output:3
  37
  38 *** Keywords ***
  39 Start SuiteVtnMa
  40     [Arguments]    ${version_flag}=none
  41     [Documentation]    Start VTN Manager Init Test Suite
  42     Create Session    session    http://${ODL_SYSTEM_IP}:${RESTPORT}    auth=${AUTH}    headers=${HEADERS}
  43     BuiltIn.Wait_Until_Keyword_Succeeds    30    3    Fetch vtn list
  44     Start Suite
  45     Run Keyword If    '${version_flag}' == 'OF13'    Set Global Variable    ${OPENFLOW_VERSION}    OF13
  46     ...    ELSE    Set Global Variable    ${OPENFLOW_VERSION}    OF10
  47
  48 Stop SuiteVtnMa
  49     [Documentation]    Stop VTN Manager Test Suite
  50     Delete All Sessions
  51
  52 Start SuiteVtnMaTest
  53     [Documentation]    Start VTN Manager Test Suite
  54     Create Session    session    http://${ODL_SYSTEM_IP}:${RESTPORT}    auth=${AUTH}    headers=${HEADERS}
  55
  56 Stop SuiteVtnMaTest
  57     [Documentation]    Stop VTN Manager Test Suite
  58     Delete All Sessions
  59
  60 Add Table Miss Flows
  61     [Documentation]    Add Flow entried to handle table miss situation
  62     Write    dpctl add-flow priority=0,actions=output:CONTROLLER -OOpenFlow13
  63     Read Until    mininet>
  64
  65 Fetch vtn list
  66     [Documentation]    Check if VTN Manager is up.
  67     ${resp}=    RequestsLibrary.Get Request    session    ${REST_CONTEXT_VTNS}
  68     Should Be Equal As Strings    ${resp.status_code}    200
  69
  70 Fetch vtn switch inventory
  71     [Arguments]    ${sw_name}
  72     [Documentation]    Check if Switch is detected.
  73     ${resp}=    RequestsLibrary.Get Request    session    ${VTN_INVENTORY}/vtn-inventory:vtn-node/${sw_name}
  74     Should Be Equal As Strings    ${resp.status_code}    200
  75
  76 Add a vtn
  77     [Arguments]    ${vtn_name}    ${vtn_data}
  78     [Documentation]    Create a vtn with specified parameters.
  79     ${resp}=    RequestsLibrary.Post Request    session    ${REST_CONTEXT_VTNS}/${vtn_name}    data=${vtn_data}
  80     Should Be Equal As Strings    ${resp.status_code}    201
  81
  82 Delete a vtn
  83     [Arguments]    ${vtn_name}
  84     [Documentation]    Create a vtn with specified parameters.
  85     ${resp}=    RequestsLibrary.Delete Request    session    ${REST_CONTEXT_VTNS}/${vtn_name}
  86     Should Be Equal As Strings    ${resp.status_code}    200
  87
  88 Add a vBridge
  89     [Arguments]    ${vtn_name}    ${vBridge_name}    ${vBridge_data}
  90     [Documentation]    Create a vBridge in a VTN
  91     ${resp}=    RequestsLibrary.Post Request    session    ${REST_CONTEXT_VTNS}/${vtn_name}/vbridges/${vBridge_name}    data=${vBridge_data}
  92     Should Be Equal As Strings    ${resp.status_code}    201
  93
  94 Add a interface
  95     [Arguments]    ${vtn_name}    ${vBridge_name}    ${interface_name}    ${interface_data}
  96     [Documentation]    Create a interface into a vBridge of a VTN
  97     ${resp}=    RequestsLibrary.Post Request    session    ${REST_CONTEXT_VTNS}/${vtn_name}/vbridges/${vBridge_name}/interfaces/${interface_name}    data=${interface_data}
  98     Should Be Equal As Strings    ${resp.status_code}    201
  99
 100 Add a portmap
 101     [Arguments]    ${vtn_name}    ${vBridge_name}    ${interface_name}    ${portmap_data}
 102     [Documentation]    Create a portmap for a interface of a vbridge
 103     ${json_data}=    json.dumps    ${portmap_data}
 104     ${resp}=    RequestsLibrary.Put Request    session    ${REST_CONTEXT_VTNS}/${vtn_name}/vbridges/${vBridge_name}/interfaces/${interface_name}/portmap    data=${json_data}    headers=${HEADERS}
 105     Should Be Equal As Strings    ${resp.status_code}    200
 106
 107 Verify Data Flows
 108     [Arguments]    ${vtn_name}    ${vBridge_name}
 109     [Documentation]    Verify the reason and physical data flows for the specified vtn and vbridge
 110     ${resp}=    RequestsLibrary.Get Request    session    ${REST_CONTEXT_VTNS}/${vtn_name}/flows/detail
 111     Run Keyword If    '${vBridge_name}' == 'vBridge1'    DataFlowsForBridge    ${resp}    @{BRIDGE1_DATAFLOW}
 112     ...    ELSE IF    '${vBridge_name}' == 'vBridge2'    DataFlowsForBridge    ${resp}    @{BRIDGE2_DATAFLOW}
 113     ...    ELSE IF    '${vBridge_name}' == 'vBridge1_vlan'    DataFlowsForBridge    ${resp}    @{VLANMAP_BRIDGE1_DATAFLOW}
 114     ...    ELSE    DataFlowsForBridge    ${resp}    @{VLANMAP_BRIDGE2_DATAFLOW}
 115
 116 DataFlowsForBridge
 117     [Arguments]    ${resp}    @{BRIDGE_DATAFLOW}
 118     [Documentation]    Verify whether the required attributes exists.
 119     : FOR    ${dataflowElement}    IN    @{BRIDGE_DATAFLOW}
 120     \    should Contain    ${resp.content}    ${dataflowElement}
 121
 122 Add a pathmap
 123     [Arguments]    ${pathmap_data}
 124     [Documentation]    Create a pathmap for a vtn
 125     ${json_data}=    json.dumps    ${pathmap_data}
 126     ${resp}=    RequestsLibrary.Put Request    session    ${REST_CONTEXT}/pathmaps/${policy_id}    data=${pathmap_data}    headers=${HEADERS}
 127     Should Be Equal As Strings    ${resp.status_code}    201
 128
 129 Get a pathmap
 130     [Documentation]    Get a pathmap for a vtn.
 131     ${resp}=    RequestsLibrary.Get Request    session    ${REST_CONTEXT}/pathmaps
 132     : FOR    ${pathElement}    IN    @{PATHMAP_ATTR}
 133     \    should Contain    ${resp.content}    ${pathElement}
 134
 135 Add a pathpolicy
 136     [Arguments]    ${pathpolicy_data}
 137     [Documentation]    Create a pathpolicy for a vtn
 138     ${json_data}=    json.dumps    ${pathpolicy_data}
 139     ${resp}=    RequestsLibrary.Put Request    session    ${REST_CONTEXT}/pathpolicies/${policy_id}    data=${pathpolicy_data}    headers=${HEADERS}
 140     Should Be Equal As Strings    ${resp.status_code}    201
 141
 142 Get a pathpolicy
 143     [Documentation]    Get a pathpolicy for a vtn.
 144     ${resp}=    RequestsLibrary.Get Request    session    ${REST_CONTEXT}/pathpolicies/${policy_id}
 145     : FOR    ${pathpolicyElement}    IN    @{PATHPOLICY_ATTR}
 146     \    should Contain    ${resp.content}    ${pathpolicyElement}
 147
 148 Verify flowEntryPathPolicy
 149     [Arguments]    ${of_version}    ${port}    ${output}
 150     [Documentation]    Checking Flows on switch S1 and switch S3 after applying path policy
 151     ${DUMPFLOWS}=    Set Variable If    "${of_version}"=="OF10"    ${DUMPFLOWS_OF10}    ${DUMPFLOWS_OF13}
 152     write    ${DUMPFLOWS}
 153     ${result}    Read Until    mininet>
 154     Should Contain    ${result}    in_port=${port}    actions=${output}
 155
 156 Start PathSuiteVtnMaTest
 157     [Documentation]    Start VTN Manager Test Suite and Mininet
 158     Start SuiteVtnMaTest
 159     Start Mininet    ${TOOLS_SYSTEM_IP}    ${pathpolicy_topo_13}    ${custom}
 160
 161 Start PathSuiteVtnMaTestOF10
 162     [Documentation]    Start VTN Manager Test Suite and Mininet in Open Flow 10 Specification
 163     Start SuiteVtnMaTest
 164     Start Mininet    ${TOOLS_SYSTEM_IP}    ${pathpolicy_topo_10}    ${custom}
 165
 166 Stop PathSuiteVtnMaTest
 167     [Documentation]    Cleanup/Shutdown work at the completion of all tests.
 168     Delete All Sessions
 169     Stop Mininet    ${mininet_conn_id}
 170
 171 Delete a pathmap
 172     [Documentation]    Delete a pathmap for a vtn
 173     ${resp}=    RequestsLibrary.Delete Request    session    ${REST_CONTEXT}/pathmaps/1
 174     Should Be Equal As Strings    ${resp.status_code}    200
 175
 176 Get a pathmap after delete
 177     [Documentation]    Get a pathmap for a vtn.
 178     ${resp}=    RequestsLibrary.Get Request    session    ${REST_CONTEXT}/pathmaps
 179     : FOR    ${pathElement}    IN    @{PATHMAP_ATTR}
 180     \    should Not Contain    ${resp.content}    ${pathElement}
 181
 182 Delete a pathpolicy
 183     [Documentation]    Delete a pathpolicy for a vtn
 184     ${resp}=    RequestsLibrary.Delete Request    session    ${REST_CONTEXT}/pathpolicies/1
 185     Should Be Equal As Strings    ${resp.status_code}    200
 186
 187 Get a pathpolicy after delete
 188     [Documentation]    Get a pathpolicy for a vtn after delete.
 189     ${resp}=    RequestsLibrary.Get Request    session    ${REST_CONTEXT}/pathpolicies/${policy_id}
 190     : FOR    ${pathpolicyElement}    IN    @{PATHPOLICY_ATTR}
 191     \    should Not Contain    ${resp.content}    ${pathpolicyElement}
 192
 193 Add a macmap
 194     [Arguments]    ${vtn_name}    ${vBridge_name}    ${macmap_data}
 195     [Documentation]    Create a macmap for a vbridge
 196     ${json_data}=    json.dumps    ${macmap_data}
 197     ${resp}=    RequestsLibrary.Post Request    session    ${REST_CONTEXT_VTNS}/${vtn_name}/vbridges/${vBridge_name}/macmap/allow    data=${macmap_data}    headers=${HEADERS}
 198     Should Be Equal As Strings    ${resp.status_code}    201
 199
 200 Get DynamicMacAddress
 201     [Arguments]    ${h}
 202     [Documentation]    Get Dynamic mac address of Host
 203     write    ${h} ifconfig -a | grep HWaddr
 204     ${source}    Read Until    mininet>
 205     ${HWaddress}=    Split String    ${source}    ${SPACE}
 206     ${sourceHWaddr}=    Get from List    ${HWaddress}    ${index}
 207     ${sourceHWaddress}=    Convert To Lowercase    ${sourceHWaddr}
 208     Return From Keyword    ${sourceHWaddress}    # Also [Return] would work here.
 209
 210 Add a vBridgeMacMapping
 211     [Arguments]    ${tenant_name}    ${Bridge_name}    ${bridge_macmap_data}
 212     [Documentation]    Create a vbridge macmap for a bridge
 213     ${json_data}=    json.dumps    ${bridge_macmap_data}
 214     ${resp}=    RequestsLibrary.Post Request    session    ${REST_CONTEXT_VTNS}/${tenant_name}/vbridges/${Bridge_name}/macmap/allow    data=${json_data}    headers=${HEADERS}
 215     Should Be Equal As Strings    ${resp.status_code}    201
 216
 217 Mininet Ping Should Succeed
 218     [Arguments]    ${host1}    ${host2}
 219     [Documentation]    Ping hosts to check connectivity
 220     Write    ${host1} ping -c 1 ${host2}
 221     ${result}    Read Until    mininet>
 222     Should Contain    ${result}    64 bytes
 223
 224 Mininet Ping Should Not Succeed
 225     [Arguments]    ${host1}    ${host2}
 226     [Documentation]    Ping hosts when there is no connectivity and check hosts is unreachable
 227     Write    ${host1} ping -c 3 ${host2}
 228     ${result}    Read Until    mininet>
 229     Should Not Contain    ${result}    64 bytes
 230
 231 Delete a interface
 232     [Arguments]    ${vtn_name}    ${vBridge_name}    ${interface_name}
 233     [Documentation]    Delete a interface with specified parameters.
 234     ${resp}=    RequestsLibrary.Delete Request    session    ${REST_CONTEXT_VTNS}/${vtn_name}/vbridges/${vBridge_name}/interfaces/${interface_name}
 235     Should Be Equal As Strings    ${resp.status_code}    200
 236
 237 Start vlan_topo
 238     [Arguments]    ${OF}
 239     Clean Mininet System
 240     ${mininet_conn_id1}=    Open Connection    ${TOOLS_SYSTEM_IP}    prompt=${DEFAULT_LINUX_PROMPT}    timeout=30s
 241     Set Suite Variable    ${mininet_conn_id1}
 242     Login With Public Key    ${TOOLS_SYSTEM_USER}    ${USER_HOME}/.ssh/${SSH_KEY}    any
 243     Execute Command    sudo ovs-vsctl set-manager ptcp:6644
 244     Put File    ${CURDIR}/${CREATE_VLAN_TOPOLOGY_FILE_PATH}
 245     Run Keyword If    '${OF}' == 'OF13'    Write    ${vlan_topo_13}
 246     ...    ELSE IF    '${OF}' == 'OF10'    Write    ${vlan_topo_10}
 247     ${result}    Read Until    mininet>
 248
 249 Add a vlanmap
 250     [Arguments]    ${vtn_name}    ${vBridge_name}    ${vlanmap_data}
 251     [Documentation]    Create a vlanmap
 252     ${resp}=    RequestsLibrary.Post Request    session    ${REST_CONTEXT_VTNS}/${vtn_name}/vbridges/${vBridge_name}/vlanmaps/    data=${vlanmap_data}    headers=${HEADERS}
 253     Should Be Equal As Strings    ${resp.status_code}    201
 254
 255 Get flow
 256     [Arguments]    ${vtn_name}
 257     [Documentation]    Get data flow.
 258     ${resp}=    RequestsLibrary.Get Request    session    ${REST_CONTEXT_VTNS}/${vtn_name}/flows/detail
 259     Should Be Equal As Strings    ${resp.status_code}    200
 260
 261 Remove a portmap
 262     [Arguments]    ${vtn_name}    ${vBridge_name}    ${interface_name}    ${portmap_data}
 263     [Documentation]    Remove a portmap for a interface of a vbridge
 264     ${json_data}=    json.dumps    ${portmap_data}
 265     ${resp}=    RequestsLibrary.Delete Request    session    ${REST_CONTEXT_VTNS}/${vtn_name}/vbridges/${vBridge_name}/interfaces/${interface_name}/portmap    data=${json_data}    headers=${HEADERS}
 266     Should Be Equal As Strings    ${resp.status_code}    200
 267
 268 Verify FlowMacAddress
 269     [Arguments]    ${host1}    ${host2}    ${OF_VERSION}
 270     [Documentation]    Verify the source and destination mac address.
 271     Run Keyword If    '${OF_VERSION}' == 'OF10'    Verify Flows On OpenFlow    ${host1}    ${host2}    ${DUMPFLOWS_OF10}
 272     ...    ELSE    VerifyFlowsOnOpenFlow    ${host1}    ${host2}    ${DUMPFLOWS_OF13}
 273
 274 Verify Flows On OpenFlow
 275     [Arguments]    ${host1}    ${host2}    ${DUMPFLOWS}
 276     [Documentation]    Verify the mac addresses on the specified open flow.
 277     ${booleanValue}=    Run Keyword And Return Status    Verify macaddress    ${host1}    ${host2}    ${DUMPFLOWS}
 278     Should Be Equal As Strings    ${booleanValue}    True
 279
 280 Verify RemovedFlowMacAddress
 281     [Arguments]    ${host1}    ${host2}    ${OF_VERSION}
 282     [Documentation]    Verify the removed source and destination mac address.
 283     Run Keyword If    '${OF_VERSION}' == 'OF10'    Verify Removed Flows On OpenFlow    ${host1}    ${host2}    ${DUMPFLOWS_OF10}
 284     ...    ELSE    VerifyRemovedFlowsOnOpenFlow    ${host1}    ${host2}    ${DUMPFLOWS_OF13}
 285
 286 Verify Removed Flows On OpenFlow
 287     [Arguments]    ${host1}    ${host2}    ${DUMPFLOWS}
 288     [Documentation]    Verify the removed mac addresses on the specified open flow.
 289     ${booleanValue}=    Run Keyword And Return Status    Verify macaddress    ${host1}    ${host2}    ${DUMPFLOWS}
 290     Should Not Be Equal As Strings    ${booleanValue}    True
 291
 292 Verify macaddress
 293     [Arguments]    ${host1}    ${host2}    ${DUMPFLOWS}
 294     [Documentation]    Verify the source and destination mac address after ping in the dumpflows
 295     write    ${host1} ifconfig -a | grep HWaddr
 296     ${sourcemacaddr}    Read Until    mininet>
 297     ${macaddress}=    Split String    ${sourcemacaddr}    ${SPACE}
 298     ${sourcemacaddr}=    Get from List    ${macaddress}    ${index}
 299     ${sourcemacaddress}=    Convert To Lowercase    ${sourcemacaddr}
 300     write    ${host2} ifconfig -a | grep HWaddr
 301     ${destmacaddr}    Read Until    mininet>
 302     ${macaddress}=    Split String    ${destmacaddr}    ${SPACE}
 303     ${destmacaddr}=    Get from List    ${macaddress}    ${index}
 304     ${destmacaddress}=    Convert To Lowercase    ${destmacaddr}
 305     write    ${DUMPFLOWS}
 306     ${result}    Read Until    mininet>
 307     Should Contain    ${result}    ${sourcemacaddress}
 308     Should Contain    ${result}    ${destmacaddress}
 309
 310 Add a flowcondition
 311     [Arguments]    ${cond_name}    ${flowcond_data}
 312     [Documentation]    Create a flowcondition for a interface of a vbridge
 313     ${json_data}=    json.dumps    ${flowcond_data}
 314     ${resp}=    RequestsLibrary.Put Request    session    ${REST_CONTEXT}/flowconditions/${cond_name}    data=${json_data}    headers=${HEADERS}
 315     Should Be Equal As Strings    ${resp.status_code}    201
 316
 317 Delete a flowcondition
 318     [Arguments]    ${cond_name}
 319     [Documentation]    Delete a flowcondition for a interface of a vbridge
 320     ${resp}=    RequestsLibrary.Delete Request    session    ${REST_CONTEXT}/flowconditions/${cond_name}
 321     Should Be Equal As Strings    ${resp.status_code}    200
 322
 323 Add a flowfilter
 324     [Arguments]    ${vtn_name}    ${vBridge_name}    ${interface_name}    ${flowfilter_data}    ${ff_index}
 325     [Documentation]    Create a flowfilter for a vtn
 326     ${resp}=    RequestsLibrary.Put Request    session    ${REST_CONTEXT_VTNS}/${vtn_name}/vbridges/${vBridge_name}/interfaces/${interface_name}/flowfilters/IN/${ff_index}    data=${flowfilter_data}    headers=${HEADERS}
 327     Should Be Equal As Strings    ${resp.status_code}    201
 328
 329 Add a flowfilter_vtn
 330     [Arguments]    ${vtn_name}    ${flowfilter_data}    ${ff_index}
 331     [Documentation]    Create a flowfilter for a vtn
 332     ${resp}=    RequestsLibrary.Put Request    session    ${REST_CONTEXT_VTNS}/${vtn_name}/flowfilters/${ff_index}    data=${flowfilter_data}    headers=${HEADERS}
 333     Should Be Equal As Strings    ${resp.status_code}    201
 334
 335 Add a flowfilter_vbr
 336     [Arguments]    ${vtn_name}    ${vBridge_name}    ${flowfilter_data}    ${ff_index}
 337     [Documentation]    Create a flowfilter for a vbr
 338     ${resp}=    RequestsLibrary.Put Request    session    ${REST_CONTEXT_VTNS}/${vtn_name}/vbridges/${vBridge_name}/flowfilters/IN/${ff_index}    data=${flowfilter_data}    headers=${HEADERS}
 339     Should Be Equal As Strings    ${resp.status_code}    201
 340
 341 Update a flowfilter
 342     [Arguments]    ${vtn_name}    ${vBridge_name}    ${interface_name}    ${flowfilter_data}    ${ff_index}
 343     [Documentation]    Create a flowfilter for a vtn
 344     ${resp}=    RequestsLibrary.Put Request    session    ${REST_CONTEXT_VTNS}/${vtn_name}/vbridges/${vBridge_name}/interfaces/${interface_name}/flowfilters/IN/${ff_index}    data=${flowfilter_data}    headers=${HEADERS}
 345     Should Be Equal As Strings    ${resp.status_code}    200
 346
 347 Add a flowfilter for drop
 348     [Arguments]    ${vtn_name}    ${vBridge_name}    ${interface_name}    ${flowfilter_data}    ${ff_index}
 349     [Documentation]    Create a flowfilter for a vtn
 350     ${resp}=    RequestsLibrary.Put Request    session    ${REST_CONTEXT_VTNS}/${vtn_name}/vbridges/${vBridge_name}/interfaces/${interface_name}/flowfilters/IN/${ff_index}    data=${flowfilter_data}    headers=${HEADERS}
 351     Should Be Equal As Strings    ${resp.status_code}    200
 352
 353 Verify Flow Entry for Inet Flowfilter
 354     [Documentation]    Verify switch flow entry using flowfilter for a vtn
 355     ${booleanValue}=    Run Keyword And Return Status    Verify Actions on Flow Entry
 356     Should Not Be Equal As Strings    ${booleanValue}    True
 357
 358 Verify Removed Flow Entry for Inet Drop Flowfilter
 359     [Documentation]    Verify removed switch flow entry using flowfilter drop for a vtn
 360     ${booleanValue}=    Run Keyword And Return Status    Verify Actions on Flow Entry
 361     Should Be Equal As Strings    ${booleanValue}    True
 362
 363 Verify Actions on Flow Entry
 364     write    ${DUMPFLOWS_OF13}
 365     ${result}    Read Until    mininet>
 366     : FOR    ${flowElement}    IN    @{FLOWELMENTS}
 367     \    should Contain    ${result}    ${flowElement}