csit/suites/bgpcep/bgpclustering/singlepeer_pc_shm_300kroutes.robot

   1 *** Settings ***
   2 Documentation     BGP performance of ingesting from 1 iBGP peer, data change counter is NOT used.
   3 ...
   4 ...               Copyright (c) 2015-2017 Cisco Systems, Inc. and others. All rights reserved.
   5 ...
   6 ...               This program and the accompanying materials are made available under the
   7 ...               terms of the Eclipse Public License v1.0 which accompanies this distribution,
   8 ...               and is available at http://www.eclipse.org/legal/epl-v10.html
   9 ...
  10 ...               This suite uses play.py as single iBGP peer which talks to
  11 ...               single controller in three node cluster configuration.
  12 ...               Test suite checks changes of the the example-ipv4-topology on all nodes.
  13 ...               RIB is not examined.
  14 ...
  15 ...               singlepeer_pc_shm_300kroutes:
  16 ...               pc - prefix counting
  17 ...               shm - shard monitoring (during the process of prefix advertizing)
  18 Suite Setup       PrefixcountKeywords.Setup_Everything
  19 Suite Teardown    PrefixcountKeywords.Teardown_Everything
  20 Test Setup        SetupUtils.Setup_Test_With_Logging_And_Fast_Failing
  21 Test Teardown     SetupUtils.Teardown_Test_Show_Bugs_And_Start_Fast_Failing_If_Test_Failed
  22 Library           SSHLibrary    timeout=10s
  23 Library           RequestsLibrary
  24 Resource          ${CURDIR}/../../../variables/Variables.robot
  25 Resource          ${CURDIR}/../../../libraries/BGPSpeaker.robot
  26 Resource          ${CURDIR}/../../../libraries/BGPcliKeywords.robot
  27 Resource          ${CURDIR}/../../../libraries/FailFast.robot
  28 Resource          ${CURDIR}/../../../libraries/KillPythonTool.robot
  29 Resource          ${CURDIR}/../../../libraries/PrefixCounting.robot
  30 Resource          ${CURDIR}/../../../libraries/SetupUtils.robot
  31 Resource          ${CURDIR}/../../../libraries/ClusterManagement.robot
  32 Resource          ${CURDIR}/../../../libraries/SSHKeywords.robot
  33 Resource          ${CURDIR}/../../../libraries/TemplatedRequests.robot
  34 Resource          ${CURDIR}/PrefixcountKeywords.robot
  35
  36 *** Variables ***
  37 ${COUNT}          300000
  38
  39 *** Test Cases ***
  40 Get Example Bgp Rib Owner
  41     [Documentation]    Find an odl node which is able to accept incomming connection. It is a node, which is the owner of bgp rib, as it is a singleton service.
  42     ...    This node should be used for bgp peer to connect to.
  43     ${rib_owner}    ${rib_candidates}=    ClusterManagement.Get_Owner_And_Successors_For_device    example-bgp-rib    org.opendaylight.mdsal.ServiceEntityType    1
  44     BuiltIn.Set_Suite_Variable    ${rib_owner}    ${rib_owner}
  45     BuiltIn.Set_Suite_Variable    ${rib_owner_node_id}    ${ODL_SYSTEM_${rib_owner}_IP}
  46     ${session} =    ClusterManagement.Resolve_Http_Session_For_Member    ${rib_owner}
  47     BuiltIn.Set_Suite_Variable    ${config_session}    ${session}
  48
  49 Check_For_Empty_Ipv4_Topology_Before_Talking
  50     [Documentation]    Wait for ${EXAMPLE_IPV4_TOPOLOGY} to come up and empty. Give large timeout for case when BGP boots slower than restconf.
  51     [Tags]    critical
  52     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
  53     FOR    ${member_index}    IN    @{pc_all_indices}
  54         BuiltIn.Wait_Until_Keyword_Succeeds    ${INITIAL_RESTCONF_TIMEOUT}    1s    PrefixCounting.Check_Ipv4_Topology_Is_Empty    session=${operational_${member_index}}    topology=${EXAMPLE_IPV4_TOPOLOGY}
  55     END
  56
  57 Reconfigure_ODL_To_Accept_Connection
  58     [Documentation]    Configure BGP peer module with initiate-connection set to false.
  59     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
  60     &{mapping}    BuiltIn.Create_Dictionary    DEVICE_NAME=${DEVICE_NAME}    BGP_NAME=${BGP_PEER_NAME}    IP=${TOOLS_SYSTEM_IP}    HOLDTIME=${HOLDTIME}    PEER_PORT=${BGP_TOOL_PORT}
  61     ...    INITIATE=false    BGP_RIB=${RIB_INSTANCE}    PASSIVE_MODE=true    BGP_RIB_OPENCONFIG=${PROTOCOL_OPENCONFIG}
  62     TemplatedRequests.Put_As_Json_Templated    ${BGP_VARIABLES_FOLDER}    mapping=${mapping}    session=${config_session}
  63     [Teardown]    SetupUtils.Teardown_Test_Show_Bugs_If_Test_Failed
  64
  65 Start_Talking_BGP_Speaker
  66     [Documentation]    Start Python speaker to connect to ODL.
  67     PrefixcountKeywords.Start_Bgp_Peer_And_Verify_Connected    connection_retries=${3}
  68
  69 Wait_For_Stable_Talking_Ipv4_Topology
  70     [Documentation]    Wait until ${EXAMPLE_IPV4_TOPOLOGY} becomes stable. This is done by checking stability of prefix count as seen from all nodes.
  71     FOR    ${member_index}    IN    @{pc_all_indices}
  72         PrefixCounting.Wait_For_Ipv4_Topology_Prefixes_To_Become_Stable    timeout=${bgp_filling_timeout}    period=${CHECK_PERIOD}    repetitions=${REPETITIONS}    excluded_count=0    session=${operational_${member_index}}
  73         ...    topology=${EXAMPLE_IPV4_TOPOLOGY}    shards_list=${SHARD_MONITOR_LIST}    shards_details=${init_shard_details}
  74     END
  75
  76 Check_Talking_Ipv4_Topology_Count
  77     [Documentation]    Count the routes in ${EXAMPLE_IPV4_TOPOLOGY} and fail if the count is not correct as seen from node 1.
  78     [Tags]    critical
  79     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
  80     FOR    ${member_index}    IN    @{pc_all_indices}
  81         PrefixCounting.Check_Ipv4_Topology_Count    ${COUNT}    session=${operational_${member_index}}    topology=${EXAMPLE_IPV4_TOPOLOGY}
  82     END
  83
  84 Kill_Talking_BGP_Speaker
  85     [Documentation]    Abort the Python speaker. Also, attempt to stop failing fast.
  86     [Tags]    critical
  87     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
  88     BGPSpeaker.Kill_BGP_Speaker
  89     FailFast.Do_Not_Fail_Fast_From_Now_On
  90
  91 Wait_For_Stable_Ipv4_Topology_After_Listening
  92     [Documentation]    Wait until ${EXAMPLE_IPV4_TOPOLOGY} becomes stable again as seen from node 1.
  93     [Tags]    critical
  94     FOR    ${member_index}    IN    @{pc_all_indices}
  95         PrefixCounting.Wait_For_Ipv4_Topology_Prefixes_To_Become_Stable    timeout=${bgp_filling_timeout}    period=${CHECK_PERIOD}    repetitions=${REPETITIONS}    excluded_count=${COUNT}    session=${operational_${member_index}}
  96         ...    topology=${EXAMPLE_IPV4_TOPOLOGY}
  97     END
  98
  99 Check_For_Empty_Ipv4_Topology_After_Listening
 100     [Documentation]    Example-ipv4-topology should be empty now as seen from node 1.
 101     [Tags]    critical
 102     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 103     FOR    ${member_index}    IN    @{pc_all_indices}
 104         PrefixCounting.Check_Ipv4_Topology_Is_Empty    session=${operational_${member_index}}    topology=${EXAMPLE_IPV4_TOPOLOGY}
 105     END
 106
 107 Delete_Bgp_Peer_Configuration
 108     [Documentation]    Revert the BGP configuration to the original state: without any configured peers.
 109     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 110     &{mapping}    BuiltIn.Create_Dictionary    DEVICE_NAME=${DEVICE_NAME}    BGP_NAME=${BGP_PEER_NAME}    IP=${TOOLS_SYSTEM_IP}    HOLDTIME=${HOLDTIME}    PEER_PORT=${BGP_TOOL_PORT}
 111     ...    INITIATE=false    BGP_RIB=${RIB_INSTANCE}    BGP_RIB_OPENCONFIG=${PROTOCOL_OPENCONFIG}
 112     TemplatedRequests.Delete_Templated    ${BGP_VARIABLES_FOLDER}    mapping=${mapping}    session=${config_session}