csit/suites/bgpcep/bgpingest/manypeers_changecount.robot

   1 *** Settings ***
   2 Documentation     BGP performance of ingesting from many iBGP peers, data change counter is used.
   3 ...
   4 ...               Copyright (c) 2018 Cisco Systems, Inc. and others. All rights reserved.
   5 ...
   6 ...               This program and the accompanying materials are made available under the
   7 ...               terms of the Eclipse Public License v1.0 which accompanies this distribution,
   8 ...               and is available at http://www.eclipse.org/legal/epl-v10.html
   9 ...
  10 ...
  11 ...               This suite uses play.py processes as iBGP peers.
  12 ...               This is analogue of single peer performance suite, which uses many peers.
  13 ...               Each peer is of ibgp type, and they contribute to the same example-bgp-rib,
  14 ...               and thus to the same single example-ipv4-topology.
  15 ...               The suite only looks at example-ipv4-topology, so RIB is not examined.
  16 ...
  17 ...               This suite requires odl-bgpcep-data-change-counter to be installed so
  18 ...               make sure it is added to "install-features" of any jobs that are going to invoke it.
  19 ...               Use the other version of the suite (manypeers_prefixcount.robot) if the feature does not work.
  20 ...
  21 ...               The suite consists of two halves, differing on which side initiates BGP connection.
  22 ...               Data change counter is a lightweight way to detect "work is being done".
  23 ...               WaitUtils provide a nice Keyword to wait for stability, but it needs
  24 ...               initial value, that is why Store_Change_Count appears just before work-inducing action.
  25 ...               The time for Wait_For_Stable_* cases to finish is the main performance metric.
  26 ...               After waiting for stability is done, full check on number of prefixes present is performed.
  27 ...
  28 ...               TODO: Currently, if a bug causes zero increase of data changes,
  29 ...               affected test cases will wait for max time. Reconsider.
  30 ...               If zero increase is allowed as stable, higher number of repetitions should be required.
  31 ...
  32 ...               ODL distinguishes peers by their IP addresses.
  33 ...               Currently, this suite requires python utils to be started on ODL System,
  34 ...               to guarantee IP address block is available for them to bind to.
  35 ...               TODO: Figure out how to use Docker and docker IP pool available in RelEng.
  36 ...
  37 ...               Currently, 127.0.0.1 is hardcoded as the first peer address to use.
  38 ...               TODO: Figure out how to make it configurable.
  39 ...               As peer IP adresses are set incrementally, we need ipaddr to be used in Robot somehow.
  40 ...
  41 ...               Brief description how to configure BGP peer can be found here:
  42 ...               https://wiki.opendaylight.org/view/BGP_LS_PCEP:User_Guide#BGP_Peer
  43 ...               http://docs.opendaylight.org/en/stable-boron/user-guide/bgp-user-guide.html#bgp-peering
  44 ...
  45 ...               TODO: Is there a need for version of this suite where ODL connects to pers?
  46 ...               Note that configuring ODL is slow, which may affect measured performance singificantly.
  47 ...               Advanced TODO: Give manager ability to start pushing on trigger long after connections are established.
  48 Suite Setup       Setup_Everything
  49 Suite Teardown    Teardown_Everything
  50 Test Setup        SetupUtils.Setup_Test_With_Logging_And_Fast_Failing
  51 Test Teardown     SetupUtils.Teardown_Test_Show_Bugs_And_Start_Fast_Failing_If_Test_Failed
  52 Library           DateTime
  53 Library           RequestsLibrary
  54 Library           SSHLibrary    timeout=10s
  55 Resource          ../../../libraries/BGPcliKeywords.robot
  56 Resource          ../../../libraries/BGPSpeaker.robot
  57 Resource          ../../../libraries/ChangeCounter.robot
  58 Resource          ../../../libraries/CompareStream.robot
  59 Resource          ../../../libraries/FailFast.robot
  60 Resource          ../../../libraries/KarafKeywords.robot
  61 Resource          ../../../libraries/KillPythonTool.robot
  62 Resource          ../../../libraries/PrefixCounting.robot
  63 Resource          ../../../libraries/SetupUtils.robot
  64 Resource          ../../../libraries/SSHKeywords.robot
  65 Resource          ../../../libraries/TemplatedRequests.robot
  66 Resource          ../../../libraries/Utils.robot
  67 Resource          ../../../variables/Variables.robot
  68
  69 *** Variables ***
  70 ${BGP_TOOL_LOG_LEVEL}    info
  71 ${BGP_VARIABLES_FOLDER}    ${CURDIR}/../../../variables/bgpuser/
  72 ${CHECK_PERIOD}    60
  73 ${CHECK_PERIOD_CHANGE_COUNT}    ${CHECK_PERIOD}
  74 ${CHECK_PERIOD_CHANGE_COUNT_MANY}    ${CHECK_PERIOD_CHANGE_COUNT}
  75 ${COUNT}          600000
  76 ${COUNT_CHANGE_COUNT}    ${COUNT}
  77 ${COUNT_CHANGE_COUNT_MANY}    ${COUNT_CHANGE_COUNT}
  78 ${FIRST_PEER_IP}    127.0.0.1
  79 ${HOLDTIME}       180
  80 ${HOLDTIME_CHANGE_COUNT}    ${HOLDTIME}
  81 ${HOLDTIME_CHANGE_COUNT_MANY}    ${HOLDTIME_CHANGE_COUNT}
  82 ${KARAF_LOG_LEVEL}    INFO
  83 ${KARAF_BGPCEP_LOG_LEVEL}    ${KARAF_LOG_LEVEL}
  84 ${KARAF_PROTOCOL_LOG_LEVEL}    ${KARAF_BGPCEP_LOG_LEVEL}
  85 ${MULTIPLICITY}    2    # May be increased after Bug 4488 is fixed.
  86 ${MULTIPLICITY_CHANGE_COUNT}    ${MULTIPLICITY}
  87 ${MULTIPLICITY_CHANGE_COUNT_MANY}    ${MULTIPLICITY_CHANGE_COUNT}
  88 ${PEER_GROUP}     internal-neighbors
  89 ${REPETITIONS}    1    # Should be increased depending on multiplicity.
  90 ${REPETITIONS_CHANGE_COUNT}    ${REPETITIONS}
  91 ${REPETITIONS_CHANGE_COUNT_MANY}    ${REPETITIONS_CHANGE_COUNT}
  92 ${TEST_DURATION_MULTIPLIER}    1
  93 ${TEST_DURATION_MULTIPLIER_CHANGE_COUNT}    ${TEST_DURATION_MULTIPLIER}
  94 ${TEST_DURATION_MULTIPLIER_CHANGE_COUNT_MANY}    ${TEST_DURATION_MULTIPLIER_CHANGE_COUNT}
  95 ${RIB_INSTANCE}    example-bgp-rib
  96 ${PROTOCOL_OPENCONFIG}    ${RIB_INSTANCE}
  97 ${DEVICE_NAME}    controller-config
  98 # TODO: Option names can be better.
  99 ${last_change_count_many}    1
 100
 101 *** Test Cases ***
 102 Check_For_Empty_Ipv4_Topology_Before_Talking
 103     [Documentation]    Wait for example-ipv4-topology to come up and empty. Give large timeout for case when BGP boots slower than restconf.
 104     [Tags]    critical
 105     # TODO: Choose which tags to assign and make sure they are assigned correctly.
 106     BuiltIn.Wait_Until_Keyword_Succeeds    120s    1s    PrefixCounting.Check_Ipv4_Topology_Is_Empty
 107
 108 Reconfigure_ODL_To_Accept_Connections
 109     [Documentation]    Configure BGP peer modules with initiate-connection set to false.
 110     ...    In Versions Fluorine and above, it sets peer-group as template, and than sets all neighbors using it.
 111     CompareStream.Run_Keyword_If_At_Least_Fluorine    Configure_Peer_Group
 112     FOR    ${index}    IN RANGE    1    ${MULTIPLICITY_CHANGE_COUNT_MANY}+1
 113         ${peer_name} =    BuiltIn.Set_Variable    example-bgp-peer-${index}
 114         ${peer_ip} =    BuiltIn.Evaluate    str(ipaddr.IPAddress('${FIRST_PEER_IP}') + ${index} - 1)    modules=ipaddr
 115         &{mapping}    Create Dictionary    DEVICE_NAME=${DEVICE_NAME}    BGP_NAME=${peer_name}    IP=${peer_ip}    HOLDTIME=${HOLDTIME_CHANGE_COUNT_MANY}
 116         ...    PEER_PORT=${BGP_TOOL_PORT}    INITIATE=false    BGP_RIB=${RIB_INSTANCE}    PASSIVE_MODE=true    BGP_RIB_OPENCONFIG=${PROTOCOL_OPENCONFIG}
 117         ...    RIB_INSTANCE_NAME=${RIB_INSTANCE}    PEER_GROUP_NAME=${PEER_GROUP}    RR_CLIENT=false
 118         CompareStream.Run_Keyword_If_At_Least_Fluorine    TemplatedRequests.Put_As_Xml_Templated    ${BGP_VARIABLES_FOLDER}${/}bgp_peer_group    mapping=${mapping}
 119         CompareStream.Run_Keyword_If_Less_Than_Fluorine    TemplatedRequests.Put_As_Xml_Templated    ${BGP_VARIABLES_FOLDER}${/}bgp_peer    mapping=${mapping}
 120         # FIXME: Add testcase to change bgpcep and protocol log levels, when a Keyword that does it without messing with current connection is ready.
 121     END
 122
 123 Reconfigure_Data_Change_Counter
 124     [Documentation]    Configure data change counter to count transactions in example-ipv4-topology instead of example-linkstate-topology.
 125     ChangeCounter.Reconfigure_Topology_Name    example-ipv4-topology
 126
 127 Verify_For_Data_Change_Counter_Ready
 128     [Documentation]    Data change counter might have been slower to start than ipv4 topology, wait for it.
 129     BuiltIn.Wait_Until_Keyword_Succeeds    5s    1s    ChangeCounter.Get_Change_Count
 130
 131 Change_Karaf_Logging_Levels
 132     [Documentation]    We may want to set more verbose logging here after configuration is done.
 133     KarafKeywords.Set_Bgpcep_Log_Levels    bgpcep_level=${KARAF_BGPCEP_LOG_LEVEL}    protocol_level=${KARAF_PROTOCOL_LOG_LEVEL}
 134
 135 Start_Talking_BGP_Manager
 136     [Documentation]    Start Python manager to connect speakers to ODL.
 137     Store_Change_Count
 138     # Myport value is needed for checking whether connection at precise port was established.
 139     BGPSpeaker.Start_BGP_Manager    --amount=${COUNT_CHANGE_COUNT_MANY} --multiplicity=${MULTIPLICITY_CHANGE_COUNT_MANY} --myip=${FIRST_PEER_IP} --myport=${BGP_TOOL_PORT} --peerip=${ODL_SYSTEM_IP} --peerport=${ODL_BGP_PORT}
 140
 141 Wait_For_Stable_Talking_Ipv4_Topology
 142     [Documentation]    Wait until example-ipv4-topology becomes stable. This is done by checking stability of the change counter.
 143     ChangeCounter.Wait_For_Change_Count_To_Become_Stable    timeout=${bgp_filling_timeout}    period=${CHECK_PERIOD_CHANGE_COUNT_MANY}    repetitions=${REPETITIONS_CHANGE_COUNT_MANY}    count_to_overcome=${last_change_count_many}
 144
 145 Check_Talking_Ipv4_Topology_Count
 146     [Documentation]    Count the routes in example-ipv4-topology and fail if the count is not correct.
 147     [Tags]    critical
 148     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 149     PrefixCounting.Check_Ipv4_Topology_Count    ${COUNT_CHANGE_COUNT_MANY}
 150
 151 Kill_Talking_BGP_Speakers
 152     [Documentation]    Abort the Python speakers. Also, attempt to stop failing fast.
 153     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 154     Store_Change_Count
 155     BGPSpeaker.Kill_BGP_Speaker
 156     BGPcliKeywords.Store_File_To_Workspace    play.py.out    manypeers_cc_play.log
 157     FailFast.Do_Not_Fail_Fast_From_Now_On
 158     # NOTE: It is still possible to remain failing fast, if both previous and this test have failed.
 159     [Teardown]    SetupUtils.Teardown_Test_Show_Bugs_If_Test_Failed
 160
 161 Wait_For_Stable_Ipv4_Topology_After_Talking
 162     [Documentation]    Wait until example-ipv4-topology becomes stable again.
 163     [Tags]    critical
 164     ChangeCounter.Wait_For_Change_Count_To_Become_Stable    timeout=${bgp_filling_timeout}    period=${CHECK_PERIOD_CHANGE_COUNT_MANY}    repetitions=${REPETITIONS_CHANGE_COUNT_MANY}    count_to_overcome=${last_change_count_many}
 165
 166 Check_For_Empty_Ipv4_Topology_After_Talking
 167     [Documentation]    Example-ipv4-topology should be empty now.
 168     [Tags]    critical
 169     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 170     PrefixCounting.Check_Ipv4_Topology_Is_Empty
 171
 172 Restore_Karaf_Logging_Levels
 173     [Documentation]    Set logging on bgpcep and protocol to the global value.
 174     KarafKeywords.Set_Bgpcep_Log_Levels    bgpcep_level=${KARAF_LOG_LEVEL}    protocol_level=${KARAF_LOG_LEVEL}
 175
 176 Restore_Data_Change_Counter_Configuration
 177     [Documentation]    Configure data change counter back to count transactions affecting example-linkstate-topology.
 178     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 179     ChangeCounter.Reconfigure_Topology_Name    example-linkstate-topology
 180
 181 Delete_Bgp_Peer_Configuration
 182     [Documentation]    Revert the BGP configuration to the original state: without any configured peers.
 183     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 184     # TODO: Is it useful to extract peer naming logic to separate Keyword?
 185     FOR    ${index}    IN RANGE    1    ${MULTIPLICITY_CHANGE_COUNT_MANY}+1
 186         ${peer_name} =    BuiltIn.Set_Variable    example-bgp-peer-${index}
 187         ${peer_ip} =    BuiltIn.Evaluate    str(ipaddr.IPAddress('${FIRST_PEER_IP}') + ${index} - 1)    modules=ipaddr
 188         &{mapping}    BuiltIn.Create_Dictionary    DEVICE_NAME=${DEVICE_NAME}    BGP_NAME=${peer_name}    IP=${peer_ip}    BGP_RIB_OPENCONFIG=${PROTOCOL_OPENCONFIG}
 189         ...    PEER_GROUP_NAME=${PEER_GROUP}    RR_CLIENT=false
 190         CompareStream.Run_Keyword_If_At_Least_Fluorine    TemplatedRequests.Delete_Templated    ${BGP_VARIABLES_FOLDER}${/}bgp_peer_group    mapping=${mapping}
 191         CompareStream.Run_Keyword_If_Less_Than_Fluorine    TemplatedRequests.Delete_Templated    ${BGP_VARIABLES_FOLDER}${/}bgp_peer    mapping=${mapping}
 192     END
 193     CompareStream.Run_Keyword_If_At_Least_Fluorine    Deconfigure_Peer_Group
 194
 195 *** Keywords ***
 196 Setup_Everything
 197     [Documentation]    Setup imported resources, SSH-login to ODL system,
 198     ...    create HTTP session, put Python tool to ODL system.
 199     SetupUtils.Setup_Utils_For_Setup_And_Teardown
 200     TemplatedRequests.Create_Default_Session
 201     ChangeCounter.CC_Setup
 202     PrefixCounting.PC_Setup
 203     KarafKeywords.Open Controller Karaf Console On Background
 204     RequestsLibrary.Create_Session    operational    http://${ODL_SYSTEM_IP}:${RESTCONFPORT}    auth=${AUTH}    timeout=125    max_retries=0
 205     # TODO: Do not include slash in ${OPERATIONAL_TOPO_API}, having it typed here is more readable.
 206     # TODO: Alternatively, create variable in Variables which starts with http.
 207     # Both TODOs would probably need to update every suite relying on current Variables.
 208     SSHLibrary.Set_Default_Configuration    prompt=${ODL_SYSTEM_PROMPT}
 209     SSHLibrary.Open_Connection    ${ODL_SYSTEM_IP}
 210     SSHKeywords.Flexible_Controller_Login
 211     SSHKeywords.Require_Python
 212     SSHKeywords.Assure_Library_Ipaddr    target_dir=.
 213     SSHLibrary.Put_File    ${CURDIR}/../../../../tools/fastbgp/play.py
 214     # Calculate the timeout value based on how many routes are going to be pushed
 215     ${period} =    DateTime.Convert_Time    ${CHECK_PERIOD_CHANGE_COUNT_MANY}    result_format=number
 216     ${timeout} =    BuiltIn.Evaluate    ${TEST_DURATION_MULTIPLIER_CHANGE_COUNT_MANY} * (${COUNT_CHANGE_COUNT_MANY} * 3.0 / 10000 + ${period} * (${REPETITIONS_CHANGE_COUNT_MANY} + 1)) + 20
 217     Builtin.Set_Suite_Variable    ${bgp_filling_timeout}    ${timeout}
 218     ${timeout} =    BuiltIn.Evaluate    ${TEST_DURATION_MULTIPLIER_CHANGE_COUNT_MANY} * (${COUNT_CHANGE_COUNT_MANY} * 2.0 / 10000 + ${period} * (${REPETITIONS_CHANGE_COUNT_MANY} + 1)) + 20
 219     Builtin.Set_Suite_Variable    ${bgp_emptying_timeout}    ${timeout}
 220     KarafKeywords.Execute_Controller_Karaf_Command_On_Background    log:set ${KARAF_LOG_LEVEL}
 221
 222 Teardown_Everything
 223     [Documentation]    Make sure Python tool was killed and tear down imported Resources.
 224     # Environment issue may have dropped the SSH connection, but we do not want Teardown to fail.
 225     BuiltIn.Run_Keyword_And_Ignore_Error    KillPythonTool.Search_And_Kill_Remote_Python    'play\.py'
 226     BuiltIn.Run_Keyword_And_Ignore_Error    Utils.Get_Sysstat_Statistics
 227     RequestsLibrary.Delete_All_Sessions
 228     SSHLibrary.Close_All_Connections
 229
 230 Store_Change_Count
 231     [Documentation]    Get the count of changes from BGP change counter. Ignore error or store the value.
 232     ${status}    ${count} =    BuiltIn.Run_Keyword_And_Ignore_Error    ChangeCounter.Get_Change_Count
 233     BuiltIn.Run_Keyword_If    '${status}' == 'PASS'    BuiltIn.Set_Suite_Variable    ${last_change_count_many}    ${count}
 234
 235 Configure_Peer_Group
 236     [Documentation]    Configures peer group which is template for all the neighbors which are going
 237     ...    to be configured. Also after PUT, this case verifies presence of peer group within
 238     ...    peer-groups. This test case is specific to versions Fluorine and above.
 239     &{mapping}    Create Dictionary    DEVICE_NAME=${DEVICE_NAME}    HOLDTIME=${HOLDTIME_CHANGE_COUNT_MANY}    PEER_PORT=${BGP_TOOL_PORT}    INITIATE=false    BGP_RIB=${RIB_INSTANCE}
 240     ...    PASSIVE_MODE=true    BGP_RIB_OPENCONFIG=${PROTOCOL_OPENCONFIG}    RIB_INSTANCE_NAME=${RIB_INSTANCE}    PEER_GROUP_NAME=${PEER_GROUP}    RR_CLIENT=false
 241     TemplatedRequests.Put_As_Xml_Templated    ${BGP_VARIABLES_FOLDER}${/}peer_group    mapping=${mapping}
 242     TemplatedRequests.Get_As_Json_Templated    ${BGP_VARIABLES_FOLDER}${/}verify_peer_group    mapping=${mapping}    verify=True
 243
 244 Deconfigure_Peer_Group
 245     [Documentation]    Deconfigures peer group which is template for all the neighbors.
 246     ...    This test case is specific to versions Fluorine and above.
 247     &{mapping}    Create Dictionary    DEVICE_NAME=${DEVICE_NAME}    HOLDTIME=${HOLDTIME_CHANGE_COUNT_MANY}    PEER_PORT=${BGP_TOOL_PORT}    INITIATE=false    BGP_RIB=${RIB_INSTANCE}
 248     ...    PASSIVE_MODE=true    BGP_RIB_OPENCONFIG=${PROTOCOL_OPENCONFIG}    RIB_INSTANCE_NAME=${RIB_INSTANCE}    PEER_GROUP_NAME=${PEER_GROUP}    RR_CLIENT=false
 249     TemplatedRequests.Delete_Templated    ${BGP_VARIABLES_FOLDER}${/}peer_group    mapping=${mapping}