csit/libraries/controller/DnbCommons.robot

   1 *** Settings ***
   2 Documentation     DOMNotificationBroker testing: Common keywords
   3 ...
   4 ...               Copyright (c) 2017 Cisco Systems, Inc. and others. All rights reserved.
   5 ...
   6 ...               This program and the accompanying materials are made available under the
   7 ...               terms of the Eclipse Public License v1.0 which accompanies this distribution,
   8 ...               and is available at http://www.eclipse.org/legal/epl-v10.html
   9 Library           Collections
  10 Resource          ${CURDIR}/../MdsalLowlevel.robot
  11 Resource          ${CURDIR}/../ScalarClosures.robot
  12 Resource          ${CURDIR}/../WaitUtils.robot
  13
  14 *** Variables ***
  15 ${DNB_PUBLISHER_SUBSCRIBER_PAIR_RATE}    ${5000}
  16 ${DNB_PUBLISHER_LISTENER_PREFIX}    working-pair-
  17 ${DNB_TESTED_MEMBER_INDEX}    1
  18
  19 *** Keywords ***
  20 Dom_Notification_Broker_Test_Templ
  21     [Arguments]    ${total_notification_rate}    ${test_duration_in_seconds}
  22     [Documentation]    Test case template. Input parameter ${total_notification_rate} determines, how many publisher/subscriber
  23     ...    pais take part in the test case. For every ${DNB_PUBLISHER_SUBSCRIBER_PAIR_RATE} one pair is created.
  24     ...    The test case itself firstly subscribe listeners, then run publishers and at the end unsubscribe listeners
  25     ...    and check achieved rates.
  26     BuiltIn.Log    Overall requested rate: ${total_notification_rate}, test duration: ${test_duration_in_seconds} seconds.
  27     WaitUtils.WU_Setup
  28     ${count} =    BuiltIn.Set_variable    ${0}
  29     FOR    ${suffix}    IN RANGE    ${DNB_PUBLISHER_SUBSCRIBER_PAIR_RATE}    ${total_notification_rate}+1    ${DNB_PUBLISHER_SUBSCRIBER_PAIR_RATE}
  30         ${count} =    BuiltIn.Evaluate    ${count}+1
  31         MdsalLowlevel.Subscribe_Ynl    ${DNB_TESTED_MEMBER_INDEX}    ${DNB_PUBLISHER_LISTENER_PREFIX}${count}
  32     END
  33     ${count} =    BuiltIn.Convert_To_Integer    ${count}
  34     FOR    ${index}    IN RANGE    1    ${count}+1
  35         MdsalLowlevel.Start_Publish_Notifications    ${DNB_TESTED_MEMBER_INDEX}    ${DNB_PUBLISHER_LISTENER_PREFIX}${index}    ${test_duration_in_seconds}    ${DNB_PUBLISHER_SUBSCRIBER_PAIR_RATE}
  36     END
  37     ${getter} =    ScalarClosures.Closure_From_Keyword_And_Arguments    Get_Notifications_Active_Status    ${DNB_TESTED_MEMBER_INDEX}    ${count}
  38     ${validator} =    ScalarClosures.Closure_From_Keyword_And_Arguments    Check_Notifications_Active_Status    data_holder
  39     ${validation_timeout} =    BuiltIn.Evaluate    ${test_duration_in_seconds}+${60}
  40     WaitUtils.Wait_For_Getter_Failure_Or_Stateless_Validator_Pass    timeout=${validation_timeout}    period=15s    getter=${getter}    stateless_validator=${validator}
  41     ${sum_local_number}    BuiltIn.Set_Variable    ${0}
  42     ${low_limit_pair_rate} =    BuiltIn.Evaluate    0.9*${DNB_PUBLISHER_SUBSCRIBER_PAIR_RATE}
  43     ${high_limit_pair_rate} =    BuiltIn.Evaluate    1.1*${DNB_PUBLISHER_SUBSCRIBER_PAIR_RATE}
  44     FOR    ${index}    IN RANGE    1    ${count}+1
  45         ${all_not}    ${id_not}    ${err_not}    ${local_number} =    MdsalLowlevel.Unsubscribe_Ynl    ${DNB_TESTED_MEMBER_INDEX}
  46         ...    ${DNB_PUBLISHER_LISTENER_PREFIX}${index}
  47         BuiltIn.Should_Be_Equal_As_Numbers    ${err_not}    ${0}
  48         BuiltIn.Should_Not_Be_Equal_As_Numbers    ${local_number}    ${0}
  49         BuiltIn.Should_Be_Equal_As_Numbers    ${id_not}    ${local_number}
  50         ${rate} =    BuiltIn.Evaluate    ${local_number}/${test_duration_in_seconds}
  51         BuiltIn.Should_Be_True    ${rate} > ${low_limit_pair_rate}
  52         BuiltIn.Should_Be_True    ${rate} < ${high_limit_pair_rate}
  53         ${sum_local_number} =    BuiltIn.Evaluate    ${sum_local_number}+${local_number}
  54     END
  55     ${final_rate} =    BuiltIn.Evaluate    ${sum_local_number}/${test_duration_in_seconds}
  56     ${low_limit_final_rate} =    BuiltIn.Evaluate    0.9*${total_notification_rate}
  57     ${high_limit_final_rate} =    BuiltIn.Evaluate    1.1*${total_notification_rate}
  58     BuiltIn.Should_Be_True    ${final_rate} > ${low_limit_final_rate}
  59     BuiltIn.Should_Be_True    ${final_rate} < ${high_limit_final_rate}
  60
  61 Get_Notifications_Active_Status
  62     [Arguments]    ${node_to_ask}    ${nr_pairs}
  63     ${active_list} =    BuiltIn.Create_List
  64     FOR    ${index}    IN RANGE    1    ${nr_pairs}+1
  65         ${active}    ${publ_count}    ${last_error}    MdsalLowlevel.Check_Publish_Notifications    ${node_to_ask}    ${DNB_PUBLISHER_LISTENER_PREFIX}${index}
  66         Collections.Append_To_List    ${active_list}    ${active}
  67         BuiltIn.Should_Be_Equal    ${EMPTY}    ${last_error}
  68     END
  69     BuiltIn.Return_From_Keyword    ${active_list}
  70
  71 Check_Notifications_Active_Status
  72     [Arguments]    ${active_list}
  73     FOR    ${active}    IN    @{active_list}
  74         BuiltIn.Should_Be_Equal    ${False}    ${active}
  75     END